CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # An important constraint of the build is that it only produces libraries
   4 # based on the ability of the host toolchain to target various platforms.
   5
   6 cmake_minimum_required(VERSION 3.4.3)
   7
   8 # Check if compiler-rt is built as a standalone project.
   9 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR OR COMPILER_RT_STANDALONE_BUILD)
  10   project(CompilerRT C CXX ASM)
  11   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  12   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  13 endif()
  14
  15 # Add path for custom compiler-rt modules.
  16 list(INSERT CMAKE_MODULE_PATH 0
  17   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  18   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  19   )
  20
  21 if(CMAKE_CONFIGURATION_TYPES)
  22   set(CMAKE_CFG_RESOLVED_INTDIR "${CMAKE_CFG_INTDIR}/")
  23 else()
  24   set(CMAKE_CFG_RESOLVED_INTDIR "")
  25 endif()
  26
  27 include(base-config-ix)
  28 include(CompilerRTUtils)
  29
  30 option(COMPILER_RT_BUILD_BUILTINS "Build builtins" ON)
  31 mark_as_advanced(COMPILER_RT_BUILD_BUILTINS)
  32 option(COMPILER_RT_BUILD_SANITIZERS "Build sanitizers" ON)
  33 mark_as_advanced(COMPILER_RT_BUILD_SANITIZERS)
  34 option(COMPILER_RT_BUILD_XRAY "Build xray" ON)
  35 mark_as_advanced(COMPILER_RT_BUILD_XRAY)
  36 option(COMPILER_RT_BUILD_LIBFUZZER "Build libFuzzer" ON)
  37 mark_as_advanced(COMPILER_RT_BUILD_LIBFUZZER)
  38 option(COMPILER_RT_BUILD_PROFILE "Build profile runtime" ON)
  39 mark_as_advanced(COMPILER_RT_BUILD_PROFILE)
  40 option(COMPILER_RT_BUILD_XRAY_NO_PREINIT "Build xray with no preinit patching" OFF)
  41 mark_as_advanced(COMPILER_RT_BUILD_XRAY_NO_PREINIT)
  42
  43 set(COMPILER_RT_ASAN_SHADOW_SCALE ""
  44     CACHE STRING "Override the shadow scale to be used in ASan runtime")
  45
  46 if (NOT COMPILER_RT_ASAN_SHADOW_SCALE STREQUAL "")
  47   # Check that the shadow scale value is valid.
  48   if (NOT (COMPILER_RT_ASAN_SHADOW_SCALE GREATER -1 AND
  49            COMPILER_RT_ASAN_SHADOW_SCALE LESS 8))
  50     message(FATAL_ERROR "
  51       Invalid ASan Shadow Scale '${COMPILER_RT_ASAN_SHADOW_SCALE}'.")
  52   endif()
  53
  54   set(COMPILER_RT_ASAN_SHADOW_SCALE_LLVM_FLAG
  55       -mllvm -asan-mapping-scale=${COMPILER_RT_ASAN_SHADOW_SCALE})
  56   set(COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION
  57       ASAN_SHADOW_SCALE=${COMPILER_RT_ASAN_SHADOW_SCALE})
  58   set(COMPILER_RT_ASAN_SHADOW_SCALE_FLAG
  59       -D${COMPILER_RT_ASAN_SHADOW_SCALE_DEFINITION})
  60 endif()
  61
  62 set(COMPILER_RT_HWASAN_WITH_INTERCEPTORS ON CACHE BOOLEAN
  63     "Enable libc interceptors in HWASan (testing mode)")
  64
  65 set(COMPILER_RT_BAREMETAL_BUILD OFF CACHE BOOLEAN
  66   "Build for a bare-metal target.")
  67
  68 if (COMPILER_RT_STANDALONE_BUILD)
  69   load_llvm_config()
  70   if (TARGET intrinsics_gen)
  71     # Loading the llvm config causes this target to be imported so place it
  72     # under the appropriate folder in an IDE.
  73     set_target_properties(intrinsics_gen PROPERTIES FOLDER "Compiler-RT Misc")
  74   endif()
  75
  76   # Find Python interpreter.
  77   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
  78   include(FindPythonInterp)
  79   if(NOT PYTHONINTERP_FOUND)
  80     message(FATAL_ERROR "
  81       Unable to find Python interpreter required testing. Please install Python
  82       or specify the PYTHON_EXECUTABLE CMake variable.")
  83   endif()
  84
  85   # Ensure that fat libraries are built correctly on Darwin
  86   if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
  87     if(NOT CMAKE_LIBTOOL)
  88       find_program(CMAKE_XCRUN
  89                    NAMES
  90                      xcrun)
  91       if(CMAKE_XCRUN)
  92         execute_process(COMMAND
  93                           ${CMAKE_XCRUN} -find libtool
  94                         OUTPUT_VARIABLE
  95                           CMAKE_LIBTOOL
  96                         OUTPUT_STRIP_TRAILING_WHITESPACE)
  97       endif()
  98
  99       if(NOT CMAKE_LIBTOOL OR NOT EXISTS CMAKE_LIBTOOL)
 100         find_program(CMAKE_LIBTOOL
 101                      NAMES
 102                        libtool)
 103       endif()
 104     endif()
 105
 106     get_property(languages GLOBAL PROPERTY ENABLED_LANGUAGES)
 107
 108     if(CMAKE_LIBTOOL)
 109       set(CMAKE_LIBTOOL ${CMAKE_LIBTOOL} CACHE PATH "libtool executable")
 110       message(STATUS "Found libtool - ${CMAKE_LIBTOOL}")
 111
 112       execute_process(COMMAND
 113                         ${CMAKE_LIBTOOL} -V
 114                       OUTPUT_VARIABLE
 115                         LIBTOOL_V_OUTPUT
 116                       OUTPUT_STRIP_TRAILING_WHITESPACE)
 117       if("${LIBTOOL_V_OUTPUT}" MATCHES ".*cctools-([0-9]+).*")
 118         string(REGEX REPLACE ".*cctools-([0-9]+).*" "\\1" LIBTOOL_VERSION ${LIBTOOL_V_OUTPUT})
 119         if(NOT LIBTOOL_VERSION VERSION_LESS "862")
 120           set(LIBTOOL_NO_WARNING_FLAG "-no_warning_for_no_symbols")
 121         endif()
 122       endif()
 123
 124       foreach(lang ${languages})
 125         set(CMAKE_${lang}_CREATE_STATIC_LIBRARY "\"${CMAKE_LIBTOOL}\" -static ${LIBTOOL_NO_WARNING_FLAG} -o <TARGET> <LINK_FLAGS> <OBJECTS>")
 126       endforeach()
 127     endif()
 128
 129     # Workaround SIP :-(
 130     if(DYLD_LIBRARY_PATH)
 131       set(dyld_envar "DYLD_LIBRARY_PATH=${DYLD_LIBRARY_PATH}")
 132       foreach(lang ${languages})
 133         foreach(cmd ${CMAKE_${lang}_CREATE_STATIC_LIBRARY})
 134           list(APPEND CMAKE_${lang}_CREATE_STATIC_LIBRARY_NEW "${dyld_envar} ${cmd}")
 135         endforeach()
 136       endforeach()
 137     endif()
 138   endif()
 139
 140   # Define default arguments to lit.
 141   set(LIT_ARGS_DEFAULT "-sv")
 142   if (MSVC OR XCODE)
 143     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 144   endif()
 145   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 146   set(LLVM_LIT_OUTPUT_DIR "${COMPILER_RT_EXEC_OUTPUT_DIR}")
 147 endif()
 148
 149 construct_compiler_rt_default_triple()
 150 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*hf$")
 151   if (${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "^arm")
 152     set(COMPILER_RT_DEFAULT_TARGET_ARCH "armhf")
 153   endif()
 154 endif()
 155 if ("${COMPILER_RT_DEFAULT_TARGET_TRIPLE}" MATCHES ".*android.*")
 156   set(ANDROID 1)
 157 endif()
 158 pythonize_bool(ANDROID)
 159
 160 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 161 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 162
 163 pythonize_bool(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR)
 164
 165 # We support running instrumented tests when we're not cross compiling
 166 # and target a UNIX-like system or Windows.
 167 # We can run tests on Android even when we are cross-compiling.
 168 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND (UNIX OR WIN32)) OR ANDROID
 169    OR COMPILER_RT_EMULATOR)
 170   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 171 else()
 172   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 173 endif()
 174
 175 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 176 option(COMPILER_RT_EXTERNALIZE_DEBUGINFO
 177   "Generate dSYM files and strip executables and libraries (Darwin Only)" OFF)
 178 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 179 pythonize_bool(COMPILER_RT_DEBUG)
 180
 181 if(APPLE AND SANITIZER_MIN_OSX_VERSION AND SANITIZER_MIN_OSX_VERSION VERSION_LESS "10.9")
 182   # Mac OS X prior to 10.9 had problems with exporting symbols from
 183   # libc++/libc++abi.
 184   set(cxxabi_supported OFF)
 185 else()
 186   set(cxxabi_supported ON)
 187 endif()
 188
 189 option(SANITIZER_ALLOW_CXXABI "Allow use of C++ ABI details in ubsan" ON)
 190
 191 set(SANITIZE_CAN_USE_CXXABI OFF)
 192 if (cxxabi_supported AND SANITIZER_ALLOW_CXXABI)
 193   set(SANITIZER_CAN_USE_CXXABI ON)
 194 endif()
 195 pythonize_bool(SANITIZER_CAN_USE_CXXABI)
 196
 197 set(SANITIZER_CXX_ABI "default" CACHE STRING
 198     "Specify C++ ABI library to use.")
 199 set(CXXABIS none default libstdc++ libc++)
 200 set_property(CACHE SANITIZER_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
 201
 202 if (SANITIZER_CXX_ABI STREQUAL "default")
 203   if (APPLE OR CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
 204     set(SANITIZER_CXX_ABI_LIBNAME "libc++")
 205     set(SANITIZER_CXX_ABI_SYSTEM 1)
 206   elseif (FUCHSIA)
 207     set(SANITIZER_CXX_ABI_LIBNAME "libc++")
 208     set(SANITIZER_CXX_ABI_INTREE 1)
 209   else()
 210     set(SANITIZER_CXX_ABI_LIBNAME "libstdc++")
 211     set(SANITIZER_CXX_ABI_SYSTEM 1)
 212   endif()
 213 else()
 214   set(SANITIZER_CXX_ABI_LIBNAME "${SANITIZER_CXX_ABI}")
 215   set(SANITIZER_CXX_ABI_SYSTEM 1)
 216 endif()
 217
 218 set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY OFF)
 219 if (FUCHSIA)
 220   set(DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY ON)
 221 endif()
 222
 223 option(COMPILER_RT_USE_BUILTINS_LIBRARY
 224   "Use compiler-rt builtins instead of libgcc" ${DEFAULT_COMPILER_RT_USE_BUILTINS_LIBRARY})
 225
 226 include(config-ix)
 227
 228 #================================
 229 # Setup Compiler Flags
 230 #================================
 231
 232 if(MSVC)
 233   # Override any existing /W flags with /W4. This is what LLVM does.  Failing to
 234   # remove other /W[0-4] flags will result in a warning about overriding a
 235   # previous flag.
 236   if (COMPILER_RT_HAS_W4_FLAG)
 237     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 238     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 239     append_string_if(COMPILER_RT_HAS_W4_FLAG /W4 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 240   endif()
 241 else()
 242   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 243 endif()
 244 if(COMPILER_RT_ENABLE_WERROR)
 245   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 246   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 247 endif()
 248
 249 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 250
 251 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 252 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 253   add_definitions(-D__func__=__FUNCTION__)
 254 endif()
 255
 256 # Provide some common commmandline flags for Sanitizer runtimes.
 257 if(NOT WIN32)
 258   append_list_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 259 endif()
 260 append_list_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 261 append_list_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 262 if(NOT COMPILER_RT_DEBUG AND NOT APPLE)
 263   append_list_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 264 endif()
 265 append_list_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 266 append_list_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 267 append_list_if(COMPILER_RT_HAS_FNO_SANITIZE_SAFE_STACK_FLAG -fno-sanitize=safe-stack SANITIZER_COMMON_CFLAGS)
 268 append_list_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 269 if(NOT COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG)
 270   append_list_if(COMPILER_RT_HAS_FVISIBILITY_INLINES_HIDDEN_FLAG -fvisibility-inlines-hidden SANITIZER_COMMON_CFLAGS)
 271 endif()
 272 append_list_if(COMPILER_RT_HAS_FNO_LTO_FLAG -fno-lto SANITIZER_COMMON_CFLAGS)
 273
 274 # The following is a workaround for powerpc64le. This is the only architecture
 275 # that requires -fno-function-sections to work properly. If lacking, the ASan
 276 # Linux test function-sections-are-bad.cc fails with the following error:
 277 # 'undefined symbol: __sanitizer_unaligned_load32'.
 278 if(DEFINED TARGET_powerpc64le_CFLAGS)
 279   append_list_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections TARGET_powerpc64le_CFLAGS)
 280 endif()
 281
 282 if(MSVC)
 283   # Replace the /M[DT][d] flags with /MT, and strip any definitions of _DEBUG,
 284   # which cause definition mismatches at link time.
 285   # FIXME: In fact, sanitizers should support both /MT and /MD, see PR20214.
 286   if(COMPILER_RT_HAS_MT_FLAG)
 287     foreach(flag_var
 288       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 289       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 290       CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 291       CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 292       string(REGEX REPLACE "/M[DT]d" "/MT" ${flag_var} "${${flag_var}}")
 293       string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 294       string(REGEX REPLACE "/D_DEBUG" "" ${flag_var} "${${flag_var}}")
 295     endforeach()
 296   endif()
 297   append_list_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 298   append_list_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 299   # VS 2015 (version 1900) added support for thread safe static initialization.
 300   # However, ASan interceptors run before CRT initialization, which causes the
 301   # new thread safe code to crash. Disable this feature for now.
 302   if (MSVC_VERSION GREATER 1899 OR "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 303     list(APPEND SANITIZER_COMMON_CFLAGS /Zc:threadSafeInit-)
 304   endif()
 305 endif()
 306
 307 append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 SANITIZER_COMMON_CFLAGS)
 308
 309 # If we're using MSVC,
 310 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 311 if (NOT MSVC)
 312
 313   # Build with optimization, unless we're in debug mode.
 314   if(COMPILER_RT_DEBUG)
 315     list(APPEND SANITIZER_COMMON_CFLAGS -O0)
 316   else()
 317     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 318   endif()
 319 endif()
 320
 321 # Determine if we should restrict stack frame sizes.
 322 # Stack frames on PowerPC and Mips and in debug biuld can be much larger than
 323 # anticipated.
 324 # FIXME: Fix all sanitizers and add -Wframe-larger-than to
 325 # SANITIZER_COMMON_FLAGS
 326 if(COMPILER_RT_HAS_WFRAME_LARGER_THAN_FLAG AND NOT COMPILER_RT_DEBUG
 327    AND NOT ${COMPILER_RT_DEFAULT_TARGET_ARCH} MATCHES "powerpc|mips")
 328   set(SANITIZER_LIMIT_FRAME_SIZE TRUE)
 329 else()
 330   set(SANITIZER_LIMIT_FRAME_SIZE FALSE)
 331 endif()
 332
 333 if(FUCHSIA OR UNIX)
 334   set(SANITIZER_USE_SYMBOLS TRUE)
 335 else()
 336   set(SANITIZER_USE_SYMBOLS FALSE)
 337 endif()
 338
 339 # Build sanitizer runtimes with debug info.
 340 if(MSVC)
 341   # Use /Z7 instead of /Zi for the asan runtime. This avoids the LNK4099
 342   # warning from the MS linker complaining that it can't find the 'vc140.pdb'
 343   # file used by our object library compilations.
 344   list(APPEND SANITIZER_COMMON_CFLAGS /Z7)
 345   llvm_replace_compiler_option(CMAKE_CXX_FLAGS "/Z[i7I]" "/Z7")
 346   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_DEBUG "/Z[i7I]" "/Z7")
 347   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELWITHDEBINFO "/Z[i7I]" "/Z7")
 348 elseif(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG AND NOT COMPILER_RT_DEBUG)
 349   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 350 elseif(COMPILER_RT_HAS_G_FLAG)
 351   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 352 endif()
 353
 354 if(LLVM_ENABLE_MODULES)
 355   # Sanitizers cannot be built with -fmodules. The interceptors intentionally
 356   # don't include system headers, which is incompatible with modules.
 357   list(APPEND SANITIZER_COMMON_CFLAGS -fno-modules)
 358 endif()
 359
 360 # Turn off several warnings.
 361 append_list_if(COMPILER_RT_HAS_WGNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 362 append_list_if(COMPILER_RT_HAS_WVARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 363 append_list_if(COMPILER_RT_HAS_WC99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 364 append_list_if(COMPILER_RT_HAS_WNON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 365 append_list_if(COMPILER_RT_HAS_WD4146_FLAG /wd4146 SANITIZER_COMMON_CFLAGS)
 366 append_list_if(COMPILER_RT_HAS_WD4291_FLAG /wd4291 SANITIZER_COMMON_CFLAGS)
 367 append_list_if(COMPILER_RT_HAS_WD4391_FLAG /wd4391 SANITIZER_COMMON_CFLAGS)
 368 append_list_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 369 append_list_if(COMPILER_RT_HAS_WD4800_FLAG /wd4800 SANITIZER_COMMON_CFLAGS)
 370
 371 append_list_if(MINGW -fms-extensions SANITIZER_COMMON_CFLAGS)
 372
 373 # Set common link flags.
 374 append_list_if(COMPILER_RT_HAS_NODEFAULTLIBS_FLAG -nodefaultlibs SANITIZER_COMMON_LINK_FLAGS)
 375
 376 if (COMPILER_RT_USE_BUILTINS_LIBRARY)
 377   list(APPEND SANITIZER_COMMON_LINK_LIBS ${COMPILER_RT_BUILTINS_LIBRARY})
 378   string(REPLACE "-Wl,-z,defs" "" CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS}")
 379 else()
 380   if (ANDROID)
 381     append_list_if(COMPILER_RT_HAS_GCC_LIB gcc SANITIZER_COMMON_LINK_LIBS)
 382   else()
 383     append_list_if(COMPILER_RT_HAS_GCC_S_LIB gcc_s SANITIZER_COMMON_LINK_LIBS)
 384   endif()
 385 endif()
 386
 387 append_list_if(COMPILER_RT_HAS_LIBC c SANITIZER_COMMON_LINK_LIBS)
 388
 389 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
 390   list(APPEND SANITIZER_COMMON_LINK_FLAGS -Wl,-z,defs,-z,now,-z,relro)
 391   list(APPEND SANITIZER_COMMON_LINK_LIBS zircon)
 392 endif()
 393
 394 if (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libc++")
 395   if (SANITIZER_CXX_ABI_INTREE)
 396     if (NOT LIBCXXABI_ENABLE_STATIC_UNWINDER AND (TARGET unwind_shared OR HAVE_LIBUNWIND))
 397       list(APPEND SANITIZER_CXX_ABI_LIBRARY unwind_shared)
 398     elseif (LIBCXXABI_ENABLE_STATIC_UNWINDER AND (TARGET unwind_static OR HAVE_LIBUNWIND))
 399       list(APPEND SANITIZER_CXX_ABI_LIBRARY unwind_static)
 400     endif()
 401     if (NOT LIBCXX_ENABLE_STATIC_ABI_LIBRARY AND (TARGET cxxabi_shared OR HAVE_LIBCXXABI))
 402       list(APPEND SANITIZER_CXX_ABI_LIBRARY cxxabi_shared)
 403     elseif (LIBCXX_ENABLE_STATIC_ABI_LIBRARY AND (TARGET cxxabi_static OR HAVE_LIBCXXABI))
 404       list(APPEND SANITIZER_CXX_ABI_LIBRARY cxxabi_static)
 405     endif()
 406   else()
 407     append_list_if(COMPILER_RT_HAS_LIBCXX c++ SANITIZER_CXX_ABI_LIBRARY)
 408   endif()
 409 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libcxxabi")
 410   list(APPEND SANITIZER_CXX_ABI_LIBRARY "c++abi")
 411 elseif (SANITIZER_CXX_ABI_LIBNAME STREQUAL "libstdc++")
 412   append_list_if(COMPILER_RT_HAS_LIBSTDCXX stdc++ SANITIZER_CXX_ABI_LIBRARY)
 413 endif()
 414
 415 # Warnings to turn off for all libraries, not just sanitizers.
 416 append_string_if(COMPILER_RT_HAS_WUNUSED_PARAMETER_FLAG -Wno-unused-parameter CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 417
 418 if (CMAKE_LINKER MATCHES "link.exe$")
 419   # Silence MSVC linker warnings caused by empty object files. The
 420   # sanitizer libraries intentionally use ifdefs that result in empty
 421   # files, rather than skipping these files in the build system.
 422   # Ideally, we would pass this flag only for the libraries that need
 423   # it, but CMake doesn't seem to have a way to set linker flags for
 424   # individual static libraries, so we enable the suppression flag for
 425   # the whole compiler-rt project.
 426   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 427 endif()
 428
 429 add_subdirectory(include)
 430
 431 option(COMPILER_RT_USE_LIBCXX
 432   "Enable compiler-rt to use libc++ from the source tree" ON)
 433 if(COMPILER_RT_USE_LIBCXX)
 434   foreach(path IN ITEMS ${LLVM_MAIN_SRC_DIR}/projects/libcxx
 435                         ${LLVM_MAIN_SRC_DIR}/runtimes/libcxx
 436                         ${LLVM_MAIN_SRC_DIR}/../libcxx
 437                         ${LLVM_EXTERNAL_LIBCXX_SOURCE_DIR})
 438     if(IS_DIRECTORY ${path})
 439       set(COMPILER_RT_LIBCXX_PATH ${path})
 440       break()
 441     endif()
 442   endforeach()
 443 endif()
 444
 445 set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/tools/lld)
 446 if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 447   set(COMPILER_RT_HAS_LLD TRUE)
 448 else()
 449   set(COMPILER_RT_LLD_PATH ${LLVM_MAIN_SRC_DIR}/../lld)
 450   if(EXISTS ${COMPILER_RT_LLD_PATH}/ AND LLVM_TOOL_LLD_BUILD)
 451     set(COMPILER_RT_HAS_LLD TRUE)
 452   else()
 453     set(COMPILER_RT_HAS_LLD FALSE)
 454   endif()
 455 endif()
 456 pythonize_bool(COMPILER_RT_HAS_LLD)
 457
 458 add_subdirectory(lib)
 459
 460 if(COMPILER_RT_INCLUDE_TESTS)
 461   add_subdirectory(unittests)
 462   add_subdirectory(test)
 463   if (COMPILER_RT_STANDALONE_BUILD)
 464     # If we have a valid source tree, generate llvm-lit into the bin directory.
 465     # The user can still choose to have the check targets *use* a different lit
 466     # by specifying -DLLVM_EXTERNAL_LIT, but we generate it regardless.
 467     if (EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 468       add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit ${CMAKE_CURRENT_BINARY_DIR}/llvm-lit)
 469     elseif(NOT EXISTS ${LLVM_EXTERNAL_LIT})
 470       message(WARNING "Could not find LLVM source directory and LLVM_EXTERNAL_LIT does not"
 471                        "point to a valid file.  You will not be able to run tests.")
 472     endif()
 473   endif()
 474 endif()