cddl/contrib/dtracetoolkit/Perl/pl_calltime.d

   1 #!/usr/sbin/dtrace -Zs
   2 /*
   3  * pl_calltime.d - measure Perl elapsed times for subroutines.
   4  *                 Written for the Perl DTrace provider.
   5  *
   6  * $Id: pl_calltime.d 41 2007-09-17 02:20:10Z brendan $
   7  *
   8  * This traces Perl activity from all programs running on the system with
   9  * Perl provider support.
  10  *
  11  * USAGE: pl_calltime.d         # hit Ctrl-C to end
  12  *
  13  * FIELDS:
  14  *              FILE            Filename of the Perl program
  15  *              TYPE            Type of call (sub/total)
  16  *              NAME            Name of call
  17  *              TOTAL           Total elapsed time for calls (us)
  18  *
  19  * Filename and subroutine names are printed if available.
  20  *
  21  * COPYRIGHT: Copyright (c) 2007 Brendan Gregg.
  22  *
  23  * CDDL HEADER START
  24  *
  25  *  The contents of this file are subject to the terms of the
  26  *  Common Development and Distribution License, Version 1.0 only
  27  *  (the "License").  You may not use this file except in compliance
  28  *  with the License.
  29  *
  30  *  You can obtain a copy of the license at Docs/cddl1.txt
  31  *  or http://www.opensolaris.org/os/licensing.
  32  *  See the License for the specific language governing permissions
  33  *  and limitations under the License.
  34  *
  35  * CDDL HEADER END
  36  *
  37  * 09-Sep-2007  Brendan Gregg   Created this.
  38  */
  39
  40 #pragma D option quiet
  41
  42 dtrace:::BEGIN
  43 {
  44         printf("Tracing... Hit Ctrl-C to end.\n");
  45 }
  46
  47 perl*:::sub-entry
  48 {
  49         self->depth++;
  50         self->exclude[self->depth] = 0;
  51         self->sub[self->depth] = timestamp;
  52 }
  53
  54 perl*:::sub-return
  55 /self->sub[self->depth]/
  56 {
  57         this->elapsed_incl = timestamp - self->sub[self->depth];
  58         this->elapsed_excl = this->elapsed_incl - self->exclude[self->depth];
  59         self->sub[self->depth] = 0;
  60         self->exclude[self->depth] = 0;
  61         this->file = basename(copyinstr(arg1));
  62         this->name = copyinstr(arg0);
  63
  64         @num[this->file, "sub", this->name] = count();
  65         @num["-", "total", "-"] = count();
  66         @types_incl[this->file, "sub", this->name] = sum(this->elapsed_incl);
  67         @types_excl[this->file, "sub", this->name] = sum(this->elapsed_excl);
  68         @types_excl["-", "total", "-"] = sum(this->elapsed_excl);
  69
  70         self->depth--;
  71         self->exclude[self->depth] += this->elapsed_incl;
  72 }
  73
  74 dtrace:::END
  75 {
  76         printf("\nCount,\n");
  77         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "COUNT");
  78         printa("   %-20s %-10s %-32s %@8d\n", @num);
  79
  80         normalize(@types_excl, 1000);
  81         printf("\nExclusive subroutine elapsed times (us),\n");
  82         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
  83         printa("   %-20s %-10s %-32s %@8d\n", @types_excl);
  84
  85         normalize(@types_incl, 1000);
  86         printf("\nInclusive subroutine elapsed times (us),\n");
  87         printf("   %-20s %-10s %-32s %8s\n", "FILE", "TYPE", "NAME", "TOTAL");
  88         printa("   %-20s %-10s %-32s %@8d\n", @types_incl);
  89 }