contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[11])
  14 m4_define([VERSION_MICRO],[0])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl or https://github.com/NLnetLabs/unbound/issues, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=9
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.9.0 had 9:0:1 # add ub_ctx_set_tls
  89 # 1.9.1 had 9:1:1
  90 # 1.9.2 had 9:2:1
  91 # 1.9.3 had 9:3:1
  92 # 1.9.4 had 9:4:1
  93 # 1.9.5 had 9:5:1
  94 # 1.9.6 had 9:6:1
  95 # 1.10.0 had 9:7:1
  96 # 1.10.1 had 9:8:1
  97 # 1.11.0 had 9:9:1
  98
  99 #   Current  -- the number of the binary API that we're implementing
 100 #   Revision -- which iteration of the implementation of the binary
 101 #               API are we supplying?
 102 #   Age      -- How many previous binary API versions do we also
 103 #               support?
 104 #
 105 # If we release a new version that does not change the binary API,
 106 # increment Revision.
 107 #
 108 # If we release a new version that changes the binary API, but does
 109 # not break programs compiled against the old binary API, increment
 110 # Current and Age.  Set Revision to 0, since this is the first
 111 # implementation of the new API.
 112 #
 113 # Otherwise, we're changing the binary API and breaking backward
 114 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 115 # since we're backward compatible with no previous APIs.  Set Revision
 116 # to 0 too.
 117 AC_SUBST(LIBUNBOUND_CURRENT)
 118 AC_SUBST(LIBUNBOUND_REVISION)
 119 AC_SUBST(LIBUNBOUND_AGE)
 120
 121
 122 cmdln="`echo $@ | sed -e 's/\\\\/\\\\\\\\/g' | sed -e 's/"/\\\\"/'g`"
 123 AC_DEFINE_UNQUOTED(CONFCMDLINE, ["$cmdln"], [Command line arguments used with configure])
 124
 125 CFLAGS="$CFLAGS"
 126 AC_AIX
 127 if test "$ac_cv_header_minix_config_h" = "yes"; then
 128         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 129 fi
 130
 131 dnl
 132 dnl By default set prefix to /usr/local
 133 dnl
 134 case "$prefix" in
 135         NONE)
 136                 prefix="/usr/local"
 137         ;;
 138 esac
 139 case "$exec_prefix" in
 140         NONE)
 141                 exec_prefix="$prefix"
 142         ;;
 143 esac
 144
 145 # are we on MinGW?
 146 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 147 else
 148         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 149         else on_mingw="no"; fi
 150 fi
 151
 152 #
 153 # Determine configuration file
 154 # the eval is to evaluate shell expansion twice
 155 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 156 AC_SUBST(UNBOUND_SBIN_DIR)
 157 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 158 AC_SUBST(UNBOUND_SYSCONF_DIR)
 159 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 160 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 161 if test $on_mingw = "no"; then
 162   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 163 else
 164   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 165 fi
 166 AC_ARG_WITH([conf_file],
 167         AC_HELP_STRING([--with-conf-file=path],
 168         [Pathname to the Unbound configuration file]),
 169         [ub_conf_file="$withval"])
 170 AC_SUBST(ub_conf_file)
 171 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 172 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 173 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 174 AC_SUBST(ub_conf_dir)
 175
 176 # Determine run, chroot directory and pidfile locations
 177 AC_ARG_WITH(run-dir,
 178     AC_HELP_STRING([--with-run-dir=path],
 179     [set default directory to chdir to (by default dir part of cfg file)]),
 180     UNBOUND_RUN_DIR="$withval",
 181 if test $on_mingw = no; then
 182     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 183 else
 184     UNBOUND_RUN_DIR=""
 185 fi
 186 )
 187 AC_SUBST(UNBOUND_RUN_DIR)
 188 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 189 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 190
 191 AC_ARG_WITH(chroot-dir,
 192     AC_HELP_STRING([--with-chroot-dir=path],
 193     [set default directory to chroot to (by default same as run-dir)]),
 194     UNBOUND_CHROOT_DIR="$withval",
 195 if test $on_mingw = no; then
 196     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 197 else
 198     UNBOUND_CHROOT_DIR=""
 199 fi
 200 )
 201 AC_SUBST(UNBOUND_CHROOT_DIR)
 202 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 203 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 204
 205 AC_ARG_WITH(share-dir,
 206     AC_HELP_STRING([--with-share-dir=path],
 207     [set default directory with shared data (by default same as share/unbound)]),
 208     UNBOUND_SHARE_DIR="$withval",
 209     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 210 AC_SUBST(UNBOUND_SHARE_DIR)
 211 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 212
 213 AC_ARG_WITH(pidfile,
 214     AC_HELP_STRING([--with-pidfile=filename],
 215     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 216     UNBOUND_PIDFILE="$withval",
 217 if test $on_mingw = no; then
 218     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 219 else
 220     UNBOUND_PIDFILE=""
 221 fi
 222 )
 223 AC_SUBST(UNBOUND_PIDFILE)
 224 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 225 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 226
 227 AC_ARG_WITH(rootkey-file,
 228     AC_HELP_STRING([--with-rootkey-file=filename],
 229     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 230     UNBOUND_ROOTKEY_FILE="$withval",
 231 if test $on_mingw = no; then
 232     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 233 else
 234     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 235 fi
 236 )
 237 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 238 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 239 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 240
 241 AC_ARG_WITH(rootcert-file,
 242     AC_HELP_STRING([--with-rootcert-file=filename],
 243     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 244     UNBOUND_ROOTCERT_FILE="$withval",
 245 if test $on_mingw = no; then
 246     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 247 else
 248     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 249 fi
 250 )
 251 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 252 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 253 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 254
 255 AC_ARG_WITH(username,
 256     AC_HELP_STRING([--with-username=user],
 257     [set default user that unbound changes to (default user is unbound)]),
 258     UNBOUND_USERNAME="$withval",
 259     UNBOUND_USERNAME="unbound")
 260 AC_SUBST(UNBOUND_USERNAME)
 261 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 262
 263 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 264 ACX_RSRC_VERSION(wnvs)
 265 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 266
 267 # Checks for typedefs, structures, and compiler characteristics.
 268 AC_C_CONST
 269 AC_LANG_C
 270 # allow user to override the -g -O2 flags.
 271 default_cflags=no
 272 if test "x$CFLAGS" = "x" ; then
 273 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 274 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 275 default_cflags=yes
 276 fi
 277 AC_PROG_CC
 278 ACX_DEPFLAG
 279 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 280
 281 # debug mode flags warnings
 282 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 283 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 284 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 285 else debug_enabled="$enable_checking"; fi
 286 AC_SUBST(debug_enabled)
 287 case "$debug_enabled" in
 288         yes)
 289                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 290                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 291                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 292                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 293                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 294                 ;;
 295         no|*)
 296                 # nothing to do.
 297                 ;;
 298 esac
 299 if test "$default_cflags" = "yes"; then
 300         # only when CFLAGS was "" at the start, if the users wants to
 301         # override we shouldn't add default cflags, because they wouldn't
 302         # be able to turn off these options and set the CFLAGS wanted.
 303         ACX_CHECK_FLTO
 304         ACX_CHECK_PIE
 305         ACX_CHECK_RELRO_NOW
 306 fi
 307
 308 AC_C_INLINE
 309 ACX_CHECK_FORMAT_ATTRIBUTE
 310 ACX_CHECK_UNUSED_ATTRIBUTE
 311
 312 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 313 [AC_REQUIRE([AC_PROG_CC])
 314 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 315 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 316 [ac_cv_c_weak_attribute=no
 317 AC_TRY_COMPILE(
 318 [ #include <stdio.h>
 319 __attribute__((weak)) void f(int x) { printf("%d", x); }
 320 ], [
 321    f(1);
 322 ],
 323 [ac_cv_c_weak_attribute="yes"],
 324 [ac_cv_c_weak_attribute="no"])
 325 ])
 326
 327 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 328 if test $ac_cv_c_weak_attribute = yes; then
 329   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 330   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 331 fi
 332 ])dnl End of CHECK_WEAK_ATTRIBUTE
 333
 334 CHECK_WEAK_ATTRIBUTE
 335
 336 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 337 [AC_REQUIRE([AC_PROG_CC])
 338 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 339 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 340 [ac_cv_c_noreturn_attribute=no
 341 AC_TRY_COMPILE(
 342 [ #include <stdio.h>
 343 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 344 ], [
 345    f(1);
 346 ],
 347 [ac_cv_c_noreturn_attribute="yes"],
 348 [ac_cv_c_noreturn_attribute="no"])
 349 ])
 350
 351 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 352 if test $ac_cv_c_noreturn_attribute = yes; then
 353   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 354   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 355 fi
 356 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 357
 358 CHECK_NORETURN_ATTRIBUTE
 359
 360 if test "$srcdir" != "."; then
 361         CPPFLAGS="$CPPFLAGS -I$srcdir"
 362 fi
 363
 364 AC_DEFUN([ACX_YYLEX_DESTROY], [
 365         AC_MSG_CHECKING([for yylex_destroy])
 366         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 367                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 368                 AC_MSG_RESULT(yes)
 369         else AC_MSG_RESULT(no);
 370                 LEX=":"
 371         fi
 372 ])
 373
 374 AC_DEFUN([ACX_YYLEX_OPTION], [
 375         AC_MSG_CHECKING([for lex %option])
 376         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 377 %option nounput
 378 %%
 379 EOF
 380                 AC_MSG_RESULT(yes)
 381         else AC_MSG_RESULT(no);
 382                 LEX=":"
 383         fi
 384 ])
 385
 386 AC_PROG_LEX
 387 if test "$LEX" != "" -a "$LEX" != ":"; then
 388 ACX_YYLEX_DESTROY
 389 fi
 390 if test "$LEX" != "" -a "$LEX" != ":"; then
 391 ACX_YYLEX_OPTION
 392 fi
 393 AC_PROG_YACC
 394 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 395 AC_CHECK_TOOL(STRIP, strip)
 396 ACX_LIBTOOL_C_ONLY
 397
 398 PKG_PROG_PKG_CONFIG
 399
 400 # Checks for header files.
 401 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 402
 403 # Check for Apple header. This uncovers TARGET_OS_IPHONE, TARGET_OS_TV or TARGET_OS_WATCH
 404 AC_CHECK_HEADERS([TargetConditionals.h])
 405
 406 # check for types.
 407 # Using own tests for int64* because autoconf builtin only give 32bit.
 408 AC_CHECK_TYPE(int8_t, signed char)
 409 AC_CHECK_TYPE(int16_t, short)
 410 AC_CHECK_TYPE(int32_t, int)
 411 AC_CHECK_TYPE(int64_t, long long)
 412 AC_CHECK_TYPE(uint8_t, unsigned char)
 413 AC_CHECK_TYPE(uint16_t, unsigned short)
 414 AC_CHECK_TYPE(uint32_t, unsigned int)
 415 AC_CHECK_TYPE(uint64_t, unsigned long long)
 416 AC_TYPE_SIZE_T
 417 AC_CHECK_TYPE(ssize_t, int)
 418 AC_TYPE_UID_T
 419 AC_TYPE_PID_T
 420 AC_TYPE_OFF_T
 421 ACX_TYPE_U_CHAR
 422 ACX_TYPE_RLIM_T
 423 ACX_TYPE_SOCKLEN_T
 424 ACX_TYPE_IN_ADDR_T
 425 ACX_TYPE_IN_PORT_T
 426 ACX_CHECK_MEMCMP_SIGNED
 427
 428 AC_CHECK_SIZEOF(time_t,,[
 429 AC_INCLUDES_DEFAULT
 430 #ifdef TIME_WITH_SYS_TIME
 431 # include <sys/time.h>
 432 # include <time.h>
 433 #else
 434 # ifdef HAVE_SYS_TIME_H
 435 #  include <sys/time.h>
 436 # else
 437 #  include <time.h>
 438 # endif
 439 #endif
 440 ])
 441 AC_CHECK_SIZEOF(size_t)
 442
 443 # add option to disable the evil rpath
 444 ACX_ARG_RPATH
 445 AC_SUBST(RUNTIME_PATH)
 446
 447 # check to see if libraries are needed for these functions.
 448 AC_SEARCH_LIBS([inet_pton], [nsl])
 449 AC_SEARCH_LIBS([socket], [socket])
 450
 451 # check wether strptime also works
 452 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 453 [AC_REQUIRE([AC_PROG_CC])
 454 AC_MSG_CHECKING(whether strptime works)
 455 if test c${cross_compiling} = cno; then
 456 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 457 #define _XOPEN_SOURCE 600
 458 #include <time.h>
 459 int main(void) { struct tm tm; char *res;
 460 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 461 if (!res) return 2;
 462 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 463 if (!res) return 1; return 0; }
 464 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 465 else
 466 eval "ac_cv_c_strptime_works=maybe"
 467 fi
 468 AC_MSG_RESULT($ac_cv_c_strptime_works)
 469 if test $ac_cv_c_strptime_works = no; then
 470 AC_LIBOBJ(strptime)
 471 else
 472 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 473 fi
 474 ])dnl
 475
 476 # check some functions of the OS before linking libs (while still runnable).
 477 AC_FUNC_CHOWN
 478 AC_FUNC_FORK
 479 AC_TYPE_SIGNAL
 480 AC_FUNC_FSEEKO
 481 ACX_SYS_LARGEFILE
 482 ACX_CHECK_NONBLOCKING_BROKEN
 483 ACX_MKDIR_ONE_ARG
 484 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 485
 486 # check if we can use SO_REUSEPORT
 487 if echo "$host" | $GREP -i -e linux -e dragonfly >/dev/null; then
 488         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 489 else
 490         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 491 fi
 492
 493 # Include systemd.m4 - begin
 494 sinclude(systemd.m4)
 495 # Include systemd.m4 - end
 496
 497 # set memory allocation checking if requested
 498 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 499         [ enable to memory allocation statistics, for debug purposes ]),
 500         , )
 501 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 502         [ enable for lightweight alloc assertions, for debug purposes ]),
 503         , )
 504 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 505         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 506         , )
 507 if test x_$enable_alloc_nonregional = x_yes; then
 508         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 509 fi
 510 if test x_$enable_alloc_checks = x_yes; then
 511         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 512         SLDNS_ALLOCCHECK_EXTRA_OBJ="alloc.lo log.lo"
 513         AC_SUBST(SLDNS_ALLOCCHECK_EXTRA_OBJ)
 514         ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ="alloc.lo"
 515         AC_SUBST(ASYNCLOOK_ALLOCCHECK_EXTRA_OBJ)
 516 else
 517         if test x_$enable_alloc_lite = x_yes; then
 518                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 519         else
 520                 ACX_FUNC_MALLOC([unbound])
 521         fi
 522 fi
 523
 524 # check windows threads (we use them, not pthreads, on windows).
 525 if test "$on_mingw" = "yes"; then
 526 # check windows threads
 527         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 528         AC_MSG_CHECKING([for CreateThread])
 529         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 530 #ifdef HAVE_WINDOWS_H
 531 #include <windows.h>
 532 #endif
 533 ], [
 534         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 535 ])],
 536         AC_MSG_RESULT(yes)
 537         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 538 ,
 539         AC_MSG_RESULT(no)
 540 )
 541
 542 else
 543 # not on mingw, check thread libraries.
 544
 545 # check for thread library.
 546 # check this first, so that the pthread lib does not get linked in via
 547 # libssl or libpython, and thus distorts the tests, and we end up using
 548 # the non-threadsafe C libraries.
 549 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 550  [use pthreads library, or --without-pthreads to disable threading support.]),
 551  [ ],[ withval="yes" ])
 552 ub_have_pthreads=no
 553 if test x_$withval != x_no; then
 554         AX_PTHREAD([
 555                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 556                 if test -n "$PTHREAD_LIBS"; then
 557                   LIBS="$PTHREAD_LIBS $LIBS"
 558                 fi
 559                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 560                 CC="$PTHREAD_CC"
 561                 ub_have_pthreads=yes
 562                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 563
 564                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 565                 AC_MSG_CHECKING([if -pthread unused during linking])
 566                 # catch clang warning 'argument unused during compilation'
 567                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 568 [[
 569 int main(void) {return 0;}
 570 ]])])
 571                 pthread_unused="yes"
 572                 # first compile
 573                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 574                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 575                 if test $? = 0; then
 576                         # then link
 577                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 578                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 579                         if test $? -ne 0; then
 580                                 AC_MSG_RESULT(yes)
 581                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 582                                 PTHREAD_CFLAGS_ONLY="-pthread"
 583                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 584                         else
 585                                 AC_MSG_RESULT(no)
 586                         fi
 587                 else
 588                         AC_MSG_RESULT(no)
 589                 fi # endif cc successful
 590                 rm -f conftest conftest.c conftest.o
 591                 fi # endif -pthread in CFLAGS
 592
 593                 ])
 594 fi
 595
 596 # check solaris thread library
 597 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 598         [use solaris native thread library.]), [ ],[ withval="no" ])
 599 ub_have_sol_threads=no
 600 if test x_$withval != x_no; then
 601         if test x_$ub_have_pthreads != x_no; then
 602             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 603         else
 604         AC_SEARCH_LIBS(thr_create, [thread],
 605         [
 606                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 607
 608                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 609                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 610                 ub_have_sol_threads=yes
 611         ] , [
 612                 AC_ERROR([no solaris threads found.])
 613         ])
 614         fi
 615 fi
 616
 617 fi # end of non-mingw check of thread libraries
 618
 619 # Check for SYSLOG_FACILITY
 620 AC_ARG_WITH(syslog-facility, AC_HELP_STRING([--with-syslog-facility=LOCAL0 - LOCAL7], [ set SYSLOG_FACILITY, default DAEMON ]),
 621         [ UNBOUND_SYSLOG_FACILITY="$withval" ], [])
 622 case "${UNBOUND_SYSLOG_FACILITY}" in
 623
 624   LOCAL[[0-7]]) UNBOUND_SYSLOG_FACILITY="LOG_${UNBOUND_SYSLOG_FACILITY}" ;;
 625
 626            *) UNBOUND_SYSLOG_FACILITY="LOG_DAEMON" ;;
 627
 628 esac
 629 AC_DEFINE_UNQUOTED(UB_SYSLOG_FACILITY,${UNBOUND_SYSLOG_FACILITY},[the SYSLOG_FACILITY to use, default LOG_DAEMON])
 630
 631 # Check for dynamic library module
 632 AC_ARG_WITH(dynlibmodule,
 633    AC_HELP_STRING([--with-dynlibmodule],
 634    [build dynamic library module, or --without-dynlibmodule to disable it. (default=no)]),
 635    [], [ withval="no" ])
 636
 637 if test x_$withval != x_no; then
 638   AC_DEFINE(WITH_DYNLIBMODULE, 1, [Define if you want dynlib module.])
 639   WITH_DYNLIBMODULE=yes
 640   AC_SUBST(WITH_DYNLIBMODULE)
 641   DYNLIBMOD_OBJ="dynlibmod.lo"
 642   AC_SUBST(DYNLIBMOD_OBJ)
 643   DYNLIBMOD_HEADER='$(srcdir)/dynlibmod/dynlibmod.h'
 644   AC_SUBST(DYNLIBMOD_HEADER)
 645   if test $on_mingw = "no"; then
 646     DYNLIBMOD_EXTRALIBS="-ldl -export-dynamic"
 647   else
 648     DYNLIBMOD_EXTRALIBS="-Wl,--export-all-symbols,--out-implib,libunbound.a"
 649   fi
 650   AC_SUBST(DYNLIBMOD_EXTRALIBS)
 651 fi
 652
 653 # Check for PyUnbound
 654 AC_ARG_WITH(pyunbound,
 655    AC_HELP_STRING([--with-pyunbound],
 656    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 657    [], [ withval="no" ])
 658
 659 ub_test_python=no
 660 ub_with_pyunbound=no
 661 if test x_$withval != x_no; then
 662    ub_with_pyunbound=yes
 663    ub_test_python=yes
 664 fi
 665
 666 # Check for Python module
 667 AC_ARG_WITH(pythonmodule,
 668    AC_HELP_STRING([--with-pythonmodule],
 669    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 670    [], [ withval="no" ])
 671
 672 ub_with_pythonmod=no
 673 if test x_$withval != x_no; then
 674    ub_with_pythonmod=yes
 675    ub_test_python=yes
 676 fi
 677
 678 # Check for Python & SWIG only on PyUnbound or PyModule
 679 if test x_$ub_test_python != x_no; then
 680
 681    # Check for Python
 682    ub_have_python=no
 683    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 684    AC_PYTHON_DEVEL
 685    if test ! -z "$PYTHON_VERSION"; then
 686         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 687                 AC_ERROR([Python version >= 2.4.0 is required])
 688         fi
 689
 690       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 691       AC_SUBST(PY_MAJOR_VERSION)
 692       # Have Python
 693       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 694       if test -n "$LIBS"; then
 695         LIBS="$PYTHON_LDFLAGS $LIBS"
 696       else
 697         LIBS="$PYTHON_LDFLAGS"
 698       fi
 699       if test -n "$CPPFLAGS"; then
 700         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 701       else
 702         CPPFLAGS="$PYTHON_CPPFLAGS"
 703       fi
 704       if test "$PYTHON_LIBDIR" != "/usr/lib" -a "$PYTHON_LIBDIR" != "" -a "$PYTHON_LIBDIR" != "/usr/lib64"; then
 705         ACX_RUNTIME_PATH_ADD([$PYTHON_LIBDIR])
 706       fi
 707       ub_have_python=yes
 708       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 709                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 710                        [PC_PY_DEPENDENCY="python"])
 711       AC_SUBST(PC_PY_DEPENDENCY)
 712
 713       # Check for SWIG
 714       ub_have_swig=no
 715       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 716       if test "$enable_swig_version_check" = "yes"; then
 717         AC_PROG_SWIG(2.0.1)
 718       else
 719         AC_PROG_SWIG
 720       fi
 721       AC_MSG_CHECKING(SWIG)
 722       if test ! -x "$SWIG"; then
 723          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 724       else
 725          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 726          AC_SUBST(swig, "$SWIG")
 727          AC_MSG_RESULT(present)
 728
 729          # If have Python & SWIG
 730          # Declare PythonMod
 731          if test x_$ub_with_pythonmod != x_no; then
 732             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 733             WITH_PYTHONMODULE=yes
 734             AC_SUBST(WITH_PYTHONMODULE)
 735             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 736             AC_SUBST(PYTHONMOD_OBJ)
 737             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 738             AC_SUBST(PYTHONMOD_HEADER)
 739             PYTHONMOD_INSTALL=pythonmod-install
 740             AC_SUBST(PYTHONMOD_INSTALL)
 741             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 742             AC_SUBST(PYTHONMOD_UNINSTALL)
 743          fi
 744
 745          # Declare PyUnbound
 746          if test x_$ub_with_pyunbound != x_no; then
 747             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 748             WITH_PYUNBOUND=yes
 749             AC_SUBST(WITH_PYUNBOUND)
 750             PYUNBOUND_OBJ="libunbound_wrap.lo"
 751             AC_SUBST(PYUNBOUND_OBJ)
 752             PYUNBOUND_TARGET="_unbound.la"
 753             AC_SUBST(PYUNBOUND_TARGET)
 754             PYUNBOUND_INSTALL=pyunbound-install
 755             AC_SUBST(PYUNBOUND_INSTALL)
 756             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 757             AC_SUBST(PYUNBOUND_UNINSTALL)
 758          fi
 759       fi
 760    else
 761       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 762       ub_with_pyunbound=no
 763       ub_with_pythonmod=no
 764    fi
 765 fi
 766
 767 if test "`uname`" = "NetBSD"; then
 768         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 769         AC_SUBST(NETBSD_LINTFLAGS)
 770 fi
 771 CONFIG_DATE=`date +%Y%m%d`
 772 AC_SUBST(CONFIG_DATE)
 773
 774 # Checks for libraries.
 775
 776 # libnss
 777 USE_NSS="no"
 778 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 779         [use libnss instead of openssl, installed at path.]),
 780         [
 781         USE_NSS="yes"
 782         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 783         if test "$withval" != "" -a "$withval" != "yes"; then
 784                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 785                 LDFLAGS="$LDFLAGS -L$withval/lib"
 786                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 787                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 788         else
 789                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 790                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 791         fi
 792         LIBS="$LIBS -lnss3 -lnspr4"
 793         SSLLIB=""
 794         PC_CRYPTO_DEPENDENCY="nss nspr"
 795         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 796         ]
 797 )
 798
 799 # libnettle
 800 USE_NETTLE="no"
 801 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 802         [use libnettle as crypto library, installed at path.]),
 803         [
 804         USE_NETTLE="yes"
 805         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 806         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 807         if test "$withval" != "" -a "$withval" != "yes"; then
 808                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 809                 LDFLAGS="$LDFLAGS -L$withval/lib"
 810                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 811         else
 812                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 813         fi
 814         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 815         SSLLIB=""
 816         PC_CRYPTO_DEPENDENCY="hogweed nettle"
 817         AC_SUBST(PC_CRYPTO_DEPENDENCY)
 818         ]
 819 )
 820
 821 # openssl
 822 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 823 ACX_WITH_SSL
 824 ACX_LIB_SSL
 825 SSLLIB="-lssl"
 826
 827 PC_CRYPTO_DEPENDENCY="libcrypto libssl"
 828 AC_SUBST(PC_CRYPTO_DEPENDENCY)
 829
 830 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 831 BAKLIBS="$LIBS"
 832 LIBS="-lssl $LIBS"
 833 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 834 AC_TRY_LINK_FUNC([HMAC_Update], [
 835         AC_MSG_RESULT([no])
 836         LIBS="$BAKLIBS"
 837 ], [
 838         AC_MSG_RESULT([yes])
 839         LIBS="$BAKLIBS"
 840         LIBS="$LIBS -lcrypt32"
 841 ])
 842
 843 AC_MSG_CHECKING([for LibreSSL])
 844 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 845         AC_MSG_RESULT([yes])
 846         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 847         # libressl provides these compat functions, but they may also be
 848         # declared by the OS in libc.  See if they have been declared.
 849         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform])
 850 else
 851         AC_MSG_RESULT([no])
 852 fi
 853 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h openssl/core_names.h],,, [AC_INCLUDES_DEFAULT])
 854 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ENGINE_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex CRYPTO_THREADID_set_callback])
 855
 856 # these check_funcs need -lssl
 857 BAKLIBS="$LIBS"
 858 LIBS="-lssl $LIBS"
 859 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites SSL_CTX_set_tlsext_ticket_key_evp_cb])
 860 LIBS="$BAKLIBS"
 861
 862 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 863 AC_INCLUDES_DEFAULT
 864 #ifdef HAVE_OPENSSL_ERR_H
 865 #include <openssl/err.h>
 866 #endif
 867
 868 #ifdef HAVE_OPENSSL_RAND_H
 869 #include <openssl/rand.h>
 870 #endif
 871
 872 #ifdef HAVE_OPENSSL_CONF_H
 873 #include <openssl/conf.h>
 874 #endif
 875
 876 #ifdef HAVE_OPENSSL_ENGINE_H
 877 #include <openssl/engine.h>
 878 #endif
 879 #include <openssl/ssl.h>
 880 #include <openssl/evp.h>
 881 ])
 882
 883 if test "$ac_cv_func_HMAC_Init_ex" = "yes"; then
 884 # check function return type.
 885 AC_MSG_CHECKING(the return type of HMAC_Init_ex)
 886 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 887 #ifdef HAVE_OPENSSL_ERR_H
 888 #include <openssl/err.h>
 889 #endif
 890
 891 #ifdef HAVE_OPENSSL_RAND_H
 892 #include <openssl/rand.h>
 893 #endif
 894
 895 #ifdef HAVE_OPENSSL_CONF_H
 896 #include <openssl/conf.h>
 897 #endif
 898
 899 #ifdef HAVE_OPENSSL_ENGINE_H
 900 #include <openssl/engine.h>
 901 #endif
 902 #include <openssl/ssl.h>
 903 #include <openssl/evp.h>
 904 ], [
 905         HMAC_CTX* hmac_ctx = NULL;
 906         void* hmac_key = NULL;
 907         const EVP_MD* digest = NULL;
 908         int x = HMAC_Init_ex(hmac_ctx, hmac_key, 32, digest, NULL);
 909         (void)x;
 910 ])], [
 911         AC_MSG_RESULT(int)
 912 ], [
 913         AC_MSG_RESULT(void)
 914         AC_DEFINE([HMAC_INIT_EX_RETURNS_VOID], 1, [If HMAC_Init_ex() returns void])
 915 ])
 916 fi
 917
 918 fi
 919 AC_SUBST(SSLLIB)
 920
 921 # libbsd
 922 AC_ARG_WITH([libbsd], AC_HELP_STRING([--with-libbsd], [Use portable libbsd functions]), [
 923         AC_CHECK_HEADERS([bsd/string.h bsd/stdlib.h],,, [AC_INCLUDES_DEFAULT])
 924         if test "x$ac_cv_header_bsd_string_h" = xyes -a "x$ac_cv_header_bsd_stdlib_h" = xyes; then
 925                 for func in strlcpy strlcat arc4random arc4random_uniform reallocarray; do
 926                         AC_SEARCH_LIBS([$func], [bsd], [
 927                                 AC_DEFINE(HAVE_LIBBSD, 1, [Use portable libbsd functions])
 928                                 PC_LIBBSD_DEPENDENCY=libbsd
 929                                 AC_SUBST(PC_LIBBSD_DEPENDENCY)
 930                         ])
 931                 done
 932         fi
 933 ])
 934
 935 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 936 case "$enable_sha1" in
 937         no)
 938         ;;
 939         yes|*)
 940         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 941         ;;
 942 esac
 943
 944
 945 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 946 case "$enable_sha2" in
 947         no)
 948         ;;
 949         yes|*)
 950         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 951         ;;
 952 esac
 953
 954 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 955 case "$enable_subnet" in
 956         yes)
 957         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 958         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 959         AC_SUBST(SUBNET_OBJ)
 960         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 961         AC_SUBST(SUBNET_HEADER)
 962         ;;
 963         no|*)
 964         ;;
 965 esac
 966
 967 # check wether gost also works
 968 AC_DEFUN([AC_CHECK_GOST_WORKS],
 969 [AC_REQUIRE([AC_PROG_CC])
 970 AC_MSG_CHECKING([if GOST works])
 971 if test c${cross_compiling} = cno; then
 972 BAKCFLAGS="$CFLAGS"
 973 if test -n "$ssldir"; then
 974         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 975 fi
 976 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 977 #include <string.h>
 978 #include <openssl/ssl.h>
 979 #include <openssl/evp.h>
 980 #include <openssl/engine.h>
 981 #include <openssl/conf.h>
 982 /* routine to load gost (from sldns) */
 983 int load_gost_id(void)
 984 {
 985         static int gost_id = 0;
 986         const EVP_PKEY_ASN1_METHOD* meth;
 987         ENGINE* e;
 988
 989         if(gost_id) return gost_id;
 990
 991         /* see if configuration loaded gost implementation from other engine*/
 992         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 993         if(meth) {
 994                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 995                 return gost_id;
 996         }
 997
 998         /* see if engine can be loaded already */
 999         e = ENGINE_by_id("gost");
1000         if(!e) {
1001                 /* load it ourself, in case statically linked */
1002                 ENGINE_load_builtin_engines();
1003                 ENGINE_load_dynamic();
1004                 e = ENGINE_by_id("gost");
1005         }
1006         if(!e) {
1007                 /* no gost engine in openssl */
1008                 return 0;
1009         }
1010         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
1011                 ENGINE_finish(e);
1012                 ENGINE_free(e);
1013                 return 0;
1014         }
1015
1016         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
1017         if(!meth) {
1018                 /* algo not found */
1019                 ENGINE_finish(e);
1020                 ENGINE_free(e);
1021                 return 0;
1022         }
1023         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
1024         return gost_id;
1025 }
1026 int main(void) {
1027         EVP_MD_CTX* ctx;
1028         const EVP_MD* md;
1029         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
1030         const char* str = "Hello world";
1031         const unsigned char check[] = {
1032                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
1033                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
1034                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
1035                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
1036         };
1037         OPENSSL_config(NULL);
1038         (void)load_gost_id();
1039         md = EVP_get_digestbyname("md_gost94");
1040         if(!md) return 1;
1041         memset(digest, 0, sizeof(digest));
1042         ctx = EVP_MD_CTX_create();
1043         if(!ctx) return 2;
1044         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
1045         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
1046         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
1047         /* uncomment to see the hash calculated.
1048                 {int i;
1049                 for(i=0; i<32; i++)
1050                         printf(" %2.2x", (int)digest[i]);
1051                 printf("\n");}
1052         */
1053         if(memcmp(digest, check, sizeof(check)) != 0)
1054                 return 6;
1055         return 0;
1056 }
1057 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
1058 CFLAGS="$BAKCFLAGS"
1059 else
1060 eval "ac_cv_c_gost_works=maybe"
1061 fi
1062 AC_MSG_RESULT($ac_cv_c_gost_works)
1063 ])dnl
1064
1065 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
1066 use_gost="no"
1067 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1068 case "$enable_gost" in
1069         no)
1070         ;;
1071         *)
1072         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
1073         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
1074         AC_CHECK_GOST_WORKS
1075         if test "$ac_cv_c_gost_works" != no; then
1076                 use_gost="yes"
1077                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
1078         fi
1079         ;;
1080 esac
1081 fi dnl !USE_NSS && !USE_NETTLE
1082
1083 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
1084 use_ecdsa="no"
1085 case "$enable_ecdsa" in
1086     no)
1087       ;;
1088     *)
1089       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1090               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
1091               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
1092               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
1093 #include <openssl/evp.h>
1094               ])
1095               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
1096               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
1097               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
1098                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
1099                   AC_MSG_RESULT([no])
1100                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
1101                 else
1102                   AC_MSG_RESULT([yes])
1103                 fi
1104               else
1105                 # not OpenSSL, thus likely LibreSSL, which supports it
1106                 AC_MSG_RESULT([yes])
1107               fi
1108       fi
1109       # we now know we have ECDSA and the required curves.
1110       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
1111       use_ecdsa="yes"
1112       ;;
1113 esac
1114
1115 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
1116 use_dsa="no"
1117 case "$enable_dsa" in
1118     yes)
1119       # detect if DSA is supported, and turn it off if not.
1120       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1121       AC_CHECK_FUNC(DSA_SIG_new, [
1122       AC_CHECK_TYPE(DSA_SIG*, [
1123       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1124       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1125                fi ], [
1126 AC_INCLUDES_DEFAULT
1127 #ifdef HAVE_OPENSSL_ERR_H
1128 #include <openssl/err.h>
1129 #endif
1130
1131 #ifdef HAVE_OPENSSL_RAND_H
1132 #include <openssl/rand.h>
1133 #endif
1134
1135 #ifdef HAVE_OPENSSL_CONF_H
1136 #include <openssl/conf.h>
1137 #endif
1138
1139 #ifdef HAVE_OPENSSL_ENGINE_H
1140 #include <openssl/engine.h>
1141 #endif
1142       ])
1143       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1144                fi ])
1145       else
1146       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1147       fi
1148       ;;
1149     *)
1150       # disable dsa by default, RFC 8624 section 3.1, validators MUST NOT
1151       # support DSA for DNSSEC Validation.
1152       ;;
1153 esac
1154
1155 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1156 use_ed25519="no"
1157 case "$enable_ed25519" in
1158     no)
1159       ;;
1160     *)
1161       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1162               AC_CHECK_DECLS([NID_ED25519], [
1163                 use_ed25519="yes"
1164               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1165                 fi ], [AC_INCLUDES_DEFAULT
1166 #include <openssl/evp.h>
1167               ])
1168       fi
1169       if test $USE_NETTLE = "yes"; then
1170                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1171       fi
1172       if test $use_ed25519 = "yes"; then
1173                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1174       fi
1175       ;;
1176 esac
1177
1178 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1179 use_ed448="no"
1180 case "$enable_ed448" in
1181     no)
1182       ;;
1183     *)
1184       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1185               AC_CHECK_DECLS([NID_ED448], [
1186                 use_ed448="yes"
1187               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1188                 fi ], [AC_INCLUDES_DEFAULT
1189 #include <openssl/evp.h>
1190               ])
1191       fi
1192       if test $use_ed448 = "yes"; then
1193                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1194       fi
1195       ;;
1196 esac
1197
1198 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1199 case "$enable_event_api" in
1200     yes)
1201       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1202       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1203       ;;
1204     *)
1205       ;;
1206 esac
1207
1208 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1209 case "$enable_tfo_client" in
1210         yes)
1211                 case `uname` in
1212                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1213                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1214                                              [AC_INCLUDES_DEFAULT
1215 #include <netinet/tcp.h>
1216 ])
1217                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1218                           ;;
1219                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1220                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1221                                               [AC_INCLUDES_DEFAULT
1222 #include <sys/socket.h>
1223 ])
1224                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1225                           ;;
1226                 esac
1227         ;;
1228         no|*)
1229                 ;;
1230 esac
1231
1232 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1233 case "$enable_tfo_server" in
1234         yes)
1235               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1236 #include <netinet/tcp.h>
1237               ])
1238                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1239                 ;;
1240         no|*)
1241                 ;;
1242 esac
1243
1244 # check for libevent
1245 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1246     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1247     [ ],[ with_libevent="no" ])
1248 if test "x_$with_libevent" != x_no; then
1249         AC_DEFINE([USE_LIBEVENT], [1], [Define if you enable libevent])
1250         AC_MSG_CHECKING(for libevent)
1251         if test "x_$with_libevent" = x_ -o "x_$with_libevent" = x_yes; then
1252             with_libevent="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1253         fi
1254         for dir in $with_libevent; do
1255             thedir="$dir"
1256             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1257                 found_libevent="yes"
1258                                 dnl assume /usr is in default path.
1259                                 if test "$thedir" != "/usr"; then
1260                                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1261                                 fi
1262                                 break;
1263                     fi
1264         done
1265         if test x_$found_libevent != x_yes; then
1266                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1267                         # libevent source directory
1268                         AC_MSG_RESULT(found in $thedir)
1269                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1270                         BAK_LDFLAGS_SET="1"
1271                         BAK_LDFLAGS="$LDFLAGS"
1272                         # remove evdns from linking
1273                         mkdir build >/dev/null 2>&1
1274                         mkdir build/libevent >/dev/null 2>&1
1275                         mkdir build/libevent/.libs >/dev/null 2>&1
1276                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1277                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1278                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1279                         cp $ev_files_o build/libevent
1280                         cp $ev_files_lo build/libevent
1281                         cp $ev_files_libso build/libevent/.libs
1282                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1283                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1284                 else
1285             AC_MSG_ERROR([Cannot find the libevent library in $with_libevent
1286 You can restart ./configure --with-libevent=no to use a builtin alternative.
1287 Please note that this alternative is not as capable as libevent when using
1288 large outgoing port ranges.  ])
1289                 fi
1290         else
1291             AC_MSG_RESULT(found in $thedir)
1292             dnl if event2 exists and no event lib in dir itself, use subdir
1293             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1294                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1295                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1296             else
1297                     dnl assume /usr is in default path, do not add "".
1298                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1299                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1300                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1301                     fi
1302             fi
1303         fi
1304         # check for library used by libevent after 1.3c
1305         AC_SEARCH_LIBS([clock_gettime], [rt])
1306
1307         # is the event.h header libev or libevent?
1308         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1309         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1310                 AC_SEARCH_LIBS(event_set, [ev])
1311         ],[
1312                 AC_SEARCH_LIBS(event_set, [event])
1313         ],[AC_INCLUDES_DEFAULT
1314 #include <event.h>
1315         ])
1316         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1317         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1318         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1319         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1320         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1321         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1322         AC_CHECK_FUNCS([event_assign]) # in libevent, for thread-safety
1323         AC_CHECK_DECLS([evsignal_assign], [], [], [AC_INCLUDES_DEFAULT
1324 #ifdef HAVE_EVENT_H
1325 #  include <event.h>
1326 #else
1327 #  include "event2/event.h"
1328 #endif
1329         ])
1330         PC_LIBEVENT_DEPENDENCY="libevent"
1331         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1332         if test -n "$BAK_LDFLAGS_SET"; then
1333                 LDFLAGS="$BAK_LDFLAGS"
1334         fi
1335 else
1336         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1337 fi
1338
1339 # check for libexpat
1340 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1341     [specify explicit path for libexpat.]),
1342     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1343 AC_MSG_CHECKING(for libexpat)
1344 found_libexpat="no"
1345 for dir in $withval ; do
1346             if test -f "$dir/include/expat.h"; then
1347                 found_libexpat="yes"
1348                 dnl assume /usr is in default path.
1349                 if test "$dir" != "/usr"; then
1350                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1351                     LDFLAGS="$LDFLAGS -L$dir/lib"
1352                 fi
1353                 AC_MSG_RESULT(found in $dir)
1354                 break;
1355             fi
1356 done
1357 if test x_$found_libexpat != x_yes; then
1358         AC_ERROR([Could not find libexpat, expat.h])
1359 fi
1360 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1361 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1362 #include <expat.h>
1363 ])
1364
1365 # hiredis (redis C client for cachedb)
1366 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1367     [specify explicit path for libhiredis.]),
1368     [ ],[ withval="no" ])
1369 found_libhiredis="no"
1370 if test x_$withval = x_yes -o x_$withval != x_no; then
1371    AC_MSG_CHECKING(for libhiredis)
1372    if test x_$withval = x_ -o x_$withval = x_yes; then
1373             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1374    fi
1375    for dir in $withval ; do
1376             if test -f "$dir/include/hiredis/hiredis.h"; then
1377                 found_libhiredis="yes"
1378                 dnl assume /usr is in default path.
1379                 if test "$dir" != "/usr"; then
1380                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1381                     LDFLAGS="$LDFLAGS -L$dir/lib"
1382                 fi
1383                 AC_MSG_RESULT(found in $dir)
1384                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1385                 LIBS="$LIBS -lhiredis"
1386                 break;
1387             fi
1388     done
1389     if test x_$found_libhiredis != x_yes; then
1390         AC_ERROR([Could not find libhiredis, hiredis.h])
1391     fi
1392     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1393     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1394     #include <hiredis/hiredis.h>
1395     ])
1396 fi
1397
1398 # set static linking for uninstalled libraries if requested
1399 AC_SUBST(staticexe)
1400 staticexe=""
1401 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1402         [ enable to compile executables statically against (event) uninstalled libs, for debug purposes ]),
1403         , )
1404 if test x_$enable_static_exe = x_yes; then
1405         staticexe="-static"
1406         if test "$on_mingw" = yes; then
1407                 staticexe="-all-static"
1408                 # for static compile, include gdi32 and zlib here.
1409                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1410                         :
1411                 else
1412                         LIBS="$LIBS -lgdi32"
1413                 fi
1414                 LIBS="$LIBS -lz"
1415         fi
1416 fi
1417
1418 # set full static linking if requested
1419 AC_ARG_ENABLE(fully-static, AC_HELP_STRING([--enable-fully-static],
1420         [ enable to compile fully static ]),
1421         , )
1422 if test x_$enable_fully_static = x_yes; then
1423         staticexe="-all-static"
1424         if test "$on_mingw" = yes; then
1425                 # for static compile, include gdi32 and zlib here.
1426                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1427                         :
1428                 else
1429                         LIBS="$LIBS -lgdi32"
1430                 fi
1431                 LIBS="$LIBS -lz"
1432         fi
1433 fi
1434
1435 # set lock checking if requested
1436 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1437         [ enable to check lock and unlock calls, for debug purposes ]),
1438         , )
1439 if test x_$enable_lock_checks = x_yes; then
1440         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1441         CHECKLOCK_OBJ="checklocks.lo"
1442         AC_SUBST(CHECKLOCK_OBJ)
1443 fi
1444
1445 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1446 if test "$USE_WINSOCK" = 1; then
1447         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1448         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1449 #include <windows.h>
1450         ])
1451         AC_CHECK_TOOL(WINDRES, windres)
1452         LIBS="$LIBS -liphlpapi -lcrypt32"
1453         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1454         AC_SUBST(WINAPPS)
1455         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1456         AC_SUBST(WIN_DAEMON_SRC)
1457         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1458         AC_SUBST(WIN_DAEMON_OBJ)
1459         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1460         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1461         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1462         AC_SUBST(WIN_HOST_OBJ_LINK)
1463         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1464         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1465         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1466         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1467         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1468         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1469 fi
1470 if test $ac_cv_func_getaddrinfo = no; then
1471         AC_LIBOBJ([fake-rfc2553])
1472 fi
1473 # check after getaddrinfo for its libraries
1474 ACX_FUNC_IOCTLSOCKET
1475
1476 # see if daemon(3) exists, and if it is deprecated.
1477 AC_CHECK_FUNCS([daemon])
1478 if test $ac_cv_func_daemon = yes; then
1479         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1480 #include <stdlib.h>
1481 ])
1482 fi
1483
1484 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1485 AC_INCLUDES_DEFAULT
1486 #ifdef HAVE_SYS_UN_H
1487 #include <sys/un.h>
1488 #endif
1489 ])
1490 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1491 AC_INCLUDES_DEFAULT
1492 #if HAVE_SYS_PARAM_H
1493 #include <sys/param.h>
1494 #endif
1495
1496 #ifdef HAVE_SYS_SOCKET_H
1497 #include <sys/socket.h>
1498 #endif
1499
1500 #ifdef HAVE_SYS_UIO_H
1501 #include <sys/uio.h>
1502 #endif
1503
1504 #ifdef HAVE_NETINET_IN_H
1505 #include <netinet/in.h>
1506 #endif
1507
1508 #ifdef HAVE_NETINET_TCP_H
1509 #include <netinet/tcp.h>
1510 #endif
1511
1512 #ifdef HAVE_ARPA_INET_H
1513 #include <arpa/inet.h>
1514 #endif
1515
1516 #ifdef HAVE_WINSOCK2_H
1517 #include <winsock2.h>
1518 #endif
1519
1520 #ifdef HAVE_WS2TCPIP_H
1521 #include <ws2tcpip.h>
1522 #endif
1523 ])
1524
1525 AC_MSG_CHECKING([for htobe64])
1526 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1527 #include <stdio.h>
1528 #ifdef HAVE_ENDIAN_H
1529 #  include <endian.h>
1530 #endif
1531 #ifdef HAVE_SYS_ENDIAN_H
1532 #  include <sys/endian.h>
1533 #endif
1534 ], [unsigned long long x = htobe64(0); printf("%u", (unsigned)x);])],
1535   AC_MSG_RESULT(yes)
1536   AC_DEFINE(HAVE_HTOBE64, 1, [If we have htobe64]),
1537   AC_MSG_RESULT(no))
1538
1539 AC_MSG_CHECKING([for be64toh])
1540 AC_LINK_IFELSE([AC_LANG_PROGRAM([
1541 #include <stdio.h>
1542 #ifdef HAVE_ENDIAN_H
1543 #  include <endian.h>
1544 #endif
1545 #ifdef HAVE_SYS_ENDIAN_H
1546 #  include <sys/endian.h>
1547 #endif
1548 ], [unsigned long long x = be64toh(0); printf("%u", (unsigned)x);])],
1549   AC_MSG_RESULT(yes)
1550   AC_DEFINE(HAVE_BE64TOH, 1, [If we have be64toh]),
1551   AC_MSG_RESULT(no))
1552
1553 AC_SEARCH_LIBS([setusercontext], [util])
1554 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1555 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1556 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1557
1558 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1559 if echo $target_os | grep darwin8 > /dev/null; then
1560         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1561 fi
1562 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1563 AC_INCLUDES_DEFAULT
1564 #ifdef HAVE_NETINET_IN_H
1565 #include <netinet/in.h>
1566 #endif
1567
1568 #ifdef HAVE_NETINET_TCP_H
1569 #include <netinet/tcp.h>
1570 #endif
1571
1572 #ifdef HAVE_ARPA_INET_H
1573 #include <arpa/inet.h>
1574 #endif
1575
1576 #ifdef HAVE_WINSOCK2_H
1577 #include <winsock2.h>
1578 #endif
1579
1580 #ifdef HAVE_WS2TCPIP_H
1581 #include <ws2tcpip.h>
1582 #endif
1583 ])
1584 AC_REPLACE_FUNCS(inet_aton)
1585 AC_REPLACE_FUNCS(inet_pton)
1586 AC_REPLACE_FUNCS(inet_ntop)
1587 AC_REPLACE_FUNCS(snprintf)
1588 # test if snprintf return the proper length
1589 if test "x$ac_cv_func_snprintf" = xyes; then
1590     if test c${cross_compiling} = cno; then
1591         AC_MSG_CHECKING([for correct snprintf return value])
1592         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1593 [[
1594 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1595 ]])], [AC_MSG_RESULT(yes)], [
1596                 AC_MSG_RESULT(no)
1597                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1598                 AC_LIBOBJ(snprintf)
1599           ])
1600     fi
1601 fi
1602 AC_REPLACE_FUNCS(strlcat)
1603 AC_REPLACE_FUNCS(strlcpy)
1604 AC_REPLACE_FUNCS(memmove)
1605 AC_REPLACE_FUNCS(gmtime_r)
1606 AC_REPLACE_FUNCS(isblank)
1607 AC_REPLACE_FUNCS(explicit_bzero)
1608 dnl without CTIME, ARC4-functions and without reallocarray.
1609 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1610 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1611 AC_MSG_CHECKING([for reallocarray])
1612 AC_LINK_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1613 [[
1614 #ifndef _OPENBSD_SOURCE
1615 #define _OPENBSD_SOURCE 1
1616 #endif
1617 #include <stdlib.h>
1618 int main(void) {
1619         void* p = reallocarray(NULL, 10, 100);
1620         free(p);
1621         return 0;
1622 }
1623 ]])], [AC_MSG_RESULT(yes)
1624         AC_DEFINE(HAVE_REALLOCARRAY, 1, [If we have reallocarray(3)])
1625 ], [
1626         AC_MSG_RESULT(no)
1627         AC_LIBOBJ(reallocarray)
1628 ])
1629 AC_CHECK_DECLS([reallocarray])
1630 if test "$USE_NSS" = "no"; then
1631         AC_REPLACE_FUNCS(arc4random)
1632         AC_REPLACE_FUNCS(arc4random_uniform)
1633         if test "$ac_cv_func_arc4random" = "no"; then
1634                 AC_LIBOBJ(arc4_lock)
1635                 AC_CHECK_FUNCS([getentropy],,[
1636                     if test "$USE_WINSOCK" = 1; then
1637                         AC_LIBOBJ(getentropy_win)
1638                     else
1639                         case "$host" in
1640                         Darwin|*darwin*)
1641                                 AC_LIBOBJ(getentropy_osx)
1642                         ;;
1643                         *solaris*|*sunos*|SunOS)
1644                                 AC_LIBOBJ(getentropy_solaris)
1645                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1646                                         AC_CHECK_FUNCS([SHA512_Update],,[
1647                                                 AC_LIBOBJ(sha512)
1648                                         ])
1649                                 ], [AC_INCLUDES_DEFAULT])
1650                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1651                                         # this lib needed for sha2 on solaris
1652                                         LIBS="$LIBS -lmd"
1653                                 fi
1654                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1655                         ;;
1656                         *freebsd*|*FreeBSD)
1657                                 AC_LIBOBJ(getentropy_freebsd)
1658                         ;;
1659                         *linux*|Linux|*)
1660                                 AC_LIBOBJ(getentropy_linux)
1661                                 AC_CHECK_FUNCS([SHA512_Update],,[
1662                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1663                                         AC_LIBOBJ(sha512)
1664                                 ])
1665                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1666                                 AC_CHECK_FUNCS([getauxval])
1667                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1668                         ;;
1669                         esac
1670                     fi
1671                 ])
1672         fi
1673 fi
1674 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1675 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1676 AC_REPLACE_FUNCS(ctime_r)
1677 AC_REPLACE_FUNCS(strsep)
1678
1679 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1680 case "$enable_allsymbols" in
1681         yes)
1682         COMMON_OBJ_ALL_SYMBOLS=""
1683         UBSYMS=""
1684         EXTRALINK="-L. -L.libs -lunbound"
1685         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1686         ;;
1687         no|*)
1688         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1689         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1690         EXTRALINK=""
1691         ;;
1692 esac
1693 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1694 AC_SUBST(EXTRALINK)
1695 AC_SUBST(UBSYMS)
1696 if test x_$enable_lock_checks = x_yes; then
1697         UBSYMS="-export-symbols clubsyms.def"
1698         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1699         echo lock_protect >> clubsyms.def
1700         echo lock_unprotect >> clubsyms.def
1701         echo lock_get_mem >> clubsyms.def
1702         echo checklock_start >> clubsyms.def
1703         echo checklock_stop >> clubsyms.def
1704         echo checklock_lock >> clubsyms.def
1705         echo checklock_unlock >> clubsyms.def
1706         echo checklock_init >> clubsyms.def
1707         echo checklock_thrcreate >> clubsyms.def
1708         echo checklock_thrjoin >> clubsyms.def
1709 fi
1710
1711 # check for dnstap if requested
1712 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1713     [
1714         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1715         AC_SUBST([ENABLE_DNSTAP], [1])
1716
1717         AC_SUBST([opt_dnstap_socket_path])
1718         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1719         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1720             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1721         AC_SUBST(DNSTAP_SOCKET_PATH,["$hdr_dnstap_socket_path"])
1722
1723         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c dnstap/dnstap_fstrm.c dnstap/dtstream.c"])
1724         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo dnstap_fstrm.lo dtstream.lo"])
1725     ],
1726     [
1727         AC_SUBST([ENABLE_DNSTAP], [0])
1728     ]
1729 )
1730
1731 # check for dnscrypt if requested
1732 dnsc_DNSCRYPT([
1733         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1734         AC_SUBST([ENABLE_DNSCRYPT], [1])
1735
1736         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1737         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1738     ],
1739     [
1740         AC_SUBST([ENABLE_DNSCRYPT], [0])
1741     ]
1742 )
1743
1744 # check for cachedb if requested
1745 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1746 # turn on cachedb when hiredis support is enabled.
1747 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1748 case "$enable_cachedb" in
1749     yes)
1750         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1751         ;;
1752     no|*)
1753         # nothing
1754         ;;
1755 esac
1756
1757 # check for ipsecmod if requested
1758 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1759 case "$enable_ipsecmod" in
1760         yes)
1761                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1762                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1763                 AC_SUBST(IPSECMOD_OBJ)
1764                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1765                 AC_SUBST(IPSECMOD_HEADER)
1766                 ;;
1767         no|*)
1768                 # nothing
1769                 ;;
1770 esac
1771
1772 # check for ipset if requested
1773 AC_ARG_ENABLE(ipset, AC_HELP_STRING([--enable-ipset], [enable ipset module]))
1774 case "$enable_ipset" in
1775     yes)
1776                 AC_DEFINE([USE_IPSET], [1], [Define to 1 to use ipset support])
1777                 IPSET_SRC="ipset/ipset.c"
1778                 AC_SUBST(IPSET_SRC)
1779                 IPSET_OBJ="ipset.lo"
1780                 AC_SUBST(IPSET_OBJ)
1781
1782                 # mnl
1783                 AC_ARG_WITH(libmnl, AC_HELP_STRING([--with-libmnl=path],
1784                         [specify explicit path for libmnl.]),
1785                         [ ],[ withval="yes" ])
1786                 found_libmnl="no"
1787                 AC_MSG_CHECKING(for libmnl)
1788                 if test x_$withval = x_ -o x_$withval = x_yes; then
1789                         withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1790                 fi
1791                 for dir in $withval ; do
1792                         if test -f "$dir/include/libmnl/libmnl.h"; then
1793                                 found_libmnl="yes"
1794                                 dnl assume /usr is in default path.
1795                                 if test "$dir" != "/usr"; then
1796                                         CPPFLAGS="$CPPFLAGS -I$dir/include"
1797                                         LDFLAGS="$LDFLAGS -L$dir/lib"
1798                                 fi
1799                                 AC_MSG_RESULT(found in $dir)
1800                                 LIBS="$LIBS -lmnl"
1801                                 break;
1802                         fi
1803                 done
1804                 if test x_$found_libmnl != x_yes; then
1805                         AC_ERROR([Could not find libmnl, libmnl.h])
1806                 fi
1807                 ;;
1808     no|*)
1809         # nothing
1810                 ;;
1811 esac
1812 AC_ARG_ENABLE(explicit-port-randomisation, AC_HELP_STRING([--disable-explicit-port-randomisation], [disable explicit source port randomisation and rely on the kernel to provide random source ports]))
1813 case "$enable_explicit_port_randomisation" in
1814         no)
1815                 AC_DEFINE([DISABLE_EXPLICIT_PORT_RANDOMISATION], [1], [Define this to enable kernel based UDP source port randomization.])
1816                 ;;
1817         yes|*)
1818                 ;;
1819 esac
1820
1821
1822 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1823 # on openBSD, the implicit rule make $< work.
1824 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1825 # gmake works.
1826 cat >conftest.make <<EOF
1827 all:    conftest.lo
1828
1829 conftest.lo foo.lo bla.lo:
1830         if test -f "\$<"; then touch \$@; fi
1831
1832 .SUFFIXES: .lo
1833 .c.lo:
1834         if test -f "\$<"; then touch \$@; fi
1835
1836 conftest.lo:        conftest.dir/conftest.c
1837 EOF
1838 mkdir conftest.dir
1839 touch conftest.dir/conftest.c
1840 rm -f conftest.lo conftest.c
1841 ${MAKE:-make} -f conftest.make >/dev/null
1842 rm -f conftest.make conftest.c conftest.dir/conftest.c
1843 rm -rf conftest.dir
1844 if test ! -f conftest.lo; then
1845         AC_MSG_RESULT(no)
1846         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1847         SOURCEFILE='`cat .source`'
1848 else
1849         AC_MSG_RESULT(yes)
1850         SOURCEDETERMINE=':'
1851         SOURCEFILE='$<'
1852 fi
1853 rm -f conftest.lo
1854 AC_SUBST(SOURCEDETERMINE)
1855 AC_SUBST(SOURCEFILE)
1856
1857 # see if we want to build the library or everything
1858 ALLTARGET="alltargets"
1859 INSTALLTARGET="install-all"
1860 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1861         [do not build daemon and tool programs]),
1862         [
1863         if test "$withval" = "yes"; then
1864                 ALLTARGET="lib"
1865                 INSTALLTARGET="install-lib"
1866         fi
1867 ])
1868 if test $ALLTARGET = "alltargets"; then
1869         if test $USE_NSS = "yes"; then
1870                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1871         fi
1872         if test $USE_NETTLE = "yes"; then
1873                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1874         fi
1875 fi
1876
1877 AC_SUBST(ALLTARGET)
1878 AC_SUBST(INSTALLTARGET)
1879
1880 ACX_STRIP_EXT_FLAGS
1881 if test -n "$LATE_LDFLAGS"; then
1882   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1883 fi
1884 # remove start spaces
1885 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1886 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1887
1888 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1889
1890 AH_BOTTOM(
1891 dnl this must be first AH_CONFIG, to define the flags before any includes.
1892 AHX_CONFIG_EXT_FLAGS
1893
1894 dnl includes
1895 [
1896 #ifndef _OPENBSD_SOURCE
1897 #define _OPENBSD_SOURCE 1
1898 #endif
1899
1900 #ifndef UNBOUND_DEBUG
1901 # ifndef NDEBUG
1902 #  define NDEBUG
1903 # endif
1904 #endif
1905
1906 /** Use small-ldns codebase */
1907 #define USE_SLDNS 1
1908 #ifdef HAVE_SSL
1909 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1910 #endif
1911
1912 #include <stdio.h>
1913 #include <string.h>
1914 #include <unistd.h>
1915 #include <assert.h>
1916
1917 #if STDC_HEADERS
1918 #include <stdlib.h>
1919 #include <stddef.h>
1920 #endif
1921
1922 #ifdef HAVE_STDARG_H
1923 #include <stdarg.h>
1924 #endif
1925
1926 #ifdef HAVE_STDINT_H
1927 #include <stdint.h>
1928 #endif
1929
1930 #include <errno.h>
1931
1932 #if HAVE_SYS_PARAM_H
1933 #include <sys/param.h>
1934 #endif
1935
1936 #ifdef HAVE_SYS_SOCKET_H
1937 #include <sys/socket.h>
1938 #endif
1939
1940 #ifdef HAVE_SYS_UIO_H
1941 #include <sys/uio.h>
1942 #endif
1943
1944 #ifdef HAVE_NETINET_IN_H
1945 #include <netinet/in.h>
1946 #endif
1947
1948 #ifdef HAVE_NETINET_TCP_H
1949 #include <netinet/tcp.h>
1950 #endif
1951
1952 #ifdef HAVE_ARPA_INET_H
1953 #include <arpa/inet.h>
1954 #endif
1955
1956 #ifdef HAVE_WINSOCK2_H
1957 #include <winsock2.h>
1958 #endif
1959
1960 #ifdef HAVE_WS2TCPIP_H
1961 #include <ws2tcpip.h>
1962 #endif
1963
1964 #ifndef USE_WINSOCK
1965 #define ARG_LL "%ll"
1966 #else
1967 #define ARG_LL "%I64"
1968 #endif
1969
1970 #ifndef AF_LOCAL
1971 #define AF_LOCAL AF_UNIX
1972 #endif
1973 ]
1974
1975 AHX_CONFIG_FORMAT_ATTRIBUTE
1976 AHX_CONFIG_UNUSED_ATTRIBUTE
1977 AHX_CONFIG_FSEEKO
1978 AHX_CONFIG_MAXHOSTNAMELEN
1979 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1980 #define snprintf snprintf_unbound
1981 #define vsnprintf vsnprintf_unbound
1982 #include <stdarg.h>
1983 int snprintf (char *str, size_t count, const char *fmt, ...);
1984 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1985 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1986 AHX_CONFIG_INET_PTON(unbound)
1987 AHX_CONFIG_INET_NTOP(unbound)
1988 AHX_CONFIG_INET_ATON(unbound)
1989 AHX_CONFIG_MEMMOVE(unbound)
1990 AHX_CONFIG_STRLCAT(unbound)
1991 AHX_CONFIG_STRLCPY(unbound)
1992 AHX_CONFIG_GMTIME_R(unbound)
1993 AHX_CONFIG_REALLOCARRAY(unbound)
1994 AHX_CONFIG_W32_SLEEP
1995 AHX_CONFIG_W32_USLEEP
1996 AHX_CONFIG_W32_RANDOM
1997 AHX_CONFIG_W32_SRANDOM
1998 AHX_CONFIG_W32_FD_SET_T
1999 AHX_CONFIG_IPV6_MIN_MTU
2000 AHX_MEMCMP_BROKEN(unbound)
2001
2002 [
2003 #ifndef HAVE_CTIME_R
2004 #define ctime_r unbound_ctime_r
2005 char *ctime_r(const time_t *timep, char *buf);
2006 #endif
2007
2008 #ifndef HAVE_STRSEP
2009 #define strsep unbound_strsep
2010 char *strsep(char **stringp, const char *delim);
2011 #endif
2012
2013 #ifndef HAVE_ISBLANK
2014 #define isblank unbound_isblank
2015 int isblank(int c);
2016 #endif
2017
2018 #ifndef HAVE_EXPLICIT_BZERO
2019 #define explicit_bzero unbound_explicit_bzero
2020 void explicit_bzero(void* buf, size_t len);
2021 #endif
2022
2023 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
2024 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
2025 #endif
2026
2027 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
2028 int inet_pton(int af, const char* src, void* dst);
2029 #endif
2030
2031 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
2032 #define strptime unbound_strptime
2033 struct tm;
2034 char *strptime(const char *s, const char *format, struct tm *tm);
2035 #endif
2036
2037 #if !HAVE_DECL_REALLOCARRAY
2038 void *reallocarray(void *ptr, size_t nmemb, size_t size);
2039 #endif
2040
2041 #ifdef HAVE_LIBBSD
2042 #include <bsd/string.h>
2043 #include <bsd/stdlib.h>
2044 #endif
2045
2046 #ifdef HAVE_LIBRESSL
2047 #  if !HAVE_DECL_STRLCPY
2048 size_t strlcpy(char *dst, const char *src, size_t siz);
2049 #  endif
2050 #  if !HAVE_DECL_STRLCAT
2051 size_t strlcat(char *dst, const char *src, size_t siz);
2052 #  endif
2053 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
2054 uint32_t arc4random(void);
2055 #  endif
2056 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
2057 uint32_t arc4random_uniform(uint32_t upper_bound);
2058 #  endif
2059 #endif /* HAVE_LIBRESSL */
2060 #ifndef HAVE_ARC4RANDOM
2061 int getentropy(void* buf, size_t len);
2062 uint32_t arc4random(void);
2063 void arc4random_buf(void* buf, size_t n);
2064 void _ARC4_LOCK(void);
2065 void _ARC4_UNLOCK(void);
2066 void _ARC4_LOCK_DESTROY(void);
2067 #endif
2068 #ifndef HAVE_ARC4RANDOM_UNIFORM
2069 uint32_t arc4random_uniform(uint32_t upper_bound);
2070 #endif
2071 #ifdef COMPAT_SHA512
2072 #ifndef SHA512_DIGEST_LENGTH
2073 #define SHA512_BLOCK_LENGTH             128
2074 #define SHA512_DIGEST_LENGTH            64
2075 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
2076 typedef struct _SHA512_CTX {
2077         uint64_t        state[8];
2078         uint64_t        bitcount[2];
2079         uint8_t buffer[SHA512_BLOCK_LENGTH];
2080 } SHA512_CTX;
2081 #endif /* SHA512_DIGEST_LENGTH */
2082 void SHA512_Init(SHA512_CTX*);
2083 void SHA512_Update(SHA512_CTX*, void*, size_t);
2084 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
2085 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
2086 #endif /* COMPAT_SHA512 */
2087
2088
2089
2090 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
2091    /* using version of libevent that is not threadsafe. */
2092 #  define LIBEVENT_SIGNAL_PROBLEM 1
2093 #endif
2094
2095 #ifndef CHECKED_INET6
2096 #  define CHECKED_INET6
2097 #  ifdef AF_INET6
2098 #    define INET6
2099 #  else
2100 #    define AF_INET6        28
2101 #  endif
2102 #endif /* CHECKED_INET6 */
2103
2104 #ifndef HAVE_GETADDRINFO
2105 struct sockaddr_storage;
2106 #include "compat/fake-rfc2553.h"
2107 #endif
2108
2109 #ifdef UNBOUND_ALLOC_STATS
2110 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
2111 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
2112 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
2113 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
2114 void *unbound_stat_malloc(size_t size);
2115 void *unbound_stat_calloc(size_t nmemb, size_t size);
2116 void unbound_stat_free(void *ptr);
2117 void *unbound_stat_realloc(void *ptr, size_t size);
2118 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
2119         const char* func);
2120 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
2121         int line, const char* func);
2122 void unbound_stat_free_log(void *ptr, const char* file, int line,
2123         const char* func);
2124 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
2125         int line, const char* func);
2126 #elif defined(UNBOUND_ALLOC_LITE)
2127 #  include "util/alloc.h"
2128 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
2129
2130 /** default port for DNS traffic. */
2131 #define UNBOUND_DNS_PORT 53
2132 /** default port for DNS over TLS traffic. */
2133 #define UNBOUND_DNS_OVER_TLS_PORT 853
2134 /** default port for unbound control traffic, registered port with IANA,
2135     ub-dns-control  8953/tcp    unbound dns nameserver control */
2136 #define UNBOUND_CONTROL_PORT 8953
2137 /** the version of unbound-control that this software implements */
2138 #define UNBOUND_CONTROL_VERSION 1
2139
2140 ])
2141
2142 dnl if we build from source tree, the man pages need @date@ and @version@
2143 dnl if this is a distro tarball, that was already done by makedist.sh
2144 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
2145 AC_SUBST(date, [`date +'%b %e, %Y'`])
2146
2147 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service contrib/unbound_portable.service])
2148 AC_CONFIG_HEADER([config.h])
2149 AC_OUTPUT