cmake/Modules/HandleLibCXXABI.cmake

   1
   2 #===============================================================================
   3 # Add an ABI library if appropriate
   4 #===============================================================================
   5
   6 #
   7 # _setup_abi: Set up the build to use an ABI library
   8 #
   9 # Parameters:
  10 #   abidefines: A list of defines needed to compile libc++ with the ABI library
  11 #   abilib    : The ABI library to link against.
  12 #   abifiles  : A list of files (which may be relative paths) to copy into the
  13 #               libc++ build tree for the build.  These files will also be
  14 #               installed alongside the libc++ headers.
  15 #   abidirs   : A list of relative paths to create under an include directory
  16 #               in the libc++ build directory.
  17 #
  18 macro(setup_abi_lib abidefines abilib abifiles abidirs)
  19   list(APPEND LIBCXX_COMPILE_FLAGS ${abidefines})
  20   set(LIBCXX_CXX_ABI_INCLUDE_PATHS "${LIBCXX_CXX_ABI_INCLUDE_PATHS}"
  21     CACHE PATH
  22     "Paths to C++ ABI header directories separated by ';'." FORCE
  23     )
  24   set(LIBCXX_CXX_ABI_LIBRARY_PATH "${LIBCXX_CXX_ABI_LIBRARY_PATH}"
  25     CACHE PATH
  26     "Paths to C++ ABI library directory"
  27     )
  28   set(LIBCXX_CXX_ABI_LIBRARY ${abilib})
  29   set(LIBCXX_ABILIB_FILES ${abifiles})
  30
  31   # The place in the build tree where we store out-of-source headers.
  32   set(LIBCXX_BUILD_HEADERS_ROOT "${CMAKE_BINARY_DIR}/include/c++-build")
  33   file(MAKE_DIRECTORY "${LIBCXX_BUILD_HEADERS_ROOT}")
  34   foreach(_d ${abidirs})
  35     file(MAKE_DIRECTORY "${LIBCXX_BUILD_HEADERS_ROOT}/${_d}")
  36   endforeach()
  37
  38   foreach(fpath ${LIBCXX_ABILIB_FILES})
  39     set(found FALSE)
  40     foreach(incpath ${LIBCXX_CXX_ABI_INCLUDE_PATHS})
  41       if (EXISTS "${incpath}/${fpath}")
  42         set(found TRUE)
  43         get_filename_component(dstdir ${fpath} PATH)
  44         get_filename_component(ifile ${fpath} NAME)
  45         file(COPY "${incpath}/${fpath}"
  46           DESTINATION "${LIBCXX_BUILD_HEADERS_ROOT}/${dstdir}"
  47           )
  48         if (LIBCXX_INSTALL_HEADERS)
  49           install(FILES "${LIBCXX_BUILD_HEADERS_ROOT}/${fpath}"
  50             DESTINATION include/c++/v1/${dstdir}
  51             COMPONENT libcxx
  52             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
  53             )
  54         endif()
  55         list(APPEND abilib_headers "${LIBCXX_BUILD_HEADERS_ROOT}/${fpath}")
  56       endif()
  57     endforeach()
  58     if (NOT found)
  59       message(WARNING "Failed to find ${fpath}")
  60     endif()
  61   endforeach()
  62
  63   include_directories("${LIBCXX_BUILD_HEADERS_ROOT}")
  64 endmacro()
  65
  66
  67 # Configure based on the selected ABI library.
  68 if ("${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libstdc++" OR
  69     "${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libsupc++")
  70   set(_LIBSUPCXX_INCLUDE_FILES
  71     cxxabi.h bits/c++config.h bits/os_defines.h bits/cpu_defines.h
  72     bits/cxxabi_tweaks.h bits/cxxabi_forced.h
  73     )
  74   if ("${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libstdc++")
  75     set(_LIBSUPCXX_DEFINES "-DLIBSTDCXX")
  76     set(_LIBSUPCXX_LIBNAME stdc++)
  77   else()
  78     set(_LIBSUPCXX_DEFINES "")
  79     set(_LIBSUPCXX_LIBNAME supc++)
  80   endif()
  81   setup_abi_lib(
  82     "-D__GLIBCXX__ ${_LIBSUPCXX_DEFINES}"
  83     "${_LIBSUPCXX_LIBNAME}" "${_LIBSUPCXX_INCLUDE_FILES}" "bits"
  84     )
  85 elseif ("${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libcxxabi")
  86   if (LIBCXX_CXX_ABI_INTREE)
  87     # Link against just-built "cxxabi" target.
  88     if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
  89         set(CXXABI_LIBNAME cxxabi_static)
  90     else()
  91         set(CXXABI_LIBNAME cxxabi_shared)
  92     endif()
  93     set(LIBCXX_LIBCPPABI_VERSION "2" PARENT_SCOPE)
  94   else()
  95     # Assume c++abi is installed in the system, rely on -lc++abi link flag.
  96     set(CXXABI_LIBNAME "c++abi")
  97   endif()
  98   setup_abi_lib("-DLIBCXX_BUILDING_LIBCXXABI"
  99     ${CXXABI_LIBNAME} "cxxabi.h;__cxxabi_config.h" ""
 100     )
 101 elseif ("${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libcxxrt")
 102   setup_abi_lib("-DLIBCXXRT"
 103     "cxxrt" "cxxabi.h;unwind.h;unwind-arm.h;unwind-itanium.h" ""
 104     )
 105 elseif (NOT "${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "none")
 106   message(FATAL_ERROR
 107     "Currently libstdc++, libsupc++, libcxxabi, libcxxrt and none are "
 108     "supported for c++ abi."
 109     )
 110 endif ()