cddl/contrib/dtracetoolkit/JavaScript/js_calltime.d

   1 #!/usr/sbin/dtrace -Zs
   2 /*
   3  * js_calltime.d - measure JavaScript elapsed times for types of operation.
   4  *                 Written for the JavaScript DTrace provider.
   5  *
   6  * $Id: js_calltime.d 63 2007-10-04 04:34:38Z brendan $
   7  *
   8  * This traces JavaScript activity from all browsers running on the system with
   9  * JavaScript provider support.
  10  *
  11  * USAGE: js_calltime.d         # hit Ctrl-C to end
  12  *
  13  * FIELDS:
  14  *              FILE            Filename of the JavaScript program
  15  *              TYPE            Type of call (func/obj-new/gc/total)
  16  *              NAME            Name of call
  17  *              TOTAL           Total elapsed time for calls (us)
  18  *
  19  * Filename and function names are printed if available.
  20  *
  21  * COPYRIGHT: Copyright (c) 2007 Brendan Gregg.
  22  *
  23  * CDDL HEADER START
  24  *
  25  *  The contents of this file are subject to the terms of the
  26  *  Common Development and Distribution License, Version 1.0 only
  27  *  (the "License").  You may not use this file except in compliance
  28  *  with the License.
  29  *
  30  *  You can obtain a copy of the license at Docs/cddl1.txt
  31  *  or http://www.opensolaris.org/os/licensing.
  32  *  See the License for the specific language governing permissions
  33  *  and limitations under the License.
  34  *
  35  * CDDL HEADER END
  36  *
  37  * 09-Sep-2007  Brendan Gregg   Created this.
  38  */
  39
  40 #pragma D option quiet
  41
  42 dtrace:::BEGIN
  43 {
  44         printf("Tracing... Hit Ctrl-C to end.\n");
  45 }
  46
  47 javascript*:::function-entry
  48 {
  49         self->depth++;
  50         self->exclude[self->depth] = 0;
  51         self->function[self->depth] = timestamp;
  52 }
  53
  54 javascript*:::function-return
  55 /self->function[self->depth]/
  56 {
  57         this->elapsed_incl = timestamp - self->function[self->depth];
  58         this->elapsed_excl = this->elapsed_incl - self->exclude[self->depth];
  59         self->function[self->depth] = 0;
  60         self->exclude[self->depth] = 0;
  61         this->file = basename(copyinstr(arg0));
  62         this->name = copyinstr(arg2);
  63
  64         @num[this->file, "func", this->name] = count();
  65         @num["-", "total", "-"] = count();
  66         @types_incl[this->file, "func", this->name] = sum(this->elapsed_incl);
  67         @types_excl[this->file, "func", this->name] = sum(this->elapsed_excl);
  68         @types_excl["-", "total", "-"] = sum(this->elapsed_excl);
  69
  70         self->depth--;
  71         self->exclude[self->depth] += this->elapsed_incl;
  72 }
  73
  74 javascript*:::object-create-start
  75 {
  76         self->object = timestamp;
  77 }
  78
  79 javascript*:::object-create-done
  80 /self->object/
  81 {
  82         this->elapsed = timestamp - self->object;
  83         self->object = 0;
  84         this->file = basename(copyinstr(arg0));
  85         this->name = copyinstr(arg1);
  86
  87         @num[this->file, "obj-new", this->name] = count();
  88         @num["-", "total", "-"] = count();
  89         @types[this->file, "obj-new", this->name] = sum(this->elapsed);
  90         @types["-", "total", "-"] = sum(this->elapsed);
  91
  92         self->exclude[self->depth] += this->elapsed;
  93 }
  94
  95 dtrace:::END
  96 {
  97         printf("\nCount,\n");
  98         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "COUNT");
  99         printa("   %-20.20s %-10s %-32s %@8d\n", @num);
 100
 101         normalize(@types, 1000);
 102         printf("\nElapsed times (us),\n");
 103         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
 104         printa("   %-20.20s %-10s %-32s %@8d\n", @types);
 105
 106         normalize(@types_excl, 1000);
 107         printf("\nExclusive function elapsed times (us),\n");
 108         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
 109         printa("   %-20.20s %-10s %-32s %@8d\n", @types_excl);
 110
 111         normalize(@types_incl, 1000);
 112         printf("\nInclusive function elapsed times (us),\n");
 113         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
 114         printa("   %-20.20s %-10s %-32s %@8d\n", @types_incl);
 115 }