CMakeLists.txt

   1 #
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.12 FATAL_ERROR)
   3 #
   4 PROJECT(libarchive C)
   5 #
   6 SET(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/build/cmake")
   7 if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)
   8   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${libarchive_BINARY_DIR}/bin)
   9 endif()
  10 #
  11 # Set the Build type for make based generators.
  12 # You can choose following types:
  13 #   Debug          : Debug build
  14 #   Release        : Release build
  15 #   RelWithDebInfo : Release build with Debug Info
  16 #   MinSizeRel     : Release Min Size build
  17 IF(NOT CMAKE_BUILD_TYPE)
  18   SET(CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build Type" FORCE)
  19 ENDIF(NOT CMAKE_BUILD_TYPE)
  20 # Set a value type to properly display CMAKE_BUILD_TYPE on GUI if the
  21 # value type is "UNINITIALIZED".
  22 GET_PROPERTY(cached_type CACHE CMAKE_BUILD_TYPE PROPERTY TYPE)
  23 IF("${cached_type}" STREQUAL "UNINITIALIZED")
  24   SET(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING "Build Type" FORCE)
  25 ENDIF("${cached_type}" STREQUAL "UNINITIALIZED")
  26 # Check the Build Type.
  27 IF(NOT "${CMAKE_BUILD_TYPE}"
  28        MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  29   MESSAGE(FATAL_ERROR
  30           "Unknown keyword for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}\n"
  31           "Acceptable keywords: Debug,Release,RelWithDebInfo,MinSizeRel")
  32 ENDIF(NOT "${CMAKE_BUILD_TYPE}"
  33           MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)\$")
  34
  35 # On MacOS, prefer MacPorts libraries to system libraries.
  36 # I haven't come up with a compelling argument for this to be conditional.
  37 list(APPEND CMAKE_PREFIX_PATH /opt/local)
  38 # Enable @rpath in the install name.
  39 # detail in "cmake  --help-policy CMP0042"
  40 SET(CMAKE_MACOSX_RPATH ON)
  41
  42 #
  43 # Version - read from 'version' file.
  44 #
  45 FILE(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/build/version _version)
  46 STRING(REGEX REPLACE
  47  "^([0-9])[0-9][0-9][0-9][0-9][0-9][0-9][a-z]*$" "\\1" _major ${_version})
  48 STRING(REGEX REPLACE
  49  "^[0-9]([0-9][0-9][0-9])[0-9][0-9][0-9][a-z]*$" "\\1" _minor ${_version})
  50 STRING(REGEX REPLACE
  51  "^[0-9][0-9][0-9][0-9]([0-9][0-9][0-9])[a-z]*$" "\\1" _revision ${_version})
  52 STRING(REGEX REPLACE
  53  "^[0-9][0-9][0-9][0-9][0-9][0-9][0-9]([a-z]*)$" "\\1" _quality ${_version})
  54 SET(_version_number ${_major}${_minor}${_revision})
  55 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_minor ${_minor})
  56 STRING(REGEX REPLACE "[0]*([^0]*[0-9])$" "\\1" _trimmed_revision ${_revision})
  57 #
  58 SET(VERSION                    "${_major}.${_trimmed_minor}.${_trimmed_revision}${_quality}")
  59 SET(BSDCPIO_VERSION_STRING     "${VERSION}")
  60 SET(BSDTAR_VERSION_STRING      "${VERSION}")
  61 SET(BSDCAT_VERSION_STRING      "${VERSION}")
  62 SET(LIBARCHIVE_VERSION_NUMBER  "${_version_number}")
  63 SET(LIBARCHIVE_VERSION_STRING  "${VERSION}")
  64
  65 # INTERFACE_VERSION increments with every release
  66 # libarchive 2.7 == interface version 9 = 2 + 7
  67 # libarchive 2.8 == interface version 10 = 2 + 8
  68 # libarchive 2.9 == interface version 11 = 2 + 9
  69 # libarchive 3.0 == interface version 12
  70 # libarchive 3.1 == interface version 13
  71 math(EXPR INTERFACE_VERSION  "13 + ${_minor}")
  72
  73 # Set SOVERSION == Interface version
  74 # ?? Should there be more here ??
  75 SET(SOVERSION "${INTERFACE_VERSION}")
  76
  77 # Enalbe CMAKE_PUSH_CHECK_STATE() and CMAKE_POP_CHECK_STATE() macros
  78 # saving and restoring the state of the variables.
  79 INCLUDE(CMakePushCheckState)
  80
  81 # Initialize the state of the variables. This initialization is not
  82 # necessary but this shows you what value the variables initially have.
  83 SET(CMAKE_REQUIRED_DEFINITIONS)
  84 SET(CMAKE_REQUIRED_INCLUDES)
  85 SET(CMAKE_REQUIRED_LIBRARIES)
  86 SET(CMAKE_REQUIRED_FLAGS)
  87
  88 # Especially for early development, we want to be a little
  89 # aggressive about diagnosing build problems; this can get
  90 # relaxed somewhat in final shipping versions.
  91 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
  92   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
  93   #################################################################
  94   # Set compile flags for all build types.
  95   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
  96   #################################################################
  97   # Set compile flags for debug build.
  98   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
  99   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Werror")
 100   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 101   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 102   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 103   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 104   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 105 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$")
 106 IF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 107   SET(CMAKE_REQUIRED_FLAGS "-Wall -Wformat -Wformat-security")
 108   #################################################################
 109   # Set compile flags for all build types.
 110   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wformat -Wformat-security")
 111   #################################################################
 112   # Set compile flags for debug build.
 113   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 114   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 115   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Werror")
 116   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wextra")
 117   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wunused")
 118   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wshadow")
 119   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wmissing-prototypes")
 120   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -Wcast-qual")
 121 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 122 IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 123   SET(CMAKE_C_COMPILER "xlc_r")
 124   SET(CMAKE_REQUIRED_FLAGS "-qflag=e:e -qformat=sec")
 125   #################################################################
 126   # Set compile flags for all build types.
 127   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -qflag=e:e -qformat=sec")
 128   #################################################################
 129   # Set compile flags for debug build.
 130   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 131   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -g")
 132   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qhalt=w")
 133   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qflag=w:w")
 134   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -qinfo=pro:use")
 135 ENDIF(CMAKE_C_COMPILER_ID MATCHES "^XL$")
 136 IF (MSVC)
 137   #################################################################
 138   # Set compile flags for debug build.
 139   # This is added into CMAKE_C_FLAGS when CMAKE_BUILD_TYPE is "Debug"
 140   # Enable level 4 C4061: The enumerate has no associated handler in a switch
 141   #                       statement.
 142   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4061")
 143   # Enable level 4 C4254: A larger bit field was assigned to a smaller bit
 144   #                       field.
 145   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4254")
 146   # Enable level 4 C4295: An array was initialized but the last character in
 147   #                       the array is not a null; accessing the array may
 148   #                       produce unexpected results.
 149   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4295")
 150   # Enable level 4 C4296: An unsigned variable was used in a comparison
 151   #                       operation with zero.
 152   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4296")
 153   # Enable level 4 C4389: An operation involved signed and unsigned variables.
 154   #                       This could result in a loss of data.
 155   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4389")
 156   # Enable level 4 C4505: The given function is local and not referenced in
 157   #                       the body of the module; therefore, the function is
 158   #                       dead code.
 159   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4505")
 160   # Enable level 4 C4514: The optimizer removed an inline function that is not
 161   #                       called.
 162   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4514")
 163   # Enable level 4 C4702: Unreachable code.
 164   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4702")
 165   # Enable level 4 C4706: The test value in a conditional expression was the
 166   #                       result of an assignment.
 167   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /we4706")
 168   # /WX option is the same as gcc's -Werror option.
 169   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /WX")
 170   # /Oi option enables built-in functions.
 171   SET(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /Oi")
 172   #################################################################
 173   # Set compile flags for release build.
 174   SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Oi")
 175 ENDIF (MSVC)
 176
 177 # Enable CTest/CDash support
 178 include(CTest)
 179
 180 OPTION(ENABLE_NETTLE "Enable use of Nettle" ON)
 181 OPTION(ENABLE_OPENSSL "Enable use of OpenSSL" ON)
 182 OPTION(ENABLE_LZO "Enable the use of the system LZO library if found" OFF)
 183 OPTION(ENABLE_LZMA "Enable the use of the system LZMA library if found" ON)
 184
 185 OPTION(ENABLE_ZLIB "Enable the use of the system ZLIB library if found" ON)
 186 OPTION(ENABLE_BZip2 "Enable the use of the system BZip2 library if found" ON)
 187 OPTION(ENABLE_LIBXML2 "Enable the use of the system libxml2 library if found" ON)
 188 OPTION(ENABLE_EXPAT "Enable the use of the system EXPAT library if found" ON)
 189 OPTION(ENABLE_PCREPOSIX "Enable the use of the system PCREPOSIX library if found" ON)
 190 OPTION(ENABLE_LibGCC "Enable the use of the system LibGCC library if found" ON)
 191 # CNG is used for encrypt/decrypt Zip archives on Windows.
 192 OPTION(ENABLE_CNG "Enable the use of CNG(Crypto Next Generation)" ON)
 193
 194 OPTION(ENABLE_TAR "Enable tar building" ON)
 195 OPTION(ENABLE_TAR_SHARED "Enable dynamic build of tar" FALSE)
 196 OPTION(ENABLE_CPIO "Enable cpio building" ON)
 197 OPTION(ENABLE_CPIO_SHARED "Enable dynamic build of cpio" FALSE)
 198 OPTION(ENABLE_CAT "Enable cat building" ON)
 199 OPTION(ENABLE_CAT_SHARED "Enable dynamic build of cat" FALSE)
 200 OPTION(ENABLE_XATTR "Enable extended attribute support" ON)
 201 OPTION(ENABLE_ACL "Enable ACL support" ON)
 202 OPTION(ENABLE_ICONV "Enable iconv support" ON)
 203 OPTION(ENABLE_TEST "Enable unit and regression tests" ON)
 204 OPTION(ENABLE_COVERAGE "Enable code coverage (GCC only, automatically sets ENABLE_TEST to ON)" FALSE)
 205 OPTION(ENABLE_INSTALL "Enable installing of libraries" ON)
 206
 207 SET(POSIX_REGEX_LIB "AUTO" CACHE STRING "Choose what library should provide POSIX regular expression support")
 208 SET(ENABLE_SAFESEH "AUTO" CACHE STRING "Enable use of /SAFESEH linker flag (MSVC only)")
 209 SET(WINDOWS_VERSION "WIN7" CACHE STRING "Set Windows version to use (Windows only)")
 210
 211 IF(ENABLE_COVERAGE)
 212         include(LibarchiveCodeCoverage)
 213 ENDIF(ENABLE_COVERAGE)
 214
 215 IF(ENABLE_TEST)
 216         ENABLE_TESTING()
 217 ENDIF(ENABLE_TEST)
 218
 219 IF(WIN32)
 220   IF(WINDOWS_VERSION STREQUAL "WIN8")
 221     SET(NTDDI_VERSION 0x06020000)
 222     SET(_WIN32_WINNT 0x0602)
 223     SET(WINVER 0x0602)
 224   ELSEIF(WINDOWS_VERSION STREQUAL "WIN7")
 225     SET(NTDDI_VERSION 0x06010000)
 226     SET(_WIN32_WINNT 0x0601)
 227     SET(WINVER 0x0601)
 228   ELSEIF(WINDOWS_VERSION STREQUAL "WS08")
 229     SET(NTDDI_VERSION 0x06000100)
 230     SET(_WIN32_WINNT 0x0600)
 231     SET(WINVER 0x0600)
 232   ELSEIF(WINDOWS_VERSION STREQUAL "VISTA")
 233     SET(NTDDI_VERSION 0x06000000)
 234     SET(_WIN32_WINNT 0x0600)
 235     SET(WINVER 0x0600)
 236   ELSEIF(WINDOWS_VERSION STREQUAL "WS03")
 237     SET(NTDDI_VERSION 0x05020000)
 238     SET(_WIN32_WINNT 0x0502)
 239     SET(WINVER 0x0502)
 240   ELSEIF(WINDOWS_VERSION STREQUAL "WINXP")
 241     SET(NTDDI_VERSION 0x05010000)
 242     SET(_WIN32_WINNT 0x0501)
 243     SET(WINVER 0x0501)
 244   ELSE(WINDOWS_VERSION STREQUAL "WIN8")
 245     # Default to Windows Server 2003 API if we don't recognize the specifier
 246     SET(NTDDI_VERSION 0x05020000)
 247     SET(_WIN32_WINNT 0x0502)
 248     SET(WINVER 0x0502)
 249   ENDIF(WINDOWS_VERSION STREQUAL "WIN8")
 250 ENDIF(WIN32)
 251
 252 IF(MSVC)
 253   IF(ENABLE_SAFESEH STREQUAL "YES")
 254     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH")
 255     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH")
 256     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH")
 257     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH")
 258   ELSEIF(ENABLE_SAFESEH STREQUAL "NO")
 259     SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
 260     SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SAFESEH:NO")
 261     SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /SAFESEH:NO")
 262     SET(ENV{LDFLAGS} "$ENV{LDFLAGS} /SAFESEH:NO")
 263   ENDIF(ENABLE_SAFESEH STREQUAL "YES")
 264 ENDIF(MSVC)
 265
 266 IF("${CMAKE_C_PLATFORM_ID}" MATCHES "^(HP-UX)$")
 267   ADD_DEFINITIONS(-D_XOPEN_SOURCE=500) # Ask wchar.h for mbstate_t
 268 ENDIF()
 269
 270 #
 271 INCLUDE(CheckCSourceCompiles)
 272 INCLUDE(CheckCSourceRuns)
 273 INCLUDE(CheckFileOffsetBits)
 274 INCLUDE(CheckFuncs)
 275 INCLUDE(CheckHeaderDirent)
 276 INCLUDE(CheckIncludeFile)
 277 INCLUDE(CheckIncludeFiles)
 278 INCLUDE(CheckLibraryExists)
 279 INCLUDE(CheckStructHasMember)
 280 INCLUDE(CheckSymbolExists)
 281 INCLUDE(CheckTypeExists)
 282 INCLUDE(CheckTypeSize)
 283
 284 #
 285 # Generate list.h
 286 #
 287 MACRO (GENERATE_LIST_H _listfile _cmlist __list_sources)
 288   SET(_argv ${ARGV})
 289   # Remove _listfile and _cmlist from _argv
 290   LIST(REMOVE_AT _argv 0 1)
 291   IF (NOT EXISTS "${_listfile}" OR
 292      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 293
 294     MESSAGE(STATUS "Generating ${_listfile}")
 295     FILE(WRITE ${_listfile} "")
 296     FOREACH (testfile ${_argv})
 297       IF (testfile MATCHES "^test_[^/]+[.]c$")
 298         FILE(STRINGS ${testfile} testvar REGEX "^DEFINE_TEST")
 299         FOREACH (deftest ${testvar})
 300           FILE(APPEND ${_listfile} "${deftest}\n")
 301         ENDFOREACH (deftest)
 302       ENDIF (testfile MATCHES "^test_[^/]+[.]c$")
 303     ENDFOREACH (testfile)
 304
 305   ENDIF (NOT EXISTS "${_listfile}" OR
 306      ${_cmlist} IS_NEWER_THAN "${_listfile}")
 307 ENDMACRO (GENERATE_LIST_H)
 308 #
 309 # Generate installation rules for man pages.
 310 #
 311 MACRO (INSTALL_MAN __mans)
 312   FOREACH (_man ${ARGV})
 313     STRING(REGEX REPLACE "^.+[.]([1-9])" "\\1" _mansect ${_man})
 314     INSTALL(FILES ${_man} DESTINATION "share/man/man${_mansect}")
 315   ENDFOREACH (_man)
 316 ENDMACRO (INSTALL_MAN __mans)
 317 #
 318 # Find out what macro is needed to use libraries on Windows.
 319 #
 320 MACRO (TRY_MACRO_FOR_LIBRARY INCLUDES LIBRARIES
 321        TRY_TYPE SAMPLE_SOURCE MACRO_LIST)
 322   IF(WIN32 AND NOT CYGWIN)
 323     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 324     SET(CMAKE_REQUIRED_INCLUDES ${INCLUDES})
 325     SET(CMAKE_REQUIRED_LIBRARIES ${LIBRARIES})
 326     FOREACH(VAR ${MACRO_LIST})
 327       # Clear ${VAR} from CACHE If the libraries which ${VAR} was
 328       # checked with are changed.
 329       SET(VAR_WITH_LIB "${VAR}_WITH_LIB")
 330       GET_PROPERTY(PREV_VAR_WITH_LIB VARIABLE PROPERTY ${VAR_WITH_LIB})
 331       IF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 332         UNSET(${VAR} CACHE)
 333       ENDIF(NOT "${PREV_VAR_WITH_LIB}" STREQUAL "${LIBRARIES}")
 334       # Check if the library can be used with the macro.
 335       IF("${TRY_TYPE}" MATCHES "COMPILES")
 336         CHECK_C_SOURCE_COMPILES("${SAMPLE_SOURCE}" ${VAR})
 337       ELSEIF("${TRY_TYPE}" MATCHES "RUNS")
 338         CHECK_C_SOURCE_RUNS("${SAMPLE_SOURCE}" ${VAR})
 339       ELSE("${TRY_TYPE}" MATCHES "COMPILES")
 340         MESSAGE(FATAL_ERROR "UNKNOWN KEYWORD \"${TRY_TYPE}\" FOR TRY_TYPE")
 341       ENDIF("${TRY_TYPE}" MATCHES "COMPILES")
 342       # Save the libraries which ${VAR} is checked with.
 343       SET(${VAR_WITH_LIB} "${LIBRARIES}" CACHE INTERNAL
 344           "Macro ${VAR} is checked with")
 345     ENDFOREACH(VAR)
 346     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 347   ENDIF(WIN32 AND NOT CYGWIN)
 348 ENDMACRO (TRY_MACRO_FOR_LIBRARY)
 349 #
 350 # Check compress/decompress libraries
 351 #
 352 IF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 353   # GnuWin32 is only for Win32, not Win64.
 354   SET(__GNUWIN32PATH "C:/Program Files/GnuWin32")
 355 ENDIF(WIN32 AND NOT CMAKE_CL_64 AND NOT CYGWIN)
 356 IF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 357   # You have to add a path availabel DLL file into PATH environment variable.
 358   # Maybe DLL path is "C:/Program Files/GnuWin32/bin".
 359   # The zlib and the bzip2 Setup program have installed programs and DLLs into
 360   # "C:/Program Files/GnuWin32" by default.
 361   # This is convenience setting for Windows.
 362   SET(CMAKE_PREFIX_PATH ${__GNUWIN32PATH} $(CMAKE_PREFIX_PATH))
 363   #
 364   # If you didn't use Setup program or installed into nonstandard path,
 365   # cmake cannot find out your zlib or bzip2 libraries and include files,
 366   # you should execute cmake with  -DCMAKE_PREFIX_PATH option.
 367   #   e.g.
 368   #     cmake -DCMAKE_PREFIX_PATH=<your-GnuWin32-path> <path-to-source>
 369   #
 370   # If compiling error occurred in zconf.h, You may need patch to zconf.h.
 371   #--- zconf.h.orig     2005-07-21 00:40:26.000000000
 372   #+++ zconf.h  2009-01-19 11:39:10.093750000
 373   #@@ -286,7 +286,7 @@
 374   #
 375   # #if 1           /* HAVE_UNISTD_H -- this line is updated by ./configure */
 376   # #  include <sys/types.h> /* for off_t */
 377   #-#  include <unistd.h>    /* for SEEK_* and off_t */
 378   #+#  include <stdio.h>    /* for SEEK_* and off_t */
 379   # #  ifdef VMS
 380   # #    include <unixio.h>   /* for off_t */
 381   # #  endif
 382 ENDIF(DEFINED __GNUWIN32PATH AND EXISTS "${__GNUWIN32PATH}")
 383
 384 SET(ADDITIONAL_LIBS "")
 385 #
 386 # Find ZLIB
 387 #
 388 IF(ENABLE_ZLIB)
 389   FIND_PACKAGE(ZLIB)
 390 ELSE()
 391   SET(ZLIB_FOUND FALSE) # Override cached value
 392 ENDIF()
 393 IF(ZLIB_FOUND)
 394   SET(HAVE_LIBZ 1)
 395   SET(HAVE_ZLIB_H 1)
 396   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 397   LIST(APPEND ADDITIONAL_LIBS ${ZLIB_LIBRARIES})
 398   IF(WIN32 AND NOT CYGWIN)
 399     #
 400     # Test if ZLIB_WINAPI macro is needed to use.
 401     #
 402     TRY_MACRO_FOR_LIBRARY(
 403       "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 404       RUNS
 405       "#include <zlib.h>\nint main() {uLong f = zlibCompileFlags(); return (f&(1U<<10))?0:-1; }"
 406       ZLIB_WINAPI)
 407     IF(ZLIB_WINAPI)
 408       ADD_DEFINITIONS(-DZLIB_WINAPI)
 409     ELSE(ZLIB_WINAPI)
 410       # Test if a macro is needed for the library.
 411       TRY_MACRO_FOR_LIBRARY(
 412         "${ZLIB_INCLUDE_DIR}" "${ZLIB_LIBRARIES}"
 413         COMPILES
 414         "#include <zlib.h>\nint main() {return zlibVersion()?1:0; }"
 415         "ZLIB_DLL;WITHOUT_ZLIB_DLL")
 416       IF(ZLIB_DLL)
 417         ADD_DEFINITIONS(-DZLIB_DLL)
 418       ENDIF(ZLIB_DLL)
 419     ENDIF(ZLIB_WINAPI)
 420   ENDIF(WIN32 AND NOT CYGWIN)
 421 ENDIF(ZLIB_FOUND)
 422 MARK_AS_ADVANCED(CLEAR ZLIB_INCLUDE_DIR)
 423 MARK_AS_ADVANCED(CLEAR ZLIB_LIBRARY)
 424 #
 425 # Find BZip2
 426 #
 427 IF(ENABLE_BZip2)
 428   FIND_PACKAGE(BZip2)
 429 ELSE()
 430   SET(BZIP2_FOUND FALSE) # Override cached value
 431 ENDIF()
 432 IF(BZIP2_FOUND)
 433   SET(HAVE_LIBBZ2 1)
 434   SET(HAVE_BZLIB_H 1)
 435   INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
 436   LIST(APPEND ADDITIONAL_LIBS ${BZIP2_LIBRARIES})
 437   # Test if a macro is needed for the library.
 438   TRY_MACRO_FOR_LIBRARY(
 439     "${BZIP2_INCLUDE_DIR}" "${BZIP2_LIBRARIES}"
 440     COMPILES
 441     "#include <bzlib.h>\nint main() {return BZ2_bzlibVersion()?1:0; }"
 442     "USE_BZIP2_DLL;USE_BZIP2_STATIC")
 443   IF(USE_BZIP2_DLL)
 444     ADD_DEFINITIONS(-DUSE_BZIP2_DLL)
 445   ELSEIF(USE_BZIP2_STATIC)
 446     ADD_DEFINITIONS(-DUSE_BZIP2_STATIC)
 447   ENDIF(USE_BZIP2_DLL)
 448 ENDIF(BZIP2_FOUND)
 449 MARK_AS_ADVANCED(CLEAR BZIP2_INCLUDE_DIR)
 450 MARK_AS_ADVANCED(CLEAR BZIP2_LIBRARIES)
 451
 452
 453 #
 454 # Find LZMA
 455 #
 456 IF(ENABLE_LZMA)
 457   FIND_PACKAGE(LibLZMA)
 458 ELSE()
 459   SET(LIBZMA_FOUND FALSE) # Override cached value
 460 ENDIF()
 461
 462 IF(LIBLZMA_FOUND)
 463   SET(HAVE_LIBLZMA 1)
 464   SET(HAVE_LZMA_H 1)
 465   SET(CMAKE_REQUIRED_INCLUDES ${LIBLZMA_INCLUDE_DIR})
 466   SET(CMAKE_REQUIRED_LIBRARIES ${LIBLZMA_LIBRARIES})
 467   INCLUDE_DIRECTORIES(${LIBLZMA_INCLUDE_DIRS})
 468   LIST(APPEND ADDITIONAL_LIBS ${LIBLZMA_LIBRARIES})
 469   # Test if a macro is needed for the library.
 470   TRY_MACRO_FOR_LIBRARY(
 471     "${LIBLZMA_INCLUDE_DIRS}" "${LIBLZMA_LIBRARIES}"
 472     COMPILES
 473     "#include <lzma.h>\nint main() {return (int)lzma_version_number(); }"
 474     "WITHOUT_LZMA_API_STATIC;LZMA_API_STATIC")
 475   IF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 476     ADD_DEFINITIONS(-DLZMA_API_STATIC)
 477   ENDIF(NOT WITHOUT_LZMA_API_STATIC AND LZMA_API_STATIC)
 478 ELSE(LIBLZMA_FOUND)
 479 # LZMA not found and will not be used.
 480 ENDIF(LIBLZMA_FOUND)
 481 #
 482 # Find LZO2
 483 #
 484 IF(ENABLE_LZO)
 485   IF (LZO2_INCLUDE_DIR)
 486     # Already in cache, be silent
 487     SET(LZO2_FIND_QUIETLY TRUE)
 488   ENDIF (LZO2_INCLUDE_DIR)
 489
 490   FIND_PATH(LZO2_INCLUDE_DIR lzo/lzoconf.h)
 491   FIND_LIBRARY(LZO2_LIBRARY NAMES lzo2 liblzo2)
 492   INCLUDE(FindPackageHandleStandardArgs)
 493   FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZO2 DEFAULT_MSG LZO2_LIBRARY LZO2_INCLUDE_DIR)
 494 ELSE(ENABLE_LZO)
 495   SET(LIBZMA_FOUND FALSE) # Override cached value
 496 ENDIF(ENABLE_LZO)
 497 IF(LZO2_FOUND)
 498   SET(HAVE_LIBLZO2 1)
 499   SET(HAVE_LZO_LZOCONF_H 1)
 500   SET(HAVE_LZO_LZO1X_H 1)
 501   INCLUDE_DIRECTORIES(${LZO2_INCLUDE_DIR})
 502   LIST(APPEND ADDITIONAL_LIBS ${LZO2_LIBRARY})
 503   #
 504   # TODO: test for static library.
 505   #
 506 ENDIF(LZO2_FOUND)
 507 MARK_AS_ADVANCED(CLEAR LZO2_INCLUDE_DIR)
 508 MARK_AS_ADVANCED(CLEAR LZO2_LIBRARY)
 509 #
 510 # Find LZ4
 511 #
 512 IF (LZ4_INCLUDE_DIR)
 513   # Already in cache, be silent
 514   SET(LZ4_FIND_QUIETLY TRUE)
 515 ENDIF (LZ4_INCLUDE_DIR)
 516
 517 FIND_PATH(LZ4_INCLUDE_DIR lz4.h)
 518 FIND_LIBRARY(LZ4_LIBRARY NAMES lz4 liblz4)
 519 INCLUDE(FindPackageHandleStandardArgs)
 520 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LZ4 DEFAULT_MSG LZ4_LIBRARY LZ4_INCLUDE_DIR)
 521 IF(LZ4_FOUND)
 522   SET(HAVE_LIBLZ4 1)
 523   SET(HAVE_LZ4_H 1)
 524   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
 525   SET(CMAKE_REQUIRED_INCLUDES ${LZ4_INCLUDE_DIR})
 526   CHECK_INCLUDE_FILES("lz4hc.h" HAVE_LZ4HC_H)
 527   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
 528   INCLUDE_DIRECTORIES(${LZ4_INCLUDE_DIR})
 529   LIST(APPEND ADDITIONAL_LIBS ${LZ4_LIBRARY})
 530   #
 531   # TODO: test for static library.
 532   #
 533 ENDIF(LZ4_FOUND)
 534 MARK_AS_ADVANCED(CLEAR LZ4_INCLUDE_DIR)
 535 MARK_AS_ADVANCED(CLEAR LZ4_LIBRARY)
 536
 537 #
 538 # Check headers
 539 #
 540 CHECK_HEADER_DIRENT()
 541
 542 SET(INCLUDES "")
 543 MACRO (LA_CHECK_INCLUDE_FILE header var)
 544       CHECK_INCLUDE_FILES("${INCLUDES};${header}" ${var})
 545       IF (${var})
 546          SET(INCLUDES ${INCLUDES} ${header})
 547       ENDIF (${var})
 548 ENDMACRO (LA_CHECK_INCLUDE_FILE)
 549
 550 # Some FreeBSD headers assume sys/types.h was already included.
 551 LA_CHECK_INCLUDE_FILE("sys/types.h" HAVE_SYS_TYPES_H)
 552
 553 # Alphabetize the rest unless there's a compelling reason
 554 LA_CHECK_INCLUDE_FILE("acl/libacl.h" HAVE_ACL_LIBACL_H)
 555 LA_CHECK_INCLUDE_FILE("attr/xattr.h" HAVE_ATTR_XATTR_H)
 556 LA_CHECK_INCLUDE_FILE("ctype.h" HAVE_CTYPE_H)
 557 LA_CHECK_INCLUDE_FILE("copyfile.h" HAVE_COPYFILE_H)
 558 LA_CHECK_INCLUDE_FILE("direct.h" HAVE_DIRECT_H)
 559 LA_CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 560 LA_CHECK_INCLUDE_FILE("errno.h" HAVE_ERRNO_H)
 561 LA_CHECK_INCLUDE_FILE("ext2fs/ext2_fs.h" HAVE_EXT2FS_EXT2_FS_H)
 562
 563 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 564 #include <ext2fs/ext2_fs.h>
 565 int main(void) { return EXT2_IOC_GETFLAGS; }" HAVE_WORKING_EXT2_IOC_GETFLAGS)
 566
 567 LA_CHECK_INCLUDE_FILE("fcntl.h" HAVE_FCNTL_H)
 568 LA_CHECK_INCLUDE_FILE("grp.h" HAVE_GRP_H)
 569 LA_CHECK_INCLUDE_FILE("inttypes.h" HAVE_INTTYPES_H)
 570 LA_CHECK_INCLUDE_FILE("io.h" HAVE_IO_H)
 571 LA_CHECK_INCLUDE_FILE("langinfo.h" HAVE_LANGINFO_H)
 572 LA_CHECK_INCLUDE_FILE("limits.h" HAVE_LIMITS_H)
 573 LA_CHECK_INCLUDE_FILE("linux/types.h" HAVE_LINUX_TYPES_H)
 574 LA_CHECK_INCLUDE_FILE("linux/fiemap.h" HAVE_LINUX_FIEMAP_H)
 575 LA_CHECK_INCLUDE_FILE("linux/fs.h" HAVE_LINUX_FS_H)
 576
 577 CHECK_C_SOURCE_COMPILES("#include <sys/ioctl.h>
 578 #include <linux/fs.h>
 579 int main(void) { return FS_IOC_GETFLAGS; }" HAVE_WORKING_FS_IOC_GETFLAGS)
 580
 581 LA_CHECK_INCLUDE_FILE("linux/magic.h" HAVE_LINUX_MAGIC_H)
 582 LA_CHECK_INCLUDE_FILE("locale.h" HAVE_LOCALE_H)
 583 LA_CHECK_INCLUDE_FILE("membership.h" HAVE_MEMBERSHIP_H)
 584 LA_CHECK_INCLUDE_FILE("memory.h" HAVE_MEMORY_H)
 585 LA_CHECK_INCLUDE_FILE("paths.h" HAVE_PATHS_H)
 586 LA_CHECK_INCLUDE_FILE("poll.h" HAVE_POLL_H)
 587 LA_CHECK_INCLUDE_FILE("process.h" HAVE_PROCESS_H)
 588 LA_CHECK_INCLUDE_FILE("pthread.h" HAVE_PTHREAD_H)
 589 LA_CHECK_INCLUDE_FILE("pwd.h" HAVE_PWD_H)
 590 LA_CHECK_INCLUDE_FILE("readpassphrase.h" HAVE_READPASSPHRASE_H)
 591 LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
 592 LA_CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 593 LA_CHECK_INCLUDE_FILE("spawn.h" HAVE_SPAWN_H)
 594 LA_CHECK_INCLUDE_FILE("stdarg.h" HAVE_STDARG_H)
 595 LA_CHECK_INCLUDE_FILE("stdint.h" HAVE_STDINT_H)
 596 LA_CHECK_INCLUDE_FILE("stdlib.h" HAVE_STDLIB_H)
 597 LA_CHECK_INCLUDE_FILE("string.h" HAVE_STRING_H)
 598 LA_CHECK_INCLUDE_FILE("strings.h" HAVE_STRINGS_H)
 599 LA_CHECK_INCLUDE_FILE("sys/acl.h" HAVE_SYS_ACL_H)
 600 LA_CHECK_INCLUDE_FILE("sys/cdefs.h" HAVE_SYS_CDEFS_H)
 601 LA_CHECK_INCLUDE_FILE("sys/extattr.h" HAVE_SYS_EXTATTR_H)
 602 LA_CHECK_INCLUDE_FILE("sys/ioctl.h" HAVE_SYS_IOCTL_H)
 603 LA_CHECK_INCLUDE_FILE("sys/mkdev.h" HAVE_SYS_MKDEV_H)
 604 LA_CHECK_INCLUDE_FILE("sys/mount.h" HAVE_SYS_MOUNT_H)
 605 LA_CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 606 LA_CHECK_INCLUDE_FILE("sys/poll.h" HAVE_SYS_POLL_H)
 607 LA_CHECK_INCLUDE_FILE("sys/richacl.h" HAVE_SYS_RICHACL_H)
 608 LA_CHECK_INCLUDE_FILE("sys/select.h" HAVE_SYS_SELECT_H)
 609 LA_CHECK_INCLUDE_FILE("sys/stat.h" HAVE_SYS_STAT_H)
 610 LA_CHECK_INCLUDE_FILE("sys/statfs.h" HAVE_SYS_STATFS_H)
 611 LA_CHECK_INCLUDE_FILE("sys/statvfs.h" HAVE_SYS_STATVFS_H)
 612 LA_CHECK_INCLUDE_FILE("sys/time.h" HAVE_SYS_TIME_H)
 613 LA_CHECK_INCLUDE_FILE("sys/utime.h" HAVE_SYS_UTIME_H)
 614 LA_CHECK_INCLUDE_FILE("sys/utsname.h" HAVE_SYS_UTSNAME_H)
 615 LA_CHECK_INCLUDE_FILE("sys/vfs.h" HAVE_SYS_VFS_H)
 616 LA_CHECK_INCLUDE_FILE("sys/wait.h" HAVE_SYS_WAIT_H)
 617 LA_CHECK_INCLUDE_FILE("sys/xattr.h" HAVE_SYS_XATTR_H)
 618 LA_CHECK_INCLUDE_FILE("time.h" HAVE_TIME_H)
 619 LA_CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 620 LA_CHECK_INCLUDE_FILE("utime.h" HAVE_UTIME_H)
 621 LA_CHECK_INCLUDE_FILE("wchar.h" HAVE_WCHAR_H)
 622 LA_CHECK_INCLUDE_FILE("wctype.h" HAVE_WCTYPE_H)
 623 LA_CHECK_INCLUDE_FILE("windows.h" HAVE_WINDOWS_H)
 624 IF(ENABLE_CNG)
 625   LA_CHECK_INCLUDE_FILE("Bcrypt.h" HAVE_BCRYPT_H)
 626   IF(HAVE_BCRYPT_H)
 627     LIST(APPEND ADDITIONAL_LIBS "Bcrypt")
 628   ENDIF(HAVE_BCRYPT_H)
 629 ELSE(ENABLE_CNG)
 630   UNSET(HAVE_BCRYPT_H CACHE)
 631 ENDIF(ENABLE_CNG)
 632 # Following files need windows.h, so we should test it after windows.h test.
 633 LA_CHECK_INCLUDE_FILE("wincrypt.h" HAVE_WINCRYPT_H)
 634 LA_CHECK_INCLUDE_FILE("winioctl.h" HAVE_WINIOCTL_H)
 635
 636 #
 637 # Check whether use of __EXTENSIONS__ is safe.
 638 # We need some macro such as _GNU_SOURCE to use extension functions.
 639 #
 640 SET(_INCLUDE_FILES)
 641 FOREACH (it ${_HEADER})
 642    SET(_INCLUDE_FILES "${_INCLUDE_FILES}#include <${it}>\n")
 643 ENDFOREACH (it)
 644
 645 CHECK_C_SOURCE_COMPILES(
 646   "#define __EXTENSIONS__ 1
 647    ${_INCLUDE_FILES}
 648    int main() { return 0;}"
 649  SAFE_TO_DEFINE_EXTENSIONS)
 650
 651 #
 652 # Find Nettle
 653 #
 654 IF(ENABLE_NETTLE)
 655   FIND_PACKAGE(Nettle)
 656   IF(NETTLE_FOUND)
 657     SET(HAVE_LIBNETTLE 1)
 658     LIST(APPEND ADDITIONAL_LIBS ${NETTLE_LIBRARIES})
 659     INCLUDE_DIRECTORIES(${NETTLE_INCLUDE_DIR})
 660
 661     LIST(APPEND CMAKE_REQUIRED_INCLUDES ${NETTLE_INCLUDE_DIR})
 662     LA_CHECK_INCLUDE_FILE("nettle/aes.h" HAVE_NETTLE_AES_H)
 663     LA_CHECK_INCLUDE_FILE("nettle/hmac.h" HAVE_NETTLE_HMAC_H)
 664     LA_CHECK_INCLUDE_FILE("nettle/md5.h" HAVE_NETTLE_MD5_H)
 665     LA_CHECK_INCLUDE_FILE("nettle/pbkdf2.h" HAVE_NETTLE_PBKDF2_H)
 666     LA_CHECK_INCLUDE_FILE("nettle/ripemd160.h" HAVE_NETTLE_RIPEMD160_H)
 667     LA_CHECK_INCLUDE_FILE("nettle/sha.h" HAVE_NETTLE_SHA_H)
 668
 669   ENDIF(NETTLE_FOUND)
 670   MARK_AS_ADVANCED(CLEAR NETTLE_INCLUDE_DIR)
 671   MARK_AS_ADVANCED(CLEAR NETTLE_LIBRARIES)
 672 ENDIF(ENABLE_NETTLE)
 673
 674 #
 675 # Find OpenSSL
 676 # (Except on Mac, where OpenSSL is deprecated.)
 677 #
 678 IF(ENABLE_OPENSSL AND NOT CMAKE_SYSTEM_NAME MATCHES "Darwin")
 679   FIND_PACKAGE(OpenSSL)
 680   IF(OPENSSL_FOUND)
 681     SET(HAVE_LIBCRYPTO 1)
 682     INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 683     LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_CRYPTO_LIBRARY})
 684   ENDIF(OPENSSL_FOUND)
 685 ELSE()
 686   SET(OPENSSL_FOUND FALSE) # Override cached value
 687 ENDIF()
 688
 689 # FreeBSD libmd
 690 IF(NOT OPENSSL_FOUND)
 691   CHECK_LIBRARY_EXISTS(md "MD5Init" "" LIBMD_FOUND)
 692   IF(LIBMD_FOUND)
 693     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 694     SET(CMAKE_REQUIRED_LIBRARIES "md")
 695     FIND_LIBRARY(LIBMD_LIBRARY NAMES md)
 696     LIST(APPEND ADDITIONAL_LIBS ${LIBMD_LIBRARY})
 697     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 698   ENDIF(LIBMD_FOUND)
 699 ENDIF(NOT OPENSSL_FOUND)
 700
 701 #
 702 # How to prove that CRYPTO functions, which have several names on various
 703 # platforms, just see if archive_digest.c can compile and link against
 704 # required libraries.
 705 #
 706 MACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 707     FOREACH(ALGORITHM ${ALGORITHMS})
 708       IF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 709       STRING(TOLOWER "${ALGORITHM}" lower_algorithm)
 710       STRING(TOUPPER "${ALGORITHM}" algorithm)
 711       IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 712         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 713       ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NOT NETTLE_FOUND)
 714         SET(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} FALSE)
 715       ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND NOT OPENSSL_FOUND)
 716
 717       IF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 718         # Probe the local implementation for whether this
 719         # crypto implementation is available on this platform.
 720         SET(TRY_CRYPTO_REQUIRED_INCLUDES
 721           "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive;${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp")
 722         SET(TRY_CRYPTO_REQUIRED_LIBS)
 723         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 724             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 725               "${TRY_CRYPTO_REQUIRED_INCLUDES};${OPENSSL_INCLUDE_DIR}")
 726             SET(TRY_CRYPTO_REQUIRED_LIBS
 727                 "-DLINK_LIBRARIES:STRING=${OPENSSL_LIBRARIES}")
 728         ELSEIF("${IMPLEMENTATION}" MATCHES "^NETTLE$" AND NETTLE_FOUND)
 729             SET(TRY_CRYPTO_REQUIRED_INCLUDES
 730               "${TRY_CRYPTO_REQUIRED_INCLUDES};${NETTLE_INCLUDE_DIR}")
 731             SET(TRY_CRYPTO_REQUIRED_LIBS
 732                 "-DLINK_LIBRARIES:STRING=${NETTLE_LIBRARY}")
 733         ELSEIF("${IMPLEMENTATION}" MATCHES "^LIBMD$" AND LIBMD_FOUND)
 734             SET(TRY_CRYPTO_REQUIRED_LIBS
 735                 "-DLINK_LIBRARIES:STRING=${LIBMD_LIBRARY}")
 736         ENDIF("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 737
 738     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 739       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 740         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 741              CONFDEFS_H)
 742         FILE(READ "${CMAKE_CURRENT_SOURCE_DIR}/libarchive/archive_digest.c"
 743              ARCHIVE_CRYPTO_C)
 744
 745         SET(SOURCE "${CONFDEFS_H}
 746
 747 #define ARCHIVE_${algorithm}_COMPILE_TEST
 748 #define ARCHIVE_CRYPTO_${algorithm}_${IMPLEMENTATION}
 749 #define PLATFORM_CONFIG_H \"check_crypto_md.h\"
 750
 751 ${ARCHIVE_CRYPTO_C}
 752
 753 int
 754 main(int argc, char **argv)
 755 {
 756   archive_${lower_algorithm}_ctx ctx;
 757   archive_${lower_algorithm}_init(&ctx);
 758   archive_${lower_algorithm}_update(&ctx, *argv, argc);
 759   archive_${lower_algorithm}_final(&ctx, NULL);
 760   return 0;
 761 }
 762 ")
 763
 764   FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.h" "")
 765         FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c" "${SOURCE}")
 766         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}")
 767
 768         TRY_COMPILE(ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION}
 769           ${CMAKE_BINARY_DIR}
 770           ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_md.c
 771           CMAKE_FLAGS
 772            "${TRY_CRYPTO_REQUIRED_LIBS}"
 773            "${TRY_CRYPTO_REQUIRED_INCLUDES}"
 774           OUTPUT_VARIABLE OUTPUT)
 775
 776         # Inform user whether or not we found it; if not, log why we didn't.
 777         IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 778           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- found")
 779                   SET(ARCHIVE_CRYPTO_${ALGORITHM} 1)
 780         ELSE (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 781           MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} -- not found")
 782           FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 783             "Checking support for ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION} failed with the following output:\n"
 784             "${OUTPUT}\n"
 785             "Source file was:\n${SOURCE}\n")
 786         ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 787       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 788
 789       # Add appropriate libs/includes depending on whether the implementation
 790       # was found on this platform.
 791       IF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 792         IF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 793           INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 794           LIST(APPEND ADDITIONAL_LIBS ${OPENSSL_LIBRARIES})
 795            LIST(REMOVE_DUPLICATES ADDITIONAL_LIBS)
 796         ENDIF ("${IMPLEMENTATION}" MATCHES "^OPENSSL$" AND OPENSSL_FOUND)
 797       ENDIF (ARCHIVE_CRYPTO_${ALGORITHM}_${IMPLEMENTATION})
 798       ENDIF(NOT ARCHIVE_CRYPTO_${ALGORITHM})
 799     ENDFOREACH(ALGORITHM ${ALGORITHMS})
 800 ENDMACRO(CHECK_CRYPTO ALGORITHMS IMPLEMENTATION)
 801
 802 #
 803 # CRYPTO functions on Windows is defined at archive_windows.c, thus we do not
 804 # need the test what the functions can be mapped to archive_{crypto name}_init,
 805 # archive_{crypto name}_update and archive_{crypto name}_final.
 806 # The functions on Windows use CALG_{crypto name} macro to create a crypt object
 807 # and then we need to know what CALG_{crypto name} macros is available to show
 808 # ARCHIVE_CRYPTO_{crypto name}_WIN macros because Windows 2000 and earlier version
 809 # of Windows XP do not support SHA256, SHA384 and SHA512.
 810 #
 811 MACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 812   IF(WIN32 AND NOT CYGWIN)
 813     FOREACH(CRYPTO ${CRYPTO_LIST})
 814       IF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 815       IF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 816         STRING(TOUPPER "${CRYPTO}" crypto)
 817         SET(ALGID "")
 818         IF ("${CRYPTO}" MATCHES "^MD5$")
 819             SET(ALGID "CALG_MD5")
 820         ENDIF ("${CRYPTO}" MATCHES "^MD5$")
 821         IF ("${CRYPTO}" MATCHES "^SHA1$")
 822             SET(ALGID "CALG_SHA1")
 823         ENDIF ("${CRYPTO}" MATCHES "^SHA1$")
 824         IF ("${CRYPTO}" MATCHES "^SHA256$")
 825             SET(ALGID "CALG_SHA_256")
 826         ENDIF ("${CRYPTO}" MATCHES "^SHA256$")
 827         IF ("${CRYPTO}" MATCHES "^SHA384$")
 828             SET(ALGID "CALG_SHA_384")
 829         ENDIF ("${CRYPTO}" MATCHES "^SHA384$")
 830         IF ("${CRYPTO}" MATCHES "^SHA512$")
 831             SET(ALGID "CALG_SHA_512")
 832         ENDIF ("${CRYPTO}" MATCHES "^SHA512$")
 833
 834     CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
 835       ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h)
 836         FILE(READ "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/confdefs.h"
 837              CONFDEFS_H)
 838
 839         SET(SOURCE "${CONFDEFS_H}
 840
 841 #define ${crypto}_COMPILE_TEST
 842 #include <windows.h>
 843 #include <wincrypt.h>
 844
 845 int
 846 main(int argc, char **argv)
 847 {
 848         return ${ALGID};
 849 }
 850 ")
 851         SET(SOURCE_FILE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/check_crypto_win.c")
 852
 853         FILE(WRITE "${SOURCE_FILE}" "${SOURCE}")
 854         MESSAGE(STATUS "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN")
 855
 856         TRY_COMPILE(ARCHIVE_CRYPTO_${CRYPTO}_WIN
 857           ${CMAKE_BINARY_DIR}
 858           ${SOURCE_FILE}
 859           CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/libarchive"
 860           OUTPUT_VARIABLE OUTPUT)
 861
 862         IF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 863             MESSAGE(STATUS
 864                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- found")
 865                 SET(ARCHIVE_CRYPTO_${CRYPTO} 1)
 866         ELSE (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 867             MESSAGE(STATUS
 868                  "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN -- not found")
 869             FILE(APPEND
 870                 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 871                 "Checking support for ARCHIVE_CRYPTO_${CRYPTO}_WIN failed with the following output:\n"
 872                 "${OUTPUT}\n"
 873                 "Source file was:\n${SOURCE}\n")
 874         ENDIF (ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 875
 876       ENDIF(NOT DEFINED ARCHIVE_CRYPTO_${CRYPTO}_WIN)
 877       ENDIF(NOT ARCHIVE_CRYPTO_${CRYPTO})
 878     ENDFOREACH(CRYPTO)
 879   ENDIF(WIN32 AND NOT CYGWIN)
 880 ENDMACRO(CHECK_CRYPTO_WIN CRYPTO_LIST)
 881
 882 #
 883 # Find iconv
 884 # POSIX defines the second arg as const char **
 885 # and requires it to be in libc.  But we can accept
 886 # a non-const argument here and can support iconv()
 887 # being in libiconv.
 888 #
 889 MACRO(CHECK_ICONV LIB TRY_ICONV_CONST)
 890   IF(NOT HAVE_ICONV)
 891     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
 892     IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 893         CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 894       #
 895       # During checking iconv proto type, we should use -Werror to avoid the
 896       # success of iconv detection with a warnig which success is a miss
 897       # detection. So this needs for all build mode(even it's a release mode).
 898       #
 899       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror")
 900     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
 901            CMAKE_C_COMPILER_ID MATCHES "^Clang$")
 902     IF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 903       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -qhalt=w -qflag=w:w")
 904     ENDIF (CMAKE_C_COMPILER_ID MATCHES "^XL$")
 905     IF (MSVC)
 906       # NOTE: /WX option is the same as gcc's -Werror option.
 907       SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} /WX")
 908     ENDIF (MSVC)
 909     #
 910     CHECK_C_SOURCE_COMPILES(
 911       "#include <stdlib.h>
 912        #include <iconv.h>
 913        int main() {
 914           ${TRY_ICONV_CONST} char *ccp;
 915           iconv_t cd = iconv_open(\"\", \"\");
 916           iconv(cd, &ccp, (size_t *)0, (char **)0, (size_t *)0);
 917           iconv_close(cd);
 918           return 0;
 919        }"
 920      HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 921     IF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 922       SET(HAVE_ICONV true)
 923       SET(ICONV_CONST ${TRY_ICONV_CONST})
 924     ENDIF(HAVE_ICONV_${LIB}_${TRY_ICONV_CONST})
 925     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
 926   ENDIF(NOT HAVE_ICONV)
 927 ENDMACRO(CHECK_ICONV TRY_ICONV_CONST)
 928
 929 IF(ENABLE_ICONV)
 930   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
 931   FIND_PATH(ICONV_INCLUDE_DIR iconv.h)
 932   IF(ICONV_INCLUDE_DIR)
 933     #SET(INCLUDES ${INCLUDES} "iconv.h")
 934     SET(HAVE_ICONV_H 1)
 935     INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 936     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 937     CHECK_ICONV("libc" "const")
 938     CHECK_ICONV("libc" "")
 939
 940     # If iconv isn't in libc and we have a libiconv, try that.
 941     FIND_LIBRARY(LIBICONV_PATH NAMES iconv libiconv)
 942     IF(NOT HAVE_ICONV AND LIBICONV_PATH)
 943       LIST(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
 944       # Test if a macro is needed for the library.
 945       TRY_MACRO_FOR_LIBRARY(
 946         "${ICONV_INCLUDE_DIR}" "${LIBICONV_PATH}"
 947         COMPILES
 948         "#include <iconv.h>\nint main() {return iconv_close((iconv_t)0);}"
 949         "WITHOUT_LIBICONV_STATIC;LIBICONV_STATIC")
 950       IF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
 951         ADD_DEFINITIONS(-DLIBICONV_STATIC)
 952       ENDIF(NOT WITHOUT_LIBICONV_STATIC AND LIBICONV_STATIC)
 953       #
 954       # Set up CMAKE_REQUIRED_* for CHECK_ICONV
 955       #
 956       SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 957       SET(CMAKE_REQUIRED_LIBRARIES ${LIBICONV_PATH})
 958       IF(LIBICONV_STATIC)
 959         # LIBICONV_STATIC is necessary for the success of CHECK_ICONV
 960         # on Windows.
 961         SET(CMAKE_REQUIRED_DEFINITIONS "-DLIBICONV_STATIC")
 962       ELSE(LIBICONV_STATIC)
 963         SET(CMAKE_REQUIRED_DEFINITIONS)
 964       ENDIF(LIBICONV_STATIC)
 965       CHECK_ICONV("libiconv" "const")
 966       CHECK_ICONV("libiconv" "")
 967       IF (HAVE_ICONV)
 968         LIST(APPEND ADDITIONAL_LIBS ${LIBICONV_PATH})
 969       ENDIF(HAVE_ICONV)
 970     ENDIF(NOT HAVE_ICONV AND LIBICONV_PATH)
 971   ENDIF(ICONV_INCLUDE_DIR)
 972   #
 973   # Find locale_charset() for libiconv.
 974   #
 975   IF(LIBICONV_PATH)
 976     SET(CMAKE_REQUIRED_DEFINITIONS)
 977     SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
 978     SET(CMAKE_REQUIRED_LIBRARIES)
 979     CHECK_INCLUDE_FILES("localcharset.h" HAVE_LOCALCHARSET_H)
 980     FIND_LIBRARY(LIBCHARSET_PATH NAMES charset libcharset)
 981     IF(LIBCHARSET_PATH)
 982       SET(CMAKE_REQUIRED_LIBRARIES ${LIBCHARSET_PATH})
 983       IF(WIN32 AND NOT CYGWIN)
 984         # Test if a macro is needed for the library.
 985         TRY_MACRO_FOR_LIBRARY(
 986           "${ICONV_INCLUDE_DIR}" "${LIBCHARSET_PATH}"
 987           COMPILES
 988           "#include <localcharset.h>\nint main() {return locale_charset()?1:0;}"
 989           "WITHOUT_LIBCHARSET_STATIC;LIBCHARSET_STATIC")
 990         IF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
 991           ADD_DEFINITIONS(-DLIBCHARSET_STATIC)
 992         ENDIF(NOT WITHOUT_LIBCHARSET_STATIC AND LIBCHARSET_STATIC)
 993         IF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
 994           SET(HAVE_LOCALE_CHARSET ON CACHE INTERNAL
 995               "Have function locale_charset")
 996         ENDIF(WITHOUT_LIBCHARSET_STATIC OR LIBCHARSET_STATIC)
 997       ELSE(WIN32 AND NOT CYGWIN)
 998         CHECK_FUNCTION_EXISTS_GLIBC(locale_charset HAVE_LOCALE_CHARSET)
 999       ENDIF(WIN32 AND NOT CYGWIN)
1000       IF(HAVE_LOCALE_CHARSET)
1001         LIST(APPEND ADDITIONAL_LIBS ${LIBCHARSET_PATH})
1002       ENDIF(HAVE_LOCALE_CHARSET)
1003     ENDIF(LIBCHARSET_PATH)
1004   ENDIF(LIBICONV_PATH)
1005   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1006 ELSE(ENABLE_ICONV)
1007   # Make sure ICONV variables are not in CACHE after ENABLE_ICONV disabled
1008   # (once enabled).
1009   UNSET(HAVE_LOCALE_CHARSET CACHE)
1010   UNSET(HAVE_ICONV CACHE)
1011   UNSET(HAVE_ICONV_libc_ CACHE)
1012   UNSET(HAVE_ICONV_libc_const CACHE)
1013   UNSET(HAVE_ICONV_libiconv_ CACHE)
1014   UNSET(HAVE_ICONV_libiconv_const CACHE)
1015   UNSET(ICONV_INCLUDE_DIR CACHE)
1016   UNSET(LIBICONV_PATH CACHE)
1017   UNSET(LIBICONV_DLL CACHE)
1018   UNSET(LIBICONV_STATIC CACHE)
1019   UNSET(LIBCHARSET_DLL CACHE)
1020   UNSET(LIBCHARSET_STATIC CACHE)
1021 ENDIF(ENABLE_ICONV)
1022
1023 #
1024 # Find Libxml2
1025 #
1026 IF(ENABLE_LIBXML2)
1027   FIND_PACKAGE(LibXml2)
1028 ELSE()
1029   SET(LIBXML2_FOUND FALSE)
1030 ENDIF()
1031 IF(LIBXML2_FOUND)
1032   CMAKE_PUSH_CHECK_STATE()      # Save the state of the variables
1033   INCLUDE_DIRECTORIES(${LIBXML2_INCLUDE_DIR})
1034   LIST(APPEND ADDITIONAL_LIBS ${LIBXML2_LIBRARIES})
1035   SET(HAVE_LIBXML2 1)
1036   # libxml2's include files use iconv.h
1037   SET(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR} ${LIBXML2_INCLUDE_DIR})
1038   CHECK_INCLUDE_FILES("libxml/xmlreader.h" HAVE_LIBXML_XMLREADER_H)
1039   CHECK_INCLUDE_FILES("libxml/xmlwriter.h" HAVE_LIBXML_XMLWRITER_H)
1040   # Test if a macro is needed for the library.
1041   TRY_MACRO_FOR_LIBRARY(
1042     "${ICONV_INCLUDE_DIR};${LIBXML2_INCLUDE_DIR}"
1043     "ws2_32.lib;${ZLIB_LIBRARIES};${LIBICONV_PATH};${LIBXML2_LIBRARIES}"
1044     COMPILES
1045     "#include <stddef.h>\n#include <libxml/xmlreader.h>\nint main() {return xmlTextReaderRead((xmlTextReaderPtr)(void *)0);}"
1046     "WITHOUT_LIBXML_STATIC;LIBXML_STATIC")
1047   IF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1048     ADD_DEFINITIONS(-DLIBXML_STATIC)
1049   ENDIF(NOT WITHOUT_LIBXML_STATIC AND LIBXML_STATIC)
1050   CMAKE_POP_CHECK_STATE()       # Restore the state of the variables
1051 ELSE(LIBXML2_FOUND)
1052   #
1053   # Find Expat
1054   #
1055   IF(ENABLE_EXPAT)
1056     FIND_PACKAGE(EXPAT)
1057   ELSE()
1058     SET(EXPAT_FOUND FALSE)
1059   ENDIF()
1060   IF(EXPAT_FOUND)
1061     CMAKE_PUSH_CHECK_STATE()    # Save the state of the variables
1062     INCLUDE_DIRECTORIES(${EXPAT_INCLUDE_DIR})
1063     LIST(APPEND ADDITIONAL_LIBS ${EXPAT_LIBRARIES})
1064     SET(HAVE_LIBEXPAT 1)
1065     LA_CHECK_INCLUDE_FILE("expat.h" HAVE_EXPAT_H)
1066     CMAKE_POP_CHECK_STATE()     # Restore the state of the variables
1067   ENDIF(EXPAT_FOUND)
1068 ENDIF(LIBXML2_FOUND)
1069 MARK_AS_ADVANCED(CLEAR LIBXML2_INCLUDE_DIR)
1070 MARK_AS_ADVANCED(CLEAR LIBXML2_LIBRARIES)
1071
1072 #
1073 # POSIX Regular Expression support
1074 #
1075 IF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1076   #
1077   # If PCREPOSIX is not found or not requested, try using regex
1078   # from libc or libregex
1079   #
1080   FIND_PATH(REGEX_INCLUDE_DIR regex.h)
1081   IF(REGEX_INCLUDE_DIR)
1082     CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBC)
1083     #
1084     # If libc does not provide regex, find libregex.
1085     #
1086     IF(NOT HAVE_REGCOMP_LIBC)
1087       CMAKE_PUSH_CHECK_STATE()  # Save the state of the variables
1088       FIND_LIBRARY(REGEX_LIBRARY regex)
1089       IF(REGEX_LIBRARY)
1090         SET(CMAKE_REQUIRED_LIBRARIES ${REGEX_LIBRARY})
1091         CHECK_FUNCTION_EXISTS_GLIBC(regcomp HAVE_REGCOMP_LIBREGEX)
1092         IF(HAVE_REGCOMP_LIBREGEX)
1093           LIST(APPEND ADDITIONAL_LIBS ${REGEX_LIBRARY})
1094           #
1095           # If regex.h is not found, retry looking for regex.h at
1096           # REGEX_INCLUDE_DIR
1097           #
1098           IF(NOT HAVE_REGEX_H)
1099             UNSET(HAVE_REGEX_H CACHE)
1100             INCLUDE_DIRECTORIES(${REGEX_INCLUDE_DIR})
1101             SET(CMAKE_REQUIRED_INCLUDES ${REGEX_INCLUDE_DIR})
1102             LA_CHECK_INCLUDE_FILE("regex.h" HAVE_REGEX_H)
1103           ENDIF(NOT HAVE_REGEX_H)
1104           # Test if a macro is needed for the library.
1105           TRY_MACRO_FOR_LIBRARY(
1106             "${REGEX_INCLUDE_DIR}" "${REGEX_LIBRARY}"
1107             COMPILES
1108             "#include <stddef.h>\n#include <regex.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1109             "USE_REGEX_DLL;USE_REGEX_STATIC")
1110           IF(USE_REGEX_DLL)
1111             ADD_DEFINITIONS(-DUSE_REGEX_DLL)
1112           ELSEIF(USE_REGEX_STATIC)
1113             ADD_DEFINITIONS(-DUSE_REGEX_STATIC)
1114           ENDIF(USE_REGEX_DLL)
1115         ENDIF(HAVE_REGCOMP_LIBREGEX)
1116       ENDIF(REGEX_LIBRARY)
1117       CMAKE_POP_CHECK_STATE()   # Restore the state of the variables
1118     ENDIF(NOT HAVE_REGCOMP_LIBC)
1119   ENDIF(REGEX_INCLUDE_DIR)
1120   IF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1121     SET(FOUND_POSIX_REGEX_LIB 1)
1122   ENDIF(HAVE_REGCOMP_LIBC OR HAVE_REGCOMP_LIBREGEX)
1123 ENDIF(POSIX_REGEX_LIB MATCHES "^(AUTO|LIBC|LIBREGEX)$")
1124
1125 IF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1126   #
1127   # If requested, try finding library for PCREPOSIX
1128   #
1129   IF(ENABLE_LibGCC)
1130     FIND_PACKAGE(LibGCC)
1131   ELSE()
1132     SET(LIBGCC_FOUND FALSE) # Override cached value
1133   ENDIF()
1134   IF(ENABLE_PCREPOSIX)
1135     FIND_PACKAGE(PCREPOSIX)
1136   ELSE()
1137     SET(PCREPOSIX_FOUND FALSE) # Override cached value
1138   ENDIF()
1139   IF(PCREPOSIX_FOUND)
1140     INCLUDE_DIRECTORIES(${PCRE_INCLUDE_DIR})
1141     LIST(APPEND ADDITIONAL_LIBS ${PCREPOSIX_LIBRARIES})
1142     # Test if a macro is needed for the library.
1143     TRY_MACRO_FOR_LIBRARY(
1144       "${PCRE_INCLUDE_DIR}" "${PCREPOSIX_LIBRARIES}"
1145       COMPILES
1146       "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1147       "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1148     IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1149       ADD_DEFINITIONS(-DPCRE_STATIC)
1150         ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND PCRE_FOUND)
1151           # Determine if pcre static libraries are to be used.
1152       LIST(APPEND ADDITIONAL_LIBS ${PCRE_LIBRARIES})
1153       SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES})
1154       MESSAGE(STATUS "trying again with -lpcre included")
1155       TRY_MACRO_FOR_LIBRARY(
1156         "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1157         COMPILES
1158         "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1159         "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1160       IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1161         ADD_DEFINITIONS(-DPCRE_STATIC)
1162       ELSEIF(NOT WITHOUT_PCRE_STATIC AND NOT PCRE_STATIC AND MSVC AND LIBGCC_FOUND)
1163         # When doing a Visual Studio build using pcre static libraries
1164         # built using the mingw toolchain, -lgcc is needed to resolve
1165         # ___chkstk_ms.
1166         MESSAGE(STATUS "Visual Studio build detected, trying again with -lgcc included")
1167         LIST(APPEND ADDITIONAL_LIBS ${LIBGCC_LIBRARIES})
1168         SET(TMP_LIBRARIES ${PCREPOSIX_LIBRARIES} ${PCRE_LIBRARIES} ${LIBGCC_LIBRARIES})
1169           TRY_MACRO_FOR_LIBRARY(
1170             "${PCRE_INCLUDE_DIR}" "${TMP_LIBRARIES}"
1171             COMPILES
1172             "#include <pcreposix.h>\nint main() {regex_t r;return regcomp(&r, \"\", 0);}"
1173             "WITHOUT_PCRE_STATIC;PCRE_STATIC")
1174           IF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1175             ADD_DEFINITIONS(-DPCRE_STATIC)
1176           ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1177       ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1178     ENDIF(NOT WITHOUT_PCRE_STATIC AND PCRE_STATIC)
1179   ENDIF(PCREPOSIX_FOUND)
1180   MARK_AS_ADVANCED(CLEAR PCRE_INCLUDE_DIR)
1181   MARK_AS_ADVANCED(CLEAR PCREPOSIX_LIBRARIES)
1182   MARK_AS_ADVANCED(CLEAR PCRE_LIBRARIES)
1183   MARK_AS_ADVANCED(CLEAR LIBGCC_LIBRARIES)
1184 ENDIF(NOT FOUND_POSIX_REGEX_LIB AND POSIX_REGEX_LIB MATCHES "^(AUTO|LIBPCREPOSIX)$")
1185
1186 #
1187 # Check functions
1188 #
1189 CMAKE_PUSH_CHECK_STATE()        # Save the state of the variables
1190 IF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1191     CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1192   #
1193   # During checking functions, we should use -fno-builtin to avoid the
1194   # failure of function detection which failure is an error "conflicting
1195   # types for built-in function" caused by using -Werror option.
1196   #
1197   SET(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fno-builtin")
1198 ENDIF (CMAKE_C_COMPILER_ID MATCHES "^GNU$" OR
1199        CMAKE_C_COMPILER_ID MATCHES "^Clang$")
1200 CHECK_SYMBOL_EXISTS(_CrtSetReportMode "crtdbg.h" HAVE__CrtSetReportMode)
1201 CHECK_FUNCTION_EXISTS_GLIBC(arc4random_buf HAVE_ARC4RANDOM_BUF)
1202 CHECK_FUNCTION_EXISTS_GLIBC(chflags HAVE_CHFLAGS)
1203 CHECK_FUNCTION_EXISTS_GLIBC(chown HAVE_CHOWN)
1204 CHECK_FUNCTION_EXISTS_GLIBC(chroot HAVE_CHROOT)
1205 CHECK_FUNCTION_EXISTS_GLIBC(ctime_r HAVE_CTIME_R)
1206 CHECK_FUNCTION_EXISTS_GLIBC(dirfd HAVE_DIRFD)
1207 CHECK_FUNCTION_EXISTS_GLIBC(fchdir HAVE_FCHDIR)
1208 CHECK_FUNCTION_EXISTS_GLIBC(fchflags HAVE_FCHFLAGS)
1209 CHECK_FUNCTION_EXISTS_GLIBC(fchmod HAVE_FCHMOD)
1210 CHECK_FUNCTION_EXISTS_GLIBC(fchown HAVE_FCHOWN)
1211 CHECK_FUNCTION_EXISTS_GLIBC(fcntl HAVE_FCNTL)
1212 CHECK_FUNCTION_EXISTS_GLIBC(fdopendir HAVE_FDOPENDIR)
1213 CHECK_FUNCTION_EXISTS_GLIBC(fork HAVE_FORK)
1214 CHECK_FUNCTION_EXISTS_GLIBC(fstat HAVE_FSTAT)
1215 CHECK_FUNCTION_EXISTS_GLIBC(fstatat HAVE_FSTATAT)
1216 CHECK_FUNCTION_EXISTS_GLIBC(fstatfs HAVE_FSTATFS)
1217 CHECK_FUNCTION_EXISTS_GLIBC(fstatvfs HAVE_FSTATVFS)
1218 CHECK_FUNCTION_EXISTS_GLIBC(ftruncate HAVE_FTRUNCATE)
1219 CHECK_FUNCTION_EXISTS_GLIBC(futimens HAVE_FUTIMENS)
1220 CHECK_FUNCTION_EXISTS_GLIBC(futimes HAVE_FUTIMES)
1221 CHECK_FUNCTION_EXISTS_GLIBC(futimesat HAVE_FUTIMESAT)
1222 CHECK_FUNCTION_EXISTS_GLIBC(geteuid HAVE_GETEUID)
1223 CHECK_FUNCTION_EXISTS_GLIBC(getgrgid_r HAVE_GETGRGID_R)
1224 CHECK_FUNCTION_EXISTS_GLIBC(getgrnam_r HAVE_GETGRNAM_R)
1225 CHECK_FUNCTION_EXISTS_GLIBC(getpwnam_r HAVE_GETPWNAM_R)
1226 CHECK_FUNCTION_EXISTS_GLIBC(getpwuid_r HAVE_GETPWUID_R)
1227 CHECK_FUNCTION_EXISTS_GLIBC(getpid HAVE_GETPID)
1228 CHECK_FUNCTION_EXISTS_GLIBC(getvfsbyname HAVE_GETVFSBYNAME)
1229 CHECK_FUNCTION_EXISTS_GLIBC(gmtime_r HAVE_GMTIME_R)
1230 CHECK_FUNCTION_EXISTS_GLIBC(lchflags HAVE_LCHFLAGS)
1231 CHECK_FUNCTION_EXISTS_GLIBC(lchmod HAVE_LCHMOD)
1232 CHECK_FUNCTION_EXISTS_GLIBC(lchown HAVE_LCHOWN)
1233 CHECK_FUNCTION_EXISTS_GLIBC(link HAVE_LINK)
1234 CHECK_FUNCTION_EXISTS_GLIBC(localtime_r HAVE_LOCALTIME_R)
1235 CHECK_FUNCTION_EXISTS_GLIBC(lstat HAVE_LSTAT)
1236 CHECK_FUNCTION_EXISTS_GLIBC(lutimes HAVE_LUTIMES)
1237 CHECK_FUNCTION_EXISTS_GLIBC(mbrtowc HAVE_MBRTOWC)
1238 CHECK_FUNCTION_EXISTS_GLIBC(memmove HAVE_MEMMOVE)
1239 CHECK_FUNCTION_EXISTS_GLIBC(mkdir HAVE_MKDIR)
1240 CHECK_FUNCTION_EXISTS_GLIBC(mkfifo HAVE_MKFIFO)
1241 CHECK_FUNCTION_EXISTS_GLIBC(mknod HAVE_MKNOD)
1242 CHECK_FUNCTION_EXISTS_GLIBC(mkstemp HAVE_MKSTEMP)
1243 CHECK_FUNCTION_EXISTS_GLIBC(nl_langinfo HAVE_NL_LANGINFO)
1244 CHECK_FUNCTION_EXISTS_GLIBC(openat HAVE_OPENAT)
1245 CHECK_FUNCTION_EXISTS_GLIBC(pipe HAVE_PIPE)
1246 CHECK_FUNCTION_EXISTS_GLIBC(poll HAVE_POLL)
1247 CHECK_FUNCTION_EXISTS_GLIBC(posix_spawnp HAVE_POSIX_SPAWNP)
1248 CHECK_FUNCTION_EXISTS_GLIBC(readlink HAVE_READLINK)
1249 CHECK_FUNCTION_EXISTS_GLIBC(readpassphrase HAVE_READPASSPHRASE)
1250 CHECK_FUNCTION_EXISTS_GLIBC(select HAVE_SELECT)
1251 CHECK_FUNCTION_EXISTS_GLIBC(setenv HAVE_SETENV)
1252 CHECK_FUNCTION_EXISTS_GLIBC(setlocale HAVE_SETLOCALE)
1253 CHECK_FUNCTION_EXISTS_GLIBC(sigaction HAVE_SIGACTION)
1254 CHECK_FUNCTION_EXISTS_GLIBC(statfs HAVE_STATFS)
1255 CHECK_FUNCTION_EXISTS_GLIBC(statvfs HAVE_STATVFS)
1256 CHECK_FUNCTION_EXISTS_GLIBC(strchr HAVE_STRCHR)
1257 CHECK_FUNCTION_EXISTS_GLIBC(strdup HAVE_STRDUP)
1258 CHECK_FUNCTION_EXISTS_GLIBC(strerror HAVE_STRERROR)
1259 CHECK_FUNCTION_EXISTS_GLIBC(strncpy_s HAVE_STRNCPY_S)
1260 CHECK_FUNCTION_EXISTS_GLIBC(strrchr HAVE_STRRCHR)
1261 CHECK_FUNCTION_EXISTS_GLIBC(symlink HAVE_SYMLINK)
1262 CHECK_FUNCTION_EXISTS_GLIBC(timegm HAVE_TIMEGM)
1263 CHECK_FUNCTION_EXISTS_GLIBC(tzset HAVE_TZSET)
1264 CHECK_FUNCTION_EXISTS_GLIBC(unsetenv HAVE_UNSETENV)
1265 CHECK_FUNCTION_EXISTS_GLIBC(utime HAVE_UTIME)
1266 CHECK_FUNCTION_EXISTS_GLIBC(utimes HAVE_UTIMES)
1267 CHECK_FUNCTION_EXISTS_GLIBC(utimensat HAVE_UTIMENSAT)
1268 CHECK_FUNCTION_EXISTS_GLIBC(vfork HAVE_VFORK)
1269 CHECK_FUNCTION_EXISTS_GLIBC(wcrtomb HAVE_WCRTOMB)
1270 CHECK_FUNCTION_EXISTS_GLIBC(wcscmp HAVE_WCSCMP)
1271 CHECK_FUNCTION_EXISTS_GLIBC(wcscpy HAVE_WCSCPY)
1272 CHECK_FUNCTION_EXISTS_GLIBC(wcslen HAVE_WCSLEN)
1273 CHECK_FUNCTION_EXISTS_GLIBC(wctomb HAVE_WCTOMB)
1274 CHECK_FUNCTION_EXISTS_GLIBC(_ctime64_s HAVE__CTIME64_S)
1275 CHECK_FUNCTION_EXISTS_GLIBC(_fseeki64 HAVE__FSEEKI64)
1276 CHECK_FUNCTION_EXISTS_GLIBC(_get_timezone HAVE__GET_TIMEZONE)
1277 CHECK_FUNCTION_EXISTS_GLIBC(_localtime64_s HAVE__LOCALTIME64_S)
1278 CHECK_FUNCTION_EXISTS_GLIBC(_mkgmtime64 HAVE__MKGMTIME64)
1279
1280 SET(CMAKE_REQUIRED_LIBRARIES "")
1281 CHECK_FUNCTION_EXISTS(cygwin_conv_path HAVE_CYGWIN_CONV_PATH)
1282 CHECK_FUNCTION_EXISTS(fseeko HAVE_FSEEKO)
1283 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
1284 CHECK_FUNCTION_EXISTS(strftime HAVE_STRFTIME)
1285 CHECK_FUNCTION_EXISTS(vprintf HAVE_VPRINTF)
1286 CHECK_FUNCTION_EXISTS(wmemcmp HAVE_WMEMCMP)
1287 CHECK_FUNCTION_EXISTS(wmemcpy HAVE_WMEMCPY)
1288 CHECK_FUNCTION_EXISTS(wmemmove HAVE_WMEMMOVE)
1289
1290 CMAKE_POP_CHECK_STATE() # Restore the state of the variables
1291
1292 CHECK_C_SOURCE_COMPILES(
1293   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct vfsconf v; return sizeof(v);}"
1294   HAVE_STRUCT_VFSCONF)
1295
1296 CHECK_C_SOURCE_COMPILES(
1297   "#include <sys/types.h>\n#include <sys/mount.h>\nint main(void) { struct xvfsconf v; return sizeof(v);}"
1298   HAVE_STRUCT_XVFSCONF)
1299
1300 # Make sure we have the POSIX version of readdir_r, not the
1301 # older 2-argument version.
1302 CHECK_C_SOURCE_COMPILES(
1303   "#include <dirent.h>\nint main() {DIR *d = opendir(\".\"); struct dirent e,*r; return readdir_r(d,&e,&r);}"
1304   HAVE_READDIR_R)
1305
1306
1307 # Only detect readlinkat() if we also have AT_FDCWD in unistd.h.
1308 # NOTE: linux requires fcntl.h for AT_FDCWD.
1309 CHECK_C_SOURCE_COMPILES(
1310   "#include <fcntl.h>\n#include <unistd.h>\nint main() {char buf[10]; return readlinkat(AT_FDCWD, \"\", buf, 0);}"
1311   HAVE_READLINKAT)
1312
1313
1314 # To verify major(), we need to both include the header
1315 # of interest and verify that the result can be linked.
1316 # CHECK_FUNCTION_EXISTS doesn't accept a header argument,
1317 # CHECK_SYMBOL_EXISTS doesn't test linkage.
1318 CHECK_C_SOURCE_COMPILES(
1319   "#include <sys/mkdev.h>\nint main() { return major(256); }"
1320   MAJOR_IN_MKDEV)
1321 CHECK_C_SOURCE_COMPILES(
1322   "#include <sys/sysmacros.h>\nint main() { return major(256); }"
1323   MAJOR_IN_SYSMACROS)
1324
1325 CHECK_C_SOURCE_COMPILES(
1326   "#include <lzma.h>\n#if LZMA_VERSION < 50020000\n#error unsupported\n#endif\nint main(void){lzma_stream_encoder_mt(0, 0); return 0;}"
1327   HAVE_LZMA_STREAM_ENCODER_MT)
1328
1329 IF(HAVE_STRERROR_R)
1330   SET(HAVE_DECL_STRERROR_R 1)
1331 ENDIF(HAVE_STRERROR_R)
1332
1333 #
1334 # Check defines
1335 #
1336 SET(headers "limits.h")
1337 IF(HAVE_STDINT_H)
1338   LIST(APPEND headers "stdint.h")
1339 ENDIF(HAVE_STDINT_H)
1340 IF(HAVE_INTTYPES_H)
1341   LIST(APPEND headers "inttypes.h")
1342 ENDIF(HAVE_INTTYPES_H)
1343 CHECK_SYMBOL_EXISTS(EFTYPE           "errno.h"    HAVE_EFTYPE)
1344 CHECK_SYMBOL_EXISTS(EILSEQ           "errno.h"    HAVE_EILSEQ)
1345 CHECK_SYMBOL_EXISTS(D_MD_ORDER       "langinfo.h" HAVE_D_MD_ORDER)
1346 CHECK_SYMBOL_EXISTS(INT32_MAX        "${headers}" HAVE_DECL_INT32_MAX)
1347 CHECK_SYMBOL_EXISTS(INT32_MIN        "${headers}" HAVE_DECL_INT32_MIN)
1348 CHECK_SYMBOL_EXISTS(INT64_MAX        "${headers}" HAVE_DECL_INT64_MAX)
1349 CHECK_SYMBOL_EXISTS(INT64_MIN        "${headers}" HAVE_DECL_INT64_MIN)
1350 CHECK_SYMBOL_EXISTS(INTMAX_MAX       "${headers}" HAVE_DECL_INTMAX_MAX)
1351 CHECK_SYMBOL_EXISTS(INTMAX_MIN       "${headers}" HAVE_DECL_INTMAX_MIN)
1352 CHECK_SYMBOL_EXISTS(UINT32_MAX       "${headers}" HAVE_DECL_UINT32_MAX)
1353 CHECK_SYMBOL_EXISTS(UINT64_MAX       "${headers}" HAVE_DECL_UINT64_MAX)
1354 CHECK_SYMBOL_EXISTS(UINTMAX_MAX      "${headers}" HAVE_DECL_UINTMAX_MAX)
1355 CHECK_SYMBOL_EXISTS(SIZE_MAX         "${headers}" HAVE_DECL_SIZE_MAX)
1356 CHECK_SYMBOL_EXISTS(SSIZE_MAX        "limits.h"   HAVE_DECL_SSIZE_MAX)
1357
1358 #
1359 # Check struct members
1360 #
1361 # Check for tm_gmtoff in struct tm
1362 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_gmtoff
1363     "time.h" HAVE_STRUCT_TM_TM_GMTOFF)
1364 CHECK_STRUCT_HAS_MEMBER("struct tm" __tm_gmtoff
1365     "time.h" HAVE_STRUCT_TM___TM_GMTOFF)
1366
1367 # Check for f_namemax in struct statfs
1368 CHECK_STRUCT_HAS_MEMBER("struct statfs" f_namemax
1369     "sys/param.h;sys/mount.h" HAVE_STRUCT_STATFS_F_NAMEMAX)
1370
1371 # Check for birthtime in struct stat
1372 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtime
1373     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIME)
1374
1375 # Check for high-resolution timestamps in struct stat
1376 CHECK_STRUCT_HAS_MEMBER("struct stat" st_birthtimespec.tv_nsec
1377     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BIRTHTIMESPEC_TV_NSEC)
1378 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec
1379     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC)
1380 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec
1381     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIM_TV_NSEC)
1382 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_n
1383     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_N)
1384 CHECK_STRUCT_HAS_MEMBER("struct stat" st_umtime
1385     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_UMTIME)
1386 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtime_usec
1387     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_MTIME_USEC)
1388 # Check for block size support in struct stat
1389 CHECK_STRUCT_HAS_MEMBER("struct stat" st_blksize
1390     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_BLKSIZE)
1391 # Check for st_flags in struct stat (BSD fflags)
1392 CHECK_STRUCT_HAS_MEMBER("struct stat" st_flags
1393     "sys/types.h;sys/stat.h" HAVE_STRUCT_STAT_ST_FLAGS)
1394
1395 IF(HAVE_SYS_STATVFS_H)
1396   CHECK_STRUCT_HAS_MEMBER("struct statvfs" f_iosize
1397     "sys/types.h;sys/statvfs.h" HAVE_STRUCT_STATVFS_F_IOSIZE)
1398 ENDIF()
1399
1400 #
1401 #
1402 CHECK_STRUCT_HAS_MEMBER("struct tm" tm_sec
1403     "sys/types.h;sys/time.h;time.h" TIME_WITH_SYS_TIME)
1404
1405 #
1406 # Check for integer types
1407 #
1408 #
1409 CHECK_TYPE_SIZE("short" SIZE_OF_SHORT)
1410 CHECK_TYPE_SIZE("int" SIZE_OF_INT)
1411 CHECK_TYPE_SIZE("long" SIZE_OF_LONG)
1412 CHECK_TYPE_SIZE("long long"     SIZE_OF_LONG_LONG)
1413
1414 CHECK_TYPE_SIZE("unsigned short" SIZE_OF_UNSIGNED_SHORT)
1415 CHECK_TYPE_SIZE("unsigned" SIZE_OF_UNSIGNED)
1416 CHECK_TYPE_SIZE("unsigned long" SIZE_OF_UNSIGNED_LONG)
1417 CHECK_TYPE_SIZE("unsigned long long" SIZE_OF_UNSIGNED_LONG_LONG)
1418
1419 CHECK_TYPE_SIZE("__int64" __INT64)
1420 CHECK_TYPE_SIZE("unsigned __int64" UNSIGNED___INT64)
1421
1422 CHECK_TYPE_SIZE(int16_t INT16_T)
1423 CHECK_TYPE_SIZE(int32_t INT32_T)
1424 CHECK_TYPE_SIZE(int64_t INT64_T)
1425 CHECK_TYPE_SIZE(intmax_t INTMAX_T)
1426 CHECK_TYPE_SIZE(uint8_t UINT8_T)
1427 CHECK_TYPE_SIZE(uint16_t UINT16_T)
1428 CHECK_TYPE_SIZE(uint32_t UINT32_T)
1429 CHECK_TYPE_SIZE(uint64_t UINT64_T)
1430 CHECK_TYPE_SIZE(uintmax_t UINTMAX_T)
1431
1432 CHECK_TYPE_SIZE(dev_t       DEV_T)
1433 IF(NOT HAVE_DEV_T)
1434   IF(MSVC)
1435     SET(dev_t "unsigned int")
1436   ENDIF(MSVC)
1437 ENDIF(NOT HAVE_DEV_T)
1438 #
1439 CHECK_TYPE_SIZE(gid_t       GID_T)
1440 IF(NOT HAVE_GID_T)
1441   IF(WIN32)
1442     SET(gid_t "short")
1443   ELSE(WIN32)
1444     SET(gid_t "unsigned int")
1445   ENDIF(WIN32)
1446 ENDIF(NOT HAVE_GID_T)
1447 #
1448 CHECK_TYPE_SIZE(id_t        ID_T)
1449 IF(NOT HAVE_ID_T)
1450   IF(WIN32)
1451     SET(id_t "short")
1452   ELSE(WIN32)
1453     SET(id_t "unsigned int")
1454   ENDIF(WIN32)
1455 ENDIF(NOT HAVE_ID_T)
1456 #
1457 CHECK_TYPE_SIZE(mode_t      MODE_T)
1458 IF(NOT HAVE_MODE_T)
1459   IF(WIN32)
1460     SET(mode_t "unsigned short")
1461   ELSE(WIN32)
1462     SET(mode_t "int")
1463   ENDIF(WIN32)
1464 ENDIF(NOT HAVE_MODE_T)
1465 #
1466 CHECK_TYPE_SIZE(off_t       OFF_T)
1467 IF(NOT HAVE_OFF_T)
1468   SET(off_t "__int64")
1469 ENDIF(NOT HAVE_OFF_T)
1470 #
1471 CHECK_TYPE_SIZE(size_t      SIZE_T)
1472 IF(NOT HAVE_SIZE_T)
1473   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1474     SET(size_t "uint64_t")
1475   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1476     SET(size_t   "uint32_t")
1477   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1478 ENDIF(NOT HAVE_SIZE_T)
1479 #
1480 CHECK_TYPE_SIZE(ssize_t     SSIZE_T)
1481 IF(NOT HAVE_SSIZE_T)
1482   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1483     SET(ssize_t "int64_t")
1484   ELSE("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1485     SET(ssize_t "long")
1486   ENDIF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1487 ENDIF(NOT HAVE_SSIZE_T)
1488 #
1489 CHECK_TYPE_SIZE(uid_t       UID_T)
1490 IF(NOT HAVE_UID_T)
1491   IF(WIN32)
1492     SET(uid_t "short")
1493   ELSE(WIN32)
1494     SET(uid_t "unsigned int")
1495   ENDIF(WIN32)
1496 ENDIF(NOT HAVE_UID_T)
1497 #
1498 CHECK_TYPE_SIZE(pid_t       PID_T)
1499 IF(NOT HAVE_PID_T)
1500   IF(WIN32)
1501     SET(pid_t "int")
1502   ELSE(WIN32)
1503     MESSAGE(FATAL_ERROR "pid_t doesn't exist on this platform?")
1504   ENDIF(WIN32)
1505 ENDIF(NOT HAVE_PID_T)
1506 #
1507 CHECK_TYPE_SIZE(intptr_t   INTPTR_T)
1508 IF(NOT HAVE_INTPTR_T)
1509   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1510     SET(intptr_t "int64_t")
1511   ELSE()
1512     SET(intptr_t "int32_t")
1513   ENDIF()
1514 ENDIF(NOT HAVE_INTPTR_T)
1515 #
1516 CHECK_TYPE_SIZE(uintptr_t   UINTPTR_T)
1517 IF(NOT HAVE_UINTPTR_T)
1518   IF("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
1519     SET(uintptr_t "uint64_t")
1520   ELSE()
1521     SET(uintptr_t "uint32_t")
1522   ENDIF()
1523 ENDIF(NOT HAVE_UINTPTR_T)
1524 #
1525 CHECK_TYPE_SIZE(wchar_t     SIZEOF_WCHAR_T)
1526 IF(HAVE_SIZEOF_WCHAR_T)
1527   SET(HAVE_WCHAR_T 1)
1528 ENDIF(HAVE_SIZEOF_WCHAR_T)
1529 #
1530 # Check if _FILE_OFFSET_BITS macro needed for large files
1531 #
1532 CHECK_FILE_OFFSET_BITS()
1533
1534 #
1535 # Check for Extended Attribute libraries, headers, and functions
1536 #
1537 IF(ENABLE_XATTR)
1538   CHECK_LIBRARY_EXISTS(attr "setxattr" "" HAVE_LIBATTR)
1539   IF(HAVE_LIBATTR)
1540     SET(CMAKE_REQUIRED_LIBRARIES "attr")
1541   ENDIF(HAVE_LIBATTR)
1542   CHECK_SYMBOL_EXISTS(EXTATTR_NAMESPACE_USER "sys/types.h;sys/extattr.h" HAVE_DECL_EXTATTR_NAMESPACE_USER)
1543   CHECK_SYMBOL_EXISTS(XATTR_NOFOLLOW "sys/xattr.h" HAVE_DECL_XATTR_NOFOLLOW)
1544   IF(HAVE_SYS_XATTR_H AND HAVE_DECL_XATTR_NOFOLLOW)
1545     CHECK_FUNCTION_EXISTS(fgetxattr HAVE_FGETXATTR)
1546     CHECK_FUNCTION_EXISTS(flistxattr HAVE_FLISTXATTR)
1547     CHECK_FUNCTION_EXISTS(fsetxattr HAVE_FSETXATTR)
1548     CHECK_FUNCTION_EXISTS(getxattr HAVE_GETXATTR)
1549     CHECK_FUNCTION_EXISTS(listxattr HAVE_LISTXATTR)
1550     CHECK_FUNCTION_EXISTS(setxattr HAVE_SETXATTR)
1551     IF(HAVE_FGETXATTR AND
1552        HAVE_FLISTXATTR AND
1553        HAVE_FSETXATTR AND
1554        HAVE_GETXATTR AND
1555        HAVE_LISTXATTR AND
1556        HAVE_SETXATTR)
1557       SET(ARCHIVE_XATTR_DARWIN TRUE)
1558     ENDIF()
1559   ELSEIF(HAVE_SYS_EXTATTR_H AND HAVE_DECL_EXTATTR_NAMESPACE_USER)
1560     # FreeBSD xattr support
1561     CHECK_FUNCTION_EXISTS(extattr_get_fd HAVE_EXTATTR_GET_FD)
1562     CHECK_FUNCTION_EXISTS(extattr_get_file HAVE_EXTATTR_GET_FILE)
1563     CHECK_FUNCTION_EXISTS(extattr_get_link HAVE_EXTATTR_GET_LINK)
1564     CHECK_FUNCTION_EXISTS(extattr_list_fd HAVE_EXTATTR_LIST_FD)
1565     CHECK_FUNCTION_EXISTS(extattr_list_file HAVE_EXTATTR_LIST_FILE)
1566     CHECK_FUNCTION_EXISTS(extattr_list_link HAVE_EXTATTR_LIST_LINK)
1567     CHECK_FUNCTION_EXISTS(extattr_set_fd HAVE_EXTATTR_SET_FD)
1568     CHECK_FUNCTION_EXISTS(extattr_set_link HAVE_EXTATTR_SET_LINK)
1569     IF(HAVE_EXTATTR_GET_FD AND
1570        HAVE_EXTATTR_GET_FILE AND
1571        HAVE_EXTATTR_GET_LINK AND
1572        HAVE_EXTATTR_LIST_FD AND
1573        HAVE_EXTATTR_LIST_FILE AND
1574        HAVE_EXTATTR_LIST_LINK AND
1575        HAVE_EXTATTR_SET_FD AND
1576        HAVE_EXTATTR_SET_LINK)
1577       SET(ARCHIVE_XATTR_FREEBSD TRUE)
1578     ENDIF()
1579   ELSEIF(HAVE_SYS_XATTR_H OR HAVE_ATTR_XATTR_H)
1580     # Linux xattr support
1581     CHECK_FUNCTION_EXISTS_GLIBC(fgetxattr HAVE_FGETXATTR)
1582     CHECK_FUNCTION_EXISTS_GLIBC(flistxattr HAVE_FLISTXATTR)
1583     CHECK_FUNCTION_EXISTS_GLIBC(fsetxattr HAVE_FSETXATTR)
1584     CHECK_FUNCTION_EXISTS_GLIBC(getxattr HAVE_GETXATTR)
1585     CHECK_FUNCTION_EXISTS_GLIBC(lgetxattr HAVE_LGETXATTR)
1586     CHECK_FUNCTION_EXISTS_GLIBC(listxattr HAVE_LISTXATTR)
1587     CHECK_FUNCTION_EXISTS_GLIBC(llistxattr HAVE_LLISTXATTR)
1588     CHECK_FUNCTION_EXISTS_GLIBC(lsetxattr HAVE_LSETXATTR)
1589     IF(HAVE_FGETXATTR AND
1590        HAVE_FLISTXATTR AND
1591        HAVE_FSETXATTR AND
1592        HAVE_GETXATTR AND
1593        HAVE_LGETXATTR AND
1594        HAVE_LISTXATTR AND
1595        HAVE_LLISTXATTR AND
1596        HAVE_LSETXATTR)
1597       SET(ARCHIVE_XATTR_LINUX TRUE)
1598     ENDIF()
1599   ELSEIF(HAVE_SYS_EA_H)
1600     # AIX xattr support
1601     CHECK_FUNCTION_EXISTS(fgetea HAVE_FGETEA)
1602     CHECK_FUNCTION_EXISTS(flistea HAVE_FLISTEA)
1603     CHECK_FUNCTION_EXISTS(fsetea HAVE_FSETEA)
1604     CHECK_FUNCTION_EXISTS(getea HAVE_GETEA)
1605     CHECK_FUNCTION_EXISTS(lgetea HAVE_LGETEA)
1606     CHECK_FUNCTION_EXISTS(listea HAVE_LISTEA)
1607     CHECK_FUNCTION_EXISTS(llistea HAVE_LLISTEA)
1608     CHECK_FUNCTION_EXISTS(lsetea HAVE_LSETEA)
1609     IF(HAVE_FGETEA AND
1610        HAVE_FLISTEA AND
1611        HAVE_FSETEA AND
1612        HAVE_GETEA AND
1613        HAVE_LGETEA AND
1614        HAVE_LISTEA AND
1615        HAVE_LLISTEA AND
1616        HAVE_LSETEA)
1617       SET(ARCHIVE_XATTR_AIX TRUE)
1618     ENDIF()
1619   ENDIF()
1620
1621   IF(ARCHIVE_XATTR_DARWIN)
1622     MESSAGE(STATUS "Extended attributes support: Darwin")
1623   ELSEIF(ARCHIVE_XATTR_FREEBSD)
1624     MESSAGE(STATUS "Extended attributes support: FreeBSD")
1625   ELSEIF(ARCHIVE_XATTR_LINUX)
1626     MESSAGE(STATUS "Extended attributes support: Linux")
1627   ELSEIF(ARCHIVE_XATTR_AIX)
1628     MESSAGE(STATUS "Extended attributes support: AIX")
1629   ELSE()
1630     MESSAGE(STATUS "Extended attributes support: none")
1631   ENDIF()
1632 ELSE(ENABLE_XATTR)
1633   SET(ARCHIVE_XATTR_DARWIN FALSE)
1634   SET(ARCHIVE_XATTR_FREEBSD FALSE)
1635   SET(ARCHIVE_XATTR_LINUX FALSE)
1636   SET(ARCHIVE_XATTR_AIX FALSE)
1637 ENDIF(ENABLE_XATTR)
1638
1639 #
1640 # Check for ACL libraries, headers, and functions
1641 #
1642 # The ACL support in libarchive is written against the POSIX1e draft,
1643 # which was never officially approved and varies quite a bit across
1644 # platforms.  Worse, some systems have completely non-POSIX acl functions,
1645 # which makes the following checks rather more complex than I would like.
1646 #
1647 IF(ENABLE_ACL)
1648   # Solaris and derivates ACLs
1649   CHECK_FUNCTION_EXISTS(acl HAVE_ACL)
1650   CHECK_FUNCTION_EXISTS(facl HAVE_FACL)
1651
1652   # Libacl
1653   CHECK_LIBRARY_EXISTS(acl "acl_get_file" "" HAVE_LIBACL)
1654   IF(HAVE_LIBACL)
1655     SET(CMAKE_REQUIRED_LIBRARIES "acl")
1656     FIND_LIBRARY(ACL_LIBRARY NAMES acl)
1657     LIST(APPEND ADDITIONAL_LIBS ${ACL_LIBRARY})
1658   ENDIF(HAVE_LIBACL)
1659
1660   CHECK_TYPE_EXISTS(acl_t "sys/types.h;sys/acl.h" HAVE_ACL_T)
1661   CHECK_TYPE_EXISTS(acl_entry_t "sys/types.h;sys/acl.h" HAVE_ACL_ENTRY_T)
1662   CHECK_TYPE_EXISTS(acl_permset_t "sys/types.h;sys/acl.h" HAVE_ACL_PERMSET_T)
1663   CHECK_TYPE_EXISTS(acl_tag_t "sys/types.h;sys/acl.h" HAVE_ACL_TAG_T)
1664
1665   IF(HAVE_ACL AND HAVE_FACL)
1666     CHECK_TYPE_EXISTS(aclent_t "sys/acl.h" HAVE_ACLENT_T)
1667     IF(HAVE_ACLENT_T)
1668       CHECK_SYMBOL_EXISTS(GETACL "sys/acl.h" HAVE_DECL_GETACL)
1669       CHECK_SYMBOL_EXISTS(GETACLCNT "sys/acl.h" HAVE_DECL_GETACLCNT)
1670       CHECK_SYMBOL_EXISTS(SETACL "sys/acl.h" HAVE_DECL_SETACL)
1671       IF(HAVE_DECL_GETACL AND
1672          HAVE_DECL_GETACLCNT AND
1673          HAVE_DECL_SETACL)
1674         SET(ARCHIVE_ACL_SUNOS TRUE)
1675       ENDIF()
1676       CHECK_TYPE_EXISTS(ace_t "sys/acl.h" HAVE_ACE_T)
1677       IF(HAVE_ACE_T)
1678         CHECK_SYMBOL_EXISTS(ACE_GETACL "sys/acl.h" HAVE_DECL_ACE_GETACL)
1679         CHECK_SYMBOL_EXISTS(ACE_GETACLCNT "sys/acl.h" HAVE_DECL_ACE_GETACLCNT)
1680         CHECK_SYMBOL_EXISTS(ACE_SETACL "sys/acl.h" HAVE_DECL_ACE_SETACL)
1681         IF(HAVE_DECL_ACE_GETACL AND
1682            HAVE_DECL_ACE_GETACLCNT AND
1683            HAVE_DECL_ACE_SETACL)
1684           SET(ARCHIVE_ACL_SUNOS_NFS4 TRUE)
1685         ENDIF()
1686       ENDIF(HAVE_ACE_T)
1687     ENDIF(HAVE_ACLENT_T)
1688   ENDIF(HAVE_ACL AND HAVE_FACL)
1689
1690   IF(HAVE_ACL_T AND HAVE_ACL_ENTRY_T AND HAVE_ACL_PERMSET_T AND HAVE_ACL_TAG_T)
1691     CHECK_FUNCTION_EXISTS_GLIBC(acl_add_perm HAVE_ACL_ADD_PERM)
1692     CHECK_FUNCTION_EXISTS_GLIBC(acl_clear_perms HAVE_ACL_CLEAR_PERMS)
1693     CHECK_FUNCTION_EXISTS_GLIBC(acl_create_entry HAVE_ACL_CREATE_ENTRY)
1694     CHECK_FUNCTION_EXISTS_GLIBC(acl_delete_def_file HAVE_ACL_DELETE_DEF_FILE)
1695     CHECK_FUNCTION_EXISTS_GLIBC(acl_free HAVE_ACL_FREE)
1696     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_entry HAVE_ACL_GET_ENTRY)
1697     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_fd HAVE_ACL_GET_FD)
1698     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_file HAVE_ACL_GET_FILE)
1699     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_permset HAVE_ACL_GET_PERMSET)
1700     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_qualifier HAVE_ACL_GET_QUALIFIER)
1701     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_tag_type HAVE_ACL_GET_TAG_TYPE)
1702     CHECK_FUNCTION_EXISTS_GLIBC(acl_init HAVE_ACL_INIT)
1703     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_fd HAVE_ACL_SET_FD)
1704     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_file HAVE_ACL_SET_FILE)
1705     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_qualifier HAVE_ACL_SET_QUALIFIER)
1706     CHECK_FUNCTION_EXISTS_GLIBC(acl_set_tag_type HAVE_ACL_SET_TAG_TYPE)
1707     IF(HAVE_ACL_ADD_PERM AND
1708        HAVE_ACL_CLEAR_PERMS AND
1709        HAVE_ACL_CREATE_ENTRY AND
1710        HAVE_ACL_DELETE_DEF_FILE AND
1711        HAVE_ACL_FREE AND
1712        HAVE_ACL_GET_ENTRY AND
1713        HAVE_ACL_GET_FD AND
1714        HAVE_ACL_GET_FILE AND
1715        HAVE_ACL_GET_PERMSET AND
1716        HAVE_ACL_GET_QUALIFIER AND
1717        HAVE_ACL_GET_TAG_TYPE AND
1718        HAVE_ACL_INIT AND
1719        HAVE_ACL_SET_FD AND
1720        HAVE_ACL_SET_FILE AND
1721        HAVE_ACL_SET_QUALIFIER AND
1722        HAVE_ACL_SET_TAG_TYPE)
1723          SET(HAVE_POSIX_ACL_FUNCS 1)
1724     ENDIF()
1725
1726     CHECK_FUNCTION_EXISTS_GLIBC(acl_get_perm HAVE_ACL_GET_PERM)
1727
1728     IF(HAVE_POSIX_ACL_FUNCS AND HAVE_ACL_LIBACL_H AND HAVE_LIBACL AND
1729        HAVE_ACL_GET_PERM)
1730       SET(ARCHIVE_ACL_LIBACL TRUE)
1731     ELSE()
1732       CHECK_FUNCTION_EXISTS(acl_add_flag_np HAVE_ACL_ADD_FLAG_NP)
1733       CHECK_FUNCTION_EXISTS(acl_clear_flags_np HAVE_ACL_CLEAR_FLAGS_NP)
1734       CHECK_FUNCTION_EXISTS(acl_get_brand_np HAVE_ACL_GET_BRAND_NP)
1735       CHECK_FUNCTION_EXISTS(acl_get_entry_type_np HAVE_ACL_GET_ENTRY_TYPE_NP)
1736       CHECK_FUNCTION_EXISTS(acl_get_flag_np HAVE_ACL_GET_FLAG_NP)
1737       CHECK_FUNCTION_EXISTS(acl_get_flagset_np HAVE_ACL_GET_FLAGSET_NP)
1738       CHECK_FUNCTION_EXISTS(acl_get_fd_np HAVE_ACL_GET_FD_NP)
1739       CHECK_FUNCTION_EXISTS(acl_get_link_np HAVE_ACL_GET_LINK_NP)
1740       CHECK_FUNCTION_EXISTS(acl_get_perm_np HAVE_ACL_GET_PERM_NP)
1741       CHECK_FUNCTION_EXISTS(acl_is_trivial_np HAVE_ACL_IS_TRIVIAL_NP)
1742       CHECK_FUNCTION_EXISTS(acl_set_entry_type_np HAVE_ACL_SET_ENTRY_TYPE_NP)
1743       CHECK_FUNCTION_EXISTS(acl_set_fd_np HAVE_ACL_SET_FD_NP)
1744       CHECK_FUNCTION_EXISTS(acl_set_link_np HAVE_ACL_SET_LINK_NP)
1745       CHECK_FUNCTION_EXISTS(mbr_gid_to_uuid HAVE_MBR_GID_TO_UUID)
1746       CHECK_FUNCTION_EXISTS(mbr_uid_to_uuid HAVE_MBR_UID_TO_UUID)
1747       CHECK_FUNCTION_EXISTS(mbr_uuid_to_id HAVE_MBR_UUID_TO_ID)
1748
1749       CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1750 #include <sys/acl.h>
1751 int main(void) { return ACL_TYPE_EXTENDED; }" HAVE_DECL_ACL_TYPE_EXTENDED)
1752       CHECK_C_SOURCE_COMPILES("#include <sys/types.h>
1753 #include <sys/acl.h>
1754 int main(void) { return ACL_SYNCHRONIZE; }" HAVE_DECL_ACL_SYNCHRONIZE)
1755       CHECK_SYMBOL_EXISTS(ACL_TYPE_NFS4 "sys/acl.h" HAVE_DECL_ACL_TYPE_NFS4)
1756       CHECK_SYMBOL_EXISTS(ACL_USER "sys/acl.h" HAVE_DECL_ACL_USER)
1757
1758       IF(HAVE_POSIX_ACL_FUNCS AND
1759          HAVE_ACL_GET_FD_NP AND
1760          HAVE_ACL_GET_PERM_NP AND
1761          NOT HAVE_ACL_GET_PERM AND
1762          HAVE_ACL_SET_FD_NP)
1763         IF(HAVE_DECL_ACL_USER)
1764           SET(ARCHIVE_ACL_FREEBSD TRUE)
1765           IF(HAVE_DECL_ACL_TYPE_NFS4 AND
1766              HAVE_ACL_ADD_FLAG_NP AND
1767              HAVE_ACL_CLEAR_FLAGS_NP AND
1768              HAVE_ACL_GET_BRAND_NP AND
1769              HAVE_ACL_GET_ENTRY_TYPE_NP AND
1770              HAVE_ACL_GET_FLAGSET_NP AND
1771              HAVE_ACL_SET_ENTRY_TYPE_NP)
1772             SET(ARCHIVE_ACL_FREEBSD_NFS4 TRUE)
1773           ENDIF()
1774         ELSEIF(HAVE_DECL_ACL_TYPE_EXTENDED AND
1775                HAVE_MEMBERSHIP_H AND
1776                HAVE_ACL_ADD_FLAG_NP AND
1777                HAVE_ACL_CLEAR_FLAGS_NP AND
1778                HAVE_ACL_GET_FLAGSET_NP AND
1779                HAVE_ACL_GET_LINK_NP AND
1780                HAVE_ACL_SET_LINK_NP AND
1781                HAVE_MBR_UID_TO_UUID AND
1782                HAVE_MBR_GID_TO_UUID AND
1783                HAVE_MBR_UUID_TO_ID)
1784           SET(ARCHIVE_ACL_DARWIN TRUE)
1785         ENDIF()
1786       ENDIF()
1787     ENDIF()
1788   ENDIF(HAVE_ACL_T AND HAVE_ACL_ENTRY_T AND HAVE_ACL_PERMSET_T AND
1789         HAVE_ACL_TAG_T)
1790
1791   # Richacl
1792   CHECK_LIBRARY_EXISTS(richacl "richacl_get_file" "" HAVE_LIBRICHACL)
1793   IF(HAVE_LIBRICHACL)
1794     SET(CMAKE_REQUIRED_LIBRARIES "richacl")
1795     FIND_LIBRARY(RICHACL_LIBRARY NAMES richacl)
1796     LIST(APPEND ADDITIONAL_LIBS ${RICHACL_LIBRARY})
1797   ENDIF(HAVE_LIBRICHACL)
1798
1799   CHECK_STRUCT_HAS_MEMBER("struct richace" e_type "sys/richacl.h"
1800     HAVE_STRUCT_RICHACE)
1801   CHECK_STRUCT_HAS_MEMBER("struct richacl" a_flags "sys/richacl.h"
1802     HAVE_STRUCT_RICHACL)
1803
1804   IF(HAVE_LIBRICHACL AND HAVE_STRUCT_RICHACL AND HAVE_STRUCT_RICHACE)
1805     CHECK_FUNCTION_EXISTS_GLIBC(richacl_alloc HAVE_RICHACL_ALLOC)
1806     CHECK_FUNCTION_EXISTS_GLIBC(richacl_equiv_mode HAVE_RICHACL_EQUIV_MODE)
1807     CHECK_FUNCTION_EXISTS_GLIBC(richacl_free HAVE_RICHACL_FREE)
1808     CHECK_FUNCTION_EXISTS_GLIBC(richacl_get_fd HAVE_RICHACL_GET_FD)
1809     CHECK_FUNCTION_EXISTS_GLIBC(richacl_get_file HAVE_RICHACL_GET_FILE)
1810     CHECK_FUNCTION_EXISTS_GLIBC(richacl_set_fd HAVE_RICHACL_SET_FD)
1811     CHECK_FUNCTION_EXISTS_GLIBC(richacl_set_file HAVE_RICHACL_SET_FILE)
1812     IF(HAVE_RICHACL_ALLOC AND
1813        HAVE_RICHACL_EQUIV_MODE AND
1814        HAVE_RICHACL_FREE AND
1815        HAVE_RICHACL_GET_FD AND
1816        HAVE_RICHACL_GET_FILE AND
1817        HAVE_RICHACL_SET_FD AND
1818        HAVE_RICHACL_SET_FILE)
1819       SET(ARCHIVE_ACL_LIBRICHACL TRUE)
1820     ENDIF()
1821   ENDIF(HAVE_LIBRICHACL AND HAVE_STRUCT_RICHACL AND HAVE_STRUCT_RICHACE)
1822
1823   IF(ARCHIVE_ACL_DARWIN)
1824     MESSAGE(STATUS "ACL support: Darwin (limited NFSv4)")
1825   ELSEIF(ARCHIVE_ACL_FREEBSD_NFS4)
1826     MESSAGE(STATUS "ACL support: FreeBSD (POSIX.1e and NFSv4)")
1827   ELSEIF(ARCHIVE_ACL_FREEBSD)
1828     MESSAGE(STATUS "ACL support: FreeBSD (POSIX.1e)")
1829   ELSEIF(ARCHIVE_ACL_LIBACL OR ARCHIVE_ACL_LIBRICHACL)
1830     IF(ARCHIVE_ACL_LIBACL AND ARCHIVE_ACL_LIBRICHACL)
1831       MESSAGE(STATUS "ACL support: libacl (POSIX.1e) + librichacl (NFSv4)")
1832     ELSEIF(ARCHIVE_ACL_LIBRICHACL)
1833       MESSAGE(STATUS "ACL support: librichacl (NFSv4)")
1834     ELSE()
1835       MESSAGE(STATUS "ACL support: libacl (POSIX.1e)")
1836     ENDIF()
1837   ELSEIF(ARCHIVE_ACL_SUNOS_NFS4)
1838     MESSAGE(STATUS "ACL support: Solaris (POSIX.1e and NFSv4)")
1839   ELSEIF(ARCHIVE_ACL_SUNOS)
1840     MESSAGE(STATUS "ACL support: Solaris (POSIX.1e)")
1841   ELSE()
1842     MESSAGE(STATUS "ACL support: none")
1843   ENDIF()
1844
1845 ELSE(ENABLE_ACL)
1846   # If someone runs cmake, then disables ACL support, we need
1847   # to forcibly override the cached values for these.
1848   SET(ARCHIVE_ACL_DARWIN FALSE)
1849   SET(ARCHIVE_ACL_FREEBSD FALSE)
1850   SET(ARCHIVE_ACL_FREEBSD_NFS4 FALSE)
1851   SET(ARCHIVE_ACL_LIBACL FALSE)
1852   SET(ARCHIVE_ACL_SUNOS FALSE)
1853   SET(ARCHIVE_ACL_SUNOS_NFS4 FALSE)
1854 ENDIF(ENABLE_ACL)
1855
1856 #
1857 # Check MD5/RMD160/SHA support
1858 # NOTE: Crypto checks must be run last before generating config.h
1859 #
1860 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" LIBC)
1861 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC2)
1862 CHECK_CRYPTO("SHA256;SHA384;SHA512" LIBC3)
1863 CHECK_CRYPTO("MD5;SHA1;SHA256;SHA384;SHA512" LIBSYSTEM)
1864 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" NETTLE)
1865 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA384;SHA512" OPENSSL)
1866
1867 # Libmd has to be probed after OpenSSL.
1868 CHECK_CRYPTO("MD5;RMD160;SHA1;SHA256;SHA512" LIBMD)
1869
1870 CHECK_CRYPTO_WIN("MD5;SHA1;SHA256;SHA384;SHA512")
1871
1872 # Generate "config.h" from "build/cmake/config.h.in"
1873 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/config.h.in
1874         ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1875 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
1876 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
1877
1878 # Handle generation of the libarchive.pc file for pkg-config
1879 INCLUDE(CreatePkgConfigFile)
1880
1881 #
1882 # Register installation of PDF documents.
1883 #
1884 IF(WIN32 AND NOT CYGWIN)
1885   #
1886   # On Windows platform, It's better that we install PDF documents
1887   # on one's computer.
1888   # These PDF documents are available in the release package.
1889   #
1890   IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1891     INSTALL(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf
1892             DESTINATION share/man
1893             FILES_MATCHING PATTERN "*.pdf"
1894     )
1895   ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/doc/pdf)
1896 ENDIF(WIN32 AND NOT CYGWIN)
1897 #
1898 #
1899 #
1900 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/libarchive)
1901 #
1902 IF(MSVC)
1903   ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
1904 ENDIF(MSVC)
1905
1906 IF(ENABLE_TEST)
1907   ADD_CUSTOM_TARGET(run_all_tests)
1908 ENDIF(ENABLE_TEST)
1909
1910 add_subdirectory(libarchive)
1911 add_subdirectory(cat)
1912 add_subdirectory(tar)
1913 add_subdirectory(cpio)