CMakeLists.txt

   1 # See www/CMake.html for instructions on how to build libcxx with CMake.
   2
   3 #===============================================================================
   4 # Setup Project
   5 #===============================================================================
   6 cmake_minimum_required(VERSION 3.4.3)
   7
   8 if(POLICY CMP0042)
   9   cmake_policy(SET CMP0042 NEW) # Set MACOSX_RPATH=YES by default
  10 endif()
  11 if(POLICY CMP0022)
  12   cmake_policy(SET CMP0022 NEW) # Required when interacting with LLVM and Clang
  13 endif()
  14
  15 # Add path for custom modules
  16 set(CMAKE_MODULE_PATH
  17   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  18   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  19   ${CMAKE_MODULE_PATH}
  20   )
  21
  22 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  23   project(libcxx CXX C)
  24
  25   set(PACKAGE_NAME libcxx)
  26   set(PACKAGE_VERSION 5.0.0)
  27   set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28   set(PACKAGE_BUGREPORT "llvm-bugs@lists.llvm.org")
  29
  30   # Find the LLVM sources and simulate LLVM CMake options.
  31   include(HandleOutOfTreeLLVM)
  32 endif()
  33
  34 if (LIBCXX_STANDALONE_BUILD)
  35   include(FindPythonInterp)
  36   if( NOT PYTHONINTERP_FOUND )
  37     message(WARNING "Failed to find python interpreter. "
  38                     "The libc++ test suite will be disabled.")
  39     set(LLVM_INCLUDE_TESTS OFF)
  40   endif()
  41 endif()
  42
  43 # Require out of source build.
  44 include(MacroEnsureOutOfSourceBuild)
  45 MACRO_ENSURE_OUT_OF_SOURCE_BUILD(
  46  "${PROJECT_NAME} requires an out of source build. Please create a separate
  47  build directory and run 'cmake /path/to/${PROJECT_NAME} [options]' there."
  48  )
  49
  50 if (MSVC)
  51   set(LIBCXX_TARGETING_MSVC ON)
  52 else()
  53   set(LIBCXX_TARGETING_MSVC OFF)
  54 endif()
  55
  56 #===============================================================================
  57 # Setup CMake Options
  58 #===============================================================================
  59 include(CMakeDependentOption)
  60 include(HandleCompilerRT)
  61
  62 # Basic options ---------------------------------------------------------------
  63 option(LIBCXX_ENABLE_ASSERTIONS "Enable assertions independent of build mode." OFF)
  64 option(LIBCXX_ENABLE_SHARED "Build libc++ as a shared library." ON)
  65 option(LIBCXX_ENABLE_STATIC "Build libc++ as a static library." ON)
  66 option(LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY "Build libc++experimental.a" ON)
  67 set(ENABLE_FILESYSTEM_DEFAULT ${LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY})
  68 if (WIN32)
  69   set(ENABLE_FILESYSTEM_DEFAULT OFF)
  70 endif()
  71 option(LIBCXX_ENABLE_FILESYSTEM "Build filesystem as part of libc++experimental.a"
  72     ${ENABLE_FILESYSTEM_DEFAULT})
  73 option(LIBCXX_INCLUDE_TESTS "Build the libc++ tests." ${LLVM_INCLUDE_TESTS})
  74
  75 # Benchmark options -----------------------------------------------------------
  76 option(LIBCXX_INCLUDE_BENCHMARKS "Build the libc++ benchmarks and their dependancies" ON)
  77 set(LIBCXX_BENCHMARK_NATIVE_STDLIB "" CACHE STRING
  78         "Build the benchmarks against the specified native STL.
  79          The value must be one of libc++/libstdc++")
  80 set(LIBCXX_BENCHMARK_NATIVE_GCC_TOOLCHAIN "" CACHE STRING
  81     "Use alternate GCC toolchain when building the native benchmarks")
  82
  83 if (LIBCXX_BENCHMARK_NATIVE_STDLIB)
  84   if (NOT (LIBCXX_BENCHMARK_NATIVE_STDLIB STREQUAL "libc++"
  85         OR LIBCXX_BENCHMARK_NATIVE_STDLIB STREQUAL "libstdc++"))
  86     message(FATAL_ERROR "Invalid value for LIBCXX_BENCHMARK_NATIVE_STDLIB: "
  87             "'${LIBCXX_BENCHMARK_NATIVE_STDLIB}'")
  88   endif()
  89 endif()
  90
  91 option(LIBCXX_INCLUDE_DOCS "Build the libc++ documentation." ${LLVM_INCLUDE_DOCS})
  92 set(LIBCXX_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}" CACHE STRING
  93     "Define suffix of library directory name (32/64)")
  94 option(LIBCXX_INSTALL_HEADERS "Install the libc++ headers." ON)
  95 option(LIBCXX_INSTALL_LIBRARY "Install the libc++ library." ON)
  96 option(LIBCXX_INSTALL_SUPPORT_HEADERS "Install libc++ support headers." ON)
  97 cmake_dependent_option(LIBCXX_INSTALL_EXPERIMENTAL_LIBRARY
  98         "Install libc++experimental.a" ON
  99         "LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY;LIBCXX_INSTALL_LIBRARY" OFF)
 100 set(LIBCXX_ABI_VERSION 1 CACHE STRING "ABI version of libc++.")
 101 option(LIBCXX_ABI_UNSTABLE "Unstable ABI of libc++." OFF)
 102 option(LIBCXX_USE_COMPILER_RT "Use compiler-rt instead of libgcc" OFF)
 103
 104 if (NOT LIBCXX_ENABLE_SHARED AND NOT LIBCXX_ENABLE_STATIC)
 105   message(FATAL_ERROR "libc++ must be built as either a shared or static library.")
 106 endif()
 107
 108 # ABI Library options ---------------------------------------------------------
 109 set(LIBCXX_CXX_ABI "default" CACHE STRING
 110     "Specify C++ ABI library to use.")
 111 set(CXXABIS none default libcxxabi libcxxrt libstdc++ libsupc++ vcruntime)
 112 set_property(CACHE LIBCXX_CXX_ABI PROPERTY STRINGS ;${CXXABIS})
 113
 114 # Setup the default options if LIBCXX_CXX_ABI is not specified.
 115 if (LIBCXX_CXX_ABI STREQUAL "default")
 116   find_path(
 117     LIBCXX_LIBCXXABI_INCLUDES_INTERNAL
 118     cxxabi.h
 119     PATHS ${LLVM_MAIN_SRC_DIR}/projects/libcxxabi/include
 120           ${LLVM_MAIN_SRC_DIR}/runtimes/libcxxabi/include
 121           ${LLVM_MAIN_SRC_DIR}/../libcxxabi/include
 122     NO_DEFAULT_PATH
 123   )
 124   if (LIBCXX_TARGETING_MSVC)
 125     # FIXME: Figure out how to configure the ABI library on Windows.
 126     set(LIBCXX_CXX_ABI_LIBNAME "vcruntime")
 127   elseif ((NOT LIBCXX_STANDALONE_BUILD OR HAVE_LIBCXXABI) AND
 128           IS_DIRECTORY "${LIBCXX_LIBCXXABI_INCLUDES_INTERNAL}")
 129     set(LIBCXX_CXX_ABI_LIBNAME "libcxxabi")
 130     set(LIBCXX_CXX_ABI_INCLUDE_PATHS "${LIBCXX_LIBCXXABI_INCLUDES_INTERNAL}")
 131     set(LIBCXX_CXX_ABI_INTREE 1)
 132   elseif (APPLE)
 133     set(LIBCXX_CXX_ABI_LIBNAME "libcxxabi")
 134     set(LIBCXX_CXX_ABI_SYSTEM 1)
 135   else()
 136     set(LIBCXX_CXX_ABI_LIBNAME "default")
 137   endif()
 138 else()
 139   set(LIBCXX_CXX_ABI_LIBNAME "${LIBCXX_CXX_ABI}")
 140 endif()
 141
 142 # Use a static copy of the ABI library when linking libc++. This option
 143 # cannot be used with LIBCXX_ENABLE_ABI_LINKER_SCRIPT.
 144 option(LIBCXX_ENABLE_STATIC_ABI_LIBRARY "Statically link the ABI library" OFF)
 145
 146 # Generate and install a linker script inplace of libc++.so. The linker script
 147 # will link libc++ to the correct ABI library. This option is on by default
 148 # on UNIX platforms other than Apple unless 'LIBCXX_ENABLE_STATIC_ABI_LIBRARY'
 149 # is on. This option is also disabled when the ABI library is not specified
 150 # or is specified to be "none".
 151 set(ENABLE_LINKER_SCRIPT_DEFAULT_VALUE OFF)
 152 if (LLVM_HAVE_LINK_VERSION_SCRIPT AND NOT LIBCXX_ENABLE_STATIC_ABI_LIBRARY
 153       AND NOT LIBCXX_CXX_ABI_LIBNAME STREQUAL "none"
 154       AND NOT LIBCXX_CXX_ABI_LIBNAME STREQUAL "default"
 155       AND PYTHONINTERP_FOUND
 156       AND LIBCXX_ENABLE_SHARED)
 157     set(ENABLE_LINKER_SCRIPT_DEFAULT_VALUE ON)
 158 endif()
 159
 160 option(LIBCXX_ENABLE_ABI_LINKER_SCRIPT
 161       "Use and install a linker script for the given ABI library"
 162       ${ENABLE_LINKER_SCRIPT_DEFAULT_VALUE})
 163
 164 set(ENABLE_NEW_DELETE_DEFAULT ON)
 165 if (LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS)
 166 # FIXME: This option should default to off. Unfortunatly GCC 4.9 fails to link
 167 # programs due to undefined references to new/delete in libc++abi so to work
 168 # around this libc++abi currently defaults LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS
 169 # to ON. Once the GCC bug has been worked around this option should be changed
 170 # back to OFF.
 171   set(ENABLE_NEW_DELETE_DEFAULT ON)
 172 endif()
 173
 174 option(LIBCXX_ENABLE_NEW_DELETE_DEFINITIONS
 175     "Build libc++ with definitions for operator new/delete. This option can
 176     be used to disable the definitions when libc++abi is expected to provide
 177     them" ${ENABLE_NEW_DELETE_DEFAULT})
 178
 179 # Build libc++abi with libunwind. We need this option to determine whether to
 180 # link with libunwind or libgcc_s while running the test cases.
 181 option(LIBCXXABI_USE_LLVM_UNWINDER "Build and use the LLVM unwinder." OFF)
 182 option(LIBCXXABI_ENABLE_STATIC_UNWINDER "Statically link the LLVM unwinder." OFF)
 183
 184 # Target options --------------------------------------------------------------
 185 option(LIBCXX_BUILD_32_BITS "Build 32 bit libc++." ${LLVM_BUILD_32_BITS})
 186 set(LIBCXX_SYSROOT "" CACHE STRING "Use alternate sysroot.")
 187 set(LIBCXX_GCC_TOOLCHAIN "" CACHE STRING "Use alternate GCC toolchain.")
 188
 189 # Feature options -------------------------------------------------------------
 190 option(LIBCXX_ENABLE_EXCEPTIONS "Use exceptions." ON)
 191 option(LIBCXX_ENABLE_RTTI "Use run time type information." ON)
 192 option(LIBCXX_ENABLE_GLOBAL_FILESYSTEM_NAMESPACE "Build libc++ with support for the global filesystem namespace." ON)
 193 option(LIBCXX_ENABLE_STDIN "Build libc++ with support for stdin/std::cin." ON)
 194 option(LIBCXX_ENABLE_STDOUT "Build libc++ with support for stdout/std::cout." ON)
 195 option(LIBCXX_ENABLE_THREADS "Build libc++ with support for threads." ON)
 196 option(LIBCXX_ENABLE_THREAD_UNSAFE_C_FUNCTIONS "Build libc++ with support for thread-unsafe C functions" ON)
 197 option(LIBCXX_ENABLE_MONOTONIC_CLOCK
 198   "Build libc++ with support for a monotonic clock.
 199    This option may only be set to OFF when LIBCXX_ENABLE_THREADS=OFF." ON)
 200 option(LIBCXX_HAS_MUSL_LIBC "Build libc++ with support for the Musl C library" OFF)
 201 option(LIBCXX_HAS_PTHREAD_API "Ignore auto-detection and force use of pthread API" OFF)
 202 option(LIBCXX_HAS_EXTERNAL_THREAD_API
 203   "Build libc++ with an externalized threading API.
 204    This option may only be set to ON when LIBCXX_ENABLE_THREADS=ON." OFF)
 205 option(LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY
 206     "Build libc++ with an externalized threading library.
 207      This option may only be set to ON when LIBCXX_ENABLE_THREADS=ON" OFF)
 208
 209 # Misc options ----------------------------------------------------------------
 210 # FIXME: Turn -pedantic back ON. It is currently off because it warns
 211 # about #include_next which is used everywhere.
 212 option(LIBCXX_ENABLE_PEDANTIC "Compile with pedantic enabled." OFF)
 213 option(LIBCXX_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 214 option(LIBCXX_DISABLE_MACRO_CONFLICT_WARNINGS "Disable #warnings about conflicting macros." OFF)
 215
 216 option(LIBCXX_GENERATE_COVERAGE "Enable generating code coverage." OFF)
 217 set(LIBCXX_COVERAGE_LIBRARY "" CACHE STRING
 218     "The Profile-rt library used to build with code coverage")
 219
 220 # Don't allow a user to accidentally overwrite the system libc++ installation on Darwin.
 221 # If the user specifies -DCMAKE_INSTALL_PREFIX=/usr the install rules for libc++
 222 # will not be generated and a warning will be issued.
 223 option(LIBCXX_OVERRIDE_DARWIN_INSTALL "Enable overwriting darwins libc++ installation." OFF)
 224 mark_as_advanced(LIBCXX_OVERRIDE_DARWIN_INSTALL) # Don't show this option by default.
 225
 226 if (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND NOT LIBCXX_OVERRIDE_DARWIN_INSTALL)
 227   if ("${CMAKE_INSTALL_PREFIX}" STREQUAL "/usr")
 228     message(WARNING "Disabling libc++ install rules because installation would "
 229                     "overwrite the systems installation. Configure with "
 230                     "-DLIBCXX_OVERRIDE_DARWIN_INSTALL=ON to suppress this behaviour.")
 231     mark_as_advanced(CLEAR LIBCXX_OVERRIDE_DARWIN_INSTALL) # Show the override option.
 232     set(LIBCXX_INSTALL_HEADERS OFF)
 233     set(LIBCXX_INSTALL_LIBRARY OFF)
 234   endif()
 235 endif()
 236
 237 set(LIBCXX_CONFIGURE_IDE_DEFAULT OFF)
 238 if (XCODE OR MSVC_IDE)
 239   set(LIBCXX_CONFIGURE_IDE_DEFAULT ON)
 240 endif()
 241 option(LIBCXX_CONFIGURE_IDE "Configure libcxx for use within an IDE"
 242       ${LIBCXX_CONFIGURE_IDE_DEFAULT})
 243
 244 #===============================================================================
 245 # Check option configurations
 246 #===============================================================================
 247
 248 if (LIBCXX_ENABLE_FILESYSTEM AND NOT LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY)
 249   message(FATAL_ERROR
 250     "LIBCXX_ENABLE_FILESYSTEM cannot be turned on when LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY=OFF")
 251 endif()
 252
 253 # Ensure LIBCXX_ENABLE_MONOTONIC_CLOCK is set to ON only when
 254 # LIBCXX_ENABLE_THREADS is on.
 255 if(LIBCXX_ENABLE_THREADS AND NOT LIBCXX_ENABLE_MONOTONIC_CLOCK)
 256   message(FATAL_ERROR "LIBCXX_ENABLE_MONOTONIC_CLOCK can only be set to OFF"
 257                       " when LIBCXX_ENABLE_THREADS is also set to OFF.")
 258 endif()
 259
 260 if(NOT LIBCXX_ENABLE_THREADS)
 261   if(LIBCXX_HAS_PTHREAD_API)
 262     message(FATAL_ERROR "LIBCXX_HAS_PTHREAD_API can only be set to ON"
 263                         " when LIBCXX_ENABLE_THREADS is also set to ON.")
 264   endif()
 265   if(LIBCXX_HAS_EXTERNAL_THREAD_API)
 266     message(FATAL_ERROR "LIBCXX_HAS_EXTERNAL_THREAD_API can only be set to ON"
 267                         " when LIBCXX_ENABLE_THREADS is also set to ON.")
 268   endif()
 269   if (LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY)
 270     message(FATAL_ERROR "LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY can only be set "
 271                         "to ON when LIBCXX_ENABLE_THREADS is also set to ON.")
 272   endif()
 273
 274 endif()
 275
 276 if (LIBCXX_HAS_EXTERNAL_THREAD_API)
 277   if (LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY)
 278     message(FATAL_ERROR "The options LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY and "
 279                         "LIBCXX_HAS_EXTERNAL_THREAD_API cannot both be ON at "
 280                         "the same time")
 281   endif()
 282   if (LIBCXX_HAS_PTHREAD_API)
 283     message(FATAL_ERROR "The options LIBCXX_HAS_EXTERNAL_THREAD_API"
 284                         "and LIBCXX_HAS_PTHREAD_API cannot be both"
 285                         "set to ON at the same time.")
 286   endif()
 287 endif()
 288
 289 # Ensure LLVM_USE_SANITIZER is not specified when LIBCXX_GENERATE_COVERAGE
 290 # is ON.
 291 if (LLVM_USE_SANITIZER AND LIBCXX_GENERATE_COVERAGE)
 292   message(FATAL_ERROR "LLVM_USE_SANITIZER cannot be used with LIBCXX_GENERATE_COVERAGE")
 293 endif()
 294
 295 # Set LIBCXX_BUILD_32_BITS to (LIBCXX_BUILD_32_BITS OR LLVM_BUILD_32_BITS)
 296 # and check that we can build with 32 bits if requested.
 297 if (CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32)
 298   if (LIBCXX_BUILD_32_BITS AND NOT LLVM_BUILD_32_BITS) # Don't duplicate the output from LLVM
 299     message(STATUS "Building 32 bits executables and libraries.")
 300   endif()
 301 elseif(LIBCXX_BUILD_32_BITS)
 302   message(FATAL_ERROR "LIBCXX_BUILD_32_BITS=ON is not supported on this platform.")
 303 endif()
 304
 305 # Check that this option is not enabled on Apple and emit a usage warning.
 306 if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
 307   if (APPLE)
 308     message(FATAL_ERROR "LIBCXX_ENABLE_STATIC_ABI_LIBRARY is not supported on OS X")
 309   else()
 310     message(WARNING "LIBCXX_ENABLE_STATIC_ABI_LIBRARY is an experimental option")
 311   endif()
 312   if (LIBCXX_ENABLE_STATIC AND NOT PYTHONINTERP_FOUND)
 313     message(FATAL_ERROR "LIBCXX_ENABLE_STATIC_ABI_LIBRARY requires python but it was not found.")
 314   endif()
 315 endif()
 316
 317 if (LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 318     if (APPLE)
 319       message(FATAL_ERROR "LIBCXX_ENABLE_ABI_LINKER_SCRIPT cannot be used on APPLE targets")
 320     endif()
 321     if (NOT PYTHONINTERP_FOUND)
 322       message(FATAL_ERROR "LIBCXX_ENABLE_ABI_LINKER_SCRIPT requires python but it was not found.")
 323     endif()
 324     if (NOT LIBCXX_ENABLE_SHARED)
 325       message(FATAL_ERROR "LIBCXX_ENABLE_ABI_LINKER_SCRIPT is only available for shared library builds.")
 326     endif()
 327 endif()
 328
 329 if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY AND LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 330     message(FATAL_ERROR "Conflicting options given.
 331         LIBCXX_ENABLE_STATIC_ABI_LIBRARY cannot be specified with
 332         LIBCXX_ENABLE_ABI_LINKER_SCRIPT")
 333 endif()
 334
 335 if (LIBCXX_HAS_MUSL_LIBC AND NOT LIBCXX_INSTALL_SUPPORT_HEADERS)
 336   message(FATAL_ERROR "LIBCXX_INSTALL_SUPPORT_HEADERS can not be turned off"
 337                       "when building for Musl with LIBCXX_HAS_MUSL_LIBC.")
 338 endif()
 339
 340 #===============================================================================
 341 # Configure System
 342 #===============================================================================
 343
 344 set(LIBCXX_COMPILER    ${CMAKE_CXX_COMPILER})
 345 set(LIBCXX_SOURCE_DIR  ${CMAKE_CURRENT_SOURCE_DIR})
 346 set(LIBCXX_BINARY_DIR  ${CMAKE_CURRENT_BINARY_DIR})
 347 set(LIBCXX_BINARY_INCLUDE_DIR "${LIBCXX_BINARY_DIR}/include/c++build")
 348 if (LLVM_LIBRARY_OUTPUT_INTDIR)
 349   set(LIBCXX_LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 350 else()
 351   set(LIBCXX_LIBRARY_DIR ${CMAKE_BINARY_DIR}/lib${LIBCXX_LIBDIR_SUFFIX})
 352 endif()
 353 file(MAKE_DIRECTORY "${LIBCXX_BINARY_INCLUDE_DIR}")
 354
 355 set(LIBCXX_INSTALL_PREFIX "" CACHE STRING
 356     "Define libc++ destination prefix.")
 357
 358 if (NOT LIBCXX_INSTALL_PREFIX MATCHES "^$|.*/")
 359   message(FATAL_ERROR "LIBCXX_INSTALL_PREFIX has to end with \"/\".")
 360 endif()
 361
 362 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LIBCXX_LIBRARY_DIR})
 363 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LIBCXX_LIBRARY_DIR})
 364 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LIBCXX_LIBRARY_DIR})
 365
 366 # Declare libc++ configuration variables.
 367 # They are intended for use as follows:
 368 # LIBCXX_CXX_FLAGS: General flags for both the compiler and linker.
 369 # LIBCXX_COMPILE_FLAGS: Compile only flags.
 370 # LIBCXX_LINK_FLAGS: Linker only flags.
 371 # LIBCXX_LIBRARIES: libraries libc++ is linked to.
 372 # LIBCXX_INTERFACE_LIBRARIES: Libraries that must be linked when using libc++
 373 #                             These libraries are exposed in the linker script.
 374 set(LIBCXX_COMPILE_FLAGS "")
 375 set(LIBCXX_LINK_FLAGS "")
 376 set(LIBCXX_LIBRARIES "")
 377 set(LIBCXX_INTERFACE_LIBRARIES "")
 378
 379 # Include macros for adding and removing libc++ flags.
 380 include(HandleLibcxxFlags)
 381
 382 # Target flags ================================================================
 383 # These flags get added to CMAKE_CXX_FLAGS and CMAKE_C_FLAGS so that
 384 # 'config-ix' use them during feature checks. It also adds them to both
 385 # 'LIBCXX_COMPILE_FLAGS' and 'LIBCXX_LINK_FLAGS'
 386 add_target_flags_if(LIBCXX_BUILD_32_BITS "-m32")
 387 add_target_flags_if(LIBCXX_TARGET_TRIPLE "--target=${LIBCXX_TARGET_TRIPLE}")
 388 add_target_flags_if(LIBCXX_SYSROOT "--sysroot=${LIBCXX_SYSROOT}")
 389 add_target_flags_if(LIBCXX_GCC_TOOLCHAIN "--gcc-toolchain=${LIBCXX_GCC_TOOLCHAIN}")
 390 if (LIBCXX_TARGET_TRIPLE)
 391   set(TARGET_TRIPLE "${LIBCXX_TARGET_TRIPLE}")
 392 endif()
 393
 394 # Configure compiler.
 395 include(config-ix)
 396
 397 if (LIBCXX_USE_COMPILER_RT)
 398   list(APPEND LIBCXX_LINK_FLAGS "-rtlib=compiler-rt")
 399 endif()
 400
 401 # Configure coverage options.
 402 if (LIBCXX_GENERATE_COVERAGE)
 403   include(CodeCoverage)
 404   set(CMAKE_BUILD_TYPE "COVERAGE" CACHE STRING "" FORCE)
 405 endif()
 406
 407 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 408 if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 409   set(LIBCXX_DEBUG_BUILD ON)
 410 else()
 411   set(LIBCXX_DEBUG_BUILD OFF)
 412 endif()
 413
 414 #===============================================================================
 415 # Setup Compiler Flags
 416 #===============================================================================
 417
 418 include(HandleLibCXXABI) # Setup the ABI library flags
 419
 420 if (NOT LIBCXX_STANDALONE_BUILD)
 421   # Remove flags that may have snuck in.
 422   remove_flags(-DNDEBUG -UNDEBUG -D_DEBUG
 423                -lc++abi)
 424 endif()
 425 remove_flags(-stdlib=libc++ -stdlib=libstdc++)
 426
 427 # FIXME: Remove all debug flags and flags that change which Windows
 428 # default libraries are linked. Currently we only support linking the
 429 # non-debug DLLs
 430 remove_flags("/D_DEBUG" "/MTd" "/MDd" "/MT" "/Md")
 431
 432 # FIXME(EricWF): See the FIXME on LIBCXX_ENABLE_PEDANTIC.
 433 # Remove the -pedantic flag and -Wno-pedantic and -pedantic-errors
 434 # so they don't get transformed into -Wno and -errors respectively.
 435 remove_flags(-Wno-pedantic -pedantic-errors -pedantic)
 436
 437 # Required flags ==============================================================
 438 set(LIBCXX_STANDARD_VER c++11 CACHE INTERNAL "internal option to change build dialect")
 439 if (LIBCXX_HAS_MUSL_LIBC)
 440   # musl's pthread implementations uses volatile types in their structs which is
 441   # not a constexpr in C++11 but is in C++14, so we use C++14 with musl.
 442   set(LIBCXX_STANDARD_VER c++14 CACHE INTERNAL "internal option to change build dialect")
 443 endif()
 444 add_compile_flags_if_supported(-std=${LIBCXX_STANDARD_VER})
 445 mangle_name("LIBCXX_SUPPORTS_STD_EQ_${LIBCXX_STANDARD_VER}_FLAG" SUPPORTS_DIALECT_NAME)
 446 if(NOT ${SUPPORTS_DIALECT_NAME})
 447   if(NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC" AND NOT "${CMAKE_CXX_SIMULATE_ID}" STREQUAL "MSVC")
 448     message(FATAL_ERROR "C++11 or greater is required but the compiler does not support ${LIBCXX_STANDARD_VER}")
 449   endif()
 450 endif()
 451
 452 # On all systems the system c++ standard library headers need to be excluded.
 453 # MSVC only has -X, which disables all default includes; including the crt.
 454 # Thus, we do nothing and hope we don't accidentally include any of the C++
 455 # headers
 456 add_compile_flags_if_supported(-nostdinc++)
 457
 458 # Hide all inline function definitions which have not explicitly been marked
 459 # visible. This prevents new definitions for inline functions from appearing in
 460 # the dylib when get ODR used by another function.
 461 add_compile_flags_if_supported(-fvisibility-inlines-hidden)
 462
 463 if (LIBCXX_CONFIGURE_IDE)
 464   # This simply allows IDE to process <experimental/coroutine>
 465   add_compile_flags_if_supported(-fcoroutines-ts)
 466 endif()
 467
 468 # Let the library headers know they are currently being used to build the
 469 # library.
 470 add_definitions(-D_LIBCPP_BUILDING_LIBRARY)
 471
 472 if (NOT LIBCXX_ENABLE_NEW_DELETE_DEFINITIONS)
 473   add_definitions(-D_LIBCPP_DISABLE_NEW_DELETE_DEFINITIONS)
 474 endif()
 475
 476 # Warning flags ===============================================================
 477 add_definitions(-D_LIBCPP_HAS_NO_PRAGMA_SYSTEM_HEADER)
 478 add_compile_flags_if_supported(
 479     -Wall -Wextra -W -Wwrite-strings
 480     -Wno-unused-parameter -Wno-long-long
 481     -Werror=return-type)
 482 if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 483     add_compile_flags_if_supported(
 484         -Wno-user-defined-literals
 485         -Wno-covered-switch-default)
 486 elseif("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU")
 487     add_compile_flags_if_supported(
 488         -Wno-literal-suffix
 489         -Wno-c++14-compat
 490         -Wno-noexcept-type)
 491 endif()
 492 if (LIBCXX_ENABLE_WERROR)
 493   add_compile_flags_if_supported(-Werror)
 494   add_compile_flags_if_supported(-WX)
 495 else()
 496   # TODO(EricWF) Remove this. We shouldn't be suppressing errors when -Werror is
 497   # added elsewhere.
 498   add_compile_flags_if_supported(-Wno-error)
 499 endif()
 500 if (LIBCXX_ENABLE_PEDANTIC)
 501   add_compile_flags_if_supported(-pedantic)
 502 endif()
 503 if (LIBCXX_DISABLE_MACRO_CONFLICT_WARNINGS)
 504   add_definitions(-D_LIBCPP_DISABLE_MACRO_CONFLICT_WARNINGS)
 505 endif()
 506
 507 # Exception flags =============================================================
 508 if (LIBCXX_ENABLE_EXCEPTIONS)
 509   # Catches C++ exceptions only and tells the compiler to assume that extern C
 510   # functions never throw a C++ exception.
 511   add_compile_flags_if_supported(-EHsc)
 512 else()
 513   add_definitions(-D_LIBCPP_NO_EXCEPTIONS)
 514   add_compile_flags_if_supported(-EHs- -EHa-)
 515   add_compile_flags_if_supported(-fno-exceptions)
 516 endif()
 517
 518 # RTTI flags ==================================================================
 519 if (NOT LIBCXX_ENABLE_RTTI)
 520   add_definitions(-D_LIBCPP_NO_RTTI)
 521   add_compile_flags_if_supported(-GR-)
 522   add_compile_flags_if_supported(-fno-rtti)
 523 endif()
 524
 525 # Threading flags =============================================================
 526 if (LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY AND LIBCXX_ENABLE_SHARED)
 527   # Need to allow unresolved symbols if this is to work with shared library builds
 528   if (APPLE)
 529     add_link_flags("-undefined dynamic_lookup")
 530   else()
 531     # Relax this restriction from HandleLLVMOptions
 532     string(REPLACE "-Wl,-z,defs" "" CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS}")
 533   endif()
 534 endif()
 535
 536 # Assertion flags =============================================================
 537 define_if(LIBCXX_ENABLE_ASSERTIONS -UNDEBUG)
 538 define_if_not(LIBCXX_ENABLE_ASSERTIONS -DNDEBUG)
 539 define_if(LIBCXX_ENABLE_ASSERTIONS -D_LIBCPP_DEBUG=0)
 540 define_if(LIBCXX_DEBUG_BUILD -D_DEBUG)
 541 if (LIBCXX_ENABLE_ASSERTIONS AND NOT LIBCXX_DEBUG_BUILD)
 542   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
 543   define_if_not(LIBCXX_TARGETING_MSVC -D_DEBUG)
 544 endif()
 545
 546 # Modules flags ===============================================================
 547 # FIXME The libc++ sources are fundamentally non-modular. They need special
 548 # versions of the headers in order to provide C++03 and legacy ABI definitions.
 549 # NOTE: The public headers can be used with modules in all other contexts.
 550 if (LLVM_ENABLE_MODULES)
 551   # Ignore that the rest of the modules flags are now unused.
 552   add_compile_flags_if_supported(-Wno-unused-command-line-argument)
 553   add_compile_flags(-fno-modules)
 554 endif()
 555
 556 # Sanitizer flags =============================================================
 557
 558 # Configure for sanitizers. If LIBCXX_STANDALONE_BUILD then we have to do
 559 # the flag translation ourselves. Othewise LLVM's CMakeList.txt will handle it.
 560 if (LIBCXX_STANDALONE_BUILD)
 561   set(LLVM_USE_SANITIZER "" CACHE STRING
 562       "Define the sanitizer used to build the library and tests")
 563   # NOTE: LLVM_USE_SANITIZER checks for a UNIX like system instead of MSVC.
 564   # But we don't have LLVM_ON_UNIX so checking for MSVC is the best we can do.
 565   if (LLVM_USE_SANITIZER AND NOT MSVC)
 566     add_flags_if_supported("-fno-omit-frame-pointer")
 567     add_flags_if_supported("-gline-tables-only")
 568
 569     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 570         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 571         add_flags_if_supported("-gline-tables-only")
 572     endif()
 573     if (LLVM_USE_SANITIZER STREQUAL "Address")
 574       add_flags("-fsanitize=address")
 575     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 576       add_flags(-fsanitize=memory)
 577       if (LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 578         add_flags("-fsanitize-memory-track-origins")
 579       endif()
 580     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 581       add_flags("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all")
 582     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 583       add_flags(-fsanitize=thread)
 584     else()
 585       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 586     endif()
 587   elseif(LLVM_USE_SANITIZER AND MSVC)
 588     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 589   endif()
 590 endif()
 591
 592 # Configuration file flags =====================================================
 593 if (NOT LIBCXX_ABI_VERSION EQUAL "1")
 594   config_define(${LIBCXX_ABI_VERSION} _LIBCPP_ABI_VERSION)
 595 endif()
 596 config_define_if(LIBCXX_ABI_UNSTABLE _LIBCPP_ABI_UNSTABLE)
 597
 598 config_define_if_not(LIBCXX_ENABLE_GLOBAL_FILESYSTEM_NAMESPACE _LIBCPP_HAS_NO_GLOBAL_FILESYSTEM_NAMESPACE)
 599 config_define_if_not(LIBCXX_ENABLE_STDIN _LIBCPP_HAS_NO_STDIN)
 600 config_define_if_not(LIBCXX_ENABLE_STDOUT _LIBCPP_HAS_NO_STDOUT)
 601 config_define_if_not(LIBCXX_ENABLE_THREADS _LIBCPP_HAS_NO_THREADS)
 602 config_define_if_not(LIBCXX_ENABLE_MONOTONIC_CLOCK _LIBCPP_HAS_NO_MONOTONIC_CLOCK)
 603 config_define_if_not(LIBCXX_ENABLE_THREAD_UNSAFE_C_FUNCTIONS _LIBCPP_HAS_NO_THREAD_UNSAFE_C_FUNCTIONS)
 604
 605 config_define_if(LIBCXX_HAS_PTHREAD_API _LIBCPP_HAS_THREAD_API_PTHREAD)
 606 config_define_if(LIBCXX_HAS_EXTERNAL_THREAD_API _LIBCPP_HAS_THREAD_API_EXTERNAL)
 607 config_define_if(LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY _LIBCPP_HAS_THREAD_LIBRARY_EXTERNAL)
 608 config_define_if(LIBCXX_HAS_MUSL_LIBC _LIBCPP_HAS_MUSL_LIBC)
 609
 610 # By default libc++ on Windows expects to use a shared library, which requires
 611 # the headers to use DLL import/export semantics. However when building a
 612 # static library only we modify the headers to disable DLL import/export.
 613 if (DEFINED WIN32 AND LIBCXX_ENABLE_STATIC AND NOT LIBCXX_ENABLE_SHARED)
 614   message(STATUS "Generating custom __config for non-DLL Windows build")
 615   config_define(ON _LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS)
 616 endif()
 617
 618 if (LIBCXX_NEEDS_SITE_CONFIG)
 619   configure_file("include/__config_site.in"
 620                  "${LIBCXX_BINARY_DIR}/__config_site"
 621                  @ONLY)
 622
 623   # Provide the config definitions by included the generated __config_site
 624   # file at compile time.
 625   if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC" OR "${CMAKE_CXX_SIMULATE_ID}" STREQUAL "MSVC")
 626     add_compile_flags("/FI\"${LIBCXX_BINARY_DIR}/__config_site\"")
 627   else()
 628     add_compile_flags("-include ${LIBCXX_BINARY_DIR}/__config_site")
 629   endif()
 630 endif()
 631
 632 #===============================================================================
 633 # Setup Source Code And Tests
 634 #===============================================================================
 635 include_directories(include)
 636 add_subdirectory(include)
 637 add_subdirectory(lib)
 638
 639
 640 if (LIBCXX_INCLUDE_BENCHMARKS)
 641   add_subdirectory(benchmarks)
 642 endif()
 643
 644 # Create the lit.site.cfg file even when LIBCXX_INCLUDE_TESTS is OFF or
 645 # LLVM_FOUND is OFF. This allows users to run the tests manually using
 646 # LIT without requiring a full LLVM checkout.
 647 #
 648 # However, since some submission systems strip test/ subdirectories, check for
 649 # it before adding it.
 650 if(IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/test")
 651   add_subdirectory(test)
 652 endif()
 653 if (LIBCXX_INCLUDE_TESTS)
 654   add_subdirectory(lib/abi)
 655 endif()
 656
 657 if (LIBCXX_INCLUDE_DOCS)
 658   add_subdirectory(docs)
 659 endif()