config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  15         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  16         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  17         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  18         ZFS_AC_KERNEL_LOOKUP_BDEV
  19         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  20         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BIO_BVEC_ITER
  23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  26         ZFS_AC_KERNEL_BIO_RW_BARRIER
  27         ZFS_AC_KERNEL_BIO_RW_DISCARD
  28         ZFS_AC_KERNEL_BIO_RW_SYNC
  29         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  30         ZFS_AC_KERNEL_REQ_SYNC
  31         ZFS_AC_KERNEL_BLK_END_REQUEST
  32         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  33         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  35         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  36         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  37         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  38         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  39         ZFS_AC_KERNEL_BLK_RQ_BYTES
  40         ZFS_AC_KERNEL_BLK_RQ_POS
  41         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  42         ZFS_AC_KERNEL_GET_DISK_RO
  43         ZFS_AC_KERNEL_GET_GENDISK
  44         ZFS_AC_KERNEL_RQ_IS_SYNC
  45         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  46         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  47         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  48         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  49         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  50         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  51         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  52         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  53         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  54         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  55         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  61         ZFS_AC_KERNEL_CURRENT_UMASK
  62         ZFS_AC_KERNEL_SHOW_OPTIONS
  63         ZFS_AC_KERNEL_FILE_INODE
  64         ZFS_AC_KERNEL_FSYNC
  65         ZFS_AC_KERNEL_EVICT_INODE
  66         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  67         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  68         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  69         ZFS_AC_KERNEL_FALLOCATE
  70         ZFS_AC_KERNEL_MKDIR_UMODE_T
  71         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  72         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  73         ZFS_AC_KERNEL_FOLLOW_LINK
  74         ZFS_AC_KERNEL_PUT_LINK
  75         ZFS_AC_KERNEL_TRUNCATE_RANGE
  76         ZFS_AC_KERNEL_AUTOMOUNT
  77         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  78         ZFS_AC_KERNEL_COMMIT_METADATA
  79         ZFS_AC_KERNEL_CLEAR_INODE
  80         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  81         ZFS_AC_KERNEL_D_MAKE_ROOT
  82         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  83         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  84         ZFS_AC_KERNEL_D_SET_D_OP
  85         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  86         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  87         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  88         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  89         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  90         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  91         ZFS_AC_KERNEL_MOUNT_NODEV
  92         ZFS_AC_KERNEL_SHRINK
  93         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  94         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  95         ZFS_AC_KERNEL_S_D_OP
  96         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  97         ZFS_AC_KERNEL_SET_NLINK
  98         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  99         ZFS_AC_KERNEL_5ARG_SGET
 100         ZFS_AC_KERNEL_LSEEK_EXECUTE
 101         ZFS_AC_KERNEL_VFS_ITERATE
 102         ZFS_AC_KERNEL_VFS_RW_ITERATE
 103         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 104         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 105         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 106
 107         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 108                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 109         ])
 110         AC_SUBST(KERNELMAKE_PARAMS)
 111
 112
 113         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 114         dnl # compiler options are added by the kernel build system.
 115         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 116         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 117         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 118         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 119
 120         AC_SUBST(KERNELCPPFLAGS)
 121 ])
 122
 123 dnl #
 124 dnl # Detect name used for Module.symvers file in kernel
 125 dnl #
 126 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 127         modpost=$LINUX/scripts/Makefile.modpost
 128         AC_MSG_CHECKING([kernel file name for module symbols])
 129         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 130                 AS_IF([grep -q Modules.symvers $modpost], [
 131                         LINUX_SYMBOLS=Modules.symvers
 132                 ], [
 133                         LINUX_SYMBOLS=Module.symvers
 134                 ])
 135
 136                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 137                         AC_MSG_ERROR([
 138         *** Please make sure the kernel devel package for your distribution
 139         *** is installed.  If you are building with a custom kernel, make sure the
 140         *** kernel is configured, built, and the '--with-linux=PATH' configure
 141         *** option refers to the location of the kernel source.])
 142                 ])
 143         ], [
 144                 LINUX_SYMBOLS=NONE
 145         ])
 146         AC_MSG_RESULT($LINUX_SYMBOLS)
 147         AC_SUBST(LINUX_SYMBOLS)
 148 ])
 149
 150 dnl #
 151 dnl # Detect the kernel to be built against
 152 dnl #
 153 AC_DEFUN([ZFS_AC_KERNEL], [
 154         AC_ARG_WITH([linux],
 155                 AS_HELP_STRING([--with-linux=PATH],
 156                 [Path to kernel source]),
 157                 [kernelsrc="$withval"])
 158
 159         AC_ARG_WITH(linux-obj,
 160                 AS_HELP_STRING([--with-linux-obj=PATH],
 161                 [Path to kernel build objects]),
 162                 [kernelbuild="$withval"])
 163
 164         AC_MSG_CHECKING([kernel source directory])
 165         AS_IF([test -z "$kernelsrc"], [
 166                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 167                         headersdir="/lib/modules/$(uname -r)/source"
 168                         sourcelink=$(readlink -f "$headersdir")
 169                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 170                         headersdir="/lib/modules/$(uname -r)/build"
 171                         sourcelink=$(readlink -f "$headersdir")
 172                 ], [
 173                         sourcelink=$(ls -1d /usr/src/kernels/* \
 174                                      /usr/src/linux-* \
 175                                      2>/dev/null | grep -v obj | tail -1)
 176                 ])
 177
 178                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 179                         kernelsrc=`readlink -f ${sourcelink}`
 180                 ], [
 181                         kernelsrc="[Not found]"
 182                 ])
 183         ], [
 184                 AS_IF([test "$kernelsrc" = "NONE"], [
 185                         kernsrcver=NONE
 186                 ])
 187         ])
 188
 189         AC_MSG_RESULT([$kernelsrc])
 190         AS_IF([test ! -d "$kernelsrc"], [
 191                 AC_MSG_ERROR([
 192         *** Please make sure the kernel devel package for your distribution
 193         *** is installed and then try again.  If that fails, you can specify the
 194         *** location of the kernel source with the '--with-linux=PATH' option.])
 195         ])
 196
 197         AC_MSG_CHECKING([kernel build directory])
 198         AS_IF([test -z "$kernelbuild"], [
 199                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 200                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 201                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 202                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 203                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 204                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 205                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 206                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 207                 ], [
 208                         kernelbuild=${kernelsrc}
 209                 ])
 210         ])
 211         AC_MSG_RESULT([$kernelbuild])
 212
 213         AC_MSG_CHECKING([kernel source version])
 214         utsrelease1=$kernelbuild/include/linux/version.h
 215         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 216         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 217         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 218                 utsrelease=linux/version.h
 219         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 220                 utsrelease=linux/utsrelease.h
 221         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 222                 utsrelease=generated/utsrelease.h
 223         ])
 224
 225         AS_IF([test "$utsrelease"], [
 226                 kernsrcver=`(echo "#include <$utsrelease>";
 227                              echo "kernsrcver=UTS_RELEASE") |
 228                              cpp -I $kernelbuild/include |
 229                              grep "^kernsrcver=" | cut -d \" -f 2`
 230
 231                 AS_IF([test -z "$kernsrcver"], [
 232                         AC_MSG_RESULT([Not found])
 233                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 234                 ])
 235         ], [
 236                 AC_MSG_RESULT([Not found])
 237                 if test "x$enable_linux_builtin" != xyes; then
 238                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 239                 else
 240                         AC_MSG_ERROR([
 241         *** Cannot find UTS_RELEASE definition.
 242         *** Please run 'make prepare' inside the kernel source tree.])
 243                 fi
 244         ])
 245
 246         AC_MSG_RESULT([$kernsrcver])
 247
 248         LINUX=${kernelsrc}
 249         LINUX_OBJ=${kernelbuild}
 250         LINUX_VERSION=${kernsrcver}
 251
 252         AC_SUBST(LINUX)
 253         AC_SUBST(LINUX_OBJ)
 254         AC_SUBST(LINUX_VERSION)
 255
 256         ZFS_AC_MODULE_SYMVERS
 257 ])
 258
 259
 260 dnl #
 261 dnl # Detect the SPL module to be built against
 262 dnl #
 263 AC_DEFUN([ZFS_AC_SPL], [
 264         AC_ARG_WITH([spl],
 265                 AS_HELP_STRING([--with-spl=PATH],
 266                 [Path to spl source]),
 267                 [splsrc="$withval"])
 268
 269         AC_ARG_WITH([spl-obj],
 270                 AS_HELP_STRING([--with-spl-obj=PATH],
 271                 [Path to spl build objects]),
 272                 [splbuild="$withval"])
 273
 274         AC_ARG_WITH([spl-timeout],
 275                 AS_HELP_STRING([--with-spl-timeout=SECS],
 276                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 277                 [timeout="$withval"], [timeout=0])
 278
 279         dnl #
 280         dnl # The existence of spl.release.in is used to identify a valid
 281         dnl # source directory.  In order of preference:
 282         dnl #
 283         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 284         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 285         splsrc2="/usr/local/src/spl-${VERSION}"
 286         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 287         splsrc4="/usr/src/spl-${VERSION}"
 288         splsrc5="../spl/"
 289         splsrc6="$LINUX"
 290
 291         AC_MSG_CHECKING([spl source directory])
 292         AS_IF([test -z "${splsrc}"], [
 293                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 294                         splsrc=${splsrc0}
 295                 ], [ test -e "${splsrc1}/spl.release.in"], [
 296                         splsrc=${splsrc1}
 297                 ], [ test -e "${splsrc2}/spl.release.in"], [
 298                         splsrc=${splsrc2}
 299                 ], [ test -e "${splsrc3}/spl.release.in"], [
 300                         splsrc=$(readlink -f "${splsrc3}")
 301                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 302                         splsrc=${splsrc4}
 303                 ], [ test -e "${splsrc5}/spl.release.in"], [
 304                         splsrc=$(readlink -f "${splsrc5}")
 305                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 306                         splsrc=${splsrc6}
 307                 ], [
 308                         splsrc="[Not found]"
 309                 ])
 310         ], [
 311                 AS_IF([test "$splsrc" = "NONE"], [
 312                         splbuild=NONE
 313                         splsrcver=NONE
 314                 ])
 315         ])
 316
 317         AC_MSG_RESULT([$splsrc])
 318         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 319                 AC_MSG_ERROR([
 320         *** Please make sure the kmod spl devel package for your distribution
 321         *** is installed then try again.  If that fails you can specify the
 322         *** location of the spl source with the '--with-spl=PATH' option.])
 323         ])
 324
 325         dnl #
 326         dnl # The existence of the spl_config.h is used to identify a valid
 327         dnl # spl object directory.  In many cases the object and source
 328         dnl # directory are the same, however the objects may also reside
 329         dnl # is a subdirectory named after the kernel version.
 330         dnl #
 331         dnl # This file is supposed to be available after DKMS finishes
 332         dnl # building the SPL kernel module for the target kernel.  The
 333         dnl # '--with-spl-timeout' option can be passed to pause here,
 334         dnl # waiting for the file to appear from a concurrently building
 335         dnl # SPL package.
 336         dnl #
 337         AC_MSG_CHECKING([spl build directory])
 338         while true; do
 339                 AS_IF([test -z "$splbuild"], [
 340                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 341                                 splbuild="${splsrc}/${LINUX_VERSION}"
 342                         ], [ test -e "${splsrc}/spl_config.h" ], [
 343                                 splbuild="${splsrc}"
 344                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 345                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 346                         ], [
 347                                 splbuild="[Not found]"
 348                         ])
 349                 ])
 350                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 351                         break;
 352                 ], [
 353                         sleep 1
 354                         timeout=$((timeout-1))
 355                 ])
 356         done
 357
 358         AC_MSG_RESULT([$splbuild])
 359         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 360                 AC_MSG_ERROR([
 361         *** Please make sure the kmod spl devel <kernel> package for your
 362         *** distribution is installed then try again.  If that fails you
 363         *** can specify the location of the spl objects with the
 364         *** '--with-spl-obj=PATH' option.])
 365         ])
 366
 367         AC_MSG_CHECKING([spl source version])
 368         AS_IF([test -r $splbuild/spl_config.h &&
 369                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 370
 371                 splsrcver=`(echo "#include <spl_config.h>";
 372                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 373                             cpp -I $splbuild |
 374                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 375         ])
 376
 377         AS_IF([test -z "$splsrcver"], [
 378                 AC_MSG_RESULT([Not found])
 379                 AC_MSG_ERROR([
 380         *** Cannot determine the version of the spl source.
 381         *** Please prepare the spl source before running this script])
 382         ])
 383
 384         AC_MSG_RESULT([$splsrcver])
 385
 386         SPL=${splsrc}
 387         SPL_OBJ=${splbuild}
 388         SPL_VERSION=${splsrcver}
 389
 390         AC_SUBST(SPL)
 391         AC_SUBST(SPL_OBJ)
 392         AC_SUBST(SPL_VERSION)
 393
 394         dnl #
 395         dnl # Detect the name used for the SPL Module.symvers file.  If one
 396         dnl # does not exist this is likely because the SPL has been configured
 397         dnl # but not built.  The '--with-spl-timeout' option can be passed
 398         dnl # to pause here, waiting for the file to appear from a concurrently
 399         dnl # building SPL package.  If the file does not appear in time, a good
 400         dnl # guess is made as to what this file will be named based on what it
 401         dnl # is named in the kernel build products.  This file will first be
 402         dnl # used at link time so if the guess is wrong the build will fail
 403         dnl # then.  This unfortunately means the ZFS package does not contain a
 404         dnl # reliable mechanism to detect symbols exported by the SPL at
 405         dnl # configure time.
 406         dnl #
 407         AC_MSG_CHECKING([spl file name for module symbols])
 408         SPL_SYMBOLS=NONE
 409
 410         while true; do
 411                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 412                         SPL_SYMBOLS=Module.symvers
 413                 ], [test -r $SPL_OBJ/Modules.symvers], [
 414                         SPL_SYMBOLS=Modules.symvers
 415                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 416                         SPL_SYMBOLS=Module.symvers
 417                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 418                         SPL_SYMBOLS=Modules.symvers
 419                 ])
 420
 421                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 422                         break;
 423                 ], [
 424                         sleep 1
 425                         timeout=$((timeout-1))
 426                 ])
 427         done
 428
 429         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 430                 SPL_SYMBOLS=$LINUX_SYMBOLS
 431         ])
 432
 433         AC_MSG_RESULT([$SPL_SYMBOLS])
 434         AC_SUBST(SPL_SYMBOLS)
 435 ])
 436
 437 dnl #
 438 dnl # Basic toolchain sanity check.
 439 dnl #
 440 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 441         AC_MSG_CHECKING([whether modules can be built])
 442         ZFS_LINUX_TRY_COMPILE([],[],[
 443                 AC_MSG_RESULT([yes])
 444         ],[
 445                 AC_MSG_RESULT([no])
 446                 if test "x$enable_linux_builtin" != xyes; then
 447                         AC_MSG_ERROR([*** Unable to build an empty module.])
 448                 else
 449                         AC_MSG_ERROR([
 450         *** Unable to build an empty module.
 451         *** Please run 'make scripts' inside the kernel source tree.])
 452                 fi
 453         ])
 454 ])
 455
 456 dnl #
 457 dnl # Certain kernel build options are not supported.  These must be
 458 dnl # detected at configure time and cause a build failure.  Otherwise
 459 dnl # modules may be successfully built that behave incorrectly.
 460 dnl #
 461 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 462         AC_RUN_IFELSE([
 463                 AC_LANG_PROGRAM([
 464                         #include "$LINUX/include/linux/license.h"
 465                 ], [
 466                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 467                 ])
 468         ], [
 469                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 470                     [Define to 1 if GPL-only symbols can be used])
 471         ], [
 472         ])
 473
 474         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 475 ])
 476
 477 dnl #
 478 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 479 dnl #
 480 dnl # This is typically only set for debug kernels because it comes with
 481 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 482 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 483 dnl # This will cause a failure at link time which we'd rather know about
 484 dnl # at compile time.
 485 dnl #
 486 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 487 dnl # with the upstream community we add a check to detect this case.
 488 dnl #
 489 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 490
 491         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 492                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 493                 tmp_flags="$EXTRA_KCFLAGS"
 494                 ZFS_LINUX_TRY_COMPILE([
 495                         #include <linux/module.h>
 496                         #include <linux/mutex.h>
 497
 498                         MODULE_LICENSE("$ZFS_META_LICENSE");
 499                 ],[
 500                         struct mutex lock;
 501
 502                         mutex_init(&lock);
 503                         mutex_lock(&lock);
 504                         mutex_unlock(&lock);
 505                 ],[
 506                         AC_MSG_RESULT(no)
 507                 ],[
 508                         AC_MSG_RESULT(yes)
 509                         AC_MSG_ERROR([
 510         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 511         *** with the CDDL license and will prevent the module linking stage
 512         *** from succeeding.  You must rebuild your kernel without this
 513         *** option enabled.])
 514                 ])
 515                 EXTRA_KCFLAGS="$tmp_flags"
 516         ], [])
 517 ])
 518
 519 dnl #
 520 dnl # ZFS_LINUX_CONFTEST_H
 521 dnl #
 522 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 523 cat - <<_ACEOF >conftest.h
 524 $1
 525 _ACEOF
 526 ])
 527
 528 dnl #
 529 dnl # ZFS_LINUX_CONFTEST_C
 530 dnl #
 531 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 532 cat confdefs.h - <<_ACEOF >conftest.c
 533 $1
 534 _ACEOF
 535 ])
 536
 537 dnl #
 538 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 539 dnl #
 540 m4_define([ZFS_LANG_PROGRAM], [
 541 $1
 542 int
 543 main (void)
 544 {
 545 dnl Do *not* indent the following line: there may be CPP directives.
 546 dnl Don't move the `;' right after for the same reason.
 547 $2
 548   ;
 549   return 0;
 550 }
 551 ])
 552
 553 dnl #
 554 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 555 dnl #
 556 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 557         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 558         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 559         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 560         echo "obj-m := conftest.o" >build/Makefile
 561         modpost_flag=''
 562         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 563         AS_IF(
 564                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 565                 [$4],
 566                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 567         )
 568         rm -Rf build
 569 ])
 570
 571 dnl #
 572 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 573 dnl #
 574 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 575         [ZFS_LINUX_COMPILE_IFELSE(
 576         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 577         [modules],
 578         [test -s build/conftest.o],
 579         [$3], [$4])
 580 ])
 581
 582 dnl #
 583 dnl # ZFS_LINUX_CONFIG
 584 dnl #
 585 AC_DEFUN([ZFS_LINUX_CONFIG],
 586         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 587         ZFS_LINUX_TRY_COMPILE([
 588                 #include <linux/module.h>
 589         ],[
 590                 #ifndef CONFIG_$1
 591                 #error CONFIG_$1 not #defined
 592                 #endif
 593         ],[
 594                 AC_MSG_RESULT([yes])
 595                 $2
 596         ],[
 597                 AC_MSG_RESULT([no])
 598                 $3
 599         ])
 600 ])
 601
 602 dnl #
 603 dnl # ZFS_CHECK_SYMBOL_EXPORT
 604 dnl # check symbol exported or not
 605 dnl #
 606 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 607         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 608                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 609         rc=$?
 610         if test $rc -ne 0; then
 611                 export=0
 612                 for file in $2; do
 613                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 614                                 "$LINUX/$file" 2>/dev/null
 615                         rc=$?
 616                         if test $rc -eq 0; then
 617                                 export=1
 618                                 break;
 619                         fi
 620                 done
 621                 if test $export -eq 0; then :
 622                         $4
 623                 else :
 624                         $3
 625                 fi
 626         else :
 627                 $3
 628         fi
 629 ])
 630
 631 dnl #
 632 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 633 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 634 dnl # is called if not compiling for builtin
 635 dnl #
 636 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 637         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 638         if test $rc -ne 0; then :
 639                 $6
 640         else
 641                 if test "x$enable_linux_builtin" != xyes; then
 642                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 643                 fi
 644                 if test $rc -ne 0; then :
 645                         $6
 646                 else :
 647                         $5
 648                 fi
 649         fi
 650 ])
 651
 652 dnl #
 653 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 654 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 655 dnl # provided via the fifth parameter
 656 dnl #
 657 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 658         [ZFS_LINUX_COMPILE_IFELSE(
 659         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 660         [modules],
 661         [test -s build/conftest.o],
 662         [$3], [$4], [$5])
 663 ])