CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 if(POLICY CMP0075)
   4   cmake_policy(SET CMP0075 NEW)
   5 endif()
   6
   7 # If we are not building as a part of LLVM, build Clang as an
   8 # standalone project, using LLVM as an external library:
   9 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
  10   project(Clang)
  11
  12   # Rely on llvm-config.
  13   set(CONFIG_OUTPUT)
  14   if(LLVM_CONFIG)
  15     set (LLVM_CONFIG_FOUND 1)
  16     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  17     message(DEPRECATION "Using llvm-config to detect the LLVM installation is \
  18           deprecated.  The installed cmake files should be used \
  19           instead.  CMake should be able to detect your LLVM install \
  20           automatically, but you can also use LLVM_DIR to specify \
  21           the path containing LLVMConfig.cmake.")
  22     set(CONFIG_COMMAND ${LLVM_CONFIG}
  23       "--assertion-mode"
  24       "--bindir"
  25       "--libdir"
  26       "--includedir"
  27       "--prefix"
  28       "--src-root"
  29       "--cmakedir")
  30     execute_process(
  31       COMMAND ${CONFIG_COMMAND}
  32       RESULT_VARIABLE HAD_ERROR
  33       OUTPUT_VARIABLE CONFIG_OUTPUT
  34     )
  35     if(NOT HAD_ERROR)
  36       string(REGEX REPLACE
  37         "[ \t]*[\r\n]+[ \t]*" ";"
  38         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  39     else()
  40       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  41       message(STATUS "${CONFIG_COMMAND_STR}")
  42       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  43     endif()
  44
  45     list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  46     list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  47     list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  48     list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  49     list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  50     list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  51     list(GET CONFIG_OUTPUT 6 LLVM_CONFIG_CMAKE_PATH)
  52
  53     # Normalize LLVM_CMAKE_PATH. --cmakedir might contain backslashes.
  54     # CMake assumes slashes as PATH.
  55     file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_PATH} LLVM_CMAKE_PATH)
  56   endif()
  57
  58
  59   if(NOT MSVC_IDE)
  60     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  61       CACHE BOOL "Enable assertions")
  62     # Assertions should follow llvm-config's.
  63     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  64   endif()
  65
  66   find_package(LLVM REQUIRED HINTS "${LLVM_CMAKE_PATH}")
  67   list(APPEND CMAKE_MODULE_PATH ${LLVM_DIR})
  68
  69   # We can't check LLVM_CONFIG here, because find_package(LLVM ...) also sets
  70   # LLVM_CONFIG.
  71   if (NOT LLVM_CONFIG_FOUND)
  72     # Pull values from LLVMConfig.cmake.  We can drop this once the llvm-config
  73     # path is removed.
  74     set(TOOLS_BINARY_DIR ${LLVM_TOOLS_BINARY_DIR})
  75     set(LIBRARY_DIR ${LLVM_LIBRARY_DIR})
  76     set(INCLUDE_DIR ${LLVM_INCLUDE_DIR})
  77     set(LLVM_OBJ_DIR ${LLVM_BINARY_DIR})
  78   endif()
  79
  80   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  81   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  82   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  83   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  84   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  85
  86   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  87     NO_DEFAULT_PATH)
  88
  89   # They are used as destination of target generators.
  90   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  91   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  92   if(WIN32 OR CYGWIN)
  93     # DLL platform -- put DLLs into bin.
  94     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  95   else()
  96     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  97   endif()
  98
  99   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 100   option(LLVM_INSTALL_TOOLCHAIN_ONLY
 101     "Only include toolchain files in the 'install' target." OFF)
 102
 103   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 104     "Set to ON to force using an old, unsupported host toolchain." OFF)
 105   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
 106   option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 107
 108   include(AddLLVM)
 109   include(TableGen)
 110   include(HandleLLVMOptions)
 111   include(VersionFromVCS)
 112
 113   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
 114
 115   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 116     set(LLVM_INCLUDE_TESTS ON)
 117   endif()
 118
 119   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 120   link_directories("${LLVM_LIBRARY_DIR}")
 121
 122   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 123   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 124   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 125
 126   if(LLVM_INCLUDE_TESTS)
 127     set(Python_ADDITIONAL_VERSIONS 2.7)
 128     include(FindPythonInterp)
 129     if(NOT PYTHONINTERP_FOUND)
 130       message(FATAL_ERROR
 131 "Unable to find Python interpreter, required for builds and testing.
 132
 133 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 134     endif()
 135
 136     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 137       message(FATAL_ERROR "Python 2.7 or newer is required")
 138     endif()
 139
 140     # Check prebuilt llvm/utils.
 141     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 142         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 143         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 144       set(LLVM_UTILS_PROVIDED ON)
 145     endif()
 146
 147     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 148       # Note: path not really used, except for checking if lit was found
 149       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 150       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 151         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 152       endif()
 153       if(NOT LLVM_UTILS_PROVIDED)
 154         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 155         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 156         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 157         set(LLVM_UTILS_PROVIDED ON)
 158         set(CLANG_TEST_DEPS FileCheck count not)
 159       endif()
 160       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 161       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 162           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 163           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 164         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 165       endif()
 166     else()
 167       # Seek installed Lit.
 168       find_program(LLVM_LIT
 169                    NAMES llvm-lit lit.py lit
 170                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 171                    DOC "Path to lit.py")
 172     endif()
 173
 174     if(LLVM_LIT)
 175       # Define the default arguments to use with 'lit', and an option for the user
 176       # to override.
 177       set(LIT_ARGS_DEFAULT "-sv")
 178       if (MSVC OR XCODE)
 179         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 180       endif()
 181       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 182
 183       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 184       if( WIN32 AND NOT CYGWIN )
 185         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 186       endif()
 187     else()
 188       set(LLVM_INCLUDE_TESTS OFF)
 189     endif()
 190   endif()
 191
 192   set( CLANG_BUILT_STANDALONE 1 )
 193   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 194 else()
 195   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 196 endif()
 197
 198 # Make sure that our source directory is on the current cmake module path so that
 199 # we can include cmake files from this directory.
 200 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 201
 202 if(LLVM_ENABLE_LIBXML2)
 203   # Don't look for libxml if we're using MSan, since uninstrumented third party
 204   # code may call MSan interceptors like strlen, leading to false positives.
 205   if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 206     set (LIBXML2_FOUND 0)
 207     find_package(LibXml2 2.5.3 QUIET)
 208     if (LIBXML2_FOUND)
 209       set(CLANG_HAVE_LIBXML 1)
 210     endif()
 211   endif()
 212 endif()
 213
 214 include(CheckIncludeFile)
 215 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 216
 217 set(CLANG_RESOURCE_DIR "" CACHE STRING
 218   "Relative directory from the Clang binary to its resource files.")
 219
 220 set(C_INCLUDE_DIRS "" CACHE STRING
 221   "Colon separated list of directories clang will search for headers.")
 222
 223 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 224 set(DEFAULT_SYSROOT "" CACHE PATH
 225   "Default <path> to all compiler invocations for --sysroot=<path>." )
 226
 227 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 228
 229 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 230     "enable x86 relax relocations by default")
 231
 232 set(ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER FALSE CACHE BOOL
 233   "Enable the experimental new pass manager by default.")
 234
 235 # TODO: verify the values against LangStandards.def?
 236 set(CLANG_DEFAULT_STD_C "" CACHE STRING
 237   "Default standard to use for C/ObjC code (IDENT from LangStandards.def, empty for platform default)")
 238 set(CLANG_DEFAULT_STD_CXX "" CACHE STRING
 239   "Default standard to use for C++/ObjC++ code (IDENT from LangStandards.def, empty for platform default)")
 240
 241 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 242   "Default linker to use (linker name or absolute path, empty for platform default)")
 243
 244 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 245   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 246 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 247         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 248         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 249   message(WARNING "Resetting default C++ stdlib to use platform default")
 250   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 251     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 252 endif()
 253
 254 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 255   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 256 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 257         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 258         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 259   message(WARNING "Resetting default rtlib to use platform default")
 260   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 261     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 262 endif()
 263
 264 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 265   "Default objcopy executable to use.")
 266
 267 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 268   "Default OpenMP runtime used by -fopenmp.")
 269
 270 # OpenMP offloading requires at least sm_35 because we use shuffle instructions
 271 # to generate efficient code for reductions and the atomicMax instruction on
 272 # 64-bit integers in the implementation of conditional lastprivate.
 273 set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 274   "Default architecture for OpenMP offloading to Nvidia GPUs.")
 275 string(REGEX MATCH "^sm_([0-9]+)$" MATCHED_ARCH "${CLANG_OPENMP_NVPTX_DEFAULT_ARCH}")
 276 if (NOT DEFINED MATCHED_ARCH OR "${CMAKE_MATCH_1}" LESS 35)
 277   message(WARNING "Resetting default architecture for OpenMP offloading to Nvidia GPUs to sm_35")
 278   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 279     "Default architecture for OpenMP offloading to Nvidia GPUs." FORCE)
 280 endif()
 281
 282 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 283   "Vendor-specific text for showing with version information.")
 284
 285 if( CLANG_VENDOR )
 286   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 287 endif()
 288
 289 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 290   "Vendor-specific text for showing the repository the source is taken from.")
 291
 292 if(CLANG_REPOSITORY_STRING)
 293   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 294 endif()
 295
 296 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 297   "Vendor-specific uti.")
 298
 299 set(CLANG_PYTHON_BINDINGS_VERSIONS "" CACHE STRING
 300     "Python versions to install libclang python bindings for")
 301
 302 # The libdir suffix must exactly match whatever LLVM's configuration used.
 303 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 304
 305 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 306 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 307
 308 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 309   message(FATAL_ERROR "In-source builds are not allowed. "
 310 "Please create a directory and run cmake "
 311 "from there, passing the path to this source directory as the last argument. "
 312 "This process created the file `CMakeCache.txt' and the directory "
 313 "`CMakeFiles'. Please delete them.")
 314 endif()
 315
 316 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 317 if(NOT DEFINED CLANG_VERSION_MAJOR)
 318   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 319 endif()
 320 if(NOT DEFINED CLANG_VERSION_MINOR)
 321   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 322 endif()
 323 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 324   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 325 endif()
 326 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 327 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 328 message(STATUS "Clang version: ${CLANG_VERSION}")
 329
 330 # Configure the Version.inc file.
 331 configure_file(
 332   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 333   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 334
 335 # Add appropriate flags for GCC
 336 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 337   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 338   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 339     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 340   endif ()
 341
 342   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 343   if (NOT LLVM_ENABLE_PEDANTIC)
 344     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 345   endif ()
 346
 347   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 348   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 349     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 350   endif()
 351 endif ()
 352
 353 # Determine HOST_LINK_VERSION on Darwin.
 354 set(HOST_LINK_VERSION)
 355 if (APPLE)
 356   set(LD_V_OUTPUT)
 357   execute_process(
 358     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 359     RESULT_VARIABLE HAD_ERROR
 360     OUTPUT_VARIABLE LD_V_OUTPUT
 361   )
 362   if (NOT HAD_ERROR)
 363     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 364       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 365     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 366       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 367     endif()
 368   else()
 369     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 370   endif()
 371 endif()
 372
 373 include(CMakeParseArguments)
 374 include(AddClang)
 375
 376 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 377
 378 include_directories(BEFORE
 379   ${CMAKE_CURRENT_BINARY_DIR}/include
 380   ${CMAKE_CURRENT_SOURCE_DIR}/include
 381   )
 382
 383 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 384   install(DIRECTORY include/clang include/clang-c
 385     DESTINATION include
 386     FILES_MATCHING
 387     PATTERN "*.def"
 388     PATTERN "*.h"
 389     PATTERN "config.h" EXCLUDE
 390     PATTERN ".svn" EXCLUDE
 391     )
 392
 393   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 394     DESTINATION include
 395     FILES_MATCHING
 396     PATTERN "CMakeFiles" EXCLUDE
 397     PATTERN "*.inc"
 398     PATTERN "*.h"
 399     )
 400
 401   install(PROGRAMS utils/bash-autocomplete.sh
 402     DESTINATION share/clang
 403     )
 404 endif()
 405
 406 add_definitions( -D_GNU_SOURCE )
 407
 408 option(CLANG_BUILD_TOOLS
 409   "Build the Clang tools. If OFF, just generate build targets." ON)
 410
 411 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 412 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 413
 414 set(CLANG_ANALYZER_Z3_INSTALL_DIR "" CACHE STRING "Install directory of the Z3 solver.")
 415
 416 find_package(Z3 4.7.1)
 417
 418 if (CLANG_ANALYZER_Z3_INSTALL_DIR)
 419   if (NOT Z3_FOUND)
 420     message(FATAL_ERROR "Z3 4.7.1 has not been found in CLANG_ANALYZER_Z3_INSTALL_DIR: ${CLANG_ANALYZER_Z3_INSTALL_DIR}.")
 421   endif()
 422 endif()
 423
 424 set(CLANG_ANALYZER_ENABLE_Z3_SOLVER_DEFAULT "${Z3_FOUND}")
 425
 426 option(CLANG_ANALYZER_ENABLE_Z3_SOLVER
 427   "Enable Support for the Z3 constraint solver in the Clang Static Analyzer."
 428   ${CLANG_ANALYZER_ENABLE_Z3_SOLVER_DEFAULT}
 429 )
 430
 431 if (CLANG_ANALYZER_ENABLE_Z3_SOLVER)
 432   if (NOT Z3_FOUND)
 433     message(FATAL_ERROR "CLANG_ANALYZER_ENABLE_Z3_SOLVER cannot be enabled when Z3 is not available.")
 434   endif()
 435
 436   set(CLANG_ANALYZER_WITH_Z3 1)
 437 endif()
 438
 439 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 440
 441 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND (CLANG_ENABLE_ARCMT OR CLANG_ANALYZER_ENABLE_Z3_SOLVER))
 442   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 443 endif()
 444
 445 if(CLANG_ENABLE_ARCMT)
 446   set(CLANG_ENABLE_OBJC_REWRITER ON)
 447 endif()
 448
 449 # Clang version information
 450 set(CLANG_EXECUTABLE_VERSION
 451     "${CLANG_VERSION_MAJOR}" CACHE STRING
 452     "Major version number that will be appended to the clang executable name")
 453 set(LIBCLANG_LIBRARY_VERSION
 454     "${CLANG_VERSION_MAJOR}" CACHE STRING
 455     "Major version number that will be appended to the libclang library")
 456 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 457
 458 option(CLANG_INCLUDE_TESTS
 459        "Generate build targets for the Clang unit tests."
 460        ${LLVM_INCLUDE_TESTS})
 461
 462 add_subdirectory(utils/TableGen)
 463
 464 add_subdirectory(include)
 465
 466 # All targets below may depend on all tablegen'd files.
 467 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 468 add_custom_target(clang-tablegen-targets DEPENDS ${CLANG_TABLEGEN_TARGETS})
 469 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 470 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 471
 472 # Force target to be built as soon as possible. Clang modules builds depend
 473 # header-wise on it as they ship all headers from the umbrella folders. Building
 474 # an entire module might include header, which depends on intrinsics_gen.
 475 if(LLVM_ENABLE_MODULES AND NOT CLANG_BUILT_STANDALONE)
 476   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 477 endif()
 478
 479 add_subdirectory(lib)
 480 add_subdirectory(tools)
 481 add_subdirectory(runtime)
 482
 483 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 484 add_subdirectory(examples)
 485
 486 if(APPLE)
 487   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 488   # default value get updated to the new default.
 489   if(CLANG_ORDER_FILE STREQUAL "")
 490     unset(CLANG_ORDER_FILE CACHE)
 491     unset(CLANG_ORDER_FILE)
 492   endif()
 493
 494
 495   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 496     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 497
 498   if(NOT EXISTS ${CLANG_ORDER_FILE})
 499     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 500     if(PATH_START EQUAL 0)
 501       file(WRITE ${CLANG_ORDER_FILE} "\n")
 502     else()
 503       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 504     endif()
 505   endif()
 506 endif()
 507
 508
 509 if( CLANG_INCLUDE_TESTS )
 510   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 511     add_subdirectory(unittests)
 512     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 513     list(APPEND CLANG_TEST_PARAMS
 514       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 515       )
 516   endif()
 517   add_subdirectory(test)
 518   add_subdirectory(bindings/python/tests)
 519
 520   if(CLANG_BUILT_STANDALONE)
 521     # Add a global check rule now that all subdirectories have been traversed
 522     # and we know the total set of lit testsuites.
 523     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 524     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 525     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 526     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 527     get_property(LLVM_ADDITIONAL_TEST_TARGETS
 528                  GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 529     add_lit_target(check-all
 530       "Running all regression tests"
 531       ${LLVM_LIT_TESTSUITES}
 532       PARAMS ${LLVM_LIT_PARAMS}
 533       DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 534       ARGS ${LLVM_LIT_EXTRA_ARGS}
 535       )
 536   endif()
 537   add_subdirectory(utils/perf-training)
 538 endif()
 539
 540 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 541   ${LLVM_INCLUDE_DOCS})
 542 if( CLANG_INCLUDE_DOCS )
 543   add_subdirectory(docs)
 544 endif()
 545
 546 add_subdirectory(cmake/modules)
 547
 548 if(CLANG_STAGE)
 549   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 550 endif()
 551
 552 if (CLANG_ENABLE_BOOTSTRAP)
 553   include(ExternalProject)
 554
 555   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 556
 557   if(NOT CLANG_STAGE)
 558     set(CLANG_STAGE stage1)
 559   endif()
 560
 561   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 562   if(MATCHED_STAGE)
 563     if(NOT LLVM_BUILD_INSTRUMENTED)
 564       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 565       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 566     else()
 567       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 568     endif()
 569   else()
 570     set(NEXT_CLANG_STAGE bootstrap)
 571   endif()
 572
 573   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 574     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 575   endif()
 576   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 577
 578
 579   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 580   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 581
 582   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 583     add_dependencies(clang-bootstrap-deps lld)
 584   endif()
 585
 586   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 587   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 588     if(APPLE)
 589       add_dependencies(clang-bootstrap-deps LTO)
 590       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 591       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 592       # so that the host object file tools will use the just-built libLTO.
 593       # However if System Integrity Protection is enabled the DYLD variables
 594       # will be scrubbed from the environment of any base system commands. This
 595       # includes /bin/sh, which ninja uses when executing build commands. To
 596       # work around the envar being filtered away we pass it in as a CMake
 597       # variable, and have LLVM's CMake append the envar to the archiver calls.
 598       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 599         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 600     elseif(NOT WIN32)
 601       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 602       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 603         add_dependencies(clang-bootstrap-deps LLVMgold)
 604       endif()
 605       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 606       set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 607     endif()
 608   endif()
 609
 610   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 611     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 612   endif()
 613
 614   add_custom_target(${NEXT_CLANG_STAGE}-clear
 615     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 616     )
 617   add_custom_command(
 618     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 619     DEPENDS clang-bootstrap-deps
 620     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 621     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 622     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 623     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 624     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 625     )
 626
 627   if(CMAKE_VERBOSE_MAKEFILE)
 628     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 629   endif()
 630
 631   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 632     PACKAGE_VERSION
 633     PACKAGE_VENDOR
 634     LLVM_VERSION_MAJOR
 635     LLVM_VERSION_MINOR
 636     LLVM_VERSION_PATCH
 637     CLANG_VERSION_MAJOR
 638     CLANG_VERSION_MINOR
 639     CLANG_VERSION_PATCHLEVEL
 640     LLVM_VERSION_SUFFIX
 641     LLVM_BINUTILS_INCDIR
 642     CLANG_REPOSITORY_STRING
 643     CMAKE_MAKE_PROGRAM
 644     CMAKE_OSX_ARCHITECTURES
 645     LLVM_ENABLE_PROJECTS
 646     LLVM_ENABLE_RUNTIMES)
 647
 648   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 649   # because the next stage will use the same compiler used to build this stage.
 650   if(NOT LLVM_BUILD_INSTRUMENTED)
 651     if(TARGET compiler-rt)
 652       add_dependencies(clang-bootstrap-deps compiler-rt)
 653     endif()
 654     if(TARGET cxx-headers)
 655       add_dependencies(clang-bootstrap-deps cxx-headers)
 656     endif()
 657   endif()
 658
 659   set(C_COMPILER "clang")
 660   set(CXX_COMPILER "clang++")
 661   if(WIN32)
 662     set(C_COMPILER "clang-cl.exe")
 663     set(CXX_COMPILER "clang-cl.exe")
 664   endif()
 665
 666   set(COMPILER_OPTIONS
 667     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 668     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 669     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 670     -DCMAKE_ASM_COMPILER_ID=Clang)
 671
 672   if(BOOTSTRAP_CMAKE_SYSTEM_NAME)
 673     set(${CLANG_STAGE}_CONFIG -DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config)
 674     set(${CLANG_STAGE}_TABLEGEN
 675       -DLLVM_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-tblgen
 676       -DCLANG_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-tblgen)
 677     if(BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Linux")
 678       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 679         set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld)
 680       endif()
 681       if(NOT BOOTSTRAP_LLVM_ENABLE_LTO)
 682         add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 683         set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 684         set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 685       endif()
 686       add_dependencies(clang-bootstrap-deps llvm-objcopy llvm-strip)
 687       set(${CLANG_STAGE}_OBJCOPY -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy)
 688       set(${CLANG_STAGE}_STRIP -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip)
 689     endif()
 690   endif()
 691
 692   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 693     add_dependencies(clang-bootstrap-deps llvm-profdata)
 694     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 695   endif()
 696
 697   if(LLVM_BUILD_INSTRUMENTED)
 698     add_dependencies(clang-bootstrap-deps generate-profdata)
 699     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 700     # Use the current tools for LTO instead of the instrumented ones
 701     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 702       CMAKE_CXX_COMPILER
 703       CMAKE_C_COMPILER
 704       CMAKE_ASM_COMPILER
 705       CMAKE_AR
 706       CMAKE_RANLIB
 707       DARWIN_LTO_LIBRARY
 708       DYLD_LIBRARY_PATH)
 709
 710     set(COMPILER_OPTIONS)
 711     set(LTO_LIBRARY)
 712     set(LTO_AR)
 713     set(LTO_RANLIB)
 714   endif()
 715
 716   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 717   # them.
 718   get_cmake_property(variableNames VARIABLES)
 719   foreach(variableName ${variableNames})
 720     if(variableName MATCHES "^BOOTSTRAP_")
 721       string(SUBSTRING ${variableName} 10 -1 varName)
 722       string(REPLACE ";" "|" value "${${variableName}}")
 723       list(APPEND PASSTHROUGH_VARIABLES
 724         -D${varName}=${value})
 725     endif()
 726     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 727       list(APPEND PASSTHROUGH_VARIABLES
 728         -D${variableName}=${${variableName}})
 729     endif()
 730   endforeach()
 731
 732   # Populate the passthrough variables
 733   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 734     if(DEFINED ${variableName})
 735       if("${${variableName}}" STREQUAL "")
 736         set(value "")
 737       else()
 738         string(REPLACE ";" "|" value "${${variableName}}")
 739       endif()
 740       list(APPEND PASSTHROUGH_VARIABLES
 741         -D${variableName}=${value})
 742     endif()
 743   endforeach()
 744
 745   ExternalProject_Add(${NEXT_CLANG_STAGE}
 746     DEPENDS clang-bootstrap-deps
 747     PREFIX ${NEXT_CLANG_STAGE}
 748     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 749     STAMP_DIR ${STAMP_DIR}
 750     BINARY_DIR ${BINARY_DIR}
 751     EXCLUDE_FROM_ALL 1
 752     CMAKE_ARGS
 753                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 754                 # seem to work, so instead I'm passing this through
 755                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 756                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 757                 ${PASSTHROUGH_VARIABLES}
 758                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 759                 ${COMPILER_OPTIONS}
 760                 ${${CLANG_STAGE}_CONFIG}
 761                 ${${CLANG_STAGE}_TABLEGEN}
 762                 ${LTO_LIBRARY} ${verbose} ${PGO_OPT}
 763                 ${${CLANG_STAGE}_LINKER}
 764                 ${${CLANG_STAGE}_AR}
 765                 ${${CLANG_STAGE}_RANLIB}
 766                 ${${CLANG_STAGE}_OBJCOPY}
 767                 ${${CLANG_STAGE}_STRIP}
 768     INSTALL_COMMAND ""
 769     STEP_TARGETS configure build
 770     USES_TERMINAL_CONFIGURE 1
 771     USES_TERMINAL_BUILD 1
 772     USES_TERMINAL_INSTALL 1
 773     LIST_SEPARATOR |
 774     )
 775
 776   # exclude really-install from main target
 777   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 778   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 779     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 780     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 781     DEPENDEES build
 782     USES_TERMINAL 1
 783   )
 784   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 785   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 786
 787   if(NOT CLANG_BOOTSTRAP_TARGETS)
 788     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 789   endif()
 790   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 791     # exclude from main target
 792     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 793
 794     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 795       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 796       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 797       DEPENDEES configure
 798       USES_TERMINAL 1
 799     )
 800
 801     if(target MATCHES "^stage[0-9]*")
 802       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 803     endif()
 804
 805     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 806   endforeach()
 807 endif()
 808
 809 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 810   add_subdirectory(utils/ClangVisualizers)
 811 endif()
 812 add_subdirectory(utils/hmaptool)
 813
 814 configure_file(
 815   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 816   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)