devtools/M4/header.m4

   1 #
   2 # Copyright (c) 1998, 1999, 2014 Proofpoint, Inc. and its suppliers.
   3 #       All rights reserved.
   4 #
   5 # By using this file, you agree to the terms and conditions set
   6 # forth in the LICENSE file which can be found at the top level of
   7 # the sendmail distribution.
   8 #
   9 #
  10 #  Definitions for Makefile construction for sendmail
  11 #
  12 #       $Id: header.m4,v 8.29 2014-01-26 20:40:45 gshapiro Exp $
  13 #
  14 changecom(^A)
  15 undefine(`format')
  16 undefine(`hpux')
  17 undefine(`unix')
  18 ifdef(`pushdef', `',
  19         `errprint(`You need a newer version of M4, at least as new as
  20 System V or GNU')
  21         include(NoSuchFile)')
  22 define(`confABI', `')
  23 define(`confCC', `cc')
  24 define(`confSHELL', `/bin/sh')
  25 define(`confBEFORE', `')
  26 define(`confLIBDIRS', `')
  27 define(`confINCDIRS', `')
  28 define(`confLIBSEARCH', `db bind resolv 44bsd cdb')
  29 define(`confLIBSEARCHPATH', `/lib /usr/lib /usr/shlib')
  30 define(`confSHAREDLIB_EXT', `.so')
  31 define(`confSITECONFIG', `site.config')
  32 define(`confBUILDBIN', `${SRCDIR}/devtools/bin')
  33 define(`confRANLIB', `echo')
  34 define(`PUSHDIVERT', `pushdef(`__D__', divnum)divert($1)')
  35 define(`POPDIVERT', `divert(__D__)popdef(`__D__')')
  36 define(`APPENDDEF', `define(`$1', ifdef(`$1', `$1 $2', `$2'))')
  37 define(`PREPENDDEF', `define(`$1', ifdef(`$1', `$2 $1', `$2'))')