config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11         SPL_AC_KERNEL_CONFIG
  12
  13         if test "${LINUX_OBJ}" != "${LINUX}"; then
  14                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  15         fi
  16         AC_SUBST(KERNELMAKE_PARAMS)
  17
  18         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  19         AC_SUBST(KERNELCPPFLAGS)
  20
  21         SPL_AC_DEBUG
  22         SPL_AC_DEBUG_LOG
  23         SPL_AC_DEBUG_KMEM
  24         SPL_AC_DEBUG_KMEM_TRACKING
  25         SPL_AC_TEST_MODULE
  26         SPL_AC_ATOMIC_SPINLOCK
  27         SPL_AC_TYPE_ATOMIC64_CMPXCHG
  28         SPL_AC_TYPE_ATOMIC64_XCHG
  29         SPL_AC_TYPE_UINTPTR_T
  30         SPL_AC_3ARGS_INIT_WORK
  31         SPL_AC_2ARGS_REGISTER_SYSCTL
  32         SPL_AC_SET_SHRINKER
  33         SPL_AC_3ARGS_SHRINKER_CALLBACK
  34         SPL_AC_PATH_IN_NAMEIDATA
  35         SPL_AC_TASK_CURR
  36         SPL_AC_CTL_UNNUMBERED
  37         SPL_AC_CTL_NAME
  38         SPL_AC_FLS64
  39         SPL_AC_DEVICE_CREATE
  40         SPL_AC_5ARGS_DEVICE_CREATE
  41         SPL_AC_CLASS_DEVICE_CREATE
  42         SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT
  43         SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE
  44         SPL_AC_TIMESPEC_SUB
  45         SPL_AC_INIT_UTSNAME
  46         SPL_AC_FDTABLE_HEADER
  47         SPL_AC_FILES_FDTABLE
  48         SPL_AC_CLEAR_CLOSE_ON_EXEC
  49         SPL_AC_UACCESS_HEADER
  50         SPL_AC_KMALLOC_NODE
  51         SPL_AC_MONOTONIC_CLOCK
  52         SPL_AC_INODE_I_MUTEX
  53         SPL_AC_MUTEX_OWNER
  54         SPL_AC_MUTEX_OWNER_TASK_STRUCT
  55         SPL_AC_MUTEX_LOCK_NESTED
  56         SPL_AC_3ARGS_ON_EACH_CPU
  57         SPL_AC_KALLSYMS_LOOKUP_NAME
  58         SPL_AC_GET_VMALLOC_INFO
  59         SPL_AC_PGDAT_HELPERS
  60         SPL_AC_FIRST_ONLINE_PGDAT
  61         SPL_AC_NEXT_ONLINE_PGDAT
  62         SPL_AC_NEXT_ZONE
  63         SPL_AC_PGDAT_LIST
  64         SPL_AC_GLOBAL_PAGE_STATE
  65         SPL_AC_ZONE_STAT_ITEM_FREE
  66         SPL_AC_ZONE_STAT_ITEM_INACTIVE
  67         SPL_AC_ZONE_STAT_ITEM_ACTIVE
  68         SPL_AC_GET_ZONE_COUNTS
  69         SPL_AC_USER_PATH_DIR
  70         SPL_AC_SET_FS_PWD
  71         SPL_AC_2ARGS_SET_FS_PWD
  72         SPL_AC_2ARGS_VFS_UNLINK
  73         SPL_AC_4ARGS_VFS_RENAME
  74         SPL_AC_VFS_FSYNC
  75         SPL_AC_2ARGS_VFS_FSYNC
  76         SPL_AC_FS_STRUCT_SPINLOCK
  77         SPL_AC_CRED_STRUCT
  78         SPL_AC_GROUPS_SEARCH
  79         SPL_AC_PUT_TASK_STRUCT
  80         SPL_AC_5ARGS_PROC_HANDLER
  81         SPL_AC_KVASPRINTF
  82         SPL_AC_EXPORTED_RWSEM_IS_LOCKED
  83         SPL_AC_KERNEL_INVALIDATE_INODES
  84         SPL_AC_KERNEL_2ARGS_INVALIDATE_INODES
  85         SPL_AC_SHRINK_DCACHE_MEMORY
  86         SPL_AC_SHRINK_ICACHE_MEMORY
  87         SPL_AC_KERN_PATH_PARENT_HEADER
  88         SPL_AC_KERN_PATH_PARENT_SYMBOL
  89         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  90         SPL_AC_SHRINK_CONTROL_STRUCT
  91         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  92         SPL_AC_PMD_ALLOC_WITH_MASK
  93 ])
  94
  95 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  96         modpost=$LINUX/scripts/Makefile.modpost
  97         AC_MSG_CHECKING([kernel file name for module symbols])
  98         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
  99                 if grep -q Modules.symvers $modpost; then
 100                         LINUX_SYMBOLS=Modules.symvers
 101                 else
 102                         LINUX_SYMBOLS=Module.symvers
 103                 fi
 104
 105                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
 106                         AC_MSG_ERROR([
 107         *** Please make sure the kernel devel package for your distribution
 108         *** is installed.  If your building with a custom kernel make sure the
 109         *** kernel is configured, built, and the '--with-linux=PATH' configure
 110         *** option refers to the location of the kernel source.])
 111                 fi
 112         else
 113                 LINUX_SYMBOLS=NONE
 114         fi
 115         AC_MSG_RESULT($LINUX_SYMBOLS)
 116         AC_SUBST(LINUX_SYMBOLS)
 117 ])
 118
 119 AC_DEFUN([SPL_AC_KERNEL], [
 120         AC_ARG_WITH([linux],
 121                 AS_HELP_STRING([--with-linux=PATH],
 122                 [Path to kernel source]),
 123                 [kernelsrc="$withval"])
 124
 125         AC_ARG_WITH([linux-obj],
 126                 AS_HELP_STRING([--with-linux-obj=PATH],
 127                 [Path to kernel build objects]),
 128                 [kernelbuild="$withval"])
 129
 130         AC_MSG_CHECKING([kernel source directory])
 131         if test -z "$kernelsrc"; then
 132                 if test -e "/lib/modules/$(uname -r)/source"; then
 133                         headersdir="/lib/modules/$(uname -r)/source"
 134                         sourcelink=$(readlink -f "$headersdir")
 135                 elif test -e "/lib/modules/$(uname -r)/build"; then
 136                         headersdir="/lib/modules/$(uname -r)/build"
 137                         sourcelink=$(readlink -f "$headersdir")
 138                 else
 139                         sourcelink=$(ls -1d /usr/src/kernels/* \
 140                                      /usr/src/linux-* \
 141                                      2>/dev/null | grep -v obj | tail -1)
 142                 fi
 143
 144                 if test -n "$sourcelink" && test -e ${sourcelink}; then
 145                         kernelsrc=`readlink -f ${sourcelink}`
 146                 else
 147                         AC_MSG_RESULT([Not found])
 148                         AC_MSG_ERROR([
 149         *** Please make sure the kernel devel package for your distribution
 150         *** is installed then try again.  If that fails you can specify the
 151         *** location of the kernel source with the '--with-linux=PATH' option.])
 152                 fi
 153         else
 154                 if test "$kernelsrc" = "NONE"; then
 155                         kernsrcver=NONE
 156                 fi
 157         fi
 158
 159         AC_MSG_RESULT([$kernelsrc])
 160         AC_MSG_CHECKING([kernel build directory])
 161         if test -z "$kernelbuild"; then
 162                 if test -e "/lib/modules/$(uname -r)/build"; then
 163                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 164                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 165                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 166                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 167                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 168                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 169                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 170                 else
 171                         kernelbuild=${kernelsrc}
 172                 fi
 173         fi
 174         AC_MSG_RESULT([$kernelbuild])
 175
 176         AC_MSG_CHECKING([kernel source version])
 177         utsrelease1=$kernelbuild/include/linux/version.h
 178         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 179         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 180         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 181                 utsrelease=linux/version.h
 182         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 183                 utsrelease=linux/utsrelease.h
 184         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 185                 utsrelease=generated/utsrelease.h
 186         fi
 187
 188         if test "$utsrelease"; then
 189                 kernsrcver=`(echo "#include <$utsrelease>";
 190                              echo "kernsrcver=UTS_RELEASE") |
 191                              cpp -I $kernelbuild/include |
 192                              grep "^kernsrcver=" | cut -d \" -f 2`
 193
 194                 if test -z "$kernsrcver"; then
 195                         AC_MSG_RESULT([Not found])
 196                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 197                 fi
 198         else
 199                 AC_MSG_RESULT([Not found])
 200                 if test "x$enable_linux_builtin" != xyes; then
 201                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 202                 else
 203                         AC_MSG_ERROR([
 204         *** Cannot find UTS_RELEASE definition.
 205         *** Please run 'make prepare' inside the kernel source tree.])
 206                 fi
 207         fi
 208
 209         AC_MSG_RESULT([$kernsrcver])
 210
 211         LINUX=${kernelsrc}
 212         LINUX_OBJ=${kernelbuild}
 213         LINUX_VERSION=${kernsrcver}
 214
 215         AC_SUBST(LINUX)
 216         AC_SUBST(LINUX_OBJ)
 217         AC_SUBST(LINUX_VERSION)
 218
 219         SPL_AC_MODULE_SYMVERS
 220 ])
 221
 222 AC_DEFUN([SPL_AC_KERNEL_CONFIG], [
 223         SPL_LINUX_CONFIG([PREEMPT],
 224                 AC_MSG_ERROR([
 225                 *** Kernel built with CONFIG_PREEMPT which is not supported.
 226                 ** You must rebuild your kernel without this option.]), [])
 227 ])
 228
 229 dnl #
 230 dnl # Default SPL user configuration
 231 dnl #
 232 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 233
 234 dnl #
 235 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 236 dnl # are missing it is non-fatal but you will not be able to build
 237 dnl # RPM packages and will be warned if you try too.
 238 dnl #
 239 AC_DEFUN([SPL_AC_RPM], [
 240         RPM=rpm
 241         RPMBUILD=rpmbuild
 242
 243         AC_MSG_CHECKING([whether $RPM is available])
 244         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 245                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 246                 HAVE_RPM=yes
 247                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 248         ],[
 249                 HAVE_RPM=no
 250                 AC_MSG_RESULT([$HAVE_RPM])
 251         ])
 252
 253         AC_MSG_CHECKING([whether $RPMBUILD is available])
 254         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 255                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 256                 HAVE_RPMBUILD=yes
 257                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 258         ],[
 259                 HAVE_RPMBUILD=no
 260                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 261         ])
 262
 263         AC_SUBST(HAVE_RPM)
 264         AC_SUBST(RPM)
 265         AC_SUBST(RPM_VERSION)
 266
 267         AC_SUBST(HAVE_RPMBUILD)
 268         AC_SUBST(RPMBUILD)
 269         AC_SUBST(RPMBUILD_VERSION)
 270 ])
 271
 272 dnl #
 273 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 274 dnl # tools are missing it is non-fatal but you will not be able to build
 275 dnl # DEB packages and will be warned if you try too.
 276 dnl #
 277 AC_DEFUN([SPL_AC_DPKG], [
 278         DPKG=dpkg
 279         DPKGBUILD=dpkg-buildpackage
 280
 281         AC_MSG_CHECKING([whether $DPKG is available])
 282         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 283                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 284                 HAVE_DPKG=yes
 285                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 286         ],[
 287                 HAVE_DPKG=no
 288                 AC_MSG_RESULT([$HAVE_DPKG])
 289         ])
 290
 291         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 292         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 293                 DPKGBUILD_VERSION=$(echo $tmp | \
 294                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 295                 HAVE_DPKGBUILD=yes
 296                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 297         ],[
 298                 HAVE_DPKGBUILD=no
 299                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 300         ])
 301
 302         AC_SUBST(HAVE_DPKG)
 303         AC_SUBST(DPKG)
 304         AC_SUBST(DPKG_VERSION)
 305
 306         AC_SUBST(HAVE_DPKGBUILD)
 307         AC_SUBST(DPKGBUILD)
 308         AC_SUBST(DPKGBUILD_VERSION)
 309 ])
 310
 311 dnl #
 312 dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
 313 dnl # tools are missing it is non-fatal but you will not be able to
 314 dnl # build Arch Linux packages and will be warned if you try too.
 315 dnl #
 316 AC_DEFUN([SPL_AC_PACMAN], [
 317         PACMAN=pacman
 318         MAKEPKG=makepkg
 319
 320         AC_MSG_CHECKING([whether $PACMAN is available])
 321         tmp=$($PACMAN --version 2>/dev/null)
 322         AS_IF([test -n "$tmp"], [
 323                 PACMAN_VERSION=$(echo $tmp |
 324                                  $AWK '/Pacman/ { print $[3] }' |
 325                                  $SED 's/^v//')
 326                 HAVE_PACMAN=yes
 327                 AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
 328         ],[
 329                 HAVE_PACMAN=no
 330                 AC_MSG_RESULT([$HAVE_PACMAN])
 331         ])
 332
 333         AC_MSG_CHECKING([whether $MAKEPKG is available])
 334         tmp=$($MAKEPKG --version 2>/dev/null)
 335         AS_IF([test -n "$tmp"], [
 336                 MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
 337                 HAVE_MAKEPKG=yes
 338                 AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
 339         ],[
 340                 HAVE_MAKEPKG=no
 341                 AC_MSG_RESULT([$HAVE_MAKEPKG])
 342         ])
 343
 344         AC_SUBST(HAVE_PACMAN)
 345         AC_SUBST(PACMAN)
 346         AC_SUBST(PACMAN_VERSION)
 347
 348         AC_SUBST(HAVE_MAKEPKG)
 349         AC_SUBST(MAKEPKG)
 350         AC_SUBST(MAKEPKG_VERSION)
 351 ])
 352
 353 dnl #
 354 dnl # Until native packaging for various different packing systems
 355 dnl # can be added the least we can do is attempt to use alien to
 356 dnl # convert the RPM packages to the needed package type.  This is
 357 dnl # a hack but so far it has worked reasonable well.
 358 dnl #
 359 AC_DEFUN([SPL_AC_ALIEN], [
 360         ALIEN=alien
 361
 362         AC_MSG_CHECKING([whether $ALIEN is available])
 363         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 364                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 365                 HAVE_ALIEN=yes
 366                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 367         ],[
 368                 HAVE_ALIEN=no
 369                 AC_MSG_RESULT([$HAVE_ALIEN])
 370         ])
 371
 372         AC_SUBST(HAVE_ALIEN)
 373         AC_SUBST(ALIEN)
 374         AC_SUBST(ALIEN_VERSION)
 375 ])
 376
 377 dnl #
 378 dnl # Using the VENDOR tag from config.guess set the default
 379 dnl # package type for 'make pkg': (rpm | deb | tgz)
 380 dnl #
 381 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 382         AC_MSG_CHECKING([linux distribution])
 383         if test -f /etc/toss-release ; then
 384                 VENDOR=toss ;
 385         elif test -f /etc/fedora-release ; then
 386                 VENDOR=fedora ;
 387         elif test -f /etc/redhat-release ; then
 388                 VENDOR=redhat ;
 389         elif test -f /etc/gentoo-release ; then
 390                 VENDOR=gentoo ;
 391         elif test -f /etc/arch-release ; then
 392                 VENDOR=arch ;
 393         elif test -f /etc/SuSE-release ; then
 394                 VENDOR=sles ;
 395         elif test -f /etc/slackware-version ; then
 396                 VENDOR=slackware ;
 397         elif test -f /etc/lunar.release ; then
 398                 VENDOR=lunar ;
 399         elif test -f /etc/lsb-release ; then
 400                 VENDOR=ubuntu ;
 401         elif test -f /etc/debian_version ; then
 402                 VENDOR=debian ;
 403         else
 404                 VENDOR= ;
 405         fi
 406         AC_MSG_RESULT([$VENDOR])
 407         AC_SUBST(VENDOR)
 408
 409         AC_MSG_CHECKING([default package type])
 410         case "$VENDOR" in
 411                 toss)       DEFAULT_PACKAGE=rpm  ;;
 412                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 413                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 414                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 415                 arch)       DEFAULT_PACKAGE=arch ;;
 416                 sles)       DEFAULT_PACKAGE=rpm  ;;
 417                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 418                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 419                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 420                 debian)     DEFAULT_PACKAGE=deb  ;;
 421                 *)          DEFAULT_PACKAGE=rpm  ;;
 422         esac
 423
 424         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 425         AC_SUBST(DEFAULT_PACKAGE)
 426 ])
 427
 428 dnl #
 429 dnl # Default SPL user configuration
 430 dnl #
 431 AC_DEFUN([SPL_AC_PACKAGE], [
 432         SPL_AC_DEFAULT_PACKAGE
 433         SPL_AC_RPM
 434         SPL_AC_DPKG
 435         SPL_AC_ALIEN
 436
 437         AS_IF([test "$VENDOR" = "arch"], [SPL_AC_PACMAN])
 438 ])
 439
 440 AC_DEFUN([SPL_AC_LICENSE], [
 441         AC_MSG_CHECKING([spl license])
 442         LICENSE=GPL
 443         AC_MSG_RESULT([$LICENSE])
 444         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DHAVE_GPL_ONLY_SYMBOLS"
 445         AC_SUBST(LICENSE)
 446 ])
 447
 448 AC_DEFUN([SPL_AC_CONFIG], [
 449         SPL_CONFIG=all
 450         AC_ARG_WITH([config],
 451                 AS_HELP_STRING([--with-config=CONFIG],
 452                 [Config file 'kernel|user|all|srpm']),
 453                 [SPL_CONFIG="$withval"])
 454         AC_ARG_ENABLE([linux-builtin],
 455                 [AC_HELP_STRING([--enable-linux-builtin],
 456                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 457                 [],
 458                 [enable_linux_builtin=no])
 459
 460         AC_MSG_CHECKING([spl config])
 461         AC_MSG_RESULT([$SPL_CONFIG]);
 462         AC_SUBST(SPL_CONFIG)
 463
 464         case "$SPL_CONFIG" in
 465                 kernel) SPL_AC_CONFIG_KERNEL ;;
 466                 user)   SPL_AC_CONFIG_USER   ;;
 467                 all)    SPL_AC_CONFIG_KERNEL
 468                         SPL_AC_CONFIG_USER   ;;
 469                 srpm)                        ;;
 470                 *)
 471                 AC_MSG_RESULT([Error!])
 472                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 473                              user kernel|user|all|srpm]) ;;
 474         esac
 475
 476         AM_CONDITIONAL([CONFIG_USER],
 477                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 478         AM_CONDITIONAL([CONFIG_KERNEL],
 479                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 480                        [test "x$enable_linux_builtin" != xyes ])
 481 ])
 482
 483 dnl #
 484 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 485 dnl # By default this support is disabled.
 486 dnl #
 487 AC_DEFUN([SPL_AC_DEBUG], [
 488         AC_MSG_CHECKING([whether debugging is enabled])
 489         AC_ARG_ENABLE([debug],
 490                 [AS_HELP_STRING([--enable-debug],
 491                 [Enable generic debug support @<:@default=no@:>@])],
 492                 [],
 493                 [enable_debug=no])
 494
 495         AS_IF([test "x$enable_debug" = xyes],
 496         [
 497                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 498                 DEBUG_CFLAGS="-DDEBUG -Werror"
 499                 DEBUG_SPL="_with_debug"
 500         ], [
 501                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 502                 DEBUG_CFLAGS="-DNDEBUG"
 503                 DEBUG_SPL="_without_debug"
 504         ])
 505
 506         AC_SUBST(DEBUG_CFLAGS)
 507         AC_SUBST(DEBUG_SPL)
 508         AC_MSG_RESULT([$enable_debug])
 509 ])
 510
 511 dnl #
 512 dnl # Enabled by default it provides a basic debug log infrastructure.
 513 dnl # Each subsystem registers itself with a name and logs messages
 514 dnl # using predefined types.  If the debug mask it set to allow the
 515 dnl # message type it will be written to the internal log.  The log
 516 dnl # can be dumped to a file by echoing 1 to the 'dump' proc entry,
 517 dnl # after dumping the log it must be decoded using the spl utility.
 518 dnl #
 519 dnl # echo 1 >/proc/sys/kernel/spl/debug/dump
 520 dnl # spl /tmp/spl-log.xxx.yyy /tmp/spl-log.xxx.yyy.txt
 521 dnl #
 522 AC_DEFUN([SPL_AC_DEBUG_LOG], [
 523         AC_ARG_ENABLE([debug-log],
 524                 [AS_HELP_STRING([--enable-debug-log],
 525                 [Enable basic debug logging @<:@default=yes@:>@])],
 526                 [],
 527                 [enable_debug_log=yes])
 528
 529         AS_IF([test "x$enable_debug_log" = xyes],
 530         [
 531                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_LOG"
 532                 DEBUG_LOG="_with_debug_log"
 533                 AC_DEFINE([DEBUG_LOG], [1],
 534                 [Define to 1 to enable basic debug logging])
 535         ], [
 536                 DEBUG_LOG="_without_debug_log"
 537         ])
 538
 539         AC_SUBST(DEBUG_LOG)
 540         AC_MSG_CHECKING([whether basic debug logging is enabled])
 541         AC_MSG_RESULT([$enable_debug_log])
 542 ])
 543
 544 dnl #
 545 dnl # Enabled by default it provides a minimal level of memory tracking.
 546 dnl # A total count of bytes allocated is kept for each alloc and free.
 547 dnl # Then at module unload time a report to the console will be printed
 548 dnl # if memory was leaked.  Additionally, /proc/spl/kmem/slab will exist
 549 dnl # and provide an easy way to inspect the kmem based slab.
 550 dnl #
 551 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 552         AC_ARG_ENABLE([debug-kmem],
 553                 [AS_HELP_STRING([--enable-debug-kmem],
 554                 [Enable basic kmem accounting @<:@default=yes@:>@])],
 555                 [],
 556                 [enable_debug_kmem=yes])
 557
 558         AS_IF([test "x$enable_debug_kmem" = xyes],
 559         [
 560                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 561                 DEBUG_KMEM="_with_debug_kmem"
 562                 AC_DEFINE([DEBUG_KMEM], [1],
 563                 [Define to 1 to enable basic kmem accounting])
 564         ], [
 565                 DEBUG_KMEM="_without_debug_kmem"
 566         ])
 567
 568         AC_SUBST(DEBUG_KMEM)
 569         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 570         AC_MSG_RESULT([$enable_debug_kmem])
 571 ])
 572
 573 dnl #
 574 dnl # Disabled by default it provides detailed memory tracking.  This
 575 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 576 dnl # not only will total bytes be tracked but also the location of every
 577 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 578 dnl # addresses and where they were allocated will be dumped to the console.
 579 dnl # Enabling this feature has a significant impact on performance but it
 580 dnl # makes finding memory leaks pretty straight forward.
 581 dnl #
 582 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 583         AC_ARG_ENABLE([debug-kmem-tracking],
 584                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 585                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 586                 [],
 587                 [enable_debug_kmem_tracking=no])
 588
 589         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 590         [
 591                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 592                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 593                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 594                 [Define to 1 to enable detailed kmem tracking])
 595         ], [
 596                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 597         ])
 598
 599         AC_SUBST(DEBUG_KMEM_TRACKING)
 600         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 601         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 602 ])
 603
 604 dnl #
 605 dnl # SPL_LINUX_CONFTEST
 606 dnl #
 607 AC_DEFUN([SPL_LINUX_CONFTEST], [
 608 cat confdefs.h - <<_ACEOF >conftest.c
 609 $1
 610 _ACEOF
 611 ])
 612
 613 dnl #
 614 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 615 dnl #
 616 m4_define([SPL_LANG_PROGRAM], [
 617 $1
 618 int
 619 main (void)
 620 {
 621 dnl Do *not* indent the following line: there may be CPP directives.
 622 dnl Don't move the `;' right after for the same reason.
 623 $2
 624   ;
 625   return 0;
 626 }
 627 ])
 628
 629 dnl #
 630 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 631 dnl #
 632 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 633         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 634         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 635         echo "obj-m := conftest.o" >build/Makefile
 636         modpost_flag=''
 637         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 638         AS_IF(
 639                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 640                 [$4],
 641                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 642         )
 643         rm -Rf build
 644 ])
 645
 646 dnl #
 647 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 648 dnl #
 649 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 650         [SPL_LINUX_COMPILE_IFELSE(
 651         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 652         [modules],
 653         [test -s build/conftest.o],
 654         [$3], [$4])
 655 ])
 656
 657 dnl #
 658 dnl # SPL_LINUX_CONFIG
 659 dnl #
 660 AC_DEFUN([SPL_LINUX_CONFIG],
 661         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 662         SPL_LINUX_TRY_COMPILE([
 663                 #include <linux/module.h>
 664         ],[
 665                 #ifndef CONFIG_$1
 666                 #error CONFIG_$1 not #defined
 667                 #endif
 668         ],[
 669                 AC_MSG_RESULT([yes])
 670                 $2
 671         ],[
 672                 AC_MSG_RESULT([no])
 673                 $3
 674         ])
 675 ])
 676
 677 dnl #
 678 dnl # SPL_CHECK_SYMBOL_EXPORT
 679 dnl # check symbol exported or not
 680 dnl #
 681 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 682         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 683                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 684         rc=$?
 685         if test $rc -ne 0; then
 686                 export=0
 687                 for file in $2; do
 688                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 689                                 "$LINUX_OBJ/$file" 2>/dev/null
 690                         rc=$?
 691                         if test $rc -eq 0; then
 692                                 export=1
 693                                 break;
 694                         fi
 695                 done
 696                 if test $export -eq 0; then :
 697                         $4
 698                 else :
 699                         $3
 700                 fi
 701         else :
 702                 $3
 703         fi
 704 ])
 705
 706 dnl #
 707 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 708 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 709 dnl # is called if not compiling for builtin
 710 dnl #
 711 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 712         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 713         if test $rc -ne 0; then :
 714                 $6
 715         else
 716                 if test "x$enable_linux_builtin" != xyes; then
 717                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 718                 fi
 719                 if test $rc -ne 0; then :
 720                         $6
 721                 else :
 722                         $5
 723                 fi
 724         fi
 725 ])
 726
 727 dnl #
 728 dnl # SPL_CHECK_SYMBOL_HEADER
 729 dnl # check if a symbol prototype is defined in listed headers.
 730 dnl #
 731 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 732         AC_MSG_CHECKING([whether symbol $1 exists in header])
 733         header=0
 734         for file in $3; do
 735                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 736                 rc=$?
 737                 if test $rc -eq 0; then
 738                         header=1
 739                         break;
 740                 fi
 741         done
 742         if test $header -eq 0; then
 743                 AC_MSG_RESULT([no])
 744                 $5
 745         else
 746                 AC_MSG_RESULT([yes])
 747                 $4
 748         fi
 749 ])
 750
 751 dnl #
 752 dnl # SPL_CHECK_HEADER
 753 dnl # check whether header exists and define HAVE_$2_HEADER
 754 dnl #
 755 AC_DEFUN([SPL_CHECK_HEADER],
 756         [AC_MSG_CHECKING([whether header $1 exists])
 757         SPL_LINUX_TRY_COMPILE([
 758                 #include <$1>
 759         ],[
 760                 return 0;
 761         ],[
 762                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 763                 AC_MSG_RESULT(yes)
 764                 $3
 765         ],[
 766                 AC_MSG_RESULT(no)
 767                 $4
 768         ])
 769 ])
 770
 771 dnl #
 772 dnl # Basic toolchain sanity check.
 773 dnl #
 774 AC_DEFUN([SPL_AC_TEST_MODULE],
 775         [AC_MSG_CHECKING([whether modules can be built])
 776         SPL_LINUX_TRY_COMPILE([],[],[
 777                 AC_MSG_RESULT([yes])
 778         ],[
 779                 AC_MSG_RESULT([no])
 780                 if test "x$enable_linux_builtin" != xyes; then
 781                         AC_MSG_ERROR([*** Unable to build an empty module.])
 782                 else
 783                         AC_MSG_ERROR([
 784         *** Unable to build an empty module.
 785         *** Please run 'make scripts' inside the kernel source tree.])
 786                 fi
 787         ])
 788 ])
 789
 790 dnl #
 791 dnl # Use the atomic implemenation based on global spinlocks.  This
 792 dnl # should only be needed by 32-bit kernels which do not provide
 793 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 794 dnl # if problems are observed with the direct mapping to the native
 795 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 796 dnl # if you kernel does not an atomic64_* API.
 797 dnl #
 798 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 799         AC_ARG_ENABLE([atomic-spinlocks],
 800                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 801                 [Atomic types use spinlocks @<:@default=check@:>@])],
 802                 [],
 803                 [enable_atomic_spinlocks=check])
 804
 805         SPL_LINUX_TRY_COMPILE([
 806                 #include <asm/atomic.h>
 807         ],[
 808                 atomic64_t *ptr __attribute__ ((unused));
 809         ],[
 810                 have_atomic64_t=yes
 811                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 812                         [kernel defines atomic64_t])
 813         ],[
 814                 have_atomic64_t=no
 815         ])
 816
 817         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 818                 AS_IF([test "x$have_atomic64_t" = xyes], [
 819                         enable_atomic_spinlocks=no
 820                 ],[
 821                         enable_atomic_spinlocks=yes
 822                 ])
 823         ])
 824
 825         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 826                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 827                         [Atomic types use spinlocks])
 828         ],[
 829                 AS_IF([test "x$have_atomic64_t" = xno], [
 830                         AC_MSG_FAILURE(
 831                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 832                 ])
 833         ])
 834
 835         AC_MSG_CHECKING([whether atomic types use spinlocks])
 836         AC_MSG_RESULT([$enable_atomic_spinlocks])
 837
 838         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 839         AC_MSG_RESULT([$have_atomic64_t])
 840 ])
 841
 842 dnl #
 843 dnl # 2.6.24 API change,
 844 dnl # check if atomic64_cmpxchg is defined
 845 dnl #
 846 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_CMPXCHG],
 847         [AC_MSG_CHECKING([whether kernel defines atomic64_cmpxchg])
 848         SPL_LINUX_TRY_COMPILE([
 849                 #include <asm/atomic.h>
 850                 #include <asm/system.h>
 851         ],[
 852                 atomic64_cmpxchg((atomic64_t *)NULL, 0, 0);
 853         ],[
 854                 AC_MSG_RESULT([yes])
 855                 AC_DEFINE(HAVE_ATOMIC64_CMPXCHG, 1,
 856                           [kernel defines atomic64_cmpxchg])
 857         ],[
 858                 AC_MSG_RESULT([no])
 859         ])
 860 ])
 861
 862 dnl #
 863 dnl # 2.6.24 API change,
 864 dnl # check if atomic64_xchg is defined
 865 dnl #
 866 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_XCHG],
 867         [AC_MSG_CHECKING([whether kernel defines atomic64_xchg])
 868         SPL_LINUX_TRY_COMPILE([
 869                 #include <asm/atomic.h>
 870         ],[
 871                 atomic64_xchg((atomic64_t *)NULL, 0);
 872         ],[
 873                 AC_MSG_RESULT([yes])
 874                 AC_DEFINE(HAVE_ATOMIC64_XCHG, 1,
 875                           [kernel defines atomic64_xchg])
 876         ],[
 877                 AC_MSG_RESULT([no])
 878         ])
 879 ])
 880
 881 dnl #
 882 dnl # 2.6.24 API change,
 883 dnl # check if uintptr_t typedef is defined
 884 dnl #
 885 AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
 886         [AC_MSG_CHECKING([whether kernel defines uintptr_t])
 887         SPL_LINUX_TRY_COMPILE([
 888                 #include <linux/types.h>
 889         ],[
 890                 uintptr_t *ptr __attribute__ ((unused));
 891         ],[
 892                 AC_MSG_RESULT([yes])
 893                 AC_DEFINE(HAVE_UINTPTR_T, 1,
 894                           [kernel defines uintptr_t])
 895         ],[
 896                 AC_MSG_RESULT([no])
 897         ])
 898 ])
 899
 900 dnl #
 901 dnl # 2.6.20 API change,
 902 dnl # INIT_WORK use 2 args and not store data inside
 903 dnl #
 904 AC_DEFUN([SPL_AC_3ARGS_INIT_WORK],
 905         [AC_MSG_CHECKING([whether INIT_WORK wants 3 args])
 906         SPL_LINUX_TRY_COMPILE([
 907                 #include <linux/workqueue.h>
 908         ],[
 909                 struct work_struct work __attribute__ ((unused));
 910                 INIT_WORK(&work, NULL, NULL);
 911         ],[
 912                 AC_MSG_RESULT(yes)
 913                 AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
 914                           [INIT_WORK wants 3 args])
 915         ],[
 916                 AC_MSG_RESULT(no)
 917         ])
 918 ])
 919
 920 dnl #
 921 dnl # 2.6.21 API change,
 922 dnl # 'register_sysctl_table' use only one argument instead of two
 923 dnl #
 924 AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
 925         [AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
 926         SPL_LINUX_TRY_COMPILE([
 927                 #include <linux/sysctl.h>
 928         ],[
 929                 (void) register_sysctl_table(NULL, 0);
 930         ],[
 931                 AC_MSG_RESULT(yes)
 932                 AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 933                           [register_sysctl_table() wants 2 args])
 934         ],[
 935                 AC_MSG_RESULT(no)
 936         ])
 937 ])
 938
 939 dnl #
 940 dnl # 2.6.23 API change
 941 dnl # Old set_shrinker API replaced with register_shrinker
 942 dnl #
 943 AC_DEFUN([SPL_AC_SET_SHRINKER], [
 944         AC_MSG_CHECKING([whether set_shrinker() available])
 945         SPL_LINUX_TRY_COMPILE([
 946                 #include <linux/mm.h>
 947         ],[
 948                 return set_shrinker(DEFAULT_SEEKS, NULL);
 949         ],[
 950                 AC_MSG_RESULT([yes])
 951                 AC_DEFINE(HAVE_SET_SHRINKER, 1,
 952                           [set_shrinker() available])
 953         ],[
 954                 AC_MSG_RESULT([no])
 955         ])
 956 ])
 957
 958 dnl #
 959 dnl # 2.6.35 API change,
 960 dnl # Add context to shrinker callback
 961 dnl #
 962 AC_DEFUN([SPL_AC_3ARGS_SHRINKER_CALLBACK],
 963         [AC_MSG_CHECKING([whether shrinker callback wants 3 args])
 964         tmp_flags="$EXTRA_KCFLAGS"
 965         EXTRA_KCFLAGS="-Werror"
 966         SPL_LINUX_TRY_COMPILE([
 967                 #include <linux/mm.h>
 968
 969                 int shrinker_cb(struct shrinker *, int, unsigned int);
 970         ],[
 971                 struct shrinker cache_shrinker = {
 972                         .shrink = shrinker_cb,
 973                         .seeks = DEFAULT_SEEKS,
 974                 };
 975                 register_shrinker(&cache_shrinker);
 976         ],[
 977                 AC_MSG_RESULT(yes)
 978                 AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 979                           [shrinker callback wants 3 args])
 980         ],[
 981                 AC_MSG_RESULT(no)
 982         ])
 983         EXTRA_KCFLAGS="$tmp_flags"
 984 ])
 985
 986 dnl #
 987 dnl # 2.6.25 API change,
 988 dnl # struct path entry added to struct nameidata
 989 dnl #
 990 AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
 991         [AC_MSG_CHECKING([whether struct path used in struct nameidata])
 992         SPL_LINUX_TRY_COMPILE([
 993                 #include <linux/namei.h>
 994         ],[
 995                 struct nameidata nd __attribute__ ((unused));
 996
 997                 nd.path.mnt = NULL;
 998                 nd.path.dentry = NULL;
 999         ],[
1000                 AC_MSG_RESULT(yes)
1001                 AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
1002                           [struct path used in struct nameidata])
1003         ],[
1004                 AC_MSG_RESULT(no)
1005         ])
1006 ])
1007
1008 dnl #
1009 dnl # Custom SPL patch may export this system it is not required
1010 dnl #
1011 AC_DEFUN([SPL_AC_TASK_CURR],
1012         [AC_MSG_CHECKING([whether task_curr() is available])
1013         SPL_LINUX_TRY_COMPILE_SYMBOL([
1014                 #include <linux/sched.h>
1015         ], [
1016                 task_curr(NULL);
1017         ], [task_curr], [kernel/sched.c], [
1018                 AC_MSG_RESULT(yes)
1019                 AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() is available])
1020         ], [
1021                 AC_MSG_RESULT(no)
1022         ])
1023 ])
1024
1025 dnl #
1026 dnl # 2.6.19 API change,
1027 dnl # Use CTL_UNNUMBERED when binary sysctl is not required
1028 dnl #
1029 AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
1030         [AC_MSG_CHECKING([whether unnumbered sysctl support exists])
1031         SPL_LINUX_TRY_COMPILE([
1032                 #include <linux/sysctl.h>
1033         ],[
1034                 #ifndef CTL_UNNUMBERED
1035                 #error CTL_UNNUMBERED undefined
1036                 #endif
1037         ],[
1038                 AC_MSG_RESULT(yes)
1039                 AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
1040                           [unnumbered sysctl support exists])
1041         ],[
1042                 AC_MSG_RESULT(no)
1043         ])
1044 ])
1045
1046 dnl #
1047 dnl # 2.6.33 API change,
1048 dnl # Removed .ctl_name from struct ctl_table.
1049 dnl #
1050 AC_DEFUN([SPL_AC_CTL_NAME], [
1051         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
1052         SPL_LINUX_TRY_COMPILE([
1053                 #include <linux/sysctl.h>
1054         ],[
1055                 struct ctl_table ctl __attribute__ ((unused));
1056                 ctl.ctl_name = 0;
1057         ],[
1058                 AC_MSG_RESULT(yes)
1059                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
1060         ],[
1061                 AC_MSG_RESULT(no)
1062         ])
1063 ])
1064
1065 dnl #
1066 dnl # 2.6.16 API change.
1067 dnl # Check if 'fls64()' is available
1068 dnl #
1069 AC_DEFUN([SPL_AC_FLS64],
1070         [AC_MSG_CHECKING([whether fls64() is available])
1071         SPL_LINUX_TRY_COMPILE([
1072                 #include <linux/bitops.h>
1073         ],[
1074                 return fls64(0);
1075         ],[
1076                 AC_MSG_RESULT(yes)
1077                 AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
1078         ],[
1079                 AC_MSG_RESULT(no)
1080         ])
1081 ])
1082
1083 dnl #
1084 dnl # 2.6.18 API change, check whether device_create() is available.
1085 dnl # Device_create() was introduced in 2.6.18 and depricated
1086 dnl # class_device_create() which was fully removed in 2.6.26.
1087 dnl #
1088 AC_DEFUN([SPL_AC_DEVICE_CREATE],
1089         [AC_MSG_CHECKING([whether device_create() is available])
1090         SPL_CHECK_SYMBOL_EXPORT([device_create], [drivers/base/core.c], [
1091                 AC_MSG_RESULT(yes)
1092                 AC_DEFINE(HAVE_DEVICE_CREATE, 1,
1093                           [device_create() is available])
1094         ], [
1095                 AC_MSG_RESULT(no)
1096         ])
1097 ])
1098
1099 dnl #
1100 dnl # 2.6.27 API change,
1101 dnl # device_create() uses 5 args, new 'drvdata' argument.
1102 dnl #
1103 AC_DEFUN([SPL_AC_5ARGS_DEVICE_CREATE], [
1104         AC_MSG_CHECKING([whether device_create() wants 5 args])
1105         tmp_flags="$EXTRA_KCFLAGS"
1106         EXTRA_KCFLAGS="-Werror"
1107         SPL_LINUX_TRY_COMPILE([
1108                 #include <linux/device.h>
1109         ],[
1110                 device_create(NULL, NULL, 0, NULL, "%d", 1);
1111         ],[
1112                 AC_MSG_RESULT(yes)
1113                 AC_DEFINE(HAVE_5ARGS_DEVICE_CREATE, 1,
1114                           [device_create wants 5 args])
1115         ],[
1116                 AC_MSG_RESULT(no)
1117         ])
1118         EXTRA_KCFLAGS="$tmp_flags"
1119 ])
1120
1121 dnl #
1122 dnl # 2.6.13 API change, check whether class_device_create() is available.
1123 dnl # Class_device_create() was introduced in 2.6.13 and depricated
1124 dnl # class_simple_device_add() which was fully removed in 2.6.13.
1125 dnl #
1126 AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE],
1127         [AC_MSG_CHECKING([whether class_device_create() is available])
1128         SPL_LINUX_TRY_COMPILE_SYMBOL([
1129                 #include <linux/device.h>
1130         ], [
1131                 class_device_create(NULL, NULL, 0, NULL, NULL);
1132         ], [class_device_create], [drivers/base/class.c], [
1133                 AC_MSG_RESULT(yes)
1134                 AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
1135                           [class_device_create() is available])
1136         ], [
1137                 AC_MSG_RESULT(no)
1138         ])
1139 ])
1140
1141 dnl #
1142 dnl # 2.6.26 API change, set_normalized_timespec() is exported.
1143 dnl #
1144 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT],
1145         [AC_MSG_CHECKING([whether set_normalized_timespec() is available as export])
1146         SPL_LINUX_TRY_COMPILE_SYMBOL([
1147                 #include <linux/time.h>
1148         ], [
1149                 set_normalized_timespec(NULL, 0, 0);
1150         ], [set_normalized_timespec], [kernel/time.c], [
1151                 AC_MSG_RESULT(yes)
1152                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
1153                           [set_normalized_timespec() is available as export])
1154         ], [
1155                 AC_MSG_RESULT(no)
1156         ])
1157 ])
1158
1159 dnl #
1160 dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
1161 dnl # previously it was available in time.h as an inline.
1162 dnl #
1163 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
1164         AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
1165         SPL_LINUX_TRY_COMPILE([
1166                 #include <linux/time.h>
1167                 void set_normalized_timespec(struct timespec *ts,
1168                                              time_t sec, long nsec) { }
1169         ],
1170         [],
1171         [
1172                 AC_MSG_RESULT(no)
1173         ],[
1174                 AC_MSG_RESULT(yes)
1175                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
1176                           [set_normalized_timespec() is available as inline])
1177         ])
1178 ])
1179
1180 dnl #
1181 dnl # 2.6.18 API change,
1182 dnl # timespec_sub() inline function available in linux/time.h
1183 dnl #
1184 AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
1185         AC_MSG_CHECKING([whether timespec_sub() is available])
1186         SPL_LINUX_TRY_COMPILE([
1187                 #include <linux/time.h>
1188         ],[
1189                 struct timespec a = { 0 };
1190                 struct timespec b = { 0 };
1191                 struct timespec c __attribute__ ((unused));
1192                 c = timespec_sub(a, b);
1193         ],[
1194                 AC_MSG_RESULT(yes)
1195                 AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
1196         ],[
1197                 AC_MSG_RESULT(no)
1198         ])
1199 ])
1200
1201 dnl #
1202 dnl # 2.6.19 API change,
1203 dnl # check if init_utsname() is available in linux/utsname.h
1204 dnl #
1205 AC_DEFUN([SPL_AC_INIT_UTSNAME], [
1206         AC_MSG_CHECKING([whether init_utsname() is available])
1207         SPL_LINUX_TRY_COMPILE([
1208                 #include <linux/utsname.h>
1209         ],[
1210                 struct new_utsname *a __attribute__ ((unused));
1211                 a = init_utsname();
1212         ],[
1213                 AC_MSG_RESULT(yes)
1214                 AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
1215         ],[
1216                 AC_MSG_RESULT(no)
1217         ])
1218 ])
1219
1220 dnl #
1221 dnl # 2.6.26 API change,
1222 dnl # definition of struct fdtable relocated to linux/fdtable.h
1223 dnl #
1224 AC_DEFUN([SPL_AC_FDTABLE_HEADER], [
1225         SPL_CHECK_HEADER([linux/fdtable.h], [FDTABLE], [], [])
1226 ])
1227
1228 dnl #
1229 dnl # 2.6.14 API change,
1230 dnl # check whether 'files_fdtable()' exists
1231 dnl #
1232 AC_DEFUN([SPL_AC_FILES_FDTABLE], [
1233         AC_MSG_CHECKING([whether files_fdtable() is available])
1234         SPL_LINUX_TRY_COMPILE([
1235                 #include <linux/sched.h>
1236                 #include <linux/file.h>
1237                 #ifdef HAVE_FDTABLE_HEADER
1238                 #include <linux/fdtable.h>
1239                 #endif
1240         ],[
1241                 struct files_struct *files = current->files;
1242                 struct fdtable *fdt __attribute__ ((unused));
1243                 fdt = files_fdtable(files);
1244         ],[
1245                 AC_MSG_RESULT(yes)
1246                 AC_DEFINE(HAVE_FILES_FDTABLE, 1, [files_fdtable() is available])
1247         ],[
1248                 AC_MSG_RESULT(no)
1249         ])
1250 ])
1251
1252 dnl #
1253 dnl # 3.4.0 API change,
1254 dnl # check whether '__clear_close_on_exec()' exists
1255 dnl #
1256 AC_DEFUN([SPL_AC_CLEAR_CLOSE_ON_EXEC], [
1257         AC_MSG_CHECKING([whether __clear_close_on_exec() is available])
1258         SPL_LINUX_TRY_COMPILE([
1259                 #include <linux/fdtable.h>
1260         ],[
1261                 struct fdtable *fdt = NULL;
1262                 int fd = 0;
1263
1264                 __clear_close_on_exec(fd, fdt);
1265         ],[
1266                 AC_MSG_RESULT(yes)
1267                 AC_DEFINE(HAVE_CLEAR_CLOSE_ON_EXEC, 1,
1268                           [__clear_close_on_exec() is available])
1269         ],[
1270                 AC_MSG_RESULT(no)
1271         ])
1272 ])
1273
1274 dnl #
1275 dnl # 2.6.18 API change,
1276 dnl # added linux/uaccess.h
1277 dnl #
1278 AC_DEFUN([SPL_AC_UACCESS_HEADER], [
1279         SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
1280 ])
1281
1282 dnl #
1283 dnl # 2.6.12 API change,
1284 dnl # check whether 'kmalloc_node()' is available.
1285 dnl #
1286 AC_DEFUN([SPL_AC_KMALLOC_NODE], [
1287         AC_MSG_CHECKING([whether kmalloc_node() is available])
1288         SPL_LINUX_TRY_COMPILE([
1289                 #include <linux/slab.h>
1290         ],[
1291                 void *a __attribute__ ((unused));
1292                 a = kmalloc_node(1, GFP_KERNEL, 0);
1293         ],[
1294                 AC_MSG_RESULT(yes)
1295                 AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
1296         ],[
1297                 AC_MSG_RESULT(no)
1298         ])
1299 ])
1300
1301 dnl #
1302 dnl # 2.6.9 API change,
1303 dnl # check whether 'monotonic_clock()' is available it may
1304 dnl # be available for some archs but not others.
1305 dnl #
1306 AC_DEFUN([SPL_AC_MONOTONIC_CLOCK],
1307         [AC_MSG_CHECKING([whether monotonic_clock() is available])
1308         SPL_LINUX_TRY_COMPILE_SYMBOL([
1309                 #include <linux/timex.h>
1310         ], [
1311                 monotonic_clock();
1312         ], [monotonic_clock], [], [
1313                 AC_MSG_RESULT(yes)
1314                 AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
1315                           [monotonic_clock() is available])
1316         ], [
1317                 AC_MSG_RESULT(no)
1318         ])
1319 ])
1320
1321 dnl #
1322 dnl # 2.6.16 API change,
1323 dnl # check whether 'struct inode' has i_mutex
1324 dnl #
1325 AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
1326         AC_MSG_CHECKING([whether struct inode has i_mutex])
1327         SPL_LINUX_TRY_COMPILE([
1328                 #include <linux/fs.h>
1329                 #include <linux/mutex.h>
1330         ],[
1331                 struct inode i;
1332                 mutex_init(&i.i_mutex);
1333         ],[
1334                 AC_MSG_RESULT(yes)
1335                 AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
1336         ],[
1337                 AC_MSG_RESULT(no)
1338         ])
1339 ])
1340
1341 dnl #
1342 dnl # 2.6.29 API change,
1343 dnl # Adaptive mutexs introduced.
1344 dnl #
1345 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
1346         AC_MSG_CHECKING([whether struct mutex has owner])
1347         SPL_LINUX_TRY_COMPILE([
1348                 #include <linux/mutex.h>
1349         ],[
1350                 struct mutex mtx __attribute__ ((unused));
1351                 mtx.owner = NULL;
1352         ],[
1353                 AC_MSG_RESULT(yes)
1354                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [struct mutex has owner])
1355         ],[
1356                 AC_MSG_RESULT(no)
1357         ])
1358 ])
1359
1360 dnl #
1361 dnl # 2.6.39 API change,
1362 dnl # Owner type change.  A Linux mutex prior to 2.6.39 would store
1363 dnl # the owner as a thread_info pointer when CONFIG_DEBUG_MUTEXES
1364 dnl # was defined.  As of 2.6.39 this was changed to a task_struct
1365 dnl # pointer which frankly makes a lot more sense.
1366 dnl #
1367 AC_DEFUN([SPL_AC_MUTEX_OWNER_TASK_STRUCT], [
1368         AC_MSG_CHECKING([whether struct mutex owner is a task_struct])
1369         tmp_flags="$EXTRA_KCFLAGS"
1370         EXTRA_KCFLAGS="-Werror"
1371         SPL_LINUX_TRY_COMPILE([
1372                 #include <linux/mutex.h>
1373         ],[
1374                 struct mutex mtx __attribute__ ((unused));
1375                 mtx.owner = current;
1376         ],[
1377                 AC_MSG_RESULT(yes)
1378                 AC_DEFINE(HAVE_MUTEX_OWNER_TASK_STRUCT, 1,
1379                 [struct mutex owner is a task_struct])
1380         ],[
1381                 AC_MSG_RESULT(no)
1382         ])
1383         EXTRA_KCFLAGS="$tmp_flags"
1384 ])
1385
1386 dnl #
1387 dnl # 2.6.18 API change,
1388 dnl # First introduced 'mutex_lock_nested()' in include/linux/mutex.h,
1389 dnl # as part of the mutex validator.  Fallback to using 'mutex_lock()'
1390 dnl # if the mutex validator is disabled or otherwise unavailable.
1391 dnl #
1392 AC_DEFUN([SPL_AC_MUTEX_LOCK_NESTED], [
1393         AC_MSG_CHECKING([whether mutex_lock_nested() is available])
1394         SPL_LINUX_TRY_COMPILE([
1395                 #include <linux/mutex.h>
1396         ],[
1397                 struct mutex mutex;
1398                 mutex_init(&mutex);
1399                 mutex_lock_nested(&mutex, 0);
1400         ],[
1401                 AC_MSG_RESULT(yes)
1402                 AC_DEFINE(HAVE_MUTEX_LOCK_NESTED, 1,
1403                 [mutex_lock_nested() is available])
1404         ],[
1405                 AC_MSG_RESULT(no)
1406         ])
1407 ])
1408
1409 dnl #
1410 dnl # 2.6.27 API change,
1411 dnl # on_each_cpu() uses 3 args, no 'retry' argument
1412 dnl #
1413 AC_DEFUN([SPL_AC_3ARGS_ON_EACH_CPU], [
1414         AC_MSG_CHECKING([whether on_each_cpu() wants 3 args])
1415         SPL_LINUX_TRY_COMPILE([
1416                 #include <linux/smp.h>
1417         ],[
1418                 on_each_cpu(NULL, NULL, 0);
1419         ],[
1420                 AC_MSG_RESULT(yes)
1421                 AC_DEFINE(HAVE_3ARGS_ON_EACH_CPU, 1,
1422                           [on_each_cpu wants 3 args])
1423         ],[
1424                 AC_MSG_RESULT(no)
1425         ])
1426 ])
1427
1428 dnl #
1429 dnl # 2.6.18 API change,
1430 dnl # kallsyms_lookup_name no longer exported
1431 dnl #
1432 AC_DEFUN([SPL_AC_KALLSYMS_LOOKUP_NAME],
1433         [AC_MSG_CHECKING([whether kallsyms_lookup_name() is available])
1434         SPL_LINUX_TRY_COMPILE_SYMBOL([
1435                 #include <linux/kallsyms.h>
1436         ], [
1437                 kallsyms_lookup_name(NULL);
1438         ], [kallsyms_lookup_name], [], [
1439                 AC_MSG_RESULT(yes)
1440                 AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
1441                           [kallsyms_lookup_name() is available])
1442         ], [
1443                 AC_MSG_RESULT(no)
1444         ])
1445 ])
1446
1447 dnl #
1448 dnl # Proposed API change,
1449 dnl # This symbol is not available in stock kernels.  You may build a
1450 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1451 dnl # these symbols for use.  If your already rolling a custom kernel for
1452 dnl # your environment this is recommended.
1453 dnl #
1454 AC_DEFUN([SPL_AC_GET_VMALLOC_INFO],
1455         [AC_MSG_CHECKING([whether get_vmalloc_info() is available])
1456         SPL_CHECK_SYMBOL_EXPORT([get_vmalloc_info], [], [
1457                 AC_MSG_RESULT(yes)
1458                 AC_DEFINE(HAVE_GET_VMALLOC_INFO, 1,
1459                           [get_vmalloc_info() is available])
1460         ], [
1461                 AC_MSG_RESULT(no)
1462         ])
1463 ])
1464
1465 dnl #
1466 dnl # 2.6.17 API change
1467 dnl # The helper functions first_online_pgdat(), next_online_pgdat(), and
1468 dnl # next_zone() are introduced to simplify for_each_zone().  These symbols
1469 dnl # were exported in 2.6.17 for use by modules which was consistent with
1470 dnl # the previous implementation of for_each_zone().  From 2.6.18 - 2.6.19
1471 dnl # the symbols were exported as 'unused', and by 2.6.20 they exports
1472 dnl # were dropped entirely leaving modules no way to directly iterate over
1473 dnl # the zone list.  Because we need access to the zone helpers we check
1474 dnl # if the kernel contains the old or new implementation.  Then we check
1475 dnl # to see if the symbols we need for each version are available.  If they
1476 dnl # are not, dynamically aquire the addresses with kallsyms_lookup_name().
1477 dnl #
1478 AC_DEFUN([SPL_AC_PGDAT_HELPERS], [
1479         AC_MSG_CHECKING([whether symbol *_pgdat exist])
1480         grep -q -E 'first_online_pgdat' $LINUX/include/linux/mmzone.h 2>/dev/null
1481         rc=$?
1482         if test $rc -eq 0; then
1483                 AC_MSG_RESULT([yes])
1484                 AC_DEFINE(HAVE_PGDAT_HELPERS, 1, [pgdat helpers are available])
1485         else
1486                 AC_MSG_RESULT([no])
1487         fi
1488 ])
1489
1490 dnl #
1491 dnl # Proposed API change,
1492 dnl # This symbol is not available in stock kernels.  You may build a
1493 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1494 dnl # these symbols for use.  If your already rolling a custom kernel for
1495 dnl # your environment this is recommended.
1496 dnl #
1497 AC_DEFUN([SPL_AC_FIRST_ONLINE_PGDAT],
1498         [AC_MSG_CHECKING([whether first_online_pgdat() is available])
1499         SPL_LINUX_TRY_COMPILE_SYMBOL([
1500                 #include <linux/mmzone.h>
1501         ], [
1502                 first_online_pgdat();
1503         ], [first_online_pgdat], [], [
1504                 AC_MSG_RESULT(yes)
1505                 AC_DEFINE(HAVE_FIRST_ONLINE_PGDAT, 1,
1506                           [first_online_pgdat() is available])
1507         ], [
1508                 AC_MSG_RESULT(no)
1509         ])
1510 ])
1511
1512 dnl #
1513 dnl # Proposed API change,
1514 dnl # This symbol is not available in stock kernels.  You may build a
1515 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1516 dnl # these symbols for use.  If your already rolling a custom kernel for
1517 dnl # your environment this is recommended.
1518 dnl #
1519 AC_DEFUN([SPL_AC_NEXT_ONLINE_PGDAT],
1520         [AC_MSG_CHECKING([whether next_online_pgdat() is available])
1521         SPL_LINUX_TRY_COMPILE_SYMBOL([
1522                 #include <linux/mmzone.h>
1523         ], [
1524                 next_online_pgdat(NULL);
1525         ], [next_online_pgdat], [], [
1526                 AC_MSG_RESULT(yes)
1527                 AC_DEFINE(HAVE_NEXT_ONLINE_PGDAT, 1,
1528                           [next_online_pgdat() is available])
1529         ], [
1530                 AC_MSG_RESULT(no)
1531         ])
1532 ])
1533
1534 dnl #
1535 dnl # Proposed API change,
1536 dnl # This symbol is not available in stock kernels.  You may build a
1537 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1538 dnl # these symbols for use.  If your already rolling a custom kernel for
1539 dnl # your environment this is recommended.
1540 dnl #
1541 AC_DEFUN([SPL_AC_NEXT_ZONE],
1542         [AC_MSG_CHECKING([whether next_zone() is available])
1543         SPL_LINUX_TRY_COMPILE_SYMBOL([
1544                 #include <linux/mmzone.h>
1545         ], [
1546                 next_zone(NULL);
1547         ], [next_zone], [], [
1548                 AC_MSG_RESULT(yes)
1549                 AC_DEFINE(HAVE_NEXT_ZONE, 1, [next_zone() is available])
1550         ], [
1551                 AC_MSG_RESULT(no)
1552         ])
1553 ])
1554
1555 dnl #
1556 dnl # 2.6.17 API change,
1557 dnl # See SPL_AC_PGDAT_HELPERS for details.
1558 dnl #
1559 AC_DEFUN([SPL_AC_PGDAT_LIST],
1560         [AC_MSG_CHECKING([whether pgdat_list is available])
1561         SPL_LINUX_TRY_COMPILE_SYMBOL([
1562                 #include <linux/topology.h>
1563                 pg_data_t *tmp = pgdat_list;
1564         ], [], [pgdat_list], [], [
1565                 AC_MSG_RESULT(yes)
1566                 AC_DEFINE(HAVE_PGDAT_LIST, 1, [pgdat_list is available])
1567         ], [
1568                 AC_MSG_RESULT(no)
1569         ])
1570 ])
1571
1572 dnl #
1573 dnl # 2.6.18 API change,
1574 dnl # First introduced global_page_state() support as an inline.
1575 dnl #
1576 AC_DEFUN([SPL_AC_GLOBAL_PAGE_STATE], [
1577         AC_MSG_CHECKING([whether global_page_state() is available])
1578         SPL_LINUX_TRY_COMPILE([
1579                 #include <linux/mm.h>
1580         ],[
1581                 unsigned long state __attribute__ ((unused));
1582                 state = global_page_state(0);
1583         ],[
1584                 AC_MSG_RESULT(yes)
1585                 AC_DEFINE(HAVE_GLOBAL_PAGE_STATE, 1,
1586                           [global_page_state() is available])
1587         ],[
1588                 AC_MSG_RESULT(no)
1589         ])
1590 ])
1591
1592 dnl #
1593 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1594 dnl # Public global zone stats now include a free page count.  However
1595 dnl # the enumerated names of the counters have changed since this API
1596 dnl # was introduced.  We need to deduce the corrent name to use.  This
1597 dnl # replaces the priviate get_zone_counts() interface.
1598 dnl #
1599 dnl # NR_FREE_PAGES was available from 2.6.21 to current kernels, which
1600 dnl # is 2.6.30 as of when this was written.
1601 dnl #
1602 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_FREE], [
1603         AC_MSG_CHECKING([whether page state NR_FREE_PAGES is available])
1604         SPL_LINUX_TRY_COMPILE([
1605                 #include <linux/mm.h>
1606         ],[
1607                 enum zone_stat_item zsi __attribute__ ((unused));
1608                 zsi = NR_FREE_PAGES;
1609         ],[
1610                 AC_MSG_RESULT(yes)
1611                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES, 1,
1612                           [Page state NR_FREE_PAGES is available])
1613         ],[
1614                 AC_MSG_RESULT(no)
1615         ])
1616 ])
1617
1618 dnl #
1619 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1620 dnl # Public global zone stats now include an inactive page count.  However
1621 dnl # the enumerated names of the counters have changed since this API
1622 dnl # was introduced.  We need to deduce the corrent name to use.  This
1623 dnl # replaces the priviate get_zone_counts() interface.
1624 dnl #
1625 dnl # NR_INACTIVE was available from 2.6.21 to 2.6.27 and included both
1626 dnl # anonymous and file inactive pages.  As of 2.6.28 it was split in
1627 dnl # to NR_INACTIVE_ANON and NR_INACTIVE_FILE.
1628 dnl #
1629 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_INACTIVE], [
1630         AC_MSG_CHECKING([whether page state NR_INACTIVE is available])
1631         SPL_LINUX_TRY_COMPILE([
1632                 #include <linux/mm.h>
1633         ],[
1634                 enum zone_stat_item zsi __attribute__ ((unused));
1635                 zsi = NR_INACTIVE;
1636         ],[
1637                 AC_MSG_RESULT(yes)
1638                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE, 1,
1639                           [Page state NR_INACTIVE is available])
1640         ],[
1641                 AC_MSG_RESULT(no)
1642         ])
1643
1644         AC_MSG_CHECKING([whether page state NR_INACTIVE_ANON is available])
1645         SPL_LINUX_TRY_COMPILE([
1646                 #include <linux/mm.h>
1647         ],[
1648                 enum zone_stat_item zsi __attribute__ ((unused));
1649                 zsi = NR_INACTIVE_ANON;
1650         ],[
1651                 AC_MSG_RESULT(yes)
1652                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON, 1,
1653                           [Page state NR_INACTIVE_ANON is available])
1654         ],[
1655                 AC_MSG_RESULT(no)
1656         ])
1657
1658         AC_MSG_CHECKING([whether page state NR_INACTIVE_FILE is available])
1659         SPL_LINUX_TRY_COMPILE([
1660                 #include <linux/mm.h>
1661         ],[
1662                 enum zone_stat_item zsi __attribute__ ((unused));
1663                 zsi = NR_INACTIVE_FILE;
1664         ],[
1665                 AC_MSG_RESULT(yes)
1666                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE, 1,
1667                           [Page state NR_INACTIVE_FILE is available])
1668         ],[
1669                 AC_MSG_RESULT(no)
1670         ])
1671 ])
1672
1673 dnl #
1674 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1675 dnl # Public global zone stats now include an active page count.  However
1676 dnl # the enumerated names of the counters have changed since this API
1677 dnl # was introduced.  We need to deduce the corrent name to use.  This
1678 dnl # replaces the priviate get_zone_counts() interface.
1679 dnl #
1680 dnl # NR_ACTIVE was available from 2.6.21 to 2.6.27 and included both
1681 dnl # anonymous and file active pages.  As of 2.6.28 it was split in
1682 dnl # to NR_ACTIVE_ANON and NR_ACTIVE_FILE.
1683 dnl #
1684 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_ACTIVE], [
1685         AC_MSG_CHECKING([whether page state NR_ACTIVE is available])
1686         SPL_LINUX_TRY_COMPILE([
1687                 #include <linux/mm.h>
1688         ],[
1689                 enum zone_stat_item zsi __attribute__ ((unused));
1690                 zsi = NR_ACTIVE;
1691         ],[
1692                 AC_MSG_RESULT(yes)
1693                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE, 1,
1694                           [Page state NR_ACTIVE is available])
1695         ],[
1696                 AC_MSG_RESULT(no)
1697         ])
1698
1699         AC_MSG_CHECKING([whether page state NR_ACTIVE_ANON is available])
1700         SPL_LINUX_TRY_COMPILE([
1701                 #include <linux/mm.h>
1702         ],[
1703                 enum zone_stat_item zsi __attribute__ ((unused));
1704                 zsi = NR_ACTIVE_ANON;
1705         ],[
1706                 AC_MSG_RESULT(yes)
1707                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON, 1,
1708                           [Page state NR_ACTIVE_ANON is available])
1709         ],[
1710                 AC_MSG_RESULT(no)
1711         ])
1712
1713         AC_MSG_CHECKING([whether page state NR_ACTIVE_FILE is available])
1714         SPL_LINUX_TRY_COMPILE([
1715                 #include <linux/mm.h>
1716         ],[
1717                 enum zone_stat_item zsi __attribute__ ((unused));
1718                 zsi = NR_ACTIVE_FILE;
1719         ],[
1720                 AC_MSG_RESULT(yes)
1721                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE, 1,
1722                           [Page state NR_ACTIVE_FILE is available])
1723         ],[
1724                 AC_MSG_RESULT(no)
1725         ])
1726 ])
1727
1728 dnl #
1729 dnl # Proposed API change for legacy kernels.
1730 dnl # This symbol is not available in older kernels.  For kernels post
1731 dnl # 2.6.21 the global_page_state() API is used to get free/inactive/active
1732 dnl # page state information.  This symbol is only used in legacy kernels
1733 dnl # any only as a last resort.
1734 dnl
1735 AC_DEFUN([SPL_AC_GET_ZONE_COUNTS], [
1736         AC_MSG_CHECKING([whether symbol get_zone_counts is needed])
1737         SPL_LINUX_TRY_COMPILE([
1738         ],[
1739                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES)
1740                 #error "global_page_state needs NR_FREE_PAGES"
1741                 #endif
1742
1743                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE) && \
1744                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON) && \
1745                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE)
1746                 #error "global_page_state needs NR_ACTIVE*"
1747                 #endif
1748
1749                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE) && \
1750                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON) && \
1751                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE)
1752                 #error "global_page_state needs NR_INACTIVE*"
1753                 #endif
1754         ],[
1755                 AC_MSG_RESULT(no)
1756         ],[
1757                 AC_MSG_RESULT(yes)
1758                 AC_DEFINE(NEED_GET_ZONE_COUNTS, 1,
1759                           [get_zone_counts() is needed])
1760
1761                 AC_MSG_CHECKING([whether get_zone_counts() is available])
1762                 SPL_LINUX_TRY_COMPILE_SYMBOL([
1763                         #include <linux/mmzone.h>
1764                 ], [
1765                         get_zone_counts(NULL, NULL, NULL);
1766                 ], [get_zone_counts], [], [
1767                         AC_MSG_RESULT(yes)
1768                         AC_DEFINE(HAVE_GET_ZONE_COUNTS, 1,
1769                                   [get_zone_counts() is available])
1770                 ], [
1771                         AC_MSG_RESULT(no)
1772                 ])
1773         ])
1774 ])
1775
1776 dnl #
1777 dnl # 2.6.27 API change,
1778 dnl # The user_path_dir() replaces __user_walk()
1779 dnl #
1780 AC_DEFUN([SPL_AC_USER_PATH_DIR],
1781         [AC_MSG_CHECKING([whether user_path_dir() is available])
1782         SPL_LINUX_TRY_COMPILE_SYMBOL([
1783                 #include <linux/fcntl.h>
1784                 #include <linux/namei.h>
1785         ], [
1786                 user_path_dir(NULL, NULL);
1787         ], [user_path_at], [], [
1788                 AC_MSG_RESULT(yes)
1789                 AC_DEFINE(HAVE_USER_PATH_DIR, 1, [user_path_dir() is available])
1790         ], [
1791                 AC_MSG_RESULT(no)
1792         ])
1793 ])
1794
1795 dnl #
1796 dnl # Symbol available in RHEL kernels not in stock kernels.
1797 dnl #
1798 AC_DEFUN([SPL_AC_SET_FS_PWD],
1799         [AC_MSG_CHECKING([whether set_fs_pwd() is available])
1800         SPL_LINUX_TRY_COMPILE_SYMBOL([
1801                 #include <linux/spinlock.h>
1802                 #include <linux/fs_struct.h>
1803         ], [
1804                 (void) set_fs_pwd;
1805         ], [set_fs_pwd], [], [
1806                 AC_MSG_RESULT(yes)
1807                 AC_DEFINE(HAVE_SET_FS_PWD, 1, [set_fs_pwd() is available])
1808         ], [
1809                 AC_MSG_RESULT(no)
1810         ])
1811 ])
1812
1813 dnl #
1814 dnl # 2.6.25 API change,
1815 dnl # Simplied API by replacing mnt+dentry args with a single path arg.
1816 dnl #
1817 AC_DEFUN([SPL_AC_2ARGS_SET_FS_PWD],
1818         [AC_MSG_CHECKING([whether set_fs_pwd() wants 2 args])
1819         SPL_LINUX_TRY_COMPILE([
1820                 #include <linux/sched.h>
1821                 #include <linux/fs_struct.h>
1822         ],[
1823                 set_fs_pwd(NULL, NULL);
1824         ],[
1825                 AC_MSG_RESULT(yes)
1826                 AC_DEFINE(HAVE_2ARGS_SET_FS_PWD, 1,
1827                           [set_fs_pwd() wants 2 args])
1828         ],[
1829                 AC_MSG_RESULT(no)
1830         ])
1831 ])
1832
1833 dnl #
1834 dnl # SLES API change, never adopted in mainline,
1835 dnl # Third 'struct vfsmount *' argument removed.
1836 dnl #
1837 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
1838         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
1839         SPL_LINUX_TRY_COMPILE([
1840                 #include <linux/fs.h>
1841         ],[
1842                 vfs_unlink(NULL, NULL);
1843         ],[
1844                 AC_MSG_RESULT(yes)
1845                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
1846                           [vfs_unlink() wants 2 args])
1847         ],[
1848                 AC_MSG_RESULT(no)
1849         ])
1850 ])
1851
1852 dnl #
1853 dnl # SLES API change, never adopted in mainline,
1854 dnl # Third and sixth 'struct vfsmount *' argument removed.
1855 dnl #
1856 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
1857         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
1858         SPL_LINUX_TRY_COMPILE([
1859                 #include <linux/fs.h>
1860         ],[
1861                 vfs_rename(NULL, NULL, NULL, NULL);
1862         ],[
1863                 AC_MSG_RESULT(yes)
1864                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
1865                           [vfs_rename() wants 4 args])
1866         ],[
1867                 AC_MSG_RESULT(no)
1868         ])
1869 ])
1870
1871 dnl #
1872 dnl # 2.6.36 API change,
1873 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1874 dnl # a spinlock_t to improve the fastpath performance.
1875 dnl #
1876 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1877         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1878         tmp_flags="$EXTRA_KCFLAGS"
1879         EXTRA_KCFLAGS="-Werror"
1880         SPL_LINUX_TRY_COMPILE([
1881                 #include <linux/sched.h>
1882                 #include <linux/fs_struct.h>
1883         ],[
1884                 struct fs_struct fs;
1885                 spin_lock_init(&fs.lock);
1886         ],[
1887                 AC_MSG_RESULT(yes)
1888                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1889                           [struct fs_struct uses spinlock_t])
1890         ],[
1891                 AC_MSG_RESULT(no)
1892         ])
1893         EXTRA_KCFLAGS="$tmp_flags"
1894 ])
1895
1896 dnl #
1897 dnl # 2.6.29 API change,
1898 dnl # check whether 'struct cred' exists
1899 dnl #
1900 AC_DEFUN([SPL_AC_CRED_STRUCT], [
1901         AC_MSG_CHECKING([whether struct cred exists])
1902         SPL_LINUX_TRY_COMPILE([
1903                 #include <linux/cred.h>
1904         ],[
1905                 struct cred *cr __attribute__ ((unused));
1906                 cr  = NULL;
1907         ],[
1908                 AC_MSG_RESULT(yes)
1909                 AC_DEFINE(HAVE_CRED_STRUCT, 1, [struct cred exists])
1910         ],[
1911                 AC_MSG_RESULT(no)
1912         ])
1913 ])
1914
1915 dnl #
1916 dnl # Custom SPL patch may export this symbol.
1917 dnl #
1918 AC_DEFUN([SPL_AC_GROUPS_SEARCH],
1919         [AC_MSG_CHECKING([whether groups_search() is available])
1920         SPL_LINUX_TRY_COMPILE_SYMBOL([
1921                 #include <linux/cred.h>
1922         ], [
1923                 groups_search(NULL, 0);
1924         ], [groups_search], [], [
1925                 AC_MSG_RESULT(yes)
1926                 AC_DEFINE(HAVE_GROUPS_SEARCH, 1, [groups_search() is available])
1927         ], [
1928                 AC_MSG_RESULT(no)
1929         ])
1930 ])
1931
1932 dnl #
1933 dnl # 2.6.x API change,
1934 dnl # __put_task_struct() was exported in RHEL5 but unavailable elsewhere.
1935 dnl #
1936 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1937         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1938         SPL_LINUX_TRY_COMPILE_SYMBOL([
1939                 #include <linux/sched.h>
1940         ], [
1941                 __put_task_struct(NULL);
1942         ], [__put_task_struct], [], [
1943                 AC_MSG_RESULT(yes)
1944                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1945                           [__put_task_struct() is available])
1946         ], [
1947                 AC_MSG_RESULT(no)
1948         ])
1949 ])
1950
1951 dnl #
1952 dnl # 2.6.32 API change,
1953 dnl # Unused 'struct file *' removed from prototype.
1954 dnl #
1955 AC_DEFUN([SPL_AC_5ARGS_PROC_HANDLER], [
1956         AC_MSG_CHECKING([whether proc_handler() wants 5 args])
1957         SPL_LINUX_TRY_COMPILE([
1958                 #include <linux/sysctl.h>
1959         ],[
1960                 proc_dostring(NULL, 0, NULL, NULL, NULL);
1961         ],[
1962                 AC_MSG_RESULT(yes)
1963                 AC_DEFINE(HAVE_5ARGS_PROC_HANDLER, 1,
1964                           [proc_handler() wants 5 args])
1965         ],[
1966                 AC_MSG_RESULT(no)
1967         ])
1968 ])
1969
1970 dnl #
1971 dnl # 2.6.x API change,
1972 dnl # kvasprintf() function added.
1973 dnl #
1974 AC_DEFUN([SPL_AC_KVASPRINTF],
1975         [AC_MSG_CHECKING([whether kvasprintf() is available])
1976         SPL_LINUX_TRY_COMPILE_SYMBOL([
1977                 #include <linux/kernel.h>
1978         ], [
1979                 kvasprintf(0, NULL, *((va_list*)NULL));
1980         ], [kvasprintf], [], [
1981                 AC_MSG_RESULT(yes)
1982                 AC_DEFINE(HAVE_KVASPRINTF, 1, [kvasprintf() is available])
1983         ], [
1984                 AC_MSG_RESULT(no)
1985         ])
1986 ])
1987
1988 dnl #
1989 dnl # 2.6.29 API change,
1990 dnl # vfs_fsync() funcation added, prior to this use file_fsync().
1991 dnl #
1992 AC_DEFUN([SPL_AC_VFS_FSYNC],
1993         [AC_MSG_CHECKING([whether vfs_fsync() is available])
1994         SPL_LINUX_TRY_COMPILE_SYMBOL([
1995                 #include <linux/fs.h>
1996         ], [
1997                 (void) vfs_fsync;
1998         ], [vfs_fsync], [fs/sync.c], [
1999                 AC_MSG_RESULT(yes)
2000                 AC_DEFINE(HAVE_VFS_FSYNC, 1, [vfs_fsync() is available])
2001         ], [
2002                 AC_MSG_RESULT(no)
2003         ])
2004 ])
2005
2006 dnl #
2007 dnl # 2.6.35 API change,
2008 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
2009 dnl #
2010 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
2011         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
2012         SPL_LINUX_TRY_COMPILE([
2013                 #include <linux/fs.h>
2014         ],[
2015                 vfs_fsync(NULL, 0);
2016         ],[
2017                 AC_MSG_RESULT(yes)
2018                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
2019         ],[
2020                 AC_MSG_RESULT(no)
2021         ])
2022 ])
2023
2024 dnl #
2025 dnl # 2.6.33 API change. Also backported in RHEL5 as of 2.6.18-190.el5.
2026 dnl # Earlier versions of rwsem_is_locked() were inline and had a race
2027 dnl # condition.  The fixed version is exported as a symbol.  The race
2028 dnl # condition is fixed by acquiring sem->wait_lock, so we must not
2029 dnl # call that version while holding sem->wait_lock.
2030 dnl #
2031 AC_DEFUN([SPL_AC_EXPORTED_RWSEM_IS_LOCKED],
2032         [AC_MSG_CHECKING([whether rwsem_is_locked() acquires sem->wait_lock])
2033         SPL_LINUX_TRY_COMPILE_SYMBOL([
2034                 #include <linux/rwsem.h>
2035                 int rwsem_is_locked(struct rw_semaphore *sem) { return 0; }
2036         ], [], [rwsem_is_locked], [lib/rwsem-spinlock.c], [
2037                 AC_MSG_RESULT(yes)
2038                 AC_DEFINE(RWSEM_IS_LOCKED_TAKES_WAIT_LOCK, 1,
2039                           [rwsem_is_locked() acquires sem->wait_lock])
2040         ], [
2041                 AC_MSG_RESULT(no)
2042         ])
2043 ])
2044
2045 dnl #
2046 dnl # 2.6.37 API compat,
2047 dnl # The function invalidate_inodes() is no longer exported by the kernel.
2048 dnl # The prototype however is still available which means it is safe
2049 dnl # to acquire the symbol's address using spl_kallsyms_lookup_name().
2050 dnl #
2051 dnl # The Proxmox VE kernel contains a patch which renames the function
2052 dnl # invalidate_inodes() to invalidate_inodes_check().  In the process
2053 dnl # it adds a 'check' argument and a '#define invalidate_inodes(x)'
2054 dnl # compatibility wrapper for legacy callers.  Therefore, if either
2055 dnl # of these functions are exported invalidate_inodes() can be
2056 dnl # safely used.
2057 dnl #
2058 AC_DEFUN([SPL_AC_KERNEL_INVALIDATE_INODES], [
2059         AC_MSG_CHECKING([whether invalidate_inodes() is available])
2060         SPL_LINUX_TRY_COMPILE_SYMBOL([
2061                 #include <linux/fs.h>
2062         ], [
2063                 invalidate_inodes;
2064         ], [invalidate_inodes], [], [
2065                 AC_MSG_RESULT(yes)
2066                 AC_DEFINE(HAVE_INVALIDATE_INODES, 1,
2067                           [invalidate_inodes() is available])
2068         ], [
2069                 AC_MSG_RESULT(no)
2070         ])
2071
2072         AC_MSG_CHECKING([whether invalidate_inodes_check() is available])
2073         SPL_LINUX_TRY_COMPILE_SYMBOL([
2074                 #include <linux/fs.h>
2075         ], [
2076                 invalidate_inodes_check(NULL, 0);
2077         ], [invalidate_inodes_check], [], [
2078                 AC_MSG_RESULT(yes)
2079                 AC_DEFINE(HAVE_INVALIDATE_INODES_CHECK, 1,
2080                           [invalidate_inodes_check() is available])
2081         ], [
2082                 AC_MSG_RESULT(no)
2083         ])
2084 ])
2085
2086 dnl #
2087 dnl # 2.6.39 API compat,
2088 dnl # The function invalidate_inodes() now take 2 arguments.  The second
2089 dnl # 'kill_dirty' argument describes how invalidate_inodes() should
2090 dnl # handle dirty inodes.  Only when set will dirty inodes be discarded,
2091 dnl # otherwise they will be handled as busy.
2092 dnl #
2093 dnl # Unfortunately, we don't have access to the invalidate_inodes()
2094 dnl # prototype so it's not easy to check how many arguments it takes.
2095 dnl # However, this change was done for the benefit of invalidate_device()
2096 dnl # which also added an argument.  The invalidate_device() symbol does
2097 dnl # exist in the development headers so if it takes two arguments we
2098 dnl # can fairly safely infer that invalidate_inodes() takes two arguments
2099 dnl # as well.  See commit 93b270f76e7ef3b81001576860c2701931cdc78b.
2100 dnl #
2101 AC_DEFUN([SPL_AC_KERNEL_2ARGS_INVALIDATE_INODES],
2102         [AC_MSG_CHECKING([whether invalidate_inodes() wants 2 args])
2103         SPL_LINUX_TRY_COMPILE([
2104                 #include <linux/fs.h>
2105         ],[
2106                 return __invalidate_device(NULL, 0);
2107         ],[
2108                 AC_MSG_RESULT(yes)
2109                 AC_DEFINE(HAVE_2ARGS_INVALIDATE_INODES, 1,
2110                           [invalidate_inodes() wants 2 args])
2111         ],[
2112                 AC_MSG_RESULT(no)
2113         ])
2114 ])
2115
2116 dnl #
2117 dnl # 2.6.xx API compat,
2118 dnl # There currently exists no exposed API to partially shrink the dcache.
2119 dnl # The expected mechanism to shrink the cache is a registered shrinker
2120 dnl # which is called during memory pressure.
2121 dnl #
2122 AC_DEFUN([SPL_AC_SHRINK_DCACHE_MEMORY],
2123         [AC_MSG_CHECKING([whether shrink_dcache_memory() is available])
2124         SPL_LINUX_TRY_COMPILE_SYMBOL([
2125                 #include <linux/dcache.h>
2126         ], [
2127                 shrink_dcache_memory(0, 0);
2128         ], [shrink_dcache_memory], [fs/dcache.c], [
2129                 AC_MSG_RESULT(yes)
2130                 AC_DEFINE(HAVE_SHRINK_DCACHE_MEMORY, 1,
2131                           [shrink_dcache_memory() is available])
2132         ], [
2133                 AC_MSG_RESULT(no)
2134         ])
2135 ])
2136
2137 dnl #
2138 dnl # 2.6.xx API compat,
2139 dnl # There currently exists no exposed API to partially shrink the icache.
2140 dnl # The expected mechanism to shrink the cache is a registered shrinker
2141 dnl # which is called during memory pressure.
2142 dnl #
2143 AC_DEFUN([SPL_AC_SHRINK_ICACHE_MEMORY],
2144         [AC_MSG_CHECKING([whether shrink_icache_memory() is available])
2145         SPL_LINUX_TRY_COMPILE_SYMBOL([
2146                 #include <linux/dcache.h>
2147         ], [
2148                 shrink_icache_memory(0, 0);
2149         ], [shrink_icache_memory], [fs/inode.c], [
2150                 AC_MSG_RESULT(yes)
2151                 AC_DEFINE(HAVE_SHRINK_ICACHE_MEMORY, 1,
2152                           [shrink_icache_memory() is available])
2153         ], [
2154                 AC_MSG_RESULT(no)
2155         ])
2156 ])
2157
2158 dnl #
2159 dnl # 2.6.39 API compat,
2160 dnl # The path_lookup() function has been renamed to kern_path_parent()
2161 dnl # and the flags argument has been removed.  The only behavior now
2162 dnl # offered is that of LOOKUP_PARENT.  The spl already always passed
2163 dnl # this flag so dropping the flag does not impact us.
2164 dnl #
2165 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_HEADER], [
2166         SPL_CHECK_SYMBOL_HEADER(
2167                 [kern_path_parent],
2168                 [int kern_path_parent(const char \*, struct nameidata \*)],
2169                 [include/linux/namei.h],
2170                 [AC_DEFINE(HAVE_KERN_PATH_PARENT_HEADER, 1,
2171                 [kern_path_parent() is available])],
2172                 [])
2173 ])
2174
2175 dnl #
2176 dnl # 3.1 API compat,
2177 dnl # The kern_path_parent() symbol is no longer exported by the kernel.
2178 dnl # However, it remains the prefered interface and since we still have
2179 dnl # access to the prototype we dynamically lookup the required address.
2180 dnl #
2181 AC_DEFUN([SPL_AC_KERN_PATH_PARENT_SYMBOL],
2182         [AC_MSG_CHECKING([whether kern_path_parent() is available])
2183         SPL_LINUX_TRY_COMPILE_SYMBOL([
2184                 #include <linux/namei.h>
2185         ], [
2186                 kern_path_parent(NULL, NULL);
2187         ], [kern_path_parent], [fs/namei.c], [
2188                 AC_MSG_RESULT(yes)
2189                 AC_DEFINE(HAVE_KERN_PATH_PARENT_SYMBOL, 1,
2190                           [kern_path_parent() is available])
2191         ], [
2192                 AC_MSG_RESULT(no)
2193         ])
2194 ])
2195
2196 dnl #
2197 dnl # 2.6.39 API compat,
2198 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
2199 dnl # This was done to avoid always having to allocate the maximum size
2200 dnl # workspace (268K).  The caller can now specific the windowBits and
2201 dnl # memLevel compression parameters to get a smaller workspace.
2202 dnl #
2203 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
2204         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
2205         SPL_LINUX_TRY_COMPILE([
2206                 #include <linux/zlib.h>
2207         ],[
2208                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
2209         ],[
2210                 AC_MSG_RESULT(yes)
2211                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
2212                           [zlib_deflate_workspacesize() wants 2 args])
2213         ],[
2214                 AC_MSG_RESULT(no)
2215         ])
2216 ])
2217
2218 dnl #
2219 dnl # 2.6.39 API change,
2220 dnl # Shrinker adjust to use common shrink_control structure.
2221 dnl #
2222 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
2223         AC_MSG_CHECKING([whether struct shrink_control exists])
2224         SPL_LINUX_TRY_COMPILE([
2225                 #include <linux/mm.h>
2226         ],[
2227                 struct shrink_control sc __attribute__ ((unused));
2228
2229                 sc.nr_to_scan = 0;
2230                 sc.gfp_mask = GFP_KERNEL;
2231         ],[
2232                 AC_MSG_RESULT(yes)
2233                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
2234                         [struct shrink_control exists])
2235         ],[
2236                 AC_MSG_RESULT(no)
2237         ])
2238 ])
2239
2240 dnl #
2241 dnl # 3.1 API Change
2242 dnl #
2243 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
2244 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
2245 dnl #
2246 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
2247         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
2248         tmp_flags="$EXTRA_KCFLAGS"
2249         EXTRA_KCFLAGS="-Werror"
2250         SPL_LINUX_TRY_COMPILE([
2251                 #include <linux/rwsem.h>
2252         ],[
2253                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
2254                 raw_spinlock_t dummy_lock __attribute__ ((unused));
2255                 dummy_semaphore.wait_lock = dummy_lock;
2256         ],[
2257                 AC_MSG_RESULT(yes)
2258                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
2259                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
2260         ],[
2261                 AC_MSG_RESULT(no)
2262         ])
2263         EXTRA_KCFLAGS="$tmp_flags"
2264 ])
2265
2266 dnl #
2267 dnl # Proposed VM Subsystem Bug Fix
2268 dnl # https://bugs.gentoo.org/show_bug.cgi?id=416685
2269 dnl #
2270 dnl # Make __pte_alloc_kernel() honor gfp flags passed to vmalloc()
2271 dnl # This is detected by checking a macro that is changed to support this.
2272 dnl #
2273 AC_DEFUN([SPL_AC_PMD_ALLOC_WITH_MASK], [
2274         AC_MSG_CHECKING([whether pmd_alloc_with_mask exists])
2275         SPL_LINUX_TRY_COMPILE([
2276                 #if !defined(CONFIG_MMU)
2277                 #define CONFIG_MMU
2278                 #endif
2279
2280                 #if defined(RCH_HAS_4LEVEL_HACK)
2281                 #undef RCH_HAS_4LEVEL_HACK
2282                 #endif
2283
2284                 #include <linux/mm.h>
2285         ],[
2286                 struct mm_struct init_mm;
2287                 pud_t *pud = NULL;
2288                 unsigned long addr = 0;
2289                 gfp_t gfp_mask = GFP_KERNEL;
2290
2291                 pmd_alloc_with_mask(&init_mm, pud, addr, gfp_mask);
2292         ],[
2293                 AC_MSG_RESULT(yes)
2294                 AC_DEFINE(HAVE_PMD_ALLOC_WITH_MASK, 1,
2295                           [pmd_alloc_with_mask exists])
2296         ],[
2297                 AC_MSG_RESULT(no)
2298         ])
2299 ])