sys/boot/arm/uboot/start.S

   1 /*-
   2  * Copyright (c) 2008 Semihalf, Rafal Czubak
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD$
  27  */
  28
  29 #include <machine/asm.h>
  30 #include <machine/armreg.h>
  31
  32 /*
  33  * Entry point to the loader that U-Boot passes control to.
  34  */
  35         .text
  36         .globl  _start
  37 _start:
  38         /* Hint where to look for the API signature */
  39         ldr     ip, =uboot_address
  40         str     sp, [ip]
  41
  42         /* Save U-Boot's r8 and r9 */
  43         ldr     ip, =saved_regs
  44         str     r8, [ip, #0]
  45         str     r9, [ip, #4]
  46
  47 #ifdef _ARM_ARCH_6
  48         mrc     p15, 0, r2, c1, c0, 0
  49         orr     r2, r2, #(CPU_CONTROL_UNAL_ENABLE)
  50         orr     r2, r2, #(CPU_CONTROL_AFLT_ENABLE)
  51         mcr     p15, 0, r2, c1, c0, 0
  52 #endif
  53
  54         /* Start loader */
  55         b       main
  56
  57 /*
  58  * syscall()
  59  */
  60 ENTRY(syscall)
  61         /* Save caller's lr, r8 and r9 */
  62         ldr     ip, =saved_regs
  63         str     r8, [ip, #8]
  64         str     r9, [ip, #12]
  65         str     lr, [ip, #16]
  66         /* Restore U-Boot's r8 and r9 */
  67         ldr     r8, [ip, #0]
  68         ldr     r9, [ip, #4]
  69         /* Call into U-Boot */
  70         ldr     lr, =return_from_syscall
  71         ldr     ip, =syscall_ptr
  72         ldr     pc, [ip]
  73 return_from_syscall:
  74         /* Restore loader's r8, r9 and lr */
  75         ldr     ip, =saved_regs
  76         ldr     lr, [ip, #16]
  77         ldr     r9, [ip, #12]
  78         ldr     r8, [ip, #8]
  79         /* Return to caller */
  80         mov     pc, lr
  81
  82 /*
  83  * Data section
  84  */
  85         .data
  86         .align  4
  87         .globl  syscall_ptr
  88 syscall_ptr:
  89         .long   0
  90
  91         .globl  uboot_address
  92 uboot_address:
  93         .long   0
  94
  95 saved_regs:
  96         .long   0       /* U-Boot's r8 */
  97         .long   0       /* U-Boot's r9 */
  98         .long   0       /* Loader's r8 */
  99         .long   0       /* Loader's r9 */
 100         .long   0       /* Loader's lr */