lib/libc/mips/string/bzero.S

   1 /*      $NetBSD: bzero.S,v 1.10 2009/12/14 02:53:52 matt Exp $  */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         ASMSTR("from: @(#)bzero.s       8.1 (Berkeley) 6/4/93")
  41 #else
  42         ASMSTR("$NetBSD: bzero.S,v 1.10 2009/12/14 02:53:52 matt Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 #define _LOCORE         /* XXX not really, just assembly-code source */
  47 #include <machine/endian.h>
  48
  49 #ifdef __ABICALLS__
  50         .abicalls
  51 #endif
  52
  53 /* bzero(s1, n) */
  54
  55 LEAF(bzero)
  56         .set    noreorder
  57         blt             a1, 3*SZREG, smallclr # small amount to clear?
  58         PTR_SUBU        a3, zero, a0    # compute # bytes to word align address
  59         and             a3, a3, SZREG-1
  60         beq             a3, zero, 1f    # skip if word aligned
  61 #if SZREG == 4
  62         PTR_SUBU        a1, a1, a3      # subtract from remaining count
  63         SWHI            zero, 0(a0)     # clear 1, 2, or 3 bytes to align
  64         PTR_ADDU        a0, a0, a3
  65 #endif
  66 #if SZREG == 8
  67         PTR_SUBU        a1, a1, a3      # subtract from remaining count
  68         PTR_ADDU        a0, a0, a3      # align dst to next word
  69         sll             a3, a3, 3       # bits to bytes
  70         li              a2, -1          # make a mask
  71 #if _BYTE_ORDER == _BIG_ENDIAN
  72         REG_SRLV        a2, a2, a3      # we want to keep the MSB bytes
  73 #endif
  74 #if _BYTE_ORDER == _LITTLE_ENDIAN
  75         REG_SLLV        a2, a2, a3      # we want to keep the LSB bytes
  76 #endif
  77         nor             a2, zero, a2    # complement the mask
  78         REG_L           v0, -SZREG(a0)  # load the word to partially clear
  79         and             v0, v0, a2      # clear the bytes
  80         REG_S           v0, -SZREG(a0)  # store it back
  81 #endif
  82 1:
  83         and             v0, a1, SZREG-1 # compute number of words left
  84         PTR_SUBU        a3, a1, v0
  85         move            a1, v0
  86         PTR_ADDU        a3, a3, a0      # compute ending address
  87 2:
  88         PTR_ADDU        a0, a0, SZREG   # clear words
  89         bne             a0, a3, 2b      #  unrolling loop doesnt help
  90         REG_S           zero, -SZREG(a0) # since we are limited by memory speed
  91 smallclr:
  92         ble             a1, zero, 2f
  93         PTR_ADDU        a3, a1, a0      # compute ending address
  94 1:
  95         PTR_ADDU        a0, a0, 1       # clear bytes
  96         bne             a0, a3, 1b
  97         sb              zero, -1(a0)
  98 2:
  99         j               ra
 100         nop
 101 END(bzero)