CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 # If we are not building as a part of LLVM, build Clang as an
   4 # standalone project, using LLVM as an external library:
   5 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
   6   project(Clang)
   7
   8   # Rely on llvm-config.
   9   set(CONFIG_OUTPUT)
  10   find_program(LLVM_CONFIG "llvm-config")
  11   if(LLVM_CONFIG)
  12     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  13     set(CONFIG_COMMAND ${LLVM_CONFIG}
  14       "--assertion-mode"
  15       "--bindir"
  16       "--libdir"
  17       "--includedir"
  18       "--prefix"
  19       "--src-root"
  20       "--cmakedir")
  21     execute_process(
  22       COMMAND ${CONFIG_COMMAND}
  23       RESULT_VARIABLE HAD_ERROR
  24       OUTPUT_VARIABLE CONFIG_OUTPUT
  25     )
  26     if(NOT HAD_ERROR)
  27       string(REGEX REPLACE
  28         "[ \t]*[\r\n]+[ \t]*" ";"
  29         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  30     else()
  31       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  32       message(STATUS "${CONFIG_COMMAND_STR}")
  33       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  34     endif()
  35   else()
  36     message(FATAL_ERROR "llvm-config not found -- ${LLVM_CONFIG}")
  37   endif()
  38
  39   list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  40   list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  41   list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  42   list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  43   list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  44   list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  45   list(GET CONFIG_OUTPUT 6 LLVM_CONFIG_CMAKE_PATH)
  46
  47   if(NOT MSVC_IDE)
  48     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  49       CACHE BOOL "Enable assertions")
  50     # Assertions should follow llvm-config's.
  51     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  52   endif()
  53
  54   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  55   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  56   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  57   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  58   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  59
  60   # Normalize LLVM_CMAKE_PATH. --cmakedir might contain backslashes.
  61   # CMake assumes slashes as PATH.
  62   file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_PATH} LLVM_CMAKE_PATH)
  63
  64   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  65     NO_DEFAULT_PATH)
  66
  67   set(LLVMCONFIG_FILE "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  68   if(EXISTS ${LLVMCONFIG_FILE})
  69     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  70     include(${LLVMCONFIG_FILE})
  71   else()
  72     message(FATAL_ERROR "Not found: ${LLVMCONFIG_FILE}")
  73   endif()
  74
  75   # They are used as destination of target generators.
  76   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  77   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  78   if(WIN32 OR CYGWIN)
  79     # DLL platform -- put DLLs into bin.
  80     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  81   else()
  82     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  83   endif()
  84
  85   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
  86   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  87     "Only include toolchain files in the 'install' target." OFF)
  88
  89   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
  90     "Set to ON to force using an old, unsupported host toolchain." OFF)
  91   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  92
  93   include(AddLLVM)
  94   include(TableGen)
  95   include(HandleLLVMOptions)
  96   include(VersionFromVCS)
  97
  98   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  99
 100   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 101     set(LLVM_INCLUDE_TESTS ON)
 102   endif()
 103
 104   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 105   link_directories("${LLVM_LIBRARY_DIR}")
 106
 107   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 108   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 109   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 110
 111   if(LLVM_INCLUDE_TESTS)
 112     set(Python_ADDITIONAL_VERSIONS 2.7)
 113     include(FindPythonInterp)
 114     if(NOT PYTHONINTERP_FOUND)
 115       message(FATAL_ERROR
 116 "Unable to find Python interpreter, required for builds and testing.
 117
 118 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 119     endif()
 120
 121     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 122       message(FATAL_ERROR "Python 2.7 or newer is required")
 123     endif()
 124
 125     # Check prebuilt llvm/utils.
 126     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 127         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 128         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 129       set(LLVM_UTILS_PROVIDED ON)
 130     endif()
 131
 132     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 133       # Note: path not really used, except for checking if lit was found
 134       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 135       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 136         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 137       endif()
 138       if(NOT LLVM_UTILS_PROVIDED)
 139         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 140         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 141         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 142         set(LLVM_UTILS_PROVIDED ON)
 143         set(CLANG_TEST_DEPS FileCheck count not)
 144       endif()
 145       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 146       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 147           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 148           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 149         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 150       endif()
 151     else()
 152       # Seek installed Lit.
 153       find_program(LLVM_LIT
 154                    NAMES llvm-lit lit.py lit
 155                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 156                    DOC "Path to lit.py")
 157     endif()
 158
 159     if(LLVM_LIT)
 160       # Define the default arguments to use with 'lit', and an option for the user
 161       # to override.
 162       set(LIT_ARGS_DEFAULT "-sv")
 163       if (MSVC OR XCODE)
 164         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 165       endif()
 166       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 167
 168       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 169       if( WIN32 AND NOT CYGWIN )
 170         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 171       endif()
 172     else()
 173       set(LLVM_INCLUDE_TESTS OFF)
 174     endif()
 175   endif()
 176
 177   set( CLANG_BUILT_STANDALONE 1 )
 178   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 179 else()
 180   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 181 endif()
 182
 183 # Make sure that our source directory is on the current cmake module path so that
 184 # we can include cmake files from this directory.
 185 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 186
 187 # Don't look for libxml if we're using MSan, since uninstrumented third party
 188 # code may call MSan interceptors like strlen, leading to false positives.
 189 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 190   set (LIBXML2_FOUND 0)
 191   find_package(LibXml2 2.5.3 QUIET)
 192   if (LIBXML2_FOUND)
 193     set(CLANG_HAVE_LIBXML 1)
 194   endif()
 195 endif()
 196
 197 include(CheckIncludeFile)
 198 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 199
 200 set(CLANG_RESOURCE_DIR "" CACHE STRING
 201   "Relative directory from the Clang binary to its resource files.")
 202
 203 set(C_INCLUDE_DIRS "" CACHE STRING
 204   "Colon separated list of directories clang will search for headers.")
 205
 206 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 207 set(DEFAULT_SYSROOT "" CACHE PATH
 208   "Default <path> to all compiler invocations for --sysroot=<path>." )
 209
 210 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 211
 212 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 213     "enable x86 relax relocations by default")
 214
 215 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 216   "Default linker to use (linker name or absolute path, empty for platform default)")
 217
 218 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 219   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 220 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 221         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 222         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 223   message(WARNING "Resetting default C++ stdlib to use platform default")
 224   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 225     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 226 endif()
 227
 228 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 229   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 230 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 231         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 232         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 233   message(WARNING "Resetting default rtlib to use platform default")
 234   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 235     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 236 endif()
 237
 238 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 239   "Default objcopy executable to use.")
 240
 241 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 242   "Default OpenMP runtime used by -fopenmp.")
 243
 244 # OpenMP offloading requires at least sm_35 because we use shuffle instructions
 245 # to generate efficient code for reductions and the atomicMax instruction on
 246 # 64-bit integers in the implementation of conditional lastprivate.
 247 set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 248   "Default architecture for OpenMP offloading to Nvidia GPUs.")
 249 string(REGEX MATCH "^sm_([0-9]+)$" MATCHED_ARCH "${CLANG_OPENMP_NVPTX_DEFAULT_ARCH}")
 250 if (NOT DEFINED MATCHED_ARCH OR "${CMAKE_MATCH_1}" LESS 35)
 251   message(WARNING "Resetting default architecture for OpenMP offloading to Nvidia GPUs to sm_35")
 252   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 253     "Default architecture for OpenMP offloading to Nvidia GPUs." FORCE)
 254 endif()
 255
 256 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 257   "Vendor-specific text for showing with version information.")
 258
 259 if( CLANG_VENDOR )
 260   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 261 endif()
 262
 263 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 264   "Vendor-specific text for showing the repository the source is taken from.")
 265
 266 if(CLANG_REPOSITORY_STRING)
 267   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 268 endif()
 269
 270 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 271   "Vendor-specific uti.")
 272
 273 # The libdir suffix must exactly match whatever LLVM's configuration used.
 274 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 275
 276 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 277 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 278
 279 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 280   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 281 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 282 "from there, passing the path to this source directory as the last argument. "
 283 "This process created the file `CMakeCache.txt' and the directory "
 284 "`CMakeFiles'. Please delete them.")
 285 endif()
 286
 287 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 288   file(GLOB_RECURSE
 289     tablegenned_files_on_include_dir
 290     "${CLANG_SOURCE_DIR}/include/clang/*.inc")
 291   if( tablegenned_files_on_include_dir )
 292     message(FATAL_ERROR "Apparently there is a previous in-source build, "
 293 "probably as the result of running `configure' and `make' on "
 294 "${CLANG_SOURCE_DIR}. This may cause problems. The suspicious files are:\n"
 295 "${tablegenned_files_on_include_dir}\nPlease clean the source directory.")
 296   endif()
 297 endif()
 298
 299 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 300 if(NOT DEFINED CLANG_VERSION_MAJOR)
 301   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 302 endif()
 303 if(NOT DEFINED CLANG_VERSION_MINOR)
 304   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 305 endif()
 306 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 307   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 308 endif()
 309 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 310 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 311 message(STATUS "Clang version: ${CLANG_VERSION}")
 312
 313 # Configure the Version.inc file.
 314 configure_file(
 315   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 316   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 317
 318 # Add appropriate flags for GCC
 319 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 320   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 321   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 322     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 323   endif ()
 324
 325   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 326   if (NOT LLVM_ENABLE_PEDANTIC)
 327     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 328   endif ()
 329
 330   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 331   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 332     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 333   endif()
 334 endif ()
 335
 336 # Determine HOST_LINK_VERSION on Darwin.
 337 set(HOST_LINK_VERSION)
 338 if (APPLE)
 339   set(LD_V_OUTPUT)
 340   execute_process(
 341     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 342     RESULT_VARIABLE HAD_ERROR
 343     OUTPUT_VARIABLE LD_V_OUTPUT
 344   )
 345   if (NOT HAD_ERROR)
 346     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 347       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 348     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 349       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 350     endif()
 351   else()
 352     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 353   endif()
 354 endif()
 355
 356 include(CMakeParseArguments)
 357 include(AddClang)
 358
 359 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 360
 361 include_directories(BEFORE
 362   ${CMAKE_CURRENT_BINARY_DIR}/include
 363   ${CMAKE_CURRENT_SOURCE_DIR}/include
 364   )
 365
 366 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 367   install(DIRECTORY include/clang include/clang-c
 368     DESTINATION include
 369     FILES_MATCHING
 370     PATTERN "*.def"
 371     PATTERN "*.h"
 372     PATTERN "config.h" EXCLUDE
 373     PATTERN ".svn" EXCLUDE
 374     )
 375
 376   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 377     DESTINATION include
 378     FILES_MATCHING
 379     PATTERN "CMakeFiles" EXCLUDE
 380     PATTERN "*.inc"
 381     PATTERN "*.h"
 382     )
 383
 384   install(PROGRAMS utils/bash-autocomplete.sh
 385     DESTINATION share/clang
 386     )
 387 endif()
 388
 389 add_definitions( -D_GNU_SOURCE )
 390
 391 option(CLANG_BUILD_TOOLS
 392   "Build the Clang tools. If OFF, just generate build targets." ON)
 393
 394 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 395 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 396
 397 option(CLANG_ANALYZER_BUILD_Z3
 398   "Build the static analyzer with the Z3 constraint manager." OFF)
 399
 400 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 401
 402 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND (CLANG_ENABLE_ARCMT OR CLANG_ANALYZER_BUILD_Z3))
 403   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 404 endif()
 405
 406 if(CLANG_ANALYZER_BUILD_Z3)
 407   find_package(Z3 4.5)
 408   if(Z3_FOUND)
 409     set(CLANG_ANALYZER_WITH_Z3 1)
 410   else()
 411     message(FATAL_ERROR "Cannot find Z3 header file or shared library")
 412   endif()
 413 endif()
 414
 415 if(CLANG_ENABLE_ARCMT)
 416   set(CLANG_ENABLE_OBJC_REWRITER ON)
 417 endif()
 418
 419 # Clang version information
 420 set(CLANG_EXECUTABLE_VERSION
 421      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 422     "Version number that will be placed into the clang executable, in the form XX.YY")
 423 set(LIBCLANG_LIBRARY_VERSION
 424      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 425     "Version number that will be placed into the libclang library , in the form XX.YY")
 426 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 427
 428 option(CLANG_INCLUDE_TESTS
 429        "Generate build targets for the Clang unit tests."
 430        ${LLVM_INCLUDE_TESTS})
 431
 432 add_subdirectory(utils/TableGen)
 433
 434 add_subdirectory(include)
 435
 436 # All targets below may depend on all tablegen'd files.
 437 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 438 add_custom_target(clang-tablegen-targets DEPENDS ${CLANG_TABLEGEN_TARGETS})
 439 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 440 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 441
 442 # Force target to be built as soon as possible. Clang modules builds depend
 443 # header-wise on it as they ship all headers from the umbrella folders. Building
 444 # an entire module might include header, which depends on intrinsics_gen.
 445 if(LLVM_ENABLE_MODULES AND NOT CLANG_BUILT_STANDALONE)
 446   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 447 endif()
 448
 449 add_subdirectory(lib)
 450 add_subdirectory(tools)
 451 add_subdirectory(runtime)
 452
 453 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 454 add_subdirectory(examples)
 455
 456 if(APPLE)
 457   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 458   # default value get updated to the new default.
 459   if(CLANG_ORDER_FILE STREQUAL "")
 460     unset(CLANG_ORDER_FILE CACHE)
 461     unset(CLANG_ORDER_FILE)
 462   endif()
 463
 464
 465   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 466     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 467
 468   if(NOT EXISTS ${CLANG_ORDER_FILE})
 469     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 470     if(PATH_START EQUAL 0)
 471       file(WRITE ${CLANG_ORDER_FILE} "\n")
 472     else()
 473       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 474     endif()
 475   endif()
 476 endif()
 477
 478
 479 if( CLANG_INCLUDE_TESTS )
 480   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 481     add_subdirectory(unittests)
 482     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 483     list(APPEND CLANG_TEST_PARAMS
 484       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 485       )
 486   endif()
 487   add_subdirectory(test)
 488
 489   if(CLANG_BUILT_STANDALONE)
 490     # Add a global check rule now that all subdirectories have been traversed
 491     # and we know the total set of lit testsuites.
 492     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 493     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 494     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 495     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 496     add_lit_target(check-all
 497       "Running all regression tests"
 498       ${LLVM_LIT_TESTSUITES}
 499       PARAMS ${LLVM_LIT_PARAMS}
 500       DEPENDS ${LLVM_LIT_DEPENDS}
 501       ARGS ${LLVM_LIT_EXTRA_ARGS}
 502       )
 503   endif()
 504   add_subdirectory(utils/perf-training)
 505 endif()
 506
 507 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 508   ${LLVM_INCLUDE_DOCS})
 509 if( CLANG_INCLUDE_DOCS )
 510   add_subdirectory(docs)
 511 endif()
 512
 513 add_subdirectory(cmake/modules)
 514
 515 if(CLANG_STAGE)
 516   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 517 endif()
 518
 519 if (CLANG_ENABLE_BOOTSTRAP)
 520   include(ExternalProject)
 521
 522   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 523
 524   if(NOT CLANG_STAGE)
 525     set(CLANG_STAGE stage1)
 526   endif()
 527
 528   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 529   if(MATCHED_STAGE)
 530     if(NOT LLVM_BUILD_INSTRUMENTED)
 531       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 532       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 533     else()
 534       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 535     endif()
 536   else()
 537     set(NEXT_CLANG_STAGE bootstrap)
 538   endif()
 539
 540   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 541     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 542   endif()
 543   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 544
 545
 546   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 547   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 548
 549   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 550     add_dependencies(clang-bootstrap-deps lld)
 551   endif()
 552
 553   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 554   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 555     if(APPLE)
 556       add_dependencies(clang-bootstrap-deps LTO)
 557       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 558       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 559       # so that the host object file tools will use the just-built libLTO.
 560       # However if System Integrity Protection is enabled the DYLD variables
 561       # will be scrubbed from the environment of any base system commands. This
 562       # includes /bin/sh, which ninja uses when executing build commands. To
 563       # work around the envar being filtered away we pass it in as a CMake
 564       # variable, and have LLVM's CMake append the envar to the archiver calls.
 565       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 566         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 567     elseif(NOT WIN32)
 568       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 569       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 570         add_dependencies(clang-bootstrap-deps LLVMgold)
 571       endif()
 572       set(LTO_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 573       set(LTO_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 574     endif()
 575   endif()
 576
 577   add_custom_target(${NEXT_CLANG_STAGE}-clear
 578     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 579     )
 580   add_custom_command(
 581     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 582     DEPENDS clang-bootstrap-deps
 583     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 584     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 585     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 586     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 587     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 588     )
 589
 590   if(CMAKE_VERBOSE_MAKEFILE)
 591     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 592   endif()
 593
 594   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 595     PACKAGE_VERSION
 596     PACKAGE_VENDOR
 597     LLVM_VERSION_MAJOR
 598     LLVM_VERSION_MINOR
 599     LLVM_VERSION_PATCH
 600     CLANG_VERSION_MAJOR
 601     CLANG_VERSION_MINOR
 602     CLANG_VERSION_PATCHLEVEL
 603     LLVM_VERSION_SUFFIX
 604     LLVM_BINUTILS_INCDIR
 605     CLANG_REPOSITORY_STRING
 606     CMAKE_MAKE_PROGRAM
 607     CMAKE_OSX_ARCHITECTURES
 608     LLVM_ENABLE_PROJECTS
 609     LLVM_ENABLE_RUNTIMES)
 610
 611   # We don't need to depend on compiler-rt if we're building instrumented
 612   # because the next stage will use the same compiler used to build this stage.
 613   if(TARGET compiler-rt AND NOT LLVM_BUILD_INSTRUMENTED)
 614     add_dependencies(clang-bootstrap-deps compiler-rt)
 615   endif()
 616
 617   set(C_COMPILER "clang")
 618   set(CXX_COMPILER "clang++")
 619   if(WIN32)
 620     set(C_COMPILER "clang-cl.exe")
 621     set(CXX_COMPILER "clang-cl.exe")
 622   endif()
 623
 624   set(COMPILER_OPTIONS
 625     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 626     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 627     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER})
 628
 629   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 630     add_dependencies(clang-bootstrap-deps llvm-profdata)
 631     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 632   endif()
 633
 634   if(LLVM_BUILD_INSTRUMENTED)
 635     add_dependencies(clang-bootstrap-deps generate-profdata)
 636     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 637     # Use the current tools for LTO instead of the instrumented ones
 638     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 639       CMAKE_CXX_COMPILER
 640       CMAKE_C_COMPILER
 641       CMAKE_ASM_COMPILER
 642       CMAKE_AR
 643       CMAKE_RANLIB
 644       DARWIN_LTO_LIBRARY
 645       DYLD_LIBRARY_PATH)
 646
 647     set(COMPILER_OPTIONS)
 648     set(LTO_LIBRARY)
 649     set(LTO_AR)
 650     set(LTO_RANLIB)
 651   endif()
 652
 653   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 654   # them.
 655   get_cmake_property(variableNames VARIABLES)
 656   foreach(variableName ${variableNames})
 657     if(variableName MATCHES "^BOOTSTRAP_")
 658       string(SUBSTRING ${variableName} 10 -1 varName)
 659       string(REPLACE ";" "|" value "${${variableName}}")
 660       list(APPEND PASSTHROUGH_VARIABLES
 661         -D${varName}=${value})
 662     endif()
 663     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 664       list(APPEND PASSTHROUGH_VARIABLES
 665         -D${variableName}=${${variableName}})
 666     endif()
 667   endforeach()
 668
 669   # Populate the passthrough variables
 670   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 671     if(DEFINED ${variableName})
 672       if("${${variableName}}" STREQUAL "")
 673         set(value "")
 674       else()
 675         string(REPLACE ";" "|" value "${${variableName}}")
 676       endif()
 677       list(APPEND PASSTHROUGH_VARIABLES
 678         -D${variableName}=${value})
 679     endif()
 680   endforeach()
 681
 682   ExternalProject_Add(${NEXT_CLANG_STAGE}
 683     DEPENDS clang-bootstrap-deps
 684     PREFIX ${NEXT_CLANG_STAGE}
 685     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 686     STAMP_DIR ${STAMP_DIR}
 687     BINARY_DIR ${BINARY_DIR}
 688     EXCLUDE_FROM_ALL 1
 689     CMAKE_ARGS
 690                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 691                 # seem to work, so instead I'm passing this through
 692                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 693                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 694                 ${PASSTHROUGH_VARIABLES}
 695                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 696                 ${COMPILER_OPTIONS}
 697                 ${LTO_LIBRARY} ${LTO_AR} ${LTO_RANLIB} ${verbose} ${PGO_OPT}
 698     INSTALL_COMMAND ""
 699     STEP_TARGETS configure build
 700     USES_TERMINAL_CONFIGURE 1
 701     USES_TERMINAL_BUILD 1
 702     USES_TERMINAL_INSTALL 1
 703     LIST_SEPARATOR |
 704     )
 705
 706   # exclude really-install from main target
 707   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 708   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 709     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 710     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 711     DEPENDEES build
 712     USES_TERMINAL 1
 713   )
 714   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 715   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 716
 717   if(NOT CLANG_BOOTSTRAP_TARGETS)
 718     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 719   endif()
 720   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 721     # exclude from main target
 722     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 723
 724     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 725       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 726       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 727       DEPENDEES configure
 728       USES_TERMINAL 1
 729     )
 730
 731     if(target MATCHES "^stage[0-9]*")
 732       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 733     endif()
 734
 735     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 736   endforeach()
 737 endif()
 738
 739 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 740   add_subdirectory(utils/ClangVisualizers)
 741 endif()
 742
 743 configure_file(
 744   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 745   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)