config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_QAT
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_MISC_MINOR
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_CTL_NAME
  12         ZFS_AC_KERNEL_PDE_DATA
  13         ZFS_AC_KERNEL_SET_FS_PWD_WITH_CONST
  14         ZFS_AC_KERNEL_2ARGS_VFS_FSYNC
  15         ZFS_AC_KERNEL_FS_STRUCT_SPINLOCK
  16         ZFS_AC_KERNEL_KUIDGID_T
  17         ZFS_AC_KERNEL_FALLOCATE
  18         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  19         ZFS_AC_KERNEL_RWSEM_SPINLOCK_IS_RAW
  20         ZFS_AC_KERNEL_RWSEM_ACTIVITY
  21         ZFS_AC_KERNEL_RWSEM_ATOMIC_LONG_COUNT
  22         ZFS_AC_KERNEL_SCHED_RT_HEADER
  23         ZFS_AC_KERNEL_SCHED_SIGNAL_HEADER
  24         ZFS_AC_KERNEL_IO_SCHEDULE_TIMEOUT
  25         ZFS_AC_KERNEL_4ARGS_VFS_GETATTR
  26         ZFS_AC_KERNEL_3ARGS_VFS_GETATTR
  27         ZFS_AC_KERNEL_2ARGS_VFS_GETATTR
  28         ZFS_AC_KERNEL_USLEEP_RANGE
  29         ZFS_AC_KERNEL_KMEM_CACHE_ALLOCFLAGS
  30         ZFS_AC_KERNEL_KMEM_CACHE_CREATE_USERCOPY
  31         ZFS_AC_KERNEL_WAIT_ON_BIT
  32         ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  33         ZFS_AC_KERNEL_WAIT_QUEUE_HEAD_ENTRY
  34         ZFS_AC_KERNEL_INODE_LOCK
  35         ZFS_AC_KERNEL_GROUP_INFO_GID
  36         ZFS_AC_KERNEL_WRITE
  37         ZFS_AC_KERNEL_READ
  38         ZFS_AC_KERNEL_TIMER_FUNCTION_TIMER_LIST
  39         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  40         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  41         ZFS_AC_KERNEL_SUPER_USER_NS
  42         ZFS_AC_KERNEL_SUBMIT_BIO
  43         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  44         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  45         ZFS_AC_KERNEL_TYPE_FMODE_T
  46         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  47         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  48         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  49         ZFS_AC_KERNEL_LOOKUP_BDEV
  50         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  51         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  52         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  53         ZFS_AC_KERNEL_BIO_BVEC_ITER
  54         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  55         ZFS_AC_KERNEL_BIO_SET_DEV
  56         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  57         ZFS_AC_KERNEL_REQ_OP_DISCARD
  58         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  59         ZFS_AC_KERNEL_REQ_OP_FLUSH
  60         ZFS_AC_KERNEL_BIO_BI_OPF
  61         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  62         ZFS_AC_KERNEL_BIO_BI_STATUS
  63         ZFS_AC_KERNEL_BIO_RW_BARRIER
  64         ZFS_AC_KERNEL_BIO_RW_DISCARD
  65         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  66         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_CLEAR
  67         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_SET
  68         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  69         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  70         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  71         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  72         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  73         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
  74         ZFS_AC_KERNEL_GET_DISK_RO
  75         ZFS_AC_KERNEL_GET_GENDISK
  76         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  77         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  78         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  79         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  80         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  81         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  82         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  83         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  84         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  85         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  86         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  87         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  88         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  89         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  90         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  91         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  92         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  93         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  94         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  95         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  96         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  97         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  98         ZFS_AC_KERNEL_INODE_SET_FLAGS
  99         ZFS_AC_KERNEL_INODE_SET_IVERSION
 100         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
 101         ZFS_AC_KERNEL_SHOW_OPTIONS
 102         ZFS_AC_KERNEL_FILE_INODE
 103         ZFS_AC_KERNEL_FILE_DENTRY
 104         ZFS_AC_KERNEL_FSYNC
 105         ZFS_AC_KERNEL_EVICT_INODE
 106         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
 107         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
 108         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
 109         ZFS_AC_KERNEL_FALLOCATE
 110         ZFS_AC_KERNEL_AIO_FSYNC
 111         ZFS_AC_KERNEL_MKDIR_UMODE_T
 112         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
 113         ZFS_AC_KERNEL_CREATE_NAMEIDATA
 114         ZFS_AC_KERNEL_GET_LINK
 115         ZFS_AC_KERNEL_PUT_LINK
 116         ZFS_AC_KERNEL_TMPFILE
 117         ZFS_AC_KERNEL_TRUNCATE_RANGE
 118         ZFS_AC_KERNEL_AUTOMOUNT
 119         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 120         ZFS_AC_KERNEL_COMMIT_METADATA
 121         ZFS_AC_KERNEL_CLEAR_INODE
 122         ZFS_AC_KERNEL_SETATTR_PREPARE
 123         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 124         ZFS_AC_KERNEL_D_MAKE_ROOT
 125         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
 126         ZFS_AC_KERNEL_D_PRUNE_ALIASES
 127         ZFS_AC_KERNEL_D_SET_D_OP
 128         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
 129         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
 130         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 131         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 132         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 133         ZFS_AC_KERNEL_FST_MOUNT
 134         ZFS_AC_KERNEL_SHRINK
 135         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 136         ZFS_AC_KERNEL_SHRINK_CONTROL_STRUCT
 137         ZFS_AC_KERNEL_SHRINKER_CALLBACK
 138         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 139         ZFS_AC_KERNEL_S_D_OP
 140         ZFS_AC_KERNEL_BDI
 141         ZFS_AC_KERNEL_SET_NLINK
 142         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 143         ZFS_AC_KERNEL_5ARG_SGET
 144         ZFS_AC_KERNEL_LSEEK_EXECUTE
 145         ZFS_AC_KERNEL_VFS_ITERATE
 146         ZFS_AC_KERNEL_VFS_RW_ITERATE
 147         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 148         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 149         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 150         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 151         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 152         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 153         ZFS_AC_KERNEL_FPU
 154         ZFS_AC_KERNEL_KUID_HELPERS
 155         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 156         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 157         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 158         ZFS_AC_KERNEL_CURRENT_TIME
 159         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 160         ZFS_AC_KERNEL_ACL_HAS_REFCOUNT
 161         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 162
 163         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 164                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 165         ])
 166
 167         AC_SUBST(KERNEL_MAKE)
 168 ])
 169
 170 dnl #
 171 dnl # Detect name used for Module.symvers file in kernel
 172 dnl #
 173 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 174         modpost=$LINUX/scripts/Makefile.modpost
 175         AC_MSG_CHECKING([kernel file name for module symbols])
 176         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 177                 AS_IF([grep -q Modules.symvers $modpost], [
 178                         LINUX_SYMBOLS=Modules.symvers
 179                 ], [
 180                         LINUX_SYMBOLS=Module.symvers
 181                 ])
 182
 183                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 184                         AC_MSG_ERROR([
 185         *** Please make sure the kernel devel package for your distribution
 186         *** is installed.  If you are building with a custom kernel, make sure the
 187         *** kernel is configured, built, and the '--with-linux=PATH' configure
 188         *** option refers to the location of the kernel source.])
 189                 ])
 190         ], [
 191                 LINUX_SYMBOLS=NONE
 192         ])
 193         AC_MSG_RESULT($LINUX_SYMBOLS)
 194         AC_SUBST(LINUX_SYMBOLS)
 195 ])
 196
 197 dnl #
 198 dnl # Detect the kernel to be built against
 199 dnl #
 200 AC_DEFUN([ZFS_AC_KERNEL], [
 201         AC_ARG_WITH([linux],
 202                 AS_HELP_STRING([--with-linux=PATH],
 203                 [Path to kernel source]),
 204                 [kernelsrc="$withval"])
 205
 206         AC_ARG_WITH(linux-obj,
 207                 AS_HELP_STRING([--with-linux-obj=PATH],
 208                 [Path to kernel build objects]),
 209                 [kernelbuild="$withval"])
 210
 211         AC_MSG_CHECKING([kernel source directory])
 212         AS_IF([test -z "$kernelsrc"], [
 213                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 214                         headersdir="/lib/modules/$(uname -r)/source"
 215                         sourcelink=$(readlink -f "$headersdir")
 216                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 217                         headersdir="/lib/modules/$(uname -r)/build"
 218                         sourcelink=$(readlink -f "$headersdir")
 219                 ], [
 220                         sourcelink=$(ls -1d /usr/src/kernels/* \
 221                                      /usr/src/linux-* \
 222                                      2>/dev/null | grep -v obj | tail -1)
 223                 ])
 224
 225                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 226                         kernelsrc=`readlink -f ${sourcelink}`
 227                 ], [
 228                         kernelsrc="[Not found]"
 229                 ])
 230         ], [
 231                 AS_IF([test "$kernelsrc" = "NONE"], [
 232                         kernsrcver=NONE
 233                 ])
 234                 withlinux=yes
 235         ])
 236
 237         AC_MSG_RESULT([$kernelsrc])
 238         AS_IF([test ! -d "$kernelsrc"], [
 239                 AC_MSG_ERROR([
 240         *** Please make sure the kernel devel package for your distribution
 241         *** is installed and then try again.  If that fails, you can specify the
 242         *** location of the kernel source with the '--with-linux=PATH' option.])
 243         ])
 244
 245         AC_MSG_CHECKING([kernel build directory])
 246         AS_IF([test -z "$kernelbuild"], [
 247                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 248                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 249                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 250                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 251                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 252                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 253                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 254                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 255                 ], [
 256                         kernelbuild=${kernelsrc}
 257                 ])
 258         ])
 259         AC_MSG_RESULT([$kernelbuild])
 260
 261         AC_MSG_CHECKING([kernel source version])
 262         utsrelease1=$kernelbuild/include/linux/version.h
 263         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 264         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 265         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 266                 utsrelease=linux/version.h
 267         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 268                 utsrelease=linux/utsrelease.h
 269         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 270                 utsrelease=generated/utsrelease.h
 271         ])
 272
 273         AS_IF([test "$utsrelease"], [
 274                 kernsrcver=`(echo "#include <$utsrelease>";
 275                              echo "kernsrcver=UTS_RELEASE") |
 276                              cpp -I $kernelbuild/include |
 277                              grep "^kernsrcver=" | cut -d \" -f 2`
 278
 279                 AS_IF([test -z "$kernsrcver"], [
 280                         AC_MSG_RESULT([Not found])
 281                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 282                 ])
 283         ], [
 284                 AC_MSG_RESULT([Not found])
 285                 if test "x$enable_linux_builtin" != xyes; then
 286                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 287                 else
 288                         AC_MSG_ERROR([
 289         *** Cannot find UTS_RELEASE definition.
 290         *** Please run 'make prepare' inside the kernel source tree.])
 291                 fi
 292         ])
 293
 294         AC_MSG_RESULT([$kernsrcver])
 295
 296         LINUX=${kernelsrc}
 297         LINUX_OBJ=${kernelbuild}
 298         LINUX_VERSION=${kernsrcver}
 299
 300         AC_SUBST(LINUX)
 301         AC_SUBST(LINUX_OBJ)
 302         AC_SUBST(LINUX_VERSION)
 303
 304         ZFS_AC_MODULE_SYMVERS
 305 ])
 306
 307 dnl #
 308 dnl # Detect the QAT module to be built against
 309 dnl # QAT provides hardware acceleration for data compression:
 310 dnl #   https://01.org/intel-quickassist-technology
 311 dnl # * Download and install QAT driver from the above link
 312 dnl # * Start QAT driver in your system:
 313 dnl #   service qat_service start
 314 dnl # * Enable QAT in ZFS, e.g.:
 315 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 316 dnl #   make
 317 dnl # * Set GZIP compression in ZFS dataset:
 318 dnl #   zfs set compression = gzip <dataset>
 319 dnl # Then the data written to this ZFS pool is compressed
 320 dnl # by QAT accelerator automatically, and de-compressed by
 321 dnl # QAT when read from the pool.
 322 dnl # * Get QAT hardware statistics by:
 323 dnl #   cat /proc/icp_dh895xcc_dev/qat
 324 dnl # * To disable QAT:
 325 dnl #   insmod zfs.ko zfs_qat_disable=1
 326 dnl #
 327 AC_DEFUN([ZFS_AC_QAT], [
 328         AC_ARG_WITH([qat],
 329                 AS_HELP_STRING([--with-qat=PATH],
 330                 [Path to qat source]),
 331                 AS_IF([test "$withval" = "yes"],
 332                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 333                         [qatsrc="$withval"]))
 334
 335         AC_ARG_WITH([qat-obj],
 336                 AS_HELP_STRING([--with-qat-obj=PATH],
 337                 [Path to qat build objects]),
 338                 [qatbuild="$withval"])
 339
 340         AS_IF([test ! -z "${qatsrc}"], [
 341                 AC_MSG_CHECKING([qat source directory])
 342                 AC_MSG_RESULT([$qatsrc])
 343                 QAT_SRC="${qatsrc}/quickassist"
 344                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 345                         AC_MSG_ERROR([
 346                 *** Please make sure the qat driver package is installed
 347                 *** and specify the location of the qat source with the
 348                 *** '--with-qat=PATH' option then try again. Failed to
 349                 *** find cpa.h in:
 350                 ${QAT_SRC}/include])
 351                 ])
 352         ])
 353
 354         AS_IF([test ! -z "${qatsrc}"], [
 355                 AC_MSG_CHECKING([qat build directory])
 356                 AS_IF([test -z "$qatbuild"], [
 357                         qatbuild="${qatsrc}/build"
 358                 ])
 359
 360                 AC_MSG_RESULT([$qatbuild])
 361                 QAT_OBJ=${qatbuild}
 362                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 363                         AC_MSG_ERROR([
 364                 *** Please make sure the qat driver is installed then try again.
 365                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 366                 $QAT_OBJ])
 367                 ])
 368
 369                 AC_SUBST(QAT_SRC)
 370                 AC_SUBST(QAT_OBJ)
 371
 372                 AC_DEFINE(HAVE_QAT, 1,
 373                 [qat is enabled and existed])
 374         ])
 375
 376         dnl #
 377         dnl # Detect the name used for the QAT Module.symvers file.
 378         dnl #
 379         AS_IF([test ! -z "${qatsrc}"], [
 380                 AC_MSG_CHECKING([qat file for module symbols])
 381                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 382
 383                 AS_IF([test -r $QAT_SYMBOLS], [
 384                         AC_MSG_RESULT([$QAT_SYMBOLS])
 385                         AC_SUBST(QAT_SYMBOLS)
 386                 ],[
 387                        AC_MSG_ERROR([
 388                         *** Please make sure the qat driver is installed then try again.
 389                         *** Failed to find Module.symvers in:
 390                         $QAT_SYMBOLS])
 391                         ])
 392                 ])
 393         ])
 394 ])
 395
 396 dnl #
 397 dnl # Basic toolchain sanity check.
 398 dnl #
 399 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 400         AC_MSG_CHECKING([whether modules can be built])
 401         ZFS_LINUX_TRY_COMPILE([],[],[
 402                 AC_MSG_RESULT([yes])
 403         ],[
 404                 AC_MSG_RESULT([no])
 405                 if test "x$enable_linux_builtin" != xyes; then
 406                         AC_MSG_ERROR([*** Unable to build an empty module.])
 407                 else
 408                         AC_MSG_ERROR([
 409         *** Unable to build an empty module.
 410         *** Please run 'make scripts' inside the kernel source tree.])
 411                 fi
 412         ])
 413 ])
 414
 415 dnl #
 416 dnl # Certain kernel build options are not supported.  These must be
 417 dnl # detected at configure time and cause a build failure.  Otherwise
 418 dnl # modules may be successfully built that behave incorrectly.
 419 dnl #
 420 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 421         AS_IF([test "x$cross_compiling" != xyes], [
 422                 AC_RUN_IFELSE([
 423                         AC_LANG_PROGRAM([
 424                                 #include "$LINUX/include/linux/license.h"
 425                         ], [
 426                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 427                         ])
 428                 ], [
 429                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 430                             [Define to 1 if GPL-only symbols can be used])
 431                 ], [
 432                 ])
 433         ])
 434
 435         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 436         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 437         ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS
 438         ZFS_AC_KERNEL_CONFIG_ZLIB_INFLATE
 439         ZFS_AC_KERNEL_CONFIG_ZLIB_DEFLATE
 440 ])
 441
 442 dnl #
 443 dnl # Check configured THREAD_SIZE
 444 dnl #
 445 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 446 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 447 dnl # on newer kernels and some architectures stack usage optimizations can be
 448 dnl # conditionally applied to improve performance without negatively impacting
 449 dnl # stability.
 450 dnl #
 451 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 452         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 453         ZFS_LINUX_TRY_COMPILE([
 454                 #include <linux/module.h>
 455         ],[
 456                 #if (THREAD_SIZE < 16384)
 457                 #error "THREAD_SIZE is less than 16K"
 458                 #endif
 459         ],[
 460                 AC_MSG_RESULT([yes])
 461                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 462         ],[
 463                 AC_MSG_RESULT([no])
 464         ])
 465 ])
 466
 467 dnl #
 468 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 469 dnl #
 470 dnl # This is typically only set for debug kernels because it comes with
 471 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 472 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 473 dnl # This will cause a failure at link time which we'd rather know about
 474 dnl # at compile time.
 475 dnl #
 476 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 477 dnl # with the upstream community we add a check to detect this case.
 478 dnl #
 479 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 480
 481         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 482                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 483                 tmp_flags="$EXTRA_KCFLAGS"
 484                 ZFS_LINUX_TRY_COMPILE([
 485                         #include <linux/module.h>
 486                         #include <linux/mutex.h>
 487
 488                         MODULE_LICENSE("$ZFS_META_LICENSE");
 489                 ],[
 490                         struct mutex lock;
 491
 492                         mutex_init(&lock);
 493                         mutex_lock(&lock);
 494                         mutex_unlock(&lock);
 495                 ],[
 496                         AC_MSG_RESULT(no)
 497                 ],[
 498                         AC_MSG_RESULT(yes)
 499                         AC_MSG_ERROR([
 500         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 501         *** with the CDDL license and will prevent the module linking stage
 502         *** from succeeding.  You must rebuild your kernel without this
 503         *** option enabled.])
 504                 ])
 505                 EXTRA_KCFLAGS="$tmp_flags"
 506         ], [])
 507 ])
 508
 509 dnl #
 510 dnl # Check CONFIG_TRIM_UNUSED_KSYMS
 511 dnl #
 512 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS disabled.
 513 dnl #
 514 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS], [
 515         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
 516         ZFS_LINUX_TRY_COMPILE([
 517                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
 518                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
 519                 #endif
 520         ],[ ],[
 521                 AC_MSG_RESULT([yes])
 522         ],[
 523                 AC_MSG_RESULT([no])
 524                 AC_MSG_ERROR([
 525         *** This kernel has unused symbols trimming enabled, please disable.
 526         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
 527         ])
 528 ])
 529
 530 dnl #
 531 dnl # ZFS_LINUX_CONFTEST_H
 532 dnl #
 533 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 534 cat - <<_ACEOF >conftest.h
 535 $1
 536 _ACEOF
 537 ])
 538
 539 dnl #
 540 dnl # ZFS_LINUX_CONFTEST_C
 541 dnl #
 542 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 543 cat confdefs.h - <<_ACEOF >conftest.c
 544 $1
 545 _ACEOF
 546 ])
 547
 548 dnl #
 549 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 550 dnl #
 551 m4_define([ZFS_LANG_PROGRAM], [
 552 $1
 553 int
 554 main (void)
 555 {
 556 dnl Do *not* indent the following line: there may be CPP directives.
 557 dnl Don't move the `;' right after for the same reason.
 558 $2
 559   ;
 560   return 0;
 561 }
 562 ])
 563
 564 dnl #
 565 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 566 dnl #
 567 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 568         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 569         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 570         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 571         echo "obj-m := conftest.o" >build/Makefile
 572         modpost_flag=''
 573         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 574         AS_IF(
 575                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $FRAME_LARGER_THAN $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 576                 [$4],
 577                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 578         )
 579         rm -Rf build
 580 ])
 581
 582 dnl #
 583 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 584 dnl #
 585 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 586         [ZFS_LINUX_COMPILE_IFELSE(
 587         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 588         [modules],
 589         [test -s build/conftest.o],
 590         [$3], [$4])
 591 ])
 592
 593 dnl #
 594 dnl # ZFS_LINUX_CONFIG
 595 dnl #
 596 AC_DEFUN([ZFS_LINUX_CONFIG],
 597         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 598         ZFS_LINUX_TRY_COMPILE([
 599                 #include <linux/module.h>
 600         ],[
 601                 #ifndef CONFIG_$1
 602                 #error CONFIG_$1 not #defined
 603                 #endif
 604         ],[
 605                 AC_MSG_RESULT([yes])
 606                 $2
 607         ],[
 608                 AC_MSG_RESULT([no])
 609                 $3
 610         ])
 611 ])
 612
 613 dnl #
 614 dnl # ZFS_CHECK_SYMBOL_EXPORT
 615 dnl # check symbol exported or not
 616 dnl #
 617 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 618         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 619                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 620         rc=$?
 621         if test $rc -ne 0; then
 622                 export=0
 623                 for file in $2; do
 624                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 625                                 "$LINUX/$file" 2>/dev/null
 626                         rc=$?
 627                         if test $rc -eq 0; then
 628                                 export=1
 629                                 break;
 630                         fi
 631                 done
 632                 if test $export -eq 0; then :
 633                         $4
 634                 else :
 635                         $3
 636                 fi
 637         else :
 638                 $3
 639         fi
 640 ])
 641
 642 dnl #
 643 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 644 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 645 dnl # is called if not compiling for builtin
 646 dnl #
 647 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 648         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 649         if test $rc -ne 0; then :
 650                 $6
 651         else
 652                 if test "x$enable_linux_builtin" != xyes; then
 653                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 654                 fi
 655                 if test $rc -ne 0; then :
 656                         $6
 657                 else :
 658                         $5
 659                 fi
 660         fi
 661 ])
 662
 663 dnl #
 664 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 665 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 666 dnl # provided via the fifth parameter
 667 dnl #
 668 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 669         [ZFS_LINUX_COMPILE_IFELSE(
 670         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 671         [modules],
 672         [test -s build/conftest.o],
 673         [$3], [$4], [$5])
 674 ])