sys/i386/i386/swtch.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * $FreeBSD$
  33  */
  34
  35 #include "opt_npx.h"
  36 #include "opt_sched.h"
  37
  38 #include <machine/asmacros.h>
  39
  40 #include "assym.s"
  41
  42 #if defined(SMP) && defined(SCHED_ULE)
  43 #define SETOP           xchgl
  44 #define BLOCK_SPIN(reg)                                                 \
  45                 movl            $blocked_lock,%eax ;                    \
  46         100: ;                                                          \
  47                 lock ;                                                  \
  48                 cmpxchgl        %eax,TD_LOCK(reg) ;                     \
  49                 jne             101f ;                                  \
  50                 pause ;                                                 \
  51                 jmp             100b ;                                  \
  52         101:
  53 #else
  54 #define SETOP           movl
  55 #define BLOCK_SPIN(reg)
  56 #endif
  57
  58 /*****************************************************************************/
  59 /* Scheduling                                                                */
  60 /*****************************************************************************/
  61
  62         .text
  63
  64 /*
  65  * cpu_throw()
  66  *
  67  * This is the second half of cpu_switch(). It is used when the current
  68  * thread is either a dummy or slated to die, and we no longer care
  69  * about its state.  This is only a slight optimization and is probably
  70  * not worth it anymore.  Note that we need to clear the pm_active bits so
  71  * we do need the old proc if it still exists.
  72  * 0(%esp) = ret
  73  * 4(%esp) = oldtd
  74  * 8(%esp) = newtd
  75  */
  76 ENTRY(cpu_throw)
  77         movl    PCPU(CPUID), %esi
  78         movl    4(%esp),%ecx                    /* Old thread */
  79         testl   %ecx,%ecx                       /* no thread? */
  80         jz      1f
  81         /* release bit from old pm_active */
  82         movl    PCPU(CURPMAP), %ebx
  83 #ifdef SMP
  84         lock
  85 #endif
  86         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
  87 1:
  88         movl    8(%esp),%ecx                    /* New thread */
  89         movl    TD_PCB(%ecx),%edx
  90         movl    PCB_CR3(%edx),%eax
  91         LOAD_CR3(%eax)
  92         /* set bit in new pm_active */
  93         movl    TD_PROC(%ecx),%eax
  94         movl    P_VMSPACE(%eax), %ebx
  95         addl    $VM_PMAP, %ebx
  96         movl    %ebx, PCPU(CURPMAP)
  97 #ifdef SMP
  98         lock
  99 #endif
 100         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 101         jmp     sw1
 102 END(cpu_throw)
 103
 104 /*
 105  * cpu_switch(old, new)
 106  *
 107  * Save the current thread state, then select the next thread to run
 108  * and load its state.
 109  * 0(%esp) = ret
 110  * 4(%esp) = oldtd
 111  * 8(%esp) = newtd
 112  * 12(%esp) = newlock
 113  */
 114 ENTRY(cpu_switch)
 115
 116         /* Switch to new thread.  First, save context. */
 117         movl    4(%esp),%ecx
 118
 119 #ifdef INVARIANTS
 120         testl   %ecx,%ecx                       /* no thread? */
 121         jz      badsw2                          /* no, panic */
 122 #endif
 123
 124         movl    TD_PCB(%ecx),%edx
 125
 126         movl    (%esp),%eax                     /* Hardware registers */
 127         movl    %eax,PCB_EIP(%edx)
 128         movl    %ebx,PCB_EBX(%edx)
 129         movl    %esp,PCB_ESP(%edx)
 130         movl    %ebp,PCB_EBP(%edx)
 131         movl    %esi,PCB_ESI(%edx)
 132         movl    %edi,PCB_EDI(%edx)
 133         mov     %gs,PCB_GS(%edx)
 134         pushfl                                  /* PSL */
 135         popl    PCB_PSL(%edx)
 136         /* Test if debug registers should be saved. */
 137         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 138         jz      1f                              /* no, skip over */
 139         movl    %dr7,%eax                       /* yes, do the save */
 140         movl    %eax,PCB_DR7(%edx)
 141         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 142         movl    %eax,%dr7
 143         movl    %dr6,%eax
 144         movl    %eax,PCB_DR6(%edx)
 145         movl    %dr3,%eax
 146         movl    %eax,PCB_DR3(%edx)
 147         movl    %dr2,%eax
 148         movl    %eax,PCB_DR2(%edx)
 149         movl    %dr1,%eax
 150         movl    %eax,PCB_DR1(%edx)
 151         movl    %dr0,%eax
 152         movl    %eax,PCB_DR0(%edx)
 153 1:
 154
 155 #ifdef DEV_NPX
 156         /* have we used fp, and need a save? */
 157         cmpl    %ecx,PCPU(FPCURTHREAD)
 158         jne     1f
 159         pushl   PCB_SAVEFPU(%edx)               /* h/w bugs make saving complicated */
 160         call    npxsave                         /* do it in a big C function */
 161         popl    %eax
 162 1:
 163 #endif
 164
 165         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 166         movl    4(%esp),%edi
 167         movl    8(%esp),%ecx                    /* New thread */
 168         movl    12(%esp),%esi                   /* New lock */
 169 #ifdef INVARIANTS
 170         testl   %ecx,%ecx                       /* no thread? */
 171         jz      badsw3                          /* no, panic */
 172 #endif
 173         movl    TD_PCB(%ecx),%edx
 174
 175         /* switch address space */
 176         movl    PCB_CR3(%edx),%eax
 177 #if defined(PAE) || defined(PAE_TABLES)
 178         cmpl    %eax,IdlePDPT                   /* Kernel address space? */
 179 #else
 180         cmpl    %eax,IdlePTD                    /* Kernel address space? */
 181 #endif
 182         je      sw0
 183         READ_CR3(%ebx)                          /* The same address space? */
 184         cmpl    %ebx,%eax
 185         je      sw0
 186         LOAD_CR3(%eax)                          /* new address space */
 187         movl    %esi,%eax
 188         movl    PCPU(CPUID),%esi
 189         SETOP   %eax,TD_LOCK(%edi)              /* Switchout td_lock */
 190
 191         /* Release bit from old pmap->pm_active */
 192         movl    PCPU(CURPMAP), %ebx
 193 #ifdef SMP
 194         lock
 195 #endif
 196         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
 197
 198         /* Set bit in new pmap->pm_active */
 199         movl    TD_PROC(%ecx),%eax              /* newproc */
 200         movl    P_VMSPACE(%eax), %ebx
 201         addl    $VM_PMAP, %ebx
 202         movl    %ebx, PCPU(CURPMAP)
 203 #ifdef SMP
 204         lock
 205 #endif
 206         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 207         jmp     sw1
 208
 209 sw0:
 210         SETOP   %esi,TD_LOCK(%edi)              /* Switchout td_lock */
 211 sw1:
 212         BLOCK_SPIN(%ecx)
 213 #ifdef XEN
 214         pushl   %eax
 215         pushl   %ecx
 216         pushl   %edx
 217         call    xen_handle_thread_switch
 218         popl    %edx
 219         popl    %ecx
 220         popl    %eax
 221         /*
 222          * XXX set IOPL
 223          */
 224 #else
 225         /*
 226          * At this point, we've switched address spaces and are ready
 227          * to load up the rest of the next context.
 228          */
 229         cmpl    $0, PCB_EXT(%edx)               /* has pcb extension? */
 230         je      1f                              /* If not, use the default */
 231         movl    $1, PCPU(PRIVATE_TSS)           /* mark use of private tss */
 232         movl    PCB_EXT(%edx), %edi             /* new tss descriptor */
 233         jmp     2f                              /* Load it up */
 234
 235 1:      /*
 236          * Use the common default TSS instead of our own.
 237          * Set our stack pointer into the TSS, it's set to just
 238          * below the PCB.  In C, common_tss.tss_esp0 = &pcb - 16;
 239          */
 240         leal    -16(%edx), %ebx                 /* leave space for vm86 */
 241         movl    %ebx, PCPU(COMMON_TSS) + TSS_ESP0
 242
 243         /*
 244          * Test this CPU's  bit in the bitmap to see if this
 245          * CPU was using a private TSS.
 246          */
 247         cmpl    $0, PCPU(PRIVATE_TSS)           /* Already using the common? */
 248         je      3f                              /* if so, skip reloading */
 249         movl    $0, PCPU(PRIVATE_TSS)
 250         PCPU_ADDR(COMMON_TSSD, %edi)
 251 2:
 252         /* Move correct tss descriptor into GDT slot, then reload tr. */
 253         movl    PCPU(TSS_GDT), %ebx             /* entry in GDT */
 254         movl    0(%edi), %eax
 255         movl    4(%edi), %esi
 256         movl    %eax, 0(%ebx)
 257         movl    %esi, 4(%ebx)
 258         movl    $GPROC0_SEL*8, %esi             /* GSEL(GPROC0_SEL, SEL_KPL) */
 259         ltr     %si
 260 3:
 261
 262         /* Copy the %fs and %gs selectors into this pcpu gdt */
 263         leal    PCB_FSD(%edx), %esi
 264         movl    PCPU(FSGS_GDT), %edi
 265         movl    0(%esi), %eax           /* %fs selector */
 266         movl    4(%esi), %ebx
 267         movl    %eax, 0(%edi)
 268         movl    %ebx, 4(%edi)
 269         movl    8(%esi), %eax           /* %gs selector, comes straight after */
 270         movl    12(%esi), %ebx
 271         movl    %eax, 8(%edi)
 272         movl    %ebx, 12(%edi)
 273 #endif
 274         /* Restore context. */
 275         movl    PCB_EBX(%edx),%ebx
 276         movl    PCB_ESP(%edx),%esp
 277         movl    PCB_EBP(%edx),%ebp
 278         movl    PCB_ESI(%edx),%esi
 279         movl    PCB_EDI(%edx),%edi
 280         movl    PCB_EIP(%edx),%eax
 281         movl    %eax,(%esp)
 282         pushl   PCB_PSL(%edx)
 283         popfl
 284
 285         movl    %edx, PCPU(CURPCB)
 286         movl    TD_TID(%ecx),%eax
 287         movl    %ecx, PCPU(CURTHREAD)           /* into next thread */
 288
 289         /*
 290          * Determine the LDT to use and load it if is the default one and
 291          * that is not the current one.
 292          */
 293         movl    TD_PROC(%ecx),%eax
 294         cmpl    $0,P_MD+MD_LDT(%eax)
 295         jnz     1f
 296         movl    _default_ldt,%eax
 297         cmpl    PCPU(CURRENTLDT),%eax
 298         je      2f
 299         LLDT(_default_ldt)
 300         movl    %eax,PCPU(CURRENTLDT)
 301         jmp     2f
 302 1:
 303         /* Load the LDT when it is not the default one. */
 304         pushl   %edx                            /* Preserve pointer to pcb. */
 305         addl    $P_MD,%eax                      /* Pointer to mdproc is arg. */
 306         pushl   %eax
 307         call    set_user_ldt
 308         addl    $4,%esp
 309         popl    %edx
 310 2:
 311
 312         /* This must be done after loading the user LDT. */
 313         .globl  cpu_switch_load_gs
 314 cpu_switch_load_gs:
 315         mov     PCB_GS(%edx),%gs
 316
 317         pushl   %edx
 318         pushl   PCPU(CURTHREAD)
 319         call    npxswitch
 320         popl    %edx
 321         popl    %edx
 322
 323         /* Test if debug registers should be restored. */
 324         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 325         jz      1f
 326
 327         /*
 328          * Restore debug registers.  The special code for dr7 is to
 329          * preserve the current values of its reserved bits.
 330          */
 331         movl    PCB_DR6(%edx),%eax
 332         movl    %eax,%dr6
 333         movl    PCB_DR3(%edx),%eax
 334         movl    %eax,%dr3
 335         movl    PCB_DR2(%edx),%eax
 336         movl    %eax,%dr2
 337         movl    PCB_DR1(%edx),%eax
 338         movl    %eax,%dr1
 339         movl    PCB_DR0(%edx),%eax
 340         movl    %eax,%dr0
 341         movl    %dr7,%eax
 342         andl    $0x0000fc00,%eax
 343         movl    PCB_DR7(%edx),%ecx
 344         andl    $~0x0000fc00,%ecx
 345         orl     %ecx,%eax
 346         movl    %eax,%dr7
 347 1:
 348         ret
 349
 350 #ifdef INVARIANTS
 351 badsw1:
 352         pushal
 353         pushl   $sw0_1
 354         call    panic
 355 sw0_1:  .asciz  "cpu_throw: no newthread supplied"
 356
 357 badsw2:
 358         pushal
 359         pushl   $sw0_2
 360         call    panic
 361 sw0_2:  .asciz  "cpu_switch: no curthread supplied"
 362
 363 badsw3:
 364         pushal
 365         pushl   $sw0_3
 366         call    panic
 367 sw0_3:  .asciz  "cpu_switch: no newthread supplied"
 368 #endif
 369 END(cpu_switch)
 370
 371 /*
 372  * savectx(pcb)
 373  * Update pcb, saving current processor state.
 374  */
 375 ENTRY(savectx)
 376         /* Fetch PCB. */
 377         movl    4(%esp),%ecx
 378
 379         /* Save caller's return address.  Child won't execute this routine. */
 380         movl    (%esp),%eax
 381         movl    %eax,PCB_EIP(%ecx)
 382
 383         movl    %cr3,%eax
 384         movl    %eax,PCB_CR3(%ecx)
 385
 386         movl    %ebx,PCB_EBX(%ecx)
 387         movl    %esp,PCB_ESP(%ecx)
 388         movl    %ebp,PCB_EBP(%ecx)
 389         movl    %esi,PCB_ESI(%ecx)
 390         movl    %edi,PCB_EDI(%ecx)
 391         mov     %gs,PCB_GS(%ecx)
 392         pushfl
 393         popl    PCB_PSL(%ecx)
 394
 395         movl    %cr0,%eax
 396         movl    %eax,PCB_CR0(%ecx)
 397         movl    %cr2,%eax
 398         movl    %eax,PCB_CR2(%ecx)
 399         movl    %cr4,%eax
 400         movl    %eax,PCB_CR4(%ecx)
 401
 402         movl    %dr0,%eax
 403         movl    %eax,PCB_DR0(%ecx)
 404         movl    %dr1,%eax
 405         movl    %eax,PCB_DR1(%ecx)
 406         movl    %dr2,%eax
 407         movl    %eax,PCB_DR2(%ecx)
 408         movl    %dr3,%eax
 409         movl    %eax,PCB_DR3(%ecx)
 410         movl    %dr6,%eax
 411         movl    %eax,PCB_DR6(%ecx)
 412         movl    %dr7,%eax
 413         movl    %eax,PCB_DR7(%ecx)
 414
 415         mov     %ds,PCB_DS(%ecx)
 416         mov     %es,PCB_ES(%ecx)
 417         mov     %fs,PCB_FS(%ecx)
 418         mov     %ss,PCB_SS(%ecx)
 419
 420         sgdt    PCB_GDT(%ecx)
 421         sidt    PCB_IDT(%ecx)
 422         sldt    PCB_LDT(%ecx)
 423         str     PCB_TR(%ecx)
 424
 425         movl    $1,%eax
 426         ret
 427 END(savectx)
 428
 429 /*
 430  * resumectx(pcb) __fastcall
 431  * Resuming processor state from pcb.
 432  */
 433 ENTRY(resumectx)
 434         /* Restore GDT. */
 435         lgdt    PCB_GDT(%ecx)
 436
 437         /* Restore segment registers */
 438         movzwl  PCB_DS(%ecx),%eax
 439         mov     %ax,%ds
 440         movzwl  PCB_ES(%ecx),%eax
 441         mov     %ax,%es
 442         movzwl  PCB_FS(%ecx),%eax
 443         mov     %ax,%fs
 444         movzwl  PCB_GS(%ecx),%eax
 445         movw    %ax,%gs
 446         movzwl  PCB_SS(%ecx),%eax
 447         mov     %ax,%ss
 448
 449         /* Restore CR2, CR4, CR3 and CR0 */
 450         movl    PCB_CR2(%ecx),%eax
 451         movl    %eax,%cr2
 452         movl    PCB_CR4(%ecx),%eax
 453         movl    %eax,%cr4
 454         movl    PCB_CR3(%ecx),%eax
 455         movl    %eax,%cr3
 456         movl    PCB_CR0(%ecx),%eax
 457         movl    %eax,%cr0
 458         jmp     1f
 459 1:
 460
 461         /* Restore descriptor tables */
 462         lidt    PCB_IDT(%ecx)
 463         lldt    PCB_LDT(%ecx)
 464
 465 #define SDT_SYS386TSS   9
 466 #define SDT_SYS386BSY   11
 467         /* Clear "task busy" bit and reload TR */
 468         movl    PCPU(TSS_GDT),%eax
 469         andb    $(~SDT_SYS386BSY | SDT_SYS386TSS),5(%eax)
 470         movzwl  PCB_TR(%ecx),%eax
 471         ltr     %ax
 472 #undef SDT_SYS386TSS
 473 #undef SDT_SYS386BSY
 474
 475         /* Restore debug registers */
 476         movl    PCB_DR0(%ecx),%eax
 477         movl    %eax,%dr0
 478         movl    PCB_DR1(%ecx),%eax
 479         movl    %eax,%dr1
 480         movl    PCB_DR2(%ecx),%eax
 481         movl    %eax,%dr2
 482         movl    PCB_DR3(%ecx),%eax
 483         movl    %eax,%dr3
 484         movl    PCB_DR6(%ecx),%eax
 485         movl    %eax,%dr6
 486         movl    PCB_DR7(%ecx),%eax
 487         movl    %eax,%dr7
 488
 489         /* Restore other registers */
 490         movl    PCB_EDI(%ecx),%edi
 491         movl    PCB_ESI(%ecx),%esi
 492         movl    PCB_EBP(%ecx),%ebp
 493         movl    PCB_ESP(%ecx),%esp
 494         movl    PCB_EBX(%ecx),%ebx
 495
 496         /* reload code selector by turning return into intersegmental return */
 497         pushl   PCB_EIP(%ecx)
 498         movl    $KCSEL,4(%esp)
 499         xorl    %eax,%eax
 500         lret
 501 END(resumectx)