config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         AM_COND_IF([BUILD_LINUX], [
   6                 dnl # Setup the kernel build environment.
   7                 ZFS_AC_KERNEL
   8                 ZFS_AC_QAT
   9
  10                 dnl # Sanity checks for module building and CONFIG_* defines
  11                 ZFS_AC_KERNEL_CONFIG_DEFINED
  12                 ZFS_AC_MODULE_SYMVERS
  13
  14                 dnl # Sequential ZFS_LINUX_TRY_COMPILE tests
  15                 ZFS_AC_KERNEL_FPU_HEADER
  16                 ZFS_AC_KERNEL_OBJTOOL_HEADER
  17                 ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  18                 ZFS_AC_KERNEL_MISC_MINOR
  19                 ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  20
  21                 dnl # Parallel ZFS_LINUX_TEST_SRC / ZFS_LINUX_TEST_RESULT tests
  22                 ZFS_AC_KERNEL_TEST_SRC
  23                 ZFS_AC_KERNEL_TEST_RESULT
  24
  25                 AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  26                         KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
  27                 ])
  28
  29                 AC_SUBST(KERNEL_MAKE)
  30         ])
  31 ])
  32
  33 dnl #
  34 dnl # Generate and compile all of the kernel API test cases to determine
  35 dnl # which interfaces are available.  By invoking the kernel build system
  36 dnl # only once the compilation can be done in parallel significantly
  37 dnl # speeding up the process.
  38 dnl #
  39 AC_DEFUN([ZFS_AC_KERNEL_TEST_SRC], [
  40         ZFS_AC_KERNEL_SRC_OBJTOOL
  41         ZFS_AC_KERNEL_SRC_GLOBAL_PAGE_STATE
  42         ZFS_AC_KERNEL_SRC_ACCESS_OK_TYPE
  43         ZFS_AC_KERNEL_SRC_PDE_DATA
  44         ZFS_AC_KERNEL_SRC_FALLOCATE
  45         ZFS_AC_KERNEL_SRC_FADVISE
  46         ZFS_AC_KERNEL_SRC_GENERIC_FADVISE
  47         ZFS_AC_KERNEL_SRC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  48         ZFS_AC_KERNEL_SRC_RWSEM
  49         ZFS_AC_KERNEL_SRC_SCHED
  50         ZFS_AC_KERNEL_SRC_USLEEP_RANGE
  51         ZFS_AC_KERNEL_SRC_KMEM_CACHE
  52         ZFS_AC_KERNEL_SRC_KVMALLOC
  53         ZFS_AC_KERNEL_SRC_VMALLOC_PAGE_KERNEL
  54         ZFS_AC_KERNEL_SRC_WAIT
  55         ZFS_AC_KERNEL_SRC_INODE_TIMES
  56         ZFS_AC_KERNEL_SRC_INODE_LOCK
  57         ZFS_AC_KERNEL_SRC_GROUP_INFO_GID
  58         ZFS_AC_KERNEL_SRC_RW
  59         ZFS_AC_KERNEL_SRC_TIMER_SETUP
  60         ZFS_AC_KERNEL_SRC_SUPER_USER_NS
  61         ZFS_AC_KERNEL_SRC_PROC_OPERATIONS
  62         ZFS_AC_KERNEL_SRC_BLOCK_DEVICE_OPERATIONS
  63         ZFS_AC_KERNEL_SRC_BIO
  64         ZFS_AC_KERNEL_SRC_BLKDEV
  65         ZFS_AC_KERNEL_SRC_BLK_QUEUE
  66         ZFS_AC_KERNEL_SRC_GENHD_FLAGS
  67         ZFS_AC_KERNEL_SRC_REVALIDATE_DISK
  68         ZFS_AC_KERNEL_SRC_GET_DISK_RO
  69         ZFS_AC_KERNEL_SRC_GENERIC_READLINK_GLOBAL
  70         ZFS_AC_KERNEL_SRC_DISCARD_GRANULARITY
  71         ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE
  72         ZFS_AC_KERNEL_SRC_XATTR
  73         ZFS_AC_KERNEL_SRC_ACL
  74         ZFS_AC_KERNEL_SRC_INODE_SETATTR
  75         ZFS_AC_KERNEL_SRC_INODE_GETATTR
  76         ZFS_AC_KERNEL_SRC_INODE_SET_FLAGS
  77         ZFS_AC_KERNEL_SRC_INODE_SET_IVERSION
  78         ZFS_AC_KERNEL_SRC_SHOW_OPTIONS
  79         ZFS_AC_KERNEL_SRC_FILE_INODE
  80         ZFS_AC_KERNEL_SRC_FILE_DENTRY
  81         ZFS_AC_KERNEL_SRC_FSYNC
  82         ZFS_AC_KERNEL_SRC_AIO_FSYNC
  83         ZFS_AC_KERNEL_SRC_EVICT_INODE
  84         ZFS_AC_KERNEL_SRC_DIRTY_INODE
  85         ZFS_AC_KERNEL_SRC_SHRINKER
  86         ZFS_AC_KERNEL_SRC_MKDIR
  87         ZFS_AC_KERNEL_SRC_LOOKUP_FLAGS
  88         ZFS_AC_KERNEL_SRC_CREATE
  89         ZFS_AC_KERNEL_SRC_PERMISSION
  90         ZFS_AC_KERNEL_SRC_GET_LINK
  91         ZFS_AC_KERNEL_SRC_PUT_LINK
  92         ZFS_AC_KERNEL_SRC_TMPFILE
  93         ZFS_AC_KERNEL_SRC_AUTOMOUNT
  94         ZFS_AC_KERNEL_SRC_ENCODE_FH_WITH_INODE
  95         ZFS_AC_KERNEL_SRC_COMMIT_METADATA
  96         ZFS_AC_KERNEL_SRC_CLEAR_INODE
  97         ZFS_AC_KERNEL_SRC_SETATTR_PREPARE
  98         ZFS_AC_KERNEL_SRC_INSERT_INODE_LOCKED
  99         ZFS_AC_KERNEL_SRC_DENTRY
 100         ZFS_AC_KERNEL_SRC_DENTRY_ALIAS_D_U
 101         ZFS_AC_KERNEL_SRC_TRUNCATE_SETSIZE
 102         ZFS_AC_KERNEL_SRC_SECURITY_INODE
 103         ZFS_AC_KERNEL_SRC_FST_MOUNT
 104         ZFS_AC_KERNEL_SRC_BDI
 105         ZFS_AC_KERNEL_SRC_SET_NLINK
 106         ZFS_AC_KERNEL_SRC_SGET
 107         ZFS_AC_KERNEL_SRC_LSEEK_EXECUTE
 108         ZFS_AC_KERNEL_SRC_VFS_FILEMAP_DIRTY_FOLIO
 109         ZFS_AC_KERNEL_SRC_VFS_READ_FOLIO
 110         ZFS_AC_KERNEL_SRC_VFS_GETATTR
 111         ZFS_AC_KERNEL_SRC_VFS_FSYNC_2ARGS
 112         ZFS_AC_KERNEL_SRC_VFS_ITERATE
 113         ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO
 114         ZFS_AC_KERNEL_SRC_VFS_READPAGES
 115         ZFS_AC_KERNEL_SRC_VFS_SET_PAGE_DIRTY_NOBUFFERS
 116         ZFS_AC_KERNEL_SRC_VFS_RW_ITERATE
 117         ZFS_AC_KERNEL_SRC_VFS_GENERIC_WRITE_CHECKS
 118         ZFS_AC_KERNEL_SRC_VFS_IOV_ITER
 119         ZFS_AC_KERNEL_SRC_VFS_COPY_FILE_RANGE
 120         ZFS_AC_KERNEL_SRC_VFS_GENERIC_COPY_FILE_RANGE
 121         ZFS_AC_KERNEL_SRC_VFS_SPLICE_COPY_FILE_RANGE
 122         ZFS_AC_KERNEL_SRC_VFS_REMAP_FILE_RANGE
 123         ZFS_AC_KERNEL_SRC_VFS_CLONE_FILE_RANGE
 124         ZFS_AC_KERNEL_SRC_VFS_DEDUPE_FILE_RANGE
 125         ZFS_AC_KERNEL_SRC_VFS_FILE_OPERATIONS_EXTEND
 126         ZFS_AC_KERNEL_SRC_KMAP_ATOMIC_ARGS
 127         ZFS_AC_KERNEL_SRC_FOLLOW_DOWN_ONE
 128         ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN
 129         ZFS_AC_KERNEL_SRC_GENERIC_IO_ACCT
 130         ZFS_AC_KERNEL_SRC_FPU
 131         ZFS_AC_KERNEL_SRC_FMODE_T
 132         ZFS_AC_KERNEL_SRC_KUIDGID_T
 133         ZFS_AC_KERNEL_SRC_KUID_HELPERS
 134         ZFS_AC_KERNEL_SRC_RENAME
 135         ZFS_AC_KERNEL_SRC_CURRENT_TIME
 136         ZFS_AC_KERNEL_SRC_USERNS_CAPABILITIES
 137         ZFS_AC_KERNEL_SRC_IN_COMPAT_SYSCALL
 138         ZFS_AC_KERNEL_SRC_KTIME
 139         ZFS_AC_KERNEL_SRC_TOTALRAM_PAGES_FUNC
 140         ZFS_AC_KERNEL_SRC_TOTALHIGH_PAGES
 141         ZFS_AC_KERNEL_SRC_KSTRTOUL
 142         ZFS_AC_KERNEL_SRC_PERCPU
 143         ZFS_AC_KERNEL_SRC_CPU_HOTPLUG
 144         ZFS_AC_KERNEL_SRC_GENERIC_FILLATTR
 145         ZFS_AC_KERNEL_SRC_MKNOD
 146         ZFS_AC_KERNEL_SRC_SYMLINK
 147         ZFS_AC_KERNEL_SRC_BIO_MAX_SEGS
 148         ZFS_AC_KERNEL_SRC_SIGNAL_STOP
 149         ZFS_AC_KERNEL_SRC_SIGINFO
 150         ZFS_AC_KERNEL_SRC_SYSFS
 151         ZFS_AC_KERNEL_SRC_SET_SPECIAL_STATE
 152         ZFS_AC_KERNEL_SRC_STANDALONE_LINUX_STDARG
 153         ZFS_AC_KERNEL_SRC_STRLCPY
 154         ZFS_AC_KERNEL_SRC_STRSCPY
 155         ZFS_AC_KERNEL_SRC_PAGEMAP_FOLIO_WAIT_BIT
 156         ZFS_AC_KERNEL_SRC_ADD_DISK
 157         ZFS_AC_KERNEL_SRC_KTHREAD
 158         ZFS_AC_KERNEL_SRC_ZERO_PAGE
 159         ZFS_AC_KERNEL_SRC___COPY_FROM_USER_INATOMIC
 160         ZFS_AC_KERNEL_SRC_USER_NS_COMMON_INUM
 161         ZFS_AC_KERNEL_SRC_IDMAP_MNT_API
 162         ZFS_AC_KERNEL_SRC_IDMAP_NO_USERNS
 163         ZFS_AC_KERNEL_SRC_IATTR_VFSID
 164         ZFS_AC_KERNEL_SRC_FILEMAP
 165         ZFS_AC_KERNEL_SRC_WRITEPAGE_T
 166         ZFS_AC_KERNEL_SRC_RECLAIMED
 167         ZFS_AC_KERNEL_SRC_REGISTER_SYSCTL_TABLE
 168         ZFS_AC_KERNEL_SRC_COPY_SPLICE_READ
 169         ZFS_AC_KERNEL_SRC_SYNC_BDEV
 170         ZFS_AC_KERNEL_SRC_MM_PAGE_SIZE
 171         case "$host_cpu" in
 172                 powerpc*)
 173                         ZFS_AC_KERNEL_SRC_CPU_HAS_FEATURE
 174                         ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
 175                         ;;
 176                 riscv*)
 177                         ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
 178                         ;;
 179         esac
 180
 181         AC_MSG_CHECKING([for available kernel interfaces])
 182         ZFS_LINUX_TEST_COMPILE_ALL([kabi])
 183         AC_MSG_RESULT([done])
 184 ])
 185
 186 dnl #
 187 dnl # Check results of kernel interface tests.
 188 dnl #
 189 AC_DEFUN([ZFS_AC_KERNEL_TEST_RESULT], [
 190         ZFS_AC_KERNEL_ACCESS_OK_TYPE
 191         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 192         ZFS_AC_KERNEL_OBJTOOL
 193         ZFS_AC_KERNEL_PDE_DATA
 194         ZFS_AC_KERNEL_FALLOCATE
 195         ZFS_AC_KERNEL_FADVISE
 196         ZFS_AC_KERNEL_GENERIC_FADVISE
 197         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
 198         ZFS_AC_KERNEL_RWSEM
 199         ZFS_AC_KERNEL_SCHED
 200         ZFS_AC_KERNEL_USLEEP_RANGE
 201         ZFS_AC_KERNEL_KMEM_CACHE
 202         ZFS_AC_KERNEL_KVMALLOC
 203         ZFS_AC_KERNEL_VMALLOC_PAGE_KERNEL
 204         ZFS_AC_KERNEL_WAIT
 205         ZFS_AC_KERNEL_INODE_TIMES
 206         ZFS_AC_KERNEL_INODE_LOCK
 207         ZFS_AC_KERNEL_GROUP_INFO_GID
 208         ZFS_AC_KERNEL_RW
 209         ZFS_AC_KERNEL_TIMER_SETUP
 210         ZFS_AC_KERNEL_SUPER_USER_NS
 211         ZFS_AC_KERNEL_PROC_OPERATIONS
 212         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS
 213         ZFS_AC_KERNEL_BIO
 214         ZFS_AC_KERNEL_BLKDEV
 215         ZFS_AC_KERNEL_BLK_QUEUE
 216         ZFS_AC_KERNEL_GENHD_FLAGS
 217         ZFS_AC_KERNEL_REVALIDATE_DISK
 218         ZFS_AC_KERNEL_GET_DISK_RO
 219         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
 220         ZFS_AC_KERNEL_DISCARD_GRANULARITY
 221         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
 222         ZFS_AC_KERNEL_XATTR
 223         ZFS_AC_KERNEL_ACL
 224         ZFS_AC_KERNEL_INODE_SETATTR
 225         ZFS_AC_KERNEL_INODE_GETATTR
 226         ZFS_AC_KERNEL_INODE_SET_FLAGS
 227         ZFS_AC_KERNEL_INODE_SET_IVERSION
 228         ZFS_AC_KERNEL_SHOW_OPTIONS
 229         ZFS_AC_KERNEL_FILE_INODE
 230         ZFS_AC_KERNEL_FILE_DENTRY
 231         ZFS_AC_KERNEL_FSYNC
 232         ZFS_AC_KERNEL_AIO_FSYNC
 233         ZFS_AC_KERNEL_EVICT_INODE
 234         ZFS_AC_KERNEL_DIRTY_INODE
 235         ZFS_AC_KERNEL_SHRINKER
 236         ZFS_AC_KERNEL_MKDIR
 237         ZFS_AC_KERNEL_LOOKUP_FLAGS
 238         ZFS_AC_KERNEL_CREATE
 239         ZFS_AC_KERNEL_PERMISSION
 240         ZFS_AC_KERNEL_GET_LINK
 241         ZFS_AC_KERNEL_PUT_LINK
 242         ZFS_AC_KERNEL_TMPFILE
 243         ZFS_AC_KERNEL_AUTOMOUNT
 244         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 245         ZFS_AC_KERNEL_COMMIT_METADATA
 246         ZFS_AC_KERNEL_CLEAR_INODE
 247         ZFS_AC_KERNEL_SETATTR_PREPARE
 248         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 249         ZFS_AC_KERNEL_DENTRY
 250         ZFS_AC_KERNEL_DENTRY_ALIAS_D_U
 251         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 252         ZFS_AC_KERNEL_SECURITY_INODE
 253         ZFS_AC_KERNEL_FST_MOUNT
 254         ZFS_AC_KERNEL_BDI
 255         ZFS_AC_KERNEL_SET_NLINK
 256         ZFS_AC_KERNEL_SGET
 257         ZFS_AC_KERNEL_LSEEK_EXECUTE
 258         ZFS_AC_KERNEL_VFS_FILEMAP_DIRTY_FOLIO
 259         ZFS_AC_KERNEL_VFS_READ_FOLIO
 260         ZFS_AC_KERNEL_VFS_GETATTR
 261         ZFS_AC_KERNEL_VFS_FSYNC_2ARGS
 262         ZFS_AC_KERNEL_VFS_ITERATE
 263         ZFS_AC_KERNEL_VFS_DIRECT_IO
 264         ZFS_AC_KERNEL_VFS_READPAGES
 265         ZFS_AC_KERNEL_VFS_SET_PAGE_DIRTY_NOBUFFERS
 266         ZFS_AC_KERNEL_VFS_RW_ITERATE
 267         ZFS_AC_KERNEL_VFS_GENERIC_WRITE_CHECKS
 268         ZFS_AC_KERNEL_VFS_IOV_ITER
 269         ZFS_AC_KERNEL_VFS_COPY_FILE_RANGE
 270         ZFS_AC_KERNEL_VFS_GENERIC_COPY_FILE_RANGE
 271         ZFS_AC_KERNEL_VFS_SPLICE_COPY_FILE_RANGE
 272         ZFS_AC_KERNEL_VFS_REMAP_FILE_RANGE
 273         ZFS_AC_KERNEL_VFS_CLONE_FILE_RANGE
 274         ZFS_AC_KERNEL_VFS_DEDUPE_FILE_RANGE
 275         ZFS_AC_KERNEL_VFS_FILE_OPERATIONS_EXTEND
 276         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 277         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 278         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 279         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 280         ZFS_AC_KERNEL_FPU
 281         ZFS_AC_KERNEL_FMODE_T
 282         ZFS_AC_KERNEL_KUIDGID_T
 283         ZFS_AC_KERNEL_KUID_HELPERS
 284         ZFS_AC_KERNEL_RENAME
 285         ZFS_AC_KERNEL_CURRENT_TIME
 286         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 287         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 288         ZFS_AC_KERNEL_KTIME
 289         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 290         ZFS_AC_KERNEL_TOTALHIGH_PAGES
 291         ZFS_AC_KERNEL_KSTRTOUL
 292         ZFS_AC_KERNEL_PERCPU
 293         ZFS_AC_KERNEL_CPU_HOTPLUG
 294         ZFS_AC_KERNEL_GENERIC_FILLATTR
 295         ZFS_AC_KERNEL_MKNOD
 296         ZFS_AC_KERNEL_SYMLINK
 297         ZFS_AC_KERNEL_BIO_MAX_SEGS
 298         ZFS_AC_KERNEL_SIGNAL_STOP
 299         ZFS_AC_KERNEL_SIGINFO
 300         ZFS_AC_KERNEL_SYSFS
 301         ZFS_AC_KERNEL_SET_SPECIAL_STATE
 302         ZFS_AC_KERNEL_STANDALONE_LINUX_STDARG
 303         ZFS_AC_KERNEL_STRLCPY
 304         ZFS_AC_KERNEL_STRSCPY
 305         ZFS_AC_KERNEL_PAGEMAP_FOLIO_WAIT_BIT
 306         ZFS_AC_KERNEL_ADD_DISK
 307         ZFS_AC_KERNEL_KTHREAD
 308         ZFS_AC_KERNEL_ZERO_PAGE
 309         ZFS_AC_KERNEL___COPY_FROM_USER_INATOMIC
 310         ZFS_AC_KERNEL_USER_NS_COMMON_INUM
 311         ZFS_AC_KERNEL_IDMAP_MNT_API
 312         ZFS_AC_KERNEL_IDMAP_NO_USERNS
 313         ZFS_AC_KERNEL_IATTR_VFSID
 314         ZFS_AC_KERNEL_FILEMAP
 315         ZFS_AC_KERNEL_WRITEPAGE_T
 316         ZFS_AC_KERNEL_RECLAIMED
 317         ZFS_AC_KERNEL_REGISTER_SYSCTL_TABLE
 318         ZFS_AC_KERNEL_COPY_SPLICE_READ
 319         ZFS_AC_KERNEL_SYNC_BDEV
 320         ZFS_AC_KERNEL_MM_PAGE_SIZE
 321         case "$host_cpu" in
 322                 powerpc*)
 323                         ZFS_AC_KERNEL_CPU_HAS_FEATURE
 324                         ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
 325                         ;;
 326                 riscv*)
 327                         ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
 328                         ;;
 329         esac
 330 ])
 331
 332 dnl #
 333 dnl # Detect name used for Module.symvers file in kernel
 334 dnl #
 335 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 336         modpost=$LINUX/scripts/Makefile.modpost
 337         AC_MSG_CHECKING([kernel file name for module symbols])
 338         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 339                 AS_IF([grep -q Modules.symvers $modpost], [
 340                         LINUX_SYMBOLS=Modules.symvers
 341                 ], [
 342                         LINUX_SYMBOLS=Module.symvers
 343                 ])
 344
 345                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 346                         AC_MSG_ERROR([
 347         *** Please make sure the kernel devel package for your distribution
 348         *** is installed.  If you are building with a custom kernel, make sure
 349         *** the kernel is configured, built, and the '--with-linux=PATH'
 350         *** configure option refers to the location of the kernel source.
 351                         ])
 352                 ])
 353         ], [
 354                 LINUX_SYMBOLS=NONE
 355         ])
 356         AC_MSG_RESULT($LINUX_SYMBOLS)
 357         AC_SUBST(LINUX_SYMBOLS)
 358 ])
 359
 360 dnl #
 361 dnl # Detect the kernel to be built against
 362 dnl #
 363 dnl # Most modern Linux distributions have separate locations for bare
 364 dnl # source (source) and prebuilt (build) files. Additionally, there are
 365 dnl # `source` and `build` symlinks in `/lib/modules/$(KERNEL_VERSION)`
 366 dnl # pointing to them. The directory search order is now:
 367 dnl #
 368 dnl # - `configure` command line values if both `--with-linux` and
 369 dnl #   `--with-linux-obj` were defined
 370 dnl #
 371 dnl # - If only `--with-linux` was defined, `--with-linux-obj` is assumed
 372 dnl #   to have the same value as `--with-linux`
 373 dnl #
 374 dnl # - If neither `--with-linux` nor `--with-linux-obj` were defined
 375 dnl #   autodetection is used:
 376 dnl #
 377 dnl #   - `/lib/modules/$(uname -r)/{source,build}` respectively, if exist.
 378 dnl #
 379 dnl #   - If only `/lib/modules/$(uname -r)/build` exists, it is assumed
 380 dnl #     to be both source and build directory.
 381 dnl #
 382 dnl #   - The first directory in `/lib/modules` with the highest version
 383 dnl #     number according to `sort -V` which contains both `source` and
 384 dnl #     `build` symlinks/directories. If module directory contains only
 385 dnl #     `build` component, it is assumed to be both source and build
 386 dnl #     directory.
 387 dnl #
 388 dnl #   - Last resort: the first directory matching `/usr/src/kernels/*`
 389 dnl #     and `/usr/src/linux-*` with the highest version number according
 390 dnl #     to `sort -V` is assumed to be both source and build directory.
 391 dnl #
 392 AC_DEFUN([ZFS_AC_KERNEL], [
 393         AC_ARG_WITH([linux],
 394                 AS_HELP_STRING([--with-linux=PATH],
 395                 [Path to kernel source]),
 396                 [kernelsrc="$withval"])
 397
 398         AC_ARG_WITH(linux-obj,
 399                 AS_HELP_STRING([--with-linux-obj=PATH],
 400                 [Path to kernel build objects]),
 401                 [kernelbuild="$withval"])
 402
 403         AC_MSG_CHECKING([kernel source and build directories])
 404         AS_IF([test -n "$kernelsrc" && test -z "$kernelbuild"], [
 405                 kernelbuild="$kernelsrc"
 406         ], [test -z "$kernelsrc"], [
 407                 AS_IF([test -e "/lib/modules/$(uname -r)/source" && \
 408                        test -e "/lib/modules/$(uname -r)/build"], [
 409                         src="/lib/modules/$(uname -r)/source"
 410                         build="/lib/modules/$(uname -r)/build"
 411                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 412                         build="/lib/modules/$(uname -r)/build"
 413                         src="$build"
 414                 ], [
 415                         src=
 416
 417                         for d in $(ls -1d /lib/modules/* 2>/dev/null | sort -Vr); do
 418                                 if test -e "$d/source" && test -e "$d/build"; then
 419                                         src="$d/source"
 420                                         build="$d/build"
 421                                         break
 422                                 fi
 423
 424                                 if test -e "$d/build"; then
 425                                         src="$d/build"
 426                                         build="$d/build"
 427                                         break
 428                                 fi
 429                         done
 430
 431                         # the least reliable method
 432                         if test -z "$src"; then
 433                                 src=$(ls -1d /usr/src/kernels/* /usr/src/linux-* \
 434                                       2>/dev/null | grep -v obj | sort -Vr | head -1)
 435                                 build="$src"
 436                         fi
 437                 ])
 438
 439                 AS_IF([test -n "$src" && test -e "$src"], [
 440                         kernelsrc=$(readlink -e "$src")
 441                 ], [
 442                         kernelsrc="[Not found]"
 443                 ])
 444                 AS_IF([test -n "$build" && test -e "$build"], [
 445                         kernelbuild=$(readlink -e "$build")
 446                 ], [
 447                         kernelbuild="[Not found]"
 448                 ])
 449         ], [
 450                 AS_IF([test "$kernelsrc" = "NONE"], [
 451                         kernsrcver=NONE
 452                 ])
 453                 withlinux=yes
 454         ])
 455
 456         AC_MSG_RESULT([done])
 457         AC_MSG_CHECKING([kernel source directory])
 458         AC_MSG_RESULT([$kernelsrc])
 459         AC_MSG_CHECKING([kernel build directory])
 460         AC_MSG_RESULT([$kernelbuild])
 461         AS_IF([test ! -d "$kernelsrc" || test ! -d "$kernelbuild"], [
 462                 AC_MSG_ERROR([
 463         *** Please make sure the kernel devel package for your distribution
 464         *** is installed and then try again.  If that fails, you can specify the
 465         *** location of the kernel source and build with the '--with-linux=PATH' and
 466         *** '--with-linux-obj=PATH' options respectively.])
 467         ])
 468
 469         AC_MSG_CHECKING([kernel source version])
 470         utsrelease1=$kernelbuild/include/linux/version.h
 471         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 472         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 473         AS_IF([test -r $utsrelease1 && grep -qF UTS_RELEASE $utsrelease1], [
 474                 utsrelease=$utsrelease1
 475         ], [test -r $utsrelease2 && grep -qF UTS_RELEASE $utsrelease2], [
 476                 utsrelease=$utsrelease2
 477         ], [test -r $utsrelease3 && grep -qF UTS_RELEASE $utsrelease3], [
 478                 utsrelease=$utsrelease3
 479         ])
 480
 481         AS_IF([test -n "$utsrelease"], [
 482                 kernsrcver=$($AWK '/UTS_RELEASE/ { gsub(/"/, "", $[3]); print $[3] }' $utsrelease)
 483                 AS_IF([test -z "$kernsrcver"], [
 484                         AC_MSG_RESULT([Not found])
 485                         AC_MSG_ERROR([
 486         *** Cannot determine kernel version.
 487                         ])
 488                 ])
 489         ], [
 490                 AC_MSG_RESULT([Not found])
 491                 if test "x$enable_linux_builtin" != xyes; then
 492                         AC_MSG_ERROR([
 493         *** Cannot find UTS_RELEASE definition.
 494                         ])
 495                 else
 496                         AC_MSG_ERROR([
 497         *** Cannot find UTS_RELEASE definition.
 498         *** Please run 'make prepare' inside the kernel source tree.])
 499                 fi
 500         ])
 501
 502         AC_MSG_RESULT([$kernsrcver])
 503
 504         AS_VERSION_COMPARE([$kernsrcver], [$ZFS_META_KVER_MIN], [
 505                  AC_MSG_ERROR([
 506         *** Cannot build against kernel version $kernsrcver.
 507         *** The minimum supported kernel version is $ZFS_META_KVER_MIN.
 508                 ])
 509         ])
 510
 511         LINUX=${kernelsrc}
 512         LINUX_OBJ=${kernelbuild}
 513         LINUX_VERSION=${kernsrcver}
 514
 515         AC_SUBST(LINUX)
 516         AC_SUBST(LINUX_OBJ)
 517         AC_SUBST(LINUX_VERSION)
 518 ])
 519
 520 dnl #
 521 dnl # Detect the QAT module to be built against, QAT provides hardware
 522 dnl # acceleration for data compression:
 523 dnl #
 524 dnl # https://01.org/intel-quickassist-technology
 525 dnl #
 526 dnl # 1) Download and install QAT driver from the above link
 527 dnl # 2) Start QAT driver in your system:
 528 dnl #    service qat_service start
 529 dnl # 3) Enable QAT in ZFS, e.g.:
 530 dnl #    ./configure --with-qat=<qat-driver-path>/QAT1.6
 531 dnl #    make
 532 dnl # 4) Set GZIP compression in ZFS dataset:
 533 dnl #    zfs set compression = gzip <dataset>
 534 dnl #
 535 dnl # Then the data written to this ZFS pool is compressed by QAT accelerator
 536 dnl # automatically, and de-compressed by QAT when read from the pool.
 537 dnl #
 538 dnl # 1) Get QAT hardware statistics with:
 539 dnl #    cat /proc/icp_dh895xcc_dev/qat
 540 dnl # 2) To disable QAT:
 541 dnl #    insmod zfs.ko zfs_qat_disable=1
 542 dnl #
 543 AC_DEFUN([ZFS_AC_QAT], [
 544         AC_ARG_WITH([qat],
 545                 AS_HELP_STRING([--with-qat=PATH],
 546                 [Path to qat source]),
 547                 AS_IF([test "$withval" = "yes"],
 548                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 549                         [qatsrc="$withval"]))
 550
 551         AC_ARG_WITH([qat-obj],
 552                 AS_HELP_STRING([--with-qat-obj=PATH],
 553                 [Path to qat build objects]),
 554                 [qatbuild="$withval"])
 555
 556         AS_IF([test ! -z "${qatsrc}"], [
 557                 AC_MSG_CHECKING([qat source directory])
 558                 AC_MSG_RESULT([$qatsrc])
 559                 QAT_SRC="${qatsrc}/quickassist"
 560                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 561                         AC_MSG_ERROR([
 562         *** Please make sure the qat driver package is installed
 563         *** and specify the location of the qat source with the
 564         *** '--with-qat=PATH' option then try again. Failed to
 565         *** find cpa.h in:
 566         ${QAT_SRC}/include])
 567                 ])
 568         ])
 569
 570         AS_IF([test ! -z "${qatsrc}"], [
 571                 AC_MSG_CHECKING([qat build directory])
 572                 AS_IF([test -z "$qatbuild"], [
 573                         qatbuild="${qatsrc}/build"
 574                 ])
 575
 576                 AC_MSG_RESULT([$qatbuild])
 577                 QAT_OBJ=${qatbuild}
 578                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 579                         AC_MSG_ERROR([
 580         *** Please make sure the qat driver is installed then try again.
 581         *** Failed to find icp_qa_al.ko or qat_api.ko in:
 582         $QAT_OBJ])
 583                 ])
 584
 585                 AC_SUBST(QAT_SRC)
 586                 AC_SUBST(QAT_OBJ)
 587
 588                 AC_DEFINE(HAVE_QAT, 1,
 589                 [qat is enabled and existed])
 590         ])
 591
 592         dnl #
 593         dnl # Detect the name used for the QAT Module.symvers file.
 594         dnl #
 595         AS_IF([test ! -z "${qatsrc}"], [
 596                 AC_MSG_CHECKING([qat file for module symbols])
 597                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 598
 599                 AS_IF([test -r $QAT_SYMBOLS], [
 600                         AC_MSG_RESULT([$QAT_SYMBOLS])
 601                         AC_SUBST(QAT_SYMBOLS)
 602                 ],[
 603                         AC_MSG_ERROR([
 604         *** Please make sure the qat driver is installed then try again.
 605         *** Failed to find Module.symvers in:
 606         $QAT_SYMBOLS
 607                         ])
 608                 ])
 609         ])
 610 ])
 611
 612 dnl #
 613 dnl # ZFS_LINUX_CONFTEST_H
 614 dnl #
 615 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 616 test -d build/$2 || mkdir -p build/$2
 617 cat - <<_ACEOF >build/$2/$2.h
 618 $1
 619 _ACEOF
 620 ])
 621
 622 dnl #
 623 dnl # ZFS_LINUX_CONFTEST_C
 624 dnl #
 625 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 626 test -d build/$2 || mkdir -p build/$2
 627 cat confdefs.h - <<_ACEOF >build/$2/$2.c
 628 $1
 629 _ACEOF
 630 ])
 631
 632 dnl #
 633 dnl # ZFS_LINUX_CONFTEST_MAKEFILE
 634 dnl #
 635 dnl # $1 - test case name
 636 dnl # $2 - add to top-level Makefile
 637 dnl # $3 - additional build flags
 638 dnl #
 639 AC_DEFUN([ZFS_LINUX_CONFTEST_MAKEFILE], [
 640         test -d build || mkdir -p build
 641         test -d build/$1 || mkdir -p build/$1
 642
 643         file=build/$1/Makefile
 644
 645         dnl # Example command line to manually build source.
 646         cat - <<_ACEOF >$file
 647 # Example command line to manually build source
 648 # make modules -C $LINUX_OBJ $ARCH_UM M=$PWD/build/$1
 649
 650 ccflags-y := -Werror $FRAME_LARGER_THAN
 651 _ACEOF
 652
 653         dnl # Additional custom CFLAGS as requested.
 654         m4_ifval($3, [echo "ccflags-y += $3" >>$file], [])
 655
 656         dnl # Test case source
 657         echo "obj-m := $1.o" >>$file
 658
 659         AS_IF([test "x$2" = "xyes"], [echo "obj-m += $1/" >>build/Makefile], [])
 660 ])
 661
 662 dnl #
 663 dnl # ZFS_LINUX_TEST_PROGRAM(C)([PROLOGUE], [BODY])
 664 dnl #
 665 m4_define([ZFS_LINUX_TEST_PROGRAM], [
 666 #include <linux/module.h>
 667 $1
 668
 669 int
 670 main (void)
 671 {
 672 $2
 673         ;
 674         return 0;
 675 }
 676
 677 MODULE_DESCRIPTION("conftest");
 678 MODULE_AUTHOR(ZFS_META_AUTHOR);
 679 MODULE_VERSION(ZFS_META_VERSION "-" ZFS_META_RELEASE);
 680 MODULE_LICENSE($3);
 681 ])
 682
 683 dnl #
 684 dnl # ZFS_LINUX_TEST_REMOVE
 685 dnl #
 686 dnl # Removes the specified test source and results.
 687 dnl #
 688 AC_DEFUN([ZFS_LINUX_TEST_REMOVE], [
 689         test -d build/$1 && rm -Rf build/$1
 690         test -f build/Makefile && sed '/$1/d' build/Makefile
 691 ])
 692
 693 dnl #
 694 dnl # ZFS_LINUX_COMPILE
 695 dnl #
 696 dnl # $1 - build dir
 697 dnl # $2 - test command
 698 dnl # $3 - pass command
 699 dnl # $4 - fail command
 700 dnl # $5 - set KBUILD_MODPOST_NOFINAL='yes'
 701 dnl # $6 - set KBUILD_MODPOST_WARN='yes'
 702 dnl #
 703 dnl # Used internally by ZFS_LINUX_TEST_{COMPILE,MODPOST}
 704 dnl #
 705 AC_DEFUN([ZFS_LINUX_COMPILE], [
 706         AC_ARG_VAR([KERNEL_CC], [C compiler for
 707                 building kernel modules])
 708         AC_ARG_VAR([KERNEL_LD], [Linker for
 709                 building kernel modules])
 710         AC_ARG_VAR([KERNEL_LLVM], [Binary option to
 711                 build kernel modules with LLVM/CLANG toolchain])
 712         AC_TRY_COMMAND([
 713             KBUILD_MODPOST_NOFINAL="$5" KBUILD_MODPOST_WARN="$6"
 714             make modules -k -j$TEST_JOBS ${KERNEL_CC:+CC=$KERNEL_CC}
 715             ${KERNEL_LD:+LD=$KERNEL_LD} ${KERNEL_LLVM:+LLVM=$KERNEL_LLVM}
 716             CONFIG_MODULES=y CFLAGS_MODULE=-DCONFIG_MODULES
 717             -C $LINUX_OBJ $ARCH_UM M=$PWD/$1 >$1/build.log 2>&1])
 718         AS_IF([AC_TRY_COMMAND([$2])], [$3], [$4])
 719 ])
 720
 721 dnl #
 722 dnl # ZFS_LINUX_TEST_COMPILE
 723 dnl #
 724 dnl # Perform a full compile excluding the final modpost phase.
 725 dnl #
 726 AC_DEFUN([ZFS_LINUX_TEST_COMPILE], [
 727         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 728                 mv $2/Makefile $2/Makefile.compile.$1
 729                 mv $2/build.log $2/build.log.$1
 730         ],[
 731                 AC_MSG_ERROR([
 732         *** Unable to compile test source to determine kernel interfaces.])
 733         ], [yes], [])
 734 ])
 735
 736 dnl #
 737 dnl # ZFS_LINUX_TEST_MODPOST
 738 dnl #
 739 dnl # Perform a full compile including the modpost phase.  This may
 740 dnl # be an incremental build if the objects have already been built.
 741 dnl #
 742 AC_DEFUN([ZFS_LINUX_TEST_MODPOST], [
 743         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 744                 mv $2/Makefile $2/Makefile.modpost.$1
 745                 cat $2/build.log >>build/build.log.$1
 746         ],[
 747                 AC_MSG_ERROR([
 748         *** Unable to modpost test source to determine kernel interfaces.])
 749         ], [], [yes])
 750 ])
 751
 752 dnl #
 753 dnl # Perform the compilation of the test cases in two phases.
 754 dnl #
 755 dnl # Phase 1) attempt to build the object files for all of the tests
 756 dnl #          defined by the ZFS_LINUX_TEST_SRC macro.  But do not
 757 dnl #          perform the final modpost stage.
 758 dnl #
 759 dnl # Phase 2) disable all tests which failed the initial compilation,
 760 dnl #          then invoke the final modpost step for the remaining tests.
 761 dnl #
 762 dnl # This allows us efficiently build the test cases in parallel while
 763 dnl # remaining resilient to build failures which are expected when
 764 dnl # detecting the available kernel interfaces.
 765 dnl #
 766 dnl # The maximum allowed parallelism can be controlled by setting the
 767 dnl # TEST_JOBS environment variable.  Otherwise, it default to $(nproc).
 768 dnl #
 769 AC_DEFUN([ZFS_LINUX_TEST_COMPILE_ALL], [
 770         dnl # Phase 1 - Compilation only, final linking is skipped.
 771         ZFS_LINUX_TEST_COMPILE([$1], [build])
 772
 773         dnl #
 774         dnl # Phase 2 - When building external modules disable test cases
 775         dnl # which failed to compile and invoke modpost to verify the
 776         dnl # final linking.
 777         dnl #
 778         dnl # Test names suffixed with '_license' call modpost independently
 779         dnl # to ensure that a single incompatibility does not result in the
 780         dnl # modpost phase exiting early.  This check is not performed on
 781         dnl # every symbol since the majority are compatible and doing so
 782         dnl # would significantly slow down this phase.
 783         dnl #
 784         dnl # When configuring for builtin (--enable-linux-builtin)
 785         dnl # fake the linking step artificially create the expected .ko
 786         dnl # files for tests which did compile.  This is required for
 787         dnl # kernels which do not have loadable module support or have
 788         dnl # not yet been built.
 789         dnl #
 790         AS_IF([test "x$enable_linux_builtin" = "xno"], [
 791                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 792                     build/Makefile.compile.$1); do
 793                         name=${dir%/}
 794                         AS_IF([test -f build/$name/$name.o], [
 795                                 AS_IF([test "${name##*_}" = "license"], [
 796                                         ZFS_LINUX_TEST_MODPOST([$1],
 797                                             [build/$name])
 798                                         echo "obj-n += $dir" >>build/Makefile
 799                                 ], [
 800                                         echo "obj-m += $dir" >>build/Makefile
 801                                 ])
 802                         ], [
 803                                 echo "obj-n += $dir" >>build/Makefile
 804                         ])
 805                 done
 806
 807                 ZFS_LINUX_TEST_MODPOST([$1], [build])
 808         ], [
 809                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 810                     build/Makefile.compile.$1); do
 811                         name=${dir%/}
 812                         AS_IF([test -f build/$name/$name.o], [
 813                                 touch build/$name/$name.ko
 814                         ])
 815                 done
 816         ])
 817 ])
 818
 819 dnl #
 820 dnl # ZFS_LINUX_TEST_SRC
 821 dnl #
 822 dnl # $1 - name
 823 dnl # $2 - global
 824 dnl # $3 - source
 825 dnl # $4 - extra cflags
 826 dnl # $5 - check license-compatibility
 827 dnl #
 828 dnl # Check if the test source is buildable at all and then if it is
 829 dnl # license compatible.
 830 dnl #
 831 dnl # N.B because all of the test cases are compiled in parallel they
 832 dnl # must never depend on the results of previous tests.  Each test
 833 dnl # needs to be entirely independent.
 834 dnl #
 835 AC_DEFUN([ZFS_LINUX_TEST_SRC], [
 836         ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM([[$2]], [[$3]],
 837             [["Dual BSD/GPL"]])], [$1])
 838         ZFS_LINUX_CONFTEST_MAKEFILE([$1], [yes], [$4])
 839
 840         AS_IF([ test -n "$5" ], [
 841                 ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM(
 842                     [[$2]], [[$3]], [[$5]])], [$1_license])
 843                 ZFS_LINUX_CONFTEST_MAKEFILE([$1_license], [yes], [$4])
 844         ])
 845 ])
 846
 847 dnl #
 848 dnl # ZFS_LINUX_TEST_RESULT
 849 dnl #
 850 dnl # $1 - name of a test source (ZFS_LINUX_TEST_SRC)
 851 dnl # $2 - run on success (valid .ko generated)
 852 dnl # $3 - run on failure (unable to compile)
 853 dnl #
 854 AC_DEFUN([ZFS_LINUX_TEST_RESULT], [
 855         AS_IF([test -d build/$1], [
 856                 AS_IF([test -f build/$1/$1.ko], [$2], [$3])
 857         ], [
 858                 AC_MSG_ERROR([
 859         *** No matching source for the "$1" test, check that
 860         *** both the test source and result macros refer to the same name.
 861                 ])
 862         ])
 863 ])
 864
 865 dnl #
 866 dnl # ZFS_LINUX_TEST_ERROR
 867 dnl #
 868 dnl # Generic error message which can be used when none of the expected
 869 dnl # kernel interfaces were detected.
 870 dnl #
 871 AC_DEFUN([ZFS_LINUX_TEST_ERROR], [
 872         AC_MSG_ERROR([
 873         *** None of the expected "$1" interfaces were detected.
 874         *** This may be because your kernel version is newer than what is
 875         *** supported, or you are using a patched custom kernel with
 876         *** incompatible modifications.
 877         ***
 878         *** ZFS Version: $ZFS_META_ALIAS
 879         *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
 880         ])
 881 ])
 882
 883 dnl #
 884 dnl # ZFS_LINUX_TEST_RESULT_SYMBOL
 885 dnl #
 886 dnl # Like ZFS_LINUX_TEST_RESULT except ZFS_CHECK_SYMBOL_EXPORT is called to
 887 dnl # verify symbol exports, unless --enable-linux-builtin was provided to
 888 dnl # configure.
 889 dnl #
 890 AC_DEFUN([ZFS_LINUX_TEST_RESULT_SYMBOL], [
 891         AS_IF([ ! test -f build/$1/$1.ko], [
 892                 $5
 893         ], [
 894                 AS_IF([test "x$enable_linux_builtin" != "xyes"], [
 895                         ZFS_CHECK_SYMBOL_EXPORT([$2], [$3], [$4], [$5])
 896                 ], [
 897                         $4
 898                 ])
 899         ])
 900 ])
 901
 902 dnl #
 903 dnl # ZFS_LINUX_COMPILE_IFELSE
 904 dnl #
 905 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 906         ZFS_LINUX_TEST_REMOVE([conftest])
 907
 908         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1], [conftest])])
 909         m4_ifvaln([$5], [ZFS_LINUX_CONFTEST_H([$5], [conftest])],
 910             [ZFS_LINUX_CONFTEST_H([], [conftest])])
 911
 912         ZFS_LINUX_CONFTEST_MAKEFILE([conftest], [no],
 913             [m4_ifvaln([$5], [-I$PWD/build/conftest], [])])
 914         ZFS_LINUX_COMPILE([build/conftest], [$2], [$3], [$4], [], [])
 915 ])
 916
 917 dnl #
 918 dnl # ZFS_LINUX_TRY_COMPILE
 919 dnl #
 920 dnl # $1 - global
 921 dnl # $2 - source
 922 dnl # $3 - run on success (valid .ko generated)
 923 dnl # $4 - run on failure (unable to compile)
 924 dnl #
 925 dnl # When configuring as builtin (--enable-linux-builtin) for kernels
 926 dnl # without loadable module support (CONFIG_MODULES=n) only the object
 927 dnl # file is created.  See ZFS_LINUX_TEST_COMPILE_ALL for details.
 928 dnl #
 929 AC_DEFUN([ZFS_LINUX_TRY_COMPILE], [
 930         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
 931                 ZFS_LINUX_COMPILE_IFELSE(
 932                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 933                     [[ZFS_META_LICENSE]])],
 934                     [test -f build/conftest/conftest.o], [$3], [$4])
 935         ], [
 936                 ZFS_LINUX_COMPILE_IFELSE(
 937                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 938                     [[ZFS_META_LICENSE]])],
 939                     [test -f build/conftest/conftest.ko], [$3], [$4])
 940         ])
 941 ])
 942
 943 dnl #
 944 dnl # ZFS_CHECK_SYMBOL_EXPORT
 945 dnl #
 946 dnl # Check if a symbol is exported on not by consulting the symbols
 947 dnl # file, or optionally the source code.
 948 dnl #
 949 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 950         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 951                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 952         rc=$?
 953         if test $rc -ne 0; then
 954                 export=0
 955                 for file in $2; do
 956                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 957                                 "$LINUX/$file" 2>/dev/null
 958                         rc=$?
 959                         if test $rc -eq 0; then
 960                                 export=1
 961                                 break;
 962                         fi
 963                 done
 964                 if test $export -eq 0; then :
 965                         $4
 966                 else :
 967                         $3
 968                 fi
 969         else :
 970                 $3
 971         fi
 972 ])
 973
 974 dnl #
 975 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 976 dnl #
 977 dnl # Like ZFS_LINUX_TRY_COMPILER except ZFS_CHECK_SYMBOL_EXPORT is called
 978 dnl # to verify symbol exports, unless --enable-linux-builtin was provided
 979 dnl # to configure.
 980 dnl #
 981 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 982         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 983         if test $rc -ne 0; then :
 984                 $6
 985         else
 986                 if test "x$enable_linux_builtin" != xyes; then
 987                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 988                 fi
 989                 if test $rc -ne 0; then :
 990                         $6
 991                 else :
 992                         $5
 993                 fi
 994         fi
 995 ])
 996
 997 dnl #
 998 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 999 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
1000 dnl # provided via the fifth parameter
1001 dnl #
1002 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], [
1003         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
1004                 ZFS_LINUX_COMPILE_IFELSE(
1005                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
1006                     [[ZFS_META_LICENSE]])],
1007                     [test -f build/conftest/conftest.o], [$3], [$4], [$5])
1008         ], [
1009                 ZFS_LINUX_COMPILE_IFELSE(
1010                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
1011                     [[ZFS_META_LICENSE]])],
1012                     [test -f build/conftest/conftest.ko], [$3], [$4], [$5])
1013         ])
1014 ])
1015
1016 dnl #
1017 dnl # AS_VERSION_COMPARE_LE
1018 dnl # like AS_VERSION_COMPARE_LE, but runs $3 if (and only if) $1 <= $2
1019 dnl # AS_VERSION_COMPARE_LE (version-1, version-2, [action-if-less-or-equal], [action-if-greater])
1020 dnl #
1021 AC_DEFUN([AS_VERSION_COMPARE_LE], [
1022         AS_VERSION_COMPARE([$1], [$2], [$3], [$3], [$4])
1023 ])
1024
1025 dnl #
1026 dnl # ZFS_LINUX_REQUIRE_API
1027 dnl # like ZFS_LINUX_TEST_ERROR, except only fails if the kernel is
1028 dnl # at least some specified version.
1029 dnl #
1030 AC_DEFUN([ZFS_LINUX_REQUIRE_API], [
1031         AS_VERSION_COMPARE_LE([$2], [$kernsrcver], [
1032                 AC_MSG_ERROR([
1033                 *** None of the expected "$1" interfaces were detected. This
1034                 *** interface is expected for kernels version "$2" and above.
1035                 *** This may be because your kernel version is newer than what is
1036                 *** supported, or you are using a patched custom kernel with
1037                 *** incompatible modifications.  Newer kernels may have incompatible
1038                 *** APIs.
1039                 ***
1040                 *** ZFS Version: $ZFS_META_ALIAS
1041                 *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
1042                 ])
1043         ], [
1044                 AC_MSG_RESULT(no)
1045         ])
1046 ])