CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # An important constraint of the build is that it only produces libraries
   4 # based on the ability of the host toolchain to target various platforms.
   5
   6 cmake_minimum_required(VERSION 3.4.3)
   7
   8 # Check if compiler-rt is built as a standalone project.
   9 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR COMPILER_RT_STANDALONE_BUILD)
  10   project(CompilerRT C CXX ASM)
  11   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  12 endif()
  13
  14 # Add path for custom compiler-rt modules.
  15 list(INSERT CMAKE_MODULE_PATH 0
  16   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  17   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  18   )
  19
  20 if(CMAKE_CONFIGURATION_TYPES)
  21   set(CMAKE_CFG_RESOLVED_INTDIR "${CMAKE_CFG_INTDIR}/")
  22 else()
  23   set(CMAKE_CFG_RESOLVED_INTDIR "")
  24 endif()
  25
  26 include(base-config-ix)
  27 include(CompilerRTUtils)
  28
  29 option(COMPILER_RT_BUILD_BUILTINS "Build builtins" ON)
  30 mark_as_advanced(COMPILER_RT_BUILD_BUILTINS)
  31 option(COMPILER_RT_BUILD_SANITIZERS "Build sanitizers" ON)
  32 mark_as_advanced(COMPILER_RT_BUILD_SANITIZERS)
  33 option(COMPILER_RT_BUILD_XRAY "Build xray" ON)
  34 mark_as_advanced(COMPILER_RT_BUILD_XRAY)
  35 option(COMPILER_RT_BUILD_LIBFUZZER "Build libFuzzer" ON)
  36 mark_as_advanced(COMPILER_RT_BUILD_LIBFUZZER)
  37 option(COMPILER_RT_BUILD_PROFILE "Build profile runtime" ON)
  38 mark_as_advanced(COMPILER_RT_BUILD_PROFILE)
  39 option(COMPILER_RT_BUILD_XRAY_NO_PREINIT "Build xray with no preinit patching" OFF)
  40 mark_as_advanced(COMPILER_RT_BUILD_XRAY_NO_PREINIT)
  41
  42 set(COMPILER_RT_ASAN_SHADOW_SCALE ""
  43     CACHE STRING "Override the shadow scale to be used in ASan runtime")
  44
  45 if (NOT COMPILER_RT_ASAN_SHADOW_SCALE STREQUAL "")
  46   # Check that the shadow scale value is valid.
  47   if (NOT (COMPILER_RT_ASAN_SHADOW_SCALE GREATER -1 AND
  48            COMPILER_RT_ASAN_SHADOW_SCALE LESS 8))
  49     message(FATAL_ERROR "
  50       Invalid ASan Shadow Scale '${COMPILER_RT_ASAN_SHADOW_SCALE}'.")
  51   endif()
  52
  53   set(COMPILER_RT_ASAN_SHADOW_SCALE_LLVM_FLAG
  54       -mllvm -asan-mapping-scale=${COMPILER_RT_ASAN_SHADOW_SCALE})
  55   set(COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION
  56       ASAN_SHADOW_SCALE=${COMPILER_RT_ASAN_SHADOW_SCALE})
  57   set(COMPILER_RT_ASAN_SHADOW_SCALE_FLAG
  58       -D${COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION})
  59 endif()
  60
  61 set(COMPILER_RT_BAREMETAL_BUILD OFF CACHE BOOLEAN
  62   "Build for a bare-metal target.")
  63
  64 if (COMPILER_RT_STANDALONE_BUILD)
  65   load_llvm_config()
  66
  67   # Find Python interpreter.
  68   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
  69   include(FindPythonInterp)
  70   if(NOT PYTHONINTERP_FOUND)
  71     message(FATAL_ERROR "
  72       Unable to find Python interpreter required testing. Please install Python
  73       or specify the PYTHON_EXECUTABLE CMake variable.")
  74   endif()
  75
  76   # Define default arguments to lit.
  77   set(LIT_ARGS_DEFAULT "-sv")
  78   if (MSVC OR XCODE)
  79     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  80   endif()
  81   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
  82   set(LLVM_LIT_OUTPUT_DIR "${COMPILER_RT_EXEC_OUTPUT_DIR}")
  83 endif()
  84
  85 construct_compiler_rt_default_triple()
  86 if ("${COMPILER_RT_DEFAULT_TARGET_ABI}" MATCHES "hf$")
  87   if (${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "^arm")
  88     set(COMPILER_RT_DEFAULT_TARGET_ARCH "armhf")
  89   endif()
  90 endif()
  91 if ("${COMPILER_RT_DEFAULT_TARGET_ABI}" MATCHES "^android")
  92   set(ANDROID 1)
  93 endif()
  94 pythonize_bool(ANDROID)
  95
  96 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  97 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  98
  99 # We support running instrumented tests when we're not cross compiling
 100 # and target a UNIX-like system or Windows.
 101 # We can run tests on Android even when we are cross-compiling.
 102 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND (UNIX OR WIN32)) OR ANDROID
 103    OR COMPILER_RT_EMULATOR)
 104   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 105 else()
 106   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 107 endif()
 108
 109 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 110 option(COMPILER_RT_EXTERNALIZE_DEBUGINFO
 111   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 112 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 113 pythonize_bool(COMPILER_RT_DEBUG)
 114
 115 include(HandleCompilerRT)
 116 include(config-ix)
 117
 118 if(APPLE AND SANITIZER_MIN_OSX_VERSION AND SANITIZER_MIN_OSX_VERSION VERSION_LESS "10.9")
 119   # Mac OS X prior to 10.9 had problems with exporting symbols from
 120   # libc++/libc++abi.
 121   set(cxxabi_supported OFF)
 122 else()
 123   set(cxxabi_supported ON)
 124 endif()
 125
 126 option(SANITIZER_ALLOW_CXXABI "Allow use of C++ ABI details in ubsan" ON)
 127
 128 set(SANITIZE_CAN_USE_CXXABI OFF)
 129 if (cxxabi_supported AND SANITIZER_ALLOW_CXXABI)
 130   set(SANITIZER_CAN_USE_CXXABI ON)
 131 endif()
 132 pythonize_bool(SANITIZER_CAN_USE_CXXABI)
 133
 134 set(SANITIZER_CXX_ABI "default" CACHE STRING
 135     "Specify C++ ABI library to use.")
 136 set(CXXABIS none default libcxxabi libstdc++ libc++)
 137 set_property(CACHE SANITIZER_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
 138
 139 if (SANITIZER_CXX_ABI STREQUAL "default")
 140   if (HAVE_LIBCXXABI AND COMPILER_RT_DEFAULT_TARGET_ONLY)
 141     set(SANITIZER_CXX_ABI_LIBNAME "libcxxabi")
 142     set(SANITIZER_CXX_ABI_INTREE 1)
 143   elseif (APPLE)
 144     set(SANITIZER_CXX_ABI_LIBNAME "libcxxabi")
 145     set(SANITIZER_CXX_ABI_SYSTEM 1)
 146   else()
 147     set(SANITIZER_CXX_ABI_LIBNAME "libstdc++")
 148   endif()
 149 else()
 150   set(SANITIZER_CXX_ABI_LIBNAME "${SANITIZER_CXX_ABI}")
 151 endif()
 152
 153 if (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libcxxabi")
 154   if (SANITIZER_CXX_ABI_INTREE)
 155     if (TARGET unwind_shared OR HAVE_LIBUNWIND)
 156       list(APPEND SANITIZER_CXX_ABI_LIBRARY unwind_shared)
 157     endif()
 158     if (TARGET cxxabi_shared OR HAVE_LIBCXXABI)
 159       list(APPEND SANITIZER_CXX_ABI_LIBRARY cxxabi_shared)
 160     endif()
 161   else()
 162     list(APPEND SANITIZER_CXX_ABI_LIBRARY "c++abi")
 163   endif()
 164 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libc++")
 165   list(APPEND SANITIZER_CXX_ABI_LIBRARY "c++")
 166 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libstdc++")
 167   append_list_if(COMPILER_RT_HAS_LIBSTDCXX stdc++ SANITIZER_CXX_ABI_LIBRARY)
 168 endif()
 169
 170 option(SANITIZER_USE_COMPILER_RT "Use compiler-rt builtins instead of libgcc" OFF)
 171
 172 #================================
 173 # Setup Compiler Flags
 174 #================================
 175
 176 if(MSVC)
 177   # Override any existing /W flags with /W4. This is what LLVM does.  Failing to
 178   # remove other /W[0-4] flags will result in a warning about overriding a
 179   # previous flag.
 180   if (COMPILER_RT_HAS_W4_FLAG)
 181     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 182     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 183     append_string_if(COMPILER_RT_HAS_W4_FLAG /W4 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 184   endif()
 185 else()
 186   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 187 endif()
 188 if(COMPILER_RT_ENABLE_WERROR)
 189   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 190   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 191 endif()
 192
 193 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 194
 195 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 196 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 197   add_definitions(-D__func__=__FUNCTION__)
 198 endif()
 199
 200 # Provide some common commmandline flags for Sanitizer runtimes.
 201 if(NOT WIN32)
 202   append_list_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 203 endif()
 204 append_list_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 205 append_list_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 206 if(NOT COMPILER_RT_DEBUG AND NOT APPLE)
 207   append_list_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 208 endif()
 209 append_list_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 210 append_list_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 211 append_list_if(COMPILER_RT_HAS_FNO_SANITIZE_SAFE_STACK_FLAG -fno-sanitize=safe-stack SANITIZER_COMMON_CFLAGS)
 212 append_list_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 213 if(NOT COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG)
 214   append_list_if(COMPILER_RT_HAS_FVISIBILITY_INLINES_HIDDEN_FLAG -fvisibility-inlines-hidden SANITIZER_COMMON_CFLAGS)
 215 endif()
 216 append_list_if(COMPILER_RT_HAS_FNO_LTO_FLAG -fno-lto SANITIZER_COMMON_CFLAGS)
 217
 218 # The following is a workaround for powerpc64le. This is the only architecture
 219 # that requires -fno-function-sections to work properly. If lacking, the ASan
 220 # Linux test function-sections-are-bad.cc fails with the following error:
 221 # 'undefined symbol: __sanitizer_unaligned_load32'.
 222 if(DEFINED TARGET_powerpc64le_CFLAGS)
 223   append_list_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections TARGET_powerpc64le_CFLAGS)
 224 endif()
 225
 226 if(MSVC)
 227   # Replace the /M[DT][d] flags with /MT, and strip any definitions of _DEBUG,
 228   # which cause definition mismatches at link time.
 229   # FIXME: In fact, sanitizers should support both /MT and /MD, see PR20214.
 230   if(COMPILER_RT_HAS_MT_FLAG)
 231     foreach(flag_var
 232       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 233       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 234       CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 235       CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 236       string(REGEX REPLACE "/M[DT]d" "/MT" ${flag_var} "${${flag_var}}")
 237       string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 238       string(REGEX REPLACE "/D_DEBUG" "" ${flag_var} "${${flag_var}}")
 239     endforeach()
 240   endif()
 241   append_list_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 242   append_list_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 243   # VS 2015 (version 1900) added support for thread safe static initialization.
 244   # However, ASan interceptors run before CRT initialization, which causes the
 245   # new thread safe code to crash. Disable this feature for now.
 246   if (MSVC_VERSION GREATER 1899 OR "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 247     list(APPEND SANITIZER_COMMON_CFLAGS /Zc:threadSafeInit-)
 248   endif()
 249 endif()
 250
 251 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 SANITIZER_COMMON_CFLAGS)
 252
 253 # If we're using MSVC,
 254 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 255 if (NOT MSVC)
 256
 257   # Build with optimization, unless we're in debug mode.
 258   if(COMPILER_RT_DEBUG)
 259     list(APPEND SANITIZER_COMMON_CFLAGS -O0)
 260   else()
 261     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 262   endif()
 263 endif()
 264
 265 # Determine if we should restrict stack frame sizes.
 266 # Stack frames on PowerPC and Mips and in debug biuld can be much larger than
 267 # anticipated.
 268 # FIXME: Fix all sanitizers and add -Wframe-larger-than to
 269 # SANITIZER_COMMON_FLAGS
 270 if(COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG AND NOT COMPILER_RT_DEBUG
 271    AND NOT ${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "powerpc|mips")
 272   set(SANITIZER_LIMIT_FRAME_SIZE TRUE)
 273 else()
 274   set(SANITIZER_LIMIT_FRAME_SIZE FALSE)
 275 endif()
 276
 277 # Build sanitizer runtimes with debug info.
 278 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG AND NOT COMPILER_RT_DEBUG)
 279   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 280 elseif(COMPILER_RT_HAS_G_FLAG)
 281   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 282 elseif(MSVC)
 283   # Use /Z7 instead of /Zi for the asan runtime. This avoids the LNK4099
 284   # warning from the MS linker complaining that it can't find the 'vc140.pdb'
 285   # file used by our object library compilations.
 286   list(APPEND SANITIZER_COMMON_CFLAGS /Z7)
 287   llvm_replace_compiler_option(CMAKE_CXX_FLAGS "/Z[i7I]" "/Z7")
 288   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_DEBUG "/Z[i7I]" "/Z7")
 289   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELWITHDEBINFO "/Z[i7I]" "/Z7")
 290 endif()
 291
 292 if(LLVM_ENABLE_MODULES)
 293   # Sanitizers cannot be built with -fmodules. The interceptors intentionally
 294   # don't include system headers, which is incompatible with modules.
 295   list(APPEND SANITIZER_COMMON_CFLAGS -fno-modules)
 296 endif()
 297
 298 # Turn off several warnings.
 299 append_list_if(COMPILER_RT_HAS_WGNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 300 append_list_if(COMPILER_RT_HAS_WVARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 301 append_list_if(COMPILER_RT_HAS_WC99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 302 append_list_if(COMPILER_RT_HAS_WNON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 303 append_list_if(COMPILER_RT_HAS_WD4146_FLAG /wd4146 SANITIZER_COMMON_CFLAGS)
 304 append_list_if(COMPILER_RT_HAS_WD4291_FLAG /wd4291 SANITIZER_COMMON_CFLAGS)
 305 append_list_if(COMPILER_RT_HAS_WD4391_FLAG /wd4391 SANITIZER_COMMON_CFLAGS)
 306 append_list_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 307 append_list_if(COMPILER_RT_HAS_WD4800_FLAG /wd4800 SANITIZER_COMMON_CFLAGS)
 308
 309 # Set common link flags.
 310 append_list_if(COMPILER_RT_HAS_NODEFAULTLIBS_FLAG -nodefaultlibs SANITIZER_COMMON_LINK_FLAGS)
 311
 312 if (SANITIZER_USE_COMPILER_RT)
 313   list(APPEND SANITIZER_COMMON_LINK_FLAGS -rtlib=compiler-rt)
 314   find_compiler_rt_library(builtins COMPILER_RT_BUILTINS_LIBRARY)
 315   list(APPEND SANITIZER_COMMON_LINK_LIBS ${COMPILER_RT_BUILTINS_LIBRARY})
 316 else()
 317   if (ANDROID)
 318     append_list_if(COMPILER_RT_HAS_GCC_LIB gcc SANITIZER_COMMON_LINK_LIBS)
 319   else()
 320     append_list_if(COMPILER_RT_HAS_GCC_S_LIB gcc_s SANITIZER_COMMON_LINK_LIBS)
 321   endif()
 322 endif()
 323
 324 append_list_if(COMPILER_RT_HAS_LIBC c SANITIZER_COMMON_LINK_LIBS)
 325
 326 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
 327   list(APPEND SANITIZER_COMMON_LINK_FLAGS -Wl,-z,defs,-z,now,-z,relro)
 328   list(APPEND SANITIZER_COMMON_LINK_LIBS zircon)
 329 endif()
 330
 331 # Warnings to turn off for all libraries, not just sanitizers.
 332 append_string_if(COMPILER_RT_HAS_WUNUSED_PARAMETER_FLAG -Wno-unused-parameter CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 333
 334 if (CMAKE_LINKER MATCHES "link.exe$")
 335   # Silence MSVC linker warnings caused by empty object files. The
 336   # sanitizer libraries intentionally use ifdefs that result in empty
 337   # files, rather than skipping these files in the build system.
 338   # Ideally, we would pass this flag only for the libraries that need
 339   # it, but CMake doesn't seem to have a way to set linker flags for
 340   # individual static libraries, so we enable the suppression flag for
 341   # the whole compiler-rt project.
 342   append("/IGNORE:4221" CMAKE_STATIC_LINKER_FLAGS)
 343 endif()
 344
 345 add_subdirectory(include)
 346
 347 foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxx
 348                       ${LLVM_MAIN_SRC_DIR}/runtimes/libcxx
 349                       ${LLVM_MAIN_SRC_DIR}/../libcxx
 350                       ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
 351   if(IS_DIRECTORY ${path})
 352     set(COMPILER_RT_LIBCXX_PATH ${path})
 353     break()
 354   endif()
 355 endforeach()
 356
 357 set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/tools/lld)
 358 if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 359   set(COMPILER_RT_HAS_LLD TRUE)
 360 else()
 361   set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/../lld)
 362   if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 363     set(COMPILER_RT_HAS_LLD TRUE)
 364   else()
 365     set(COMPILER_RT_HAS_LLD FALSE)
 366   endif()
 367 endif()
 368 pythonize_bool(COMPILER_RT_HAS_LLD)
 369
 370 add_subdirectory(lib)
 371
 372 if(COMPILER_RT_INCLUDE_TESTS)
 373   add_subdirectory(unittests)
 374   add_subdirectory(test)
 375   if (COMPILER_RT_STANDALONE_BUILD)
 376     # If we have a valid source tree, generate llvm-lit into the bin directory.
 377     # The user can still choose to have the check targets *use* a different lit
 378     # by specifying -DLLVM_EXTERNAL_LIT, but we generate it regardless.
 379     if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 380       add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit ${CMAKE_CURRENT_BINARY_DIR}/llvm-lit)
 381     elseif(NOT EXISTS ${LLVM_EXTERNAL_LIT})
 382       message(WARNING "Could not find LLVM source directory and LLVM_EXTERNAL_LIT does not"
 383                        "point to a valid file.  You will not be able to run tests.")
 384     endif()
 385   endif()
 386 endif()