CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 # If we are not building as a part of LLVM, build Clang as an
   4 # standalone project, using LLVM as an external library:
   5 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
   6   project(Clang)
   7
   8   # Rely on llvm-config.
   9   set(CONFIG_OUTPUT)
  10   find_program(LLVM_CONFIG "llvm-config")
  11   if(LLVM_CONFIG)
  12     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  13     set(CONFIG_COMMAND ${LLVM_CONFIG}
  14       "--assertion-mode"
  15       "--bindir"
  16       "--libdir"
  17       "--includedir"
  18       "--prefix"
  19       "--src-root"
  20       "--cmakedir")
  21     execute_process(
  22       COMMAND ${CONFIG_COMMAND}
  23       RESULT_VARIABLE HAD_ERROR
  24       OUTPUT_VARIABLE CONFIG_OUTPUT
  25     )
  26     if(NOT HAD_ERROR)
  27       string(REGEX REPLACE
  28         "[ \t]*[\r\n]+[ \t]*" ";"
  29         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  30     else()
  31       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  32       message(STATUS "${CONFIG_COMMAND_STR}")
  33       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  34     endif()
  35   else()
  36     message(FATAL_ERROR "llvm-config not found -- ${LLVM_CONFIG}")
  37   endif()
  38
  39   list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  40   list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  41   list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  42   list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  43   list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  44   list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  45   list(GET CONFIG_OUTPUT 6 LLVM_CONFIG_CMAKE_PATH)
  46
  47   if(NOT MSVC_IDE)
  48     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  49       CACHE BOOL "Enable assertions")
  50     # Assertions should follow llvm-config's.
  51     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  52   endif()
  53
  54   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  55   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  56   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  57   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  58   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  59
  60   # Normalize LLVM_CMAKE_PATH. --cmakedir might contain backslashes.
  61   # CMake assumes slashes as PATH.
  62   file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_PATH} LLVM_CMAKE_PATH)
  63
  64   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  65     NO_DEFAULT_PATH)
  66
  67   set(LLVMCONFIG_FILE "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  68   if(EXISTS ${LLVMCONFIG_FILE})
  69     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  70     include(${LLVMCONFIG_FILE})
  71   else()
  72     message(FATAL_ERROR "Not found: ${LLVMCONFIG_FILE}")
  73   endif()
  74
  75   # They are used as destination of target generators.
  76   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  77   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  78   if(WIN32 OR CYGWIN)
  79     # DLL platform -- put DLLs into bin.
  80     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  81   else()
  82     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  83   endif()
  84
  85   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
  86   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  87     "Only include toolchain files in the 'install' target." OFF)
  88
  89   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
  90     "Set to ON to force using an old, unsupported host toolchain." OFF)
  91   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  92
  93   include(AddLLVM)
  94   include(TableGen)
  95   include(HandleLLVMOptions)
  96   include(VersionFromVCS)
  97
  98   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  99
 100   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 101     set(LLVM_INCLUDE_TESTS ON)
 102   endif()
 103
 104   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 105   link_directories("${LLVM_LIBRARY_DIR}")
 106
 107   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 108   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 109   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 110
 111   if(LLVM_INCLUDE_TESTS)
 112     set(Python_ADDITIONAL_VERSIONS 2.7)
 113     include(FindPythonInterp)
 114     if(NOT PYTHONINTERP_FOUND)
 115       message(FATAL_ERROR
 116 "Unable to find Python interpreter, required for builds and testing.
 117
 118 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 119     endif()
 120
 121     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 122       message(FATAL_ERROR "Python 2.7 or newer is required")
 123     endif()
 124
 125     # Check prebuilt llvm/utils.
 126     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 127         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 128         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 129       set(LLVM_UTILS_PROVIDED ON)
 130     endif()
 131
 132     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 133       # Note: path not really used, except for checking if lit was found
 134       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 135       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 136         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 137       endif()
 138       if(NOT LLVM_UTILS_PROVIDED)
 139         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 140         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 141         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 142         set(LLVM_UTILS_PROVIDED ON)
 143         set(CLANG_TEST_DEPS FileCheck count not)
 144       endif()
 145       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 146       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 147           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 148           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 149         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 150       endif()
 151     else()
 152       # Seek installed Lit.
 153       find_program(LLVM_LIT
 154                    NAMES llvm-lit lit.py lit
 155                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 156                    DOC "Path to lit.py")
 157     endif()
 158
 159     if(LLVM_LIT)
 160       # Define the default arguments to use with 'lit', and an option for the user
 161       # to override.
 162       set(LIT_ARGS_DEFAULT "-sv")
 163       if (MSVC OR XCODE)
 164         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 165       endif()
 166       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 167
 168       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 169       if( WIN32 AND NOT CYGWIN )
 170         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 171       endif()
 172     else()
 173       set(LLVM_INCLUDE_TESTS OFF)
 174     endif()
 175   endif()
 176
 177   set( CLANG_BUILT_STANDALONE 1 )
 178   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 179 else()
 180   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 181 endif()
 182
 183 # Make sure that our source directory is on the current cmake module path so that
 184 # we can include cmake files from this directory.
 185 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 186
 187 # Don't look for libxml if we're using MSan, since uninstrumented third party
 188 # code may call MSan interceptors like strlen, leading to false positives.
 189 if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 190   set (LIBXML2_FOUND 0)
 191   find_package(LibXml2 2.5.3 QUIET)
 192   if (LIBXML2_FOUND)
 193     set(CLANG_HAVE_LIBXML 1)
 194   endif()
 195 endif()
 196
 197 include(CheckIncludeFile)
 198 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 199
 200 set(CLANG_RESOURCE_DIR "" CACHE STRING
 201   "Relative directory from the Clang binary to its resource files.")
 202
 203 set(C_INCLUDE_DIRS "" CACHE STRING
 204   "Colon separated list of directories clang will search for headers.")
 205
 206 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 207 set(DEFAULT_SYSROOT "" CACHE PATH
 208   "Default <path> to all compiler invocations for --sysroot=<path>." )
 209
 210 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 211
 212 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 213     "enable x86 relax relocations by default")
 214
 215 set(ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER FALSE CACHE BOOL
 216   "Enable the experimental new pass manager by default.")
 217
 218 # TODO: verify the values against LangStandards.def?
 219 set(CLANG_DEFAULT_STD_C "" CACHE STRING
 220   "Default standard to use for C/ObjC code (IDENT from LangStandards.def, empty for platform default)")
 221 set(CLANG_DEFAULT_STD_CXX "" CACHE STRING
 222   "Default standard to use for C++/ObjC++ code (IDENT from LangStandards.def, empty for platform default)")
 223
 224 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 225   "Default linker to use (linker name or absolute path, empty for platform default)")
 226
 227 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 228   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 229 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 230         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 231         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 232   message(WARNING "Resetting default C++ stdlib to use platform default")
 233   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 234     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 235 endif()
 236
 237 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 238   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 239 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 240         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 241         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 242   message(WARNING "Resetting default rtlib to use platform default")
 243   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 244     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 245 endif()
 246
 247 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 248   "Default objcopy executable to use.")
 249
 250 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 251   "Default OpenMP runtime used by -fopenmp.")
 252
 253 # OpenMP offloading requires at least sm_35 because we use shuffle instructions
 254 # to generate efficient code for reductions and the atomicMax instruction on
 255 # 64-bit integers in the implementation of conditional lastprivate.
 256 set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 257   "Default architecture for OpenMP offloading to Nvidia GPUs.")
 258 string(REGEX MATCH "^sm_([0-9]+)$" MATCHED_ARCH "${CLANG_OPENMP_NVPTX_DEFAULT_ARCH}")
 259 if (NOT DEFINED MATCHED_ARCH OR "${CMAKE_MATCH_1}" LESS 35)
 260   message(WARNING "Resetting default architecture for OpenMP offloading to Nvidia GPUs to sm_35")
 261   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 262     "Default architecture for OpenMP offloading to Nvidia GPUs." FORCE)
 263 endif()
 264
 265 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 266   "Vendor-specific text for showing with version information.")
 267
 268 if( CLANG_VENDOR )
 269   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 270 endif()
 271
 272 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 273   "Vendor-specific text for showing the repository the source is taken from.")
 274
 275 if(CLANG_REPOSITORY_STRING)
 276   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 277 endif()
 278
 279 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 280   "Vendor-specific uti.")
 281
 282 # The libdir suffix must exactly match whatever LLVM's configuration used.
 283 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 284
 285 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 286 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 287
 288 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 289   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 290 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 291 "from there, passing the path to this source directory as the last argument. "
 292 "This process created the file `CMakeCache.txt' and the directory "
 293 "`CMakeFiles'. Please delete them.")
 294 endif()
 295
 296 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 297   file(GLOB_RECURSE
 298     tablegenned_files_on_include_dir
 299     "${CLANG_SOURCE_DIR}/include/clang/*.inc")
 300   if( tablegenned_files_on_include_dir )
 301     message(FATAL_ERROR "Apparently there is a previous in-source build, "
 302 "probably as the result of running `configure' and `make' on "
 303 "${CLANG_SOURCE_DIR}. This may cause problems. The suspicious files are:\n"
 304 "${tablegenned_files_on_include_dir}\nPlease clean the source directory.")
 305   endif()
 306 endif()
 307
 308 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 309 if(NOT DEFINED CLANG_VERSION_MAJOR)
 310   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 311 endif()
 312 if(NOT DEFINED CLANG_VERSION_MINOR)
 313   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 314 endif()
 315 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 316   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 317 endif()
 318 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 319 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 320 message(STATUS "Clang version: ${CLANG_VERSION}")
 321
 322 # Configure the Version.inc file.
 323 configure_file(
 324   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 325   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 326
 327 # Add appropriate flags for GCC
 328 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 329   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 330   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 331     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 332   endif ()
 333
 334   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 335   if (NOT LLVM_ENABLE_PEDANTIC)
 336     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 337   endif ()
 338
 339   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 340   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 341     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 342   endif()
 343 endif ()
 344
 345 # Determine HOST_LINK_VERSION on Darwin.
 346 set(HOST_LINK_VERSION)
 347 if (APPLE)
 348   set(LD_V_OUTPUT)
 349   execute_process(
 350     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 351     RESULT_VARIABLE HAD_ERROR
 352     OUTPUT_VARIABLE LD_V_OUTPUT
 353   )
 354   if (NOT HAD_ERROR)
 355     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 356       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 357     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 358       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 359     endif()
 360   else()
 361     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 362   endif()
 363 endif()
 364
 365 include(CMakeParseArguments)
 366 include(AddClang)
 367
 368 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 369
 370 include_directories(BEFORE
 371   ${CMAKE_CURRENT_BINARY_DIR}/include
 372   ${CMAKE_CURRENT_SOURCE_DIR}/include
 373   )
 374
 375 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 376   install(DIRECTORY include/clang include/clang-c
 377     DESTINATION include
 378     FILES_MATCHING
 379     PATTERN "*.def"
 380     PATTERN "*.h"
 381     PATTERN "config.h" EXCLUDE
 382     PATTERN ".svn" EXCLUDE
 383     )
 384
 385   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 386     DESTINATION include
 387     FILES_MATCHING
 388     PATTERN "CMakeFiles" EXCLUDE
 389     PATTERN "*.inc"
 390     PATTERN "*.h"
 391     )
 392
 393   install(PROGRAMS utils/bash-autocomplete.sh
 394     DESTINATION share/clang
 395     )
 396 endif()
 397
 398 add_definitions( -D_GNU_SOURCE )
 399
 400 option(CLANG_BUILD_TOOLS
 401   "Build the Clang tools. If OFF, just generate build targets." ON)
 402
 403 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 404 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 405
 406 option(CLANG_ANALYZER_BUILD_Z3
 407   "Build the static analyzer with the Z3 constraint manager." OFF)
 408
 409 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 410
 411 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND (CLANG_ENABLE_ARCMT OR CLANG_ANALYZER_BUILD_Z3))
 412   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 413 endif()
 414
 415 if(CLANG_ANALYZER_BUILD_Z3)
 416   find_package(Z3 4.5)
 417   if(Z3_FOUND)
 418     set(CLANG_ANALYZER_WITH_Z3 1)
 419   else()
 420     message(FATAL_ERROR "Cannot find Z3 header file or shared library")
 421   endif()
 422 endif()
 423
 424 if(CLANG_ENABLE_ARCMT)
 425   set(CLANG_ENABLE_OBJC_REWRITER ON)
 426 endif()
 427
 428 # Clang version information
 429 set(CLANG_EXECUTABLE_VERSION
 430     "${CLANG_VERSION_MAJOR}" CACHE STRING
 431     "Major version number that will be appended to the clang executable name")
 432 set(LIBCLANG_LIBRARY_VERSION
 433     "${CLANG_VERSION_MAJOR}" CACHE STRING
 434     "Major version number that will be appended to the libclang library")
 435 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 436
 437 option(CLANG_INCLUDE_TESTS
 438        "Generate build targets for the Clang unit tests."
 439        ${LLVM_INCLUDE_TESTS})
 440
 441 add_subdirectory(utils/TableGen)
 442
 443 add_subdirectory(include)
 444
 445 # All targets below may depend on all tablegen'd files.
 446 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 447 add_custom_target(clang-tablegen-targets DEPENDS ${CLANG_TABLEGEN_TARGETS})
 448 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 449 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 450
 451 # Force target to be built as soon as possible. Clang modules builds depend
 452 # header-wise on it as they ship all headers from the umbrella folders. Building
 453 # an entire module might include header, which depends on intrinsics_gen.
 454 if(LLVM_ENABLE_MODULES AND NOT CLANG_BUILT_STANDALONE)
 455   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 456 endif()
 457
 458 add_subdirectory(lib)
 459 add_subdirectory(tools)
 460 add_subdirectory(runtime)
 461
 462 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 463 add_subdirectory(examples)
 464
 465 if(APPLE)
 466   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 467   # default value get updated to the new default.
 468   if(CLANG_ORDER_FILE STREQUAL "")
 469     unset(CLANG_ORDER_FILE CACHE)
 470     unset(CLANG_ORDER_FILE)
 471   endif()
 472
 473
 474   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 475     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 476
 477   if(NOT EXISTS ${CLANG_ORDER_FILE})
 478     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 479     if(PATH_START EQUAL 0)
 480       file(WRITE ${CLANG_ORDER_FILE} "\n")
 481     else()
 482       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 483     endif()
 484   endif()
 485 endif()
 486
 487
 488 if( CLANG_INCLUDE_TESTS )
 489   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 490     add_subdirectory(unittests)
 491     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 492     list(APPEND CLANG_TEST_PARAMS
 493       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 494       )
 495   endif()
 496   add_subdirectory(test)
 497
 498   if(CLANG_BUILT_STANDALONE)
 499     # Add a global check rule now that all subdirectories have been traversed
 500     # and we know the total set of lit testsuites.
 501     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 502     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 503     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 504     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 505     add_lit_target(check-all
 506       "Running all regression tests"
 507       ${LLVM_LIT_TESTSUITES}
 508       PARAMS ${LLVM_LIT_PARAMS}
 509       DEPENDS ${LLVM_LIT_DEPENDS}
 510       ARGS ${LLVM_LIT_EXTRA_ARGS}
 511       )
 512   endif()
 513   add_subdirectory(utils/perf-training)
 514 endif()
 515
 516 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 517   ${LLVM_INCLUDE_DOCS})
 518 if( CLANG_INCLUDE_DOCS )
 519   add_subdirectory(docs)
 520 endif()
 521
 522 add_subdirectory(cmake/modules)
 523
 524 if(CLANG_STAGE)
 525   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 526 endif()
 527
 528 if (CLANG_ENABLE_BOOTSTRAP)
 529   include(ExternalProject)
 530
 531   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 532
 533   if(NOT CLANG_STAGE)
 534     set(CLANG_STAGE stage1)
 535   endif()
 536
 537   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 538   if(MATCHED_STAGE)
 539     if(NOT LLVM_BUILD_INSTRUMENTED)
 540       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 541       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 542     else()
 543       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 544     endif()
 545   else()
 546     set(NEXT_CLANG_STAGE bootstrap)
 547   endif()
 548
 549   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 550     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 551   endif()
 552   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 553
 554
 555   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 556   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 557
 558   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 559     add_dependencies(clang-bootstrap-deps lld)
 560   endif()
 561
 562   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 563   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 564     if(APPLE)
 565       add_dependencies(clang-bootstrap-deps LTO)
 566       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 567       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 568       # so that the host object file tools will use the just-built libLTO.
 569       # However if System Integrity Protection is enabled the DYLD variables
 570       # will be scrubbed from the environment of any base system commands. This
 571       # includes /bin/sh, which ninja uses when executing build commands. To
 572       # work around the envar being filtered away we pass it in as a CMake
 573       # variable, and have LLVM's CMake append the envar to the archiver calls.
 574       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 575         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 576     elseif(NOT WIN32)
 577       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 578       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 579         add_dependencies(clang-bootstrap-deps LLVMgold)
 580       endif()
 581       set(LTO_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 582       set(LTO_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 583     endif()
 584   endif()
 585
 586   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 587     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 588   endif()
 589
 590   add_custom_target(${NEXT_CLANG_STAGE}-clear
 591     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 592     )
 593   add_custom_command(
 594     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 595     DEPENDS clang-bootstrap-deps
 596     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 597     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 598     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 599     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 600     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 601     )
 602
 603   if(CMAKE_VERBOSE_MAKEFILE)
 604     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 605   endif()
 606
 607   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 608     PACKAGE_VERSION
 609     PACKAGE_VENDOR
 610     LLVM_VERSION_MAJOR
 611     LLVM_VERSION_MINOR
 612     LLVM_VERSION_PATCH
 613     CLANG_VERSION_MAJOR
 614     CLANG_VERSION_MINOR
 615     CLANG_VERSION_PATCHLEVEL
 616     LLVM_VERSION_SUFFIX
 617     LLVM_BINUTILS_INCDIR
 618     CLANG_REPOSITORY_STRING
 619     CMAKE_MAKE_PROGRAM
 620     CMAKE_OSX_ARCHITECTURES
 621     LLVM_ENABLE_PROJECTS
 622     LLVM_ENABLE_RUNTIMES)
 623
 624   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 625   # because the next stage will use the same compiler used to build this stage.
 626   if(NOT LLVM_BUILD_INSTRUMENTED)
 627     if(TARGET compiler-rt)
 628       add_dependencies(clang-bootstrap-deps compiler-rt)
 629     endif()
 630     if(TARGET cxx-headers)
 631       add_dependencies(clang-bootstrap-deps cxx-headers)
 632     endif()
 633   endif()
 634
 635   set(C_COMPILER "clang")
 636   set(CXX_COMPILER "clang++")
 637   if(WIN32)
 638     set(C_COMPILER "clang-cl.exe")
 639     set(CXX_COMPILER "clang-cl.exe")
 640   endif()
 641
 642   set(COMPILER_OPTIONS
 643     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 644     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 645     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 646     -DCMAKE_ASM_COMPILER_ID=Clang)
 647
 648   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 649     add_dependencies(clang-bootstrap-deps llvm-profdata)
 650     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 651   endif()
 652
 653   if(LLVM_BUILD_INSTRUMENTED)
 654     add_dependencies(clang-bootstrap-deps generate-profdata)
 655     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 656     # Use the current tools for LTO instead of the instrumented ones
 657     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 658       CMAKE_CXX_COMPILER
 659       CMAKE_C_COMPILER
 660       CMAKE_ASM_COMPILER
 661       CMAKE_AR
 662       CMAKE_RANLIB
 663       DARWIN_LTO_LIBRARY
 664       DYLD_LIBRARY_PATH)
 665
 666     set(COMPILER_OPTIONS)
 667     set(LTO_LIBRARY)
 668     set(LTO_AR)
 669     set(LTO_RANLIB)
 670   endif()
 671
 672   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 673   # them.
 674   get_cmake_property(variableNames VARIABLES)
 675   foreach(variableName ${variableNames})
 676     if(variableName MATCHES "^BOOTSTRAP_")
 677       string(SUBSTRING ${variableName} 10 -1 varName)
 678       string(REPLACE ";" "|" value "${${variableName}}")
 679       list(APPEND PASSTHROUGH_VARIABLES
 680         -D${varName}=${value})
 681     endif()
 682     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 683       list(APPEND PASSTHROUGH_VARIABLES
 684         -D${variableName}=${${variableName}})
 685     endif()
 686   endforeach()
 687
 688   # Populate the passthrough variables
 689   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 690     if(DEFINED ${variableName})
 691       if("${${variableName}}" STREQUAL "")
 692         set(value "")
 693       else()
 694         string(REPLACE ";" "|" value "${${variableName}}")
 695       endif()
 696       list(APPEND PASSTHROUGH_VARIABLES
 697         -D${variableName}=${value})
 698     endif()
 699   endforeach()
 700
 701   ExternalProject_Add(${NEXT_CLANG_STAGE}
 702     DEPENDS clang-bootstrap-deps
 703     PREFIX ${NEXT_CLANG_STAGE}
 704     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 705     STAMP_DIR ${STAMP_DIR}
 706     BINARY_DIR ${BINARY_DIR}
 707     EXCLUDE_FROM_ALL 1
 708     CMAKE_ARGS
 709                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 710                 # seem to work, so instead I'm passing this through
 711                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 712                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 713                 ${PASSTHROUGH_VARIABLES}
 714                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 715                 ${COMPILER_OPTIONS}
 716                 ${LTO_LIBRARY} ${LTO_AR} ${LTO_RANLIB} ${verbose} ${PGO_OPT}
 717     INSTALL_COMMAND ""
 718     STEP_TARGETS configure build
 719     USES_TERMINAL_CONFIGURE 1
 720     USES_TERMINAL_BUILD 1
 721     USES_TERMINAL_INSTALL 1
 722     LIST_SEPARATOR |
 723     )
 724
 725   # exclude really-install from main target
 726   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 727   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 728     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 729     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 730     DEPENDEES build
 731     USES_TERMINAL 1
 732   )
 733   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 734   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 735
 736   if(NOT CLANG_BOOTSTRAP_TARGETS)
 737     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 738   endif()
 739   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 740     # exclude from main target
 741     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 742
 743     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 744       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 745       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 746       DEPENDEES configure
 747       USES_TERMINAL 1
 748     )
 749
 750     if(target MATCHES "^stage[0-9]*")
 751       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 752     endif()
 753
 754     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 755   endforeach()
 756 endif()
 757
 758 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 759   add_subdirectory(utils/ClangVisualizers)
 760 endif()
 761 add_subdirectory(utils/hmaptool)
 762
 763 configure_file(
 764   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 765   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)