config/kernel-is_owner_or_cap.m4

   1 dnl #
   2 dnl # 2.6.39 API change,
   3 dnl # The is_owner_or_cap() macro was renamed to inode_owner_or_capable(),
   4 dnl # This is used for permission checks in the xattr and file attribute call
   5 dnl # paths.
   6 dnl #
   7 AC_DEFUN([ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE], [
   8         ZFS_LINUX_TEST_SRC([inode_owner_or_capable], [
   9                 #include <linux/fs.h>
  10         ],[
  11                 struct inode *ip = NULL;
  12                 (void) inode_owner_or_capable(ip);
  13         ])
  14
  15         ZFS_LINUX_TEST_SRC([inode_owner_or_capable_idmapped], [
  16                 #include <linux/fs.h>
  17         ],[
  18                 struct inode *ip = NULL;
  19                 (void) inode_owner_or_capable(&init_user_ns, ip);
  20         ])
  21 ])
  22
  23 AC_DEFUN([ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE], [
  24         AC_MSG_CHECKING([whether inode_owner_or_capable() exists])
  25         ZFS_LINUX_TEST_RESULT([inode_owner_or_capable], [
  26                 AC_MSG_RESULT(yes)
  27                 AC_DEFINE(HAVE_INODE_OWNER_OR_CAPABLE, 1,
  28                     [inode_owner_or_capable() exists])
  29         ], [
  30                 AC_MSG_RESULT(no)
  31
  32                 AC_MSG_CHECKING(
  33                     [whether inode_owner_or_capable() takes user_ns])
  34                 ZFS_LINUX_TEST_RESULT([inode_owner_or_capable_idmapped], [
  35                         AC_MSG_RESULT(yes)
  36                         AC_DEFINE(HAVE_INODE_OWNER_OR_CAPABLE_IDMAPPED, 1,
  37                             [inode_owner_or_capable() takes user_ns])
  38                 ],[
  39                         ZFS_LINUX_TEST_ERROR([capability])
  40                 ])
  41         ])
  42 ])