config/kernel-bdi.m4

   1 dnl #
   2 dnl # Check available BDI interfaces.
   3 dnl #
   4 AC_DEFUN([ZFS_AC_KERNEL_SRC_BDI], [
   5         ZFS_LINUX_TEST_SRC([super_setup_bdi_name], [
   6                 #include <linux/fs.h>
   7                 struct super_block sb;
   8         ], [
   9                 char *name = "bdi";
  10                 atomic_long_t zfs_bdi_seq;
  11                 int error __attribute__((unused)) =
  12                     super_setup_bdi_name(&sb, "%.28s-%ld", name,
  13                     atomic_long_inc_return(&zfs_bdi_seq));
  14         ])
  15
  16         ZFS_LINUX_TEST_SRC([bdi_setup_and_register], [
  17                 #include <linux/backing-dev.h>
  18                 struct backing_dev_info bdi;
  19         ], [
  20                 char *name = "bdi";
  21                 int error __attribute__((unused)) =
  22                     bdi_setup_and_register(&bdi, name);
  23         ])
  24
  25         ZFS_LINUX_TEST_SRC([bdi_setup_and_register_3args], [
  26                 #include <linux/backing-dev.h>
  27                 struct backing_dev_info bdi;
  28         ], [
  29                 char *name = "bdi";
  30                 unsigned int cap = BDI_CAP_MAP_COPY;
  31                 int error __attribute__((unused)) =
  32                     bdi_setup_and_register(&bdi, name, cap);
  33         ])
  34 ])
  35
  36 AC_DEFUN([ZFS_AC_KERNEL_BDI], [
  37         dnl #
  38         dnl # 4.12, super_setup_bdi_name() introduced.
  39         dnl #
  40         AC_MSG_CHECKING([whether super_setup_bdi_name() exists])
  41         ZFS_LINUX_TEST_RESULT_SYMBOL([super_setup_bdi_name],
  42             [super_setup_bdi_name], [fs/super.c], [
  43                 AC_MSG_RESULT(yes)
  44                 AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
  45                     [super_setup_bdi_name() exits])
  46         ], [
  47                 AC_MSG_RESULT(no)
  48
  49                 dnl #
  50                 dnl # 4.0 - 4.11, bdi_setup_and_register() takes 2 arguments.
  51                 dnl #
  52                 AC_MSG_CHECKING(
  53                     [whether bdi_setup_and_register() wants 2 args])
  54                 ZFS_LINUX_TEST_RESULT_SYMBOL([bdi_setup_and_register],
  55                     [bdi_setup_and_register], [mm/backing-dev.c], [
  56                         AC_MSG_RESULT(yes)
  57                         AC_DEFINE(HAVE_2ARGS_BDI_SETUP_AND_REGISTER, 1,
  58                             [bdi_setup_and_register() wants 2 args])
  59                 ], [
  60                         AC_MSG_RESULT(no)
  61
  62                         dnl #
  63                         dnl # 2.6.34 - 3.19, bdi_setup_and_register()
  64                         dnl # takes 3 arguments.
  65                         dnl #
  66                         AC_MSG_CHECKING(
  67                             [whether bdi_setup_and_register() wants 3 args])
  68                         ZFS_LINUX_TEST_RESULT_SYMBOL(
  69                             [bdi_setup_and_register_3args],
  70                             [bdi_setup_and_register], [mm/backing-dev.c], [
  71                                 AC_MSG_RESULT(yes)
  72                                 AC_DEFINE(HAVE_3ARGS_BDI_SETUP_AND_REGISTER, 1,
  73                                     [bdi_setup_and_register() wants 3 args])
  74                         ], [
  75                                 dnl #
  76                                 dnl # 2.6.32 - 2.6.33, bdi_setup_and_register()
  77                                 dnl # is not exported.
  78                                 dnl #
  79                                 AC_MSG_RESULT(no)
  80                         ])
  81                 ])
  82         ])
  83 ])