CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 # If we are not building as a part of LLVM, build Clang as an
   4 # standalone project, using LLVM as an external library:
   5 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
   6   project(Clang)
   7
   8   # Rely on llvm-config.
   9   set(CONFIG_OUTPUT)
  10   find_program(LLVM_CONFIG "llvm-config")
  11   if(LLVM_CONFIG)
  12     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  13     set(CONFIG_COMMAND ${LLVM_CONFIG}
  14       "--assertion-mode"
  15       "--bindir"
  16       "--libdir"
  17       "--includedir"
  18       "--prefix"
  19       "--src-root"
  20       "--cmakedir")
  21     execute_process(
  22       COMMAND ${CONFIG_COMMAND}
  23       RESULT_VARIABLE HAD_ERROR
  24       OUTPUT_VARIABLE CONFIG_OUTPUT
  25     )
  26     if(NOT HAD_ERROR)
  27       string(REGEX REPLACE
  28         "[ \t]*[\r\n]+[ \t]*" ";"
  29         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  30     else()
  31       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  32       message(STATUS "${CONFIG_COMMAND_STR}")
  33       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  34     endif()
  35   else()
  36     message(FATAL_ERROR "llvm-config not found -- ${LLVM_CONFIG}")
  37   endif()
  38
  39   list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  40   list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  41   list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  42   list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  43   list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  44   list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  45   list(GET CONFIG_OUTPUT 6 LLVM_CONFIG_CMAKE_PATH)
  46
  47   if(NOT MSVC_IDE)
  48     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  49       CACHE BOOL "Enable assertions")
  50     # Assertions should follow llvm-config's.
  51     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  52   endif()
  53
  54   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  55   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  56   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  57   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  58   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  59
  60   # Normalize LLVM_CMAKE_PATH. --cmakedir might contain backslashes.
  61   # CMake assumes slashes as PATH.
  62   file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_PATH} LLVM_CMAKE_PATH)
  63
  64   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  65     NO_DEFAULT_PATH)
  66
  67   set(LLVMCONFIG_FILE "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  68   if(EXISTS ${LLVMCONFIG_FILE})
  69     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  70     include(${LLVMCONFIG_FILE})
  71   else()
  72     message(FATAL_ERROR "Not found: ${LLVMCONFIG_FILE}")
  73   endif()
  74
  75   # They are used as destination of target generators.
  76   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  77   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  78   if(WIN32 OR CYGWIN)
  79     # DLL platform -- put DLLs into bin.
  80     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  81   else()
  82     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  83   endif()
  84
  85   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  86     "Only include toolchain files in the 'install' target." OFF)
  87
  88   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
  89     "Set to ON to force using an old, unsupported host toolchain." OFF)
  90   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  91
  92   include(AddLLVM)
  93   include(TableGen)
  94   include(HandleLLVMOptions)
  95   include(VersionFromVCS)
  96
  97   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  98
  99   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 100     set(LLVM_INCLUDE_TESTS ON)
 101   endif()
 102
 103   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 104   link_directories("${LLVM_LIBRARY_DIR}")
 105
 106   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 107   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 108   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 109
 110   if(LLVM_INCLUDE_TESTS)
 111     set(Python_ADDITIONAL_VERSIONS 2.7)
 112     include(FindPythonInterp)
 113     if(NOT PYTHONINTERP_FOUND)
 114       message(FATAL_ERROR
 115 "Unable to find Python interpreter, required for builds and testing.
 116
 117 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 118     endif()
 119
 120     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 121       message(FATAL_ERROR "Python 2.7 or newer is required")
 122     endif()
 123
 124     # Check prebuilt llvm/utils.
 125     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 126         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 127         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 128       set(LLVM_UTILS_PROVIDED ON)
 129     endif()
 130
 131     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 132       # Note: path not really used, except for checking if lit was found
 133       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 134       if(NOT LLVM_UTILS_PROVIDED)
 135         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 136         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 137         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 138         set(LLVM_UTILS_PROVIDED ON)
 139         set(CLANG_TEST_DEPS FileCheck count not)
 140       endif()
 141       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 142       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 143           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 144           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 145         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 146       endif()
 147     else()
 148       # Seek installed Lit.
 149       find_program(LLVM_LIT
 150                    NAMES llvm-lit lit.py lit
 151                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 152                    DOC "Path to lit.py")
 153     endif()
 154
 155     if(LLVM_LIT)
 156       # Define the default arguments to use with 'lit', and an option for the user
 157       # to override.
 158       set(LIT_ARGS_DEFAULT "-sv")
 159       if (MSVC OR XCODE)
 160         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 161       endif()
 162       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 163
 164       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 165       if( WIN32 AND NOT CYGWIN )
 166         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 167       endif()
 168     else()
 169       set(LLVM_INCLUDE_TESTS OFF)
 170     endif()
 171   endif()
 172
 173   set( CLANG_BUILT_STANDALONE 1 )
 174   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 175 else()
 176   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 177 endif()
 178
 179 # Make sure that our source directory is on the current cmake module path so that
 180 # we can include cmake files from this directory.
 181 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 182
 183 find_package(LibXml2 2.5.3 QUIET)
 184 if (LIBXML2_FOUND)
 185   set(CLANG_HAVE_LIBXML 1)
 186 endif()
 187
 188 include(CheckIncludeFile)
 189 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 190
 191 set(CLANG_RESOURCE_DIR "" CACHE STRING
 192   "Relative directory from the Clang binary to its resource files.")
 193
 194 set(C_INCLUDE_DIRS "" CACHE STRING
 195   "Colon separated list of directories clang will search for headers.")
 196
 197 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 198 set(DEFAULT_SYSROOT "" CACHE PATH
 199   "Default <path> to all compiler invocations for --sysroot=<path>." )
 200
 201 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 202
 203 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 204     "enable x86 relax relocations by default")
 205
 206 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 207   "Default linker to use (linker name or absolute path, empty for platform default)")
 208
 209 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 210   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 211 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 212         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 213         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 214   message(WARNING "Resetting default C++ stdlib to use platform default")
 215   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 216     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 217 endif()
 218
 219 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 220   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 221 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 222         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 223         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 224   message(WARNING "Resetting default rtlib to use platform default")
 225   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 226     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 227 endif()
 228
 229 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 230   "Default OpenMP runtime used by -fopenmp.")
 231
 232 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 233   "Vendor-specific text for showing with version information.")
 234
 235 if( CLANG_VENDOR )
 236   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 237 endif()
 238
 239 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 240   "Vendor-specific text for showing the repository the source is taken from.")
 241
 242 if(CLANG_REPOSITORY_STRING)
 243   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 244 endif()
 245
 246 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 247   "Vendor-specific uti.")
 248
 249 # The libdir suffix must exactly match whatever LLVM's configuration used.
 250 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 251
 252 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 253 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 254
 255 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 256   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 257 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 258 "from there, passing the path to this source directory as the last argument. "
 259 "This process created the file `CMakeCache.txt' and the directory "
 260 "`CMakeFiles'. Please delete them.")
 261 endif()
 262
 263 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 264   file(GLOB_RECURSE
 265     tablegenned_files_on_include_dir
 266     "${CLANG_SOURCE_DIR}/include/clang/*.inc")
 267   if( tablegenned_files_on_include_dir )
 268     message(FATAL_ERROR "Apparently there is a previous in-source build, "
 269 "probably as the result of running `configure' and `make' on "
 270 "${CLANG_SOURCE_DIR}. This may cause problems. The suspicious files are:\n"
 271 "${tablegenned_files_on_include_dir}\nPlease clean the source directory.")
 272   endif()
 273 endif()
 274
 275 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 276 if(NOT DEFINED CLANG_VERSION_MAJOR)
 277   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 278 endif()
 279 if(NOT DEFINED CLANG_VERSION_MINOR)
 280   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 281 endif()
 282 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 283   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 284 endif()
 285 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 286 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 287 message(STATUS "Clang version: ${CLANG_VERSION}")
 288
 289 # Configure the Version.inc file.
 290 configure_file(
 291   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 292   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 293
 294 # Add appropriate flags for GCC
 295 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 296   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 297   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 298     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 299   endif ()
 300
 301   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 302   if (NOT LLVM_ENABLE_PEDANTIC)
 303     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 304   endif ()
 305
 306   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 307   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 308     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 309   endif()
 310 endif ()
 311
 312 # Determine HOST_LINK_VERSION on Darwin.
 313 set(HOST_LINK_VERSION)
 314 if (APPLE)
 315   set(LD_V_OUTPUT)
 316   execute_process(
 317     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 318     RESULT_VARIABLE HAD_ERROR
 319     OUTPUT_VARIABLE LD_V_OUTPUT
 320   )
 321   if (NOT HAD_ERROR)
 322     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 323       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 324     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 325       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 326     endif()
 327   else()
 328     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 329   endif()
 330 endif()
 331
 332 configure_file(
 333   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 334   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)
 335
 336 include(CMakeParseArguments)
 337 include(AddClang)
 338
 339 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 340
 341 include_directories(BEFORE
 342   ${CMAKE_CURRENT_BINARY_DIR}/include
 343   ${CMAKE_CURRENT_SOURCE_DIR}/include
 344   )
 345
 346 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 347   install(DIRECTORY include/clang include/clang-c
 348     DESTINATION include
 349     FILES_MATCHING
 350     PATTERN "*.def"
 351     PATTERN "*.h"
 352     PATTERN "config.h" EXCLUDE
 353     PATTERN ".svn" EXCLUDE
 354     )
 355
 356   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 357     DESTINATION include
 358     FILES_MATCHING
 359     PATTERN "CMakeFiles" EXCLUDE
 360     PATTERN "*.inc"
 361     PATTERN "*.h"
 362     )
 363 endif()
 364
 365 add_definitions( -D_GNU_SOURCE )
 366
 367 option(CLANG_BUILD_TOOLS
 368   "Build the Clang tools. If OFF, just generate build targets." ON)
 369
 370 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 371 if (CLANG_ENABLE_ARCMT)
 372   set(ENABLE_CLANG_ARCMT "1")
 373 else()
 374   set(ENABLE_CLANG_ARCMT "0")
 375 endif()
 376
 377 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 378 if (CLANG_ENABLE_STATIC_ANALYZER)
 379   set(ENABLE_CLANG_STATIC_ANALYZER "1")
 380 else()
 381   set(ENABLE_CLANG_STATIC_ANALYZER "0")
 382 endif()
 383
 384 if (NOT CLANG_ENABLE_STATIC_ANALYZER AND CLANG_ENABLE_ARCMT)
 385   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT")
 386 endif()
 387
 388 if(CLANG_ENABLE_ARCMT)
 389   add_definitions(-DCLANG_ENABLE_ARCMT)
 390   add_definitions(-DCLANG_ENABLE_OBJC_REWRITER)
 391 endif()
 392 if(CLANG_ENABLE_STATIC_ANALYZER)
 393   add_definitions(-DCLANG_ENABLE_STATIC_ANALYZER)
 394 endif()
 395
 396 # Clang version information
 397 set(CLANG_EXECUTABLE_VERSION
 398      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 399     "Version number that will be placed into the clang executable, in the form XX.YY")
 400 set(LIBCLANG_LIBRARY_VERSION
 401      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 402     "Version number that will be placed into the libclang library , in the form XX.YY")
 403 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 404
 405 option(CLANG_INCLUDE_TESTS
 406        "Generate build targets for the Clang unit tests."
 407        ${LLVM_INCLUDE_TESTS})
 408
 409 add_subdirectory(utils/TableGen)
 410
 411 add_subdirectory(include)
 412
 413 # All targets below may depend on all tablegen'd files.
 414 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 415 list(APPEND LLVM_COMMON_DEPENDS ${CLANG_TABLEGEN_TARGETS})
 416
 417 add_subdirectory(lib)
 418 add_subdirectory(tools)
 419 add_subdirectory(runtime)
 420
 421 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 422 if (CLANG_BUILD_EXAMPLES)
 423   set(ENABLE_CLANG_EXAMPLES "1")
 424 else()
 425   set(ENABLE_CLANG_EXAMPLES "0")
 426 endif()
 427 add_subdirectory(examples)
 428
 429 if(APPLE)
 430   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 431   # default value get updated to the new default.
 432   if(CLANG_ORDER_FILE STREQUAL "")
 433     unset(CLANG_ORDER_FILE CACHE)
 434     unset(CLANG_ORDER_FILE)
 435   endif()
 436
 437
 438   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 439     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 440
 441   if(NOT EXISTS ${CLANG_ORDER_FILE})
 442     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 443     if(PATH_START EQUAL 0)
 444       file(WRITE ${CLANG_ORDER_FILE} "\n")
 445     else()
 446       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 447     endif()
 448   endif()
 449 endif()
 450
 451
 452 if( CLANG_INCLUDE_TESTS )
 453   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 454     add_subdirectory(unittests)
 455     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 456     list(APPEND CLANG_TEST_PARAMS
 457       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 458       )
 459   endif()
 460   add_subdirectory(test)
 461
 462   if(CLANG_BUILT_STANDALONE)
 463     # Add a global check rule now that all subdirectories have been traversed
 464     # and we know the total set of lit testsuites.
 465     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 466     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 467     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 468     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 469     add_lit_target(check-all
 470       "Running all regression tests"
 471       ${LLVM_LIT_TESTSUITES}
 472       PARAMS ${LLVM_LIT_PARAMS}
 473       DEPENDS ${LLVM_LIT_DEPENDS}
 474       ARGS ${LLVM_LIT_EXTRA_ARGS}
 475       )
 476   endif()
 477   add_subdirectory(utils/perf-training)
 478 endif()
 479
 480 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 481   ${LLVM_INCLUDE_DOCS})
 482 if( CLANG_INCLUDE_DOCS )
 483   add_subdirectory(docs)
 484 endif()
 485
 486 add_subdirectory(cmake/modules)
 487
 488 if(CLANG_STAGE)
 489   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 490 endif()
 491
 492 if (CLANG_ENABLE_BOOTSTRAP)
 493   include(ExternalProject)
 494
 495   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 496
 497   if(NOT CLANG_STAGE)
 498     set(CLANG_STAGE stage1)
 499   endif()
 500
 501   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 502   if(MATCHED_STAGE)
 503     if(NOT LLVM_BUILD_INSTRUMENTED)
 504       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 505       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 506     else()
 507       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 508     endif()
 509   else()
 510     set(NEXT_CLANG_STAGE bootstrap)
 511   endif()
 512
 513   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 514     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 515   endif()
 516   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 517
 518
 519   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 520   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 521
 522   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 523   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 524     if(APPLE)
 525       add_dependencies(clang-bootstrap-deps LTO)
 526       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 527       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 528       # so that the host object file tools will use the just-built libLTO.
 529       # However if System Integrity Protection is enabled the DYLD variables
 530       # will be scrubbed from the environment of any base system commands. This
 531       # includes /bin/sh, which ninja uses when executing build commands. To
 532       # work around the envar being filtered away we pass it in as a CMake
 533       # variable, and have LLVM's CMake append the envar to the archiver calls.
 534       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 535         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 536     elseif(NOT WIN32)
 537       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 538       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 539         add_dependencies(clang-bootstrap-deps lld)
 540       elseif(LLVM_BINUTILS_INCDIR)
 541         add_dependencies(clang-bootstrap-deps LLVMgold)
 542       endif()
 543       set(LTO_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 544       set(LTO_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 545     endif()
 546   endif()
 547
 548   add_custom_target(${NEXT_CLANG_STAGE}-clear
 549     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 550     )
 551   add_custom_command(
 552     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 553     DEPENDS clang-bootstrap-deps
 554     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 555     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 556     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 557     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 558     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 559     )
 560
 561   if(CMAKE_VERBOSE_MAKEFILE)
 562     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 563   endif()
 564
 565   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 566     PACKAGE_VERSION
 567     PACKAGE_VENDOR
 568     LLVM_VERSION_MAJOR
 569     LLVM_VERSION_MINOR
 570     LLVM_VERSION_PATCH
 571     CLANG_VERSION_MAJOR
 572     CLANG_VERSION_MINOR
 573     CLANG_VERSION_PATCHLEVEL
 574     LLVM_VERSION_SUFFIX
 575     LLVM_BINUTILS_INCDIR
 576     CLANG_REPOSITORY_STRING
 577     CMAKE_MAKE_PROGRAM
 578     CMAKE_OSX_ARCHITECTURES)
 579
 580   # We don't need to depend on compiler-rt if we're building instrumented
 581   # because the next stage will use the same compiler used to build this stage.
 582   if(TARGET compiler-rt AND NOT LLVM_BUILD_INSTRUMENTED)
 583     add_dependencies(clang-bootstrap-deps compiler-rt)
 584   endif()
 585
 586   set(COMPILER_OPTIONS
 587     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++
 588     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
 589     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
 590
 591   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 592     add_dependencies(clang-bootstrap-deps llvm-profdata)
 593     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 594   endif()
 595
 596   if(LLVM_BUILD_INSTRUMENTED)
 597     add_dependencies(clang-bootstrap-deps generate-profdata)
 598     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 599     # Use the current tools for LTO instead of the instrumented ones
 600     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 601       CMAKE_CXX_COMPILER
 602       CMAKE_C_COMPILER
 603       CMAKE_ASM_COMPILER
 604       CMAKE_AR
 605       CMAKE_RANLIB
 606       DARWIN_LTO_LIBRARY
 607       DYLD_LIBRARY_PATH)
 608
 609     set(COMPILER_OPTIONS)
 610     set(LTO_LIBRARY)
 611     set(LTO_AR)
 612     set(LTO_RANLIB)
 613   endif()
 614
 615   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 616   # them.
 617   get_cmake_property(variableNames VARIABLES)
 618   foreach(variableName ${variableNames})
 619     if(variableName MATCHES "^BOOTSTRAP_")
 620       string(SUBSTRING ${variableName} 10 -1 varName)
 621       string(REPLACE ";" "\;" value "${${variableName}}")
 622       list(APPEND PASSTHROUGH_VARIABLES
 623         -D${varName}=${value})
 624     endif()
 625     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 626       list(APPEND PASSTHROUGH_VARIABLES
 627         -D${variableName}=${${variableName}})
 628     endif()
 629   endforeach()
 630
 631   # Populate the passthrough variables
 632   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 633     if(DEFINED ${variableName})
 634       if("${${variableName}}" STREQUAL "")
 635         set(value "")
 636       else()
 637         string(REPLACE ";" "\;" value ${${variableName}})
 638       endif()
 639       list(APPEND PASSTHROUGH_VARIABLES
 640         -D${variableName}=${value})
 641     endif()
 642   endforeach()
 643
 644   ExternalProject_Add(${NEXT_CLANG_STAGE}
 645     DEPENDS clang-bootstrap-deps
 646     PREFIX ${NEXT_CLANG_STAGE}
 647     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 648     STAMP_DIR ${STAMP_DIR}
 649     BINARY_DIR ${BINARY_DIR}
 650     EXCLUDE_FROM_ALL 1
 651     CMAKE_ARGS
 652                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 653                 # seem to work, so instead I'm passing this through
 654                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 655                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 656                 ${PASSTHROUGH_VARIABLES}
 657                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 658                 ${COMPILER_OPTIONS}
 659                 ${LTO_LIBRARY} ${LTO_AR} ${LTO_RANLIB} ${verbose} ${PGO_OPT}
 660     INSTALL_COMMAND ""
 661     STEP_TARGETS configure build
 662     USES_TERMINAL_CONFIGURE 1
 663     USES_TERMINAL_BUILD 1
 664     USES_TERMINAL_INSTALL 1
 665     )
 666
 667   # exclude really-install from main target
 668   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 669   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 670     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 671     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 672     DEPENDEES build
 673     USES_TERMINAL 1
 674   )
 675   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 676   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 677
 678   if(NOT CLANG_BOOTSTRAP_TARGETS)
 679     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 680   endif()
 681   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 682     # exclude from main target
 683     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 684
 685     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 686       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 687       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 688       DEPENDEES configure
 689       USES_TERMINAL 1
 690     )
 691
 692     if(target MATCHES "^stage[0-9]*")
 693       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 694     endif()
 695
 696     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 697   endforeach()
 698 endif()
 699
 700 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 701   add_subdirectory(utils/ClangVisualizers)
 702 endif()