configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl First, define all of the version numbers up front.
   4 dnl In particular, this allows the version macro to be used in AC_INIT
   5
   6 dnl These first two version numbers are updated automatically on each release.
   7 m4_define([LIBARCHIVE_VERSION_S],[3.2.1])
   8 m4_define([LIBARCHIVE_VERSION_N],[3002001])
   9
  10 dnl bsdtar and bsdcpio versioning tracks libarchive
  11 m4_define([BSDTAR_VERSION_S],LIBARCHIVE_VERSION_S())
  12 m4_define([BSDCPIO_VERSION_S],LIBARCHIVE_VERSION_S())
  13 m4_define([BSDCAT_VERSION_S],LIBARCHIVE_VERSION_S())
  14
  15 AC_PREREQ([2.69])
  16
  17 #
  18 # Now starts the "real" configure script.
  19 #
  20
  21 AC_INIT([libarchive],[LIBARCHIVE_VERSION_S()],[libarchive-discuss@googlegroups.com])
  22 # Make sure the srcdir contains "libarchive" directory
  23 AC_CONFIG_SRCDIR([libarchive])
  24 # Use auxiliary subscripts from this subdirectory (cleans up root)
  25 AC_CONFIG_AUX_DIR([build/autoconf])
  26 # M4 scripts
  27 AC_CONFIG_MACRO_DIR([build/autoconf])
  28 # Must follow AC_CONFIG macros above...
  29 AM_INIT_AUTOMAKE()
  30 AM_MAINTAINER_MODE([enable])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 # Libtool's "interface version" can be computed from the libarchive version.
  34
  35 # Libtool interface version bumps on any API change, so increments
  36 # whenever libarchive minor version does.
  37 ARCHIVE_MINOR=$(( (LIBARCHIVE_VERSION_N() / 1000) % 1000 ))
  38 # Libarchive 2.7 == libtool interface 9 = 2 + 7
  39 # Libarchive 2.8 == libtool interface 10 = 2 + 8
  40 # Libarchive 2.9 == libtool interface 11 = 2 + 8
  41 # Libarchive 3.0 == libtool interface 12
  42 # Libarchive 3.1 == libtool interface 13
  43 ARCHIVE_INTERFACE=`echo $((13 + ${ARCHIVE_MINOR}))`
  44 # Libarchive revision is bumped on any source change === libtool revision
  45 ARCHIVE_REVISION=$(( LIBARCHIVE_VERSION_N() % 1000 ))
  46 # Libarchive minor is bumped on any interface addition === libtool age
  47 ARCHIVE_LIBTOOL_VERSION=$ARCHIVE_INTERFACE:$ARCHIVE_REVISION:$ARCHIVE_MINOR
  48
  49 # Stick the version numbers into config.h
  50 AC_DEFINE([LIBARCHIVE_VERSION_STRING],"LIBARCHIVE_VERSION_S()",
  51         [Version number of libarchive])
  52 AC_DEFINE_UNQUOTED([LIBARCHIVE_VERSION_NUMBER],"LIBARCHIVE_VERSION_N()",
  53         [Version number of libarchive as a single integer])
  54 AC_DEFINE([BSDCPIO_VERSION_STRING],"BSDCPIO_VERSION_S()",
  55         [Version number of bsdcpio])
  56 AC_DEFINE([BSDTAR_VERSION_STRING],"BSDTAR_VERSION_S()",
  57         [Version number of bsdtar])
  58 AC_DEFINE([BSDCAT_VERSION_STRING],"BSDTAR_VERSION_S()",
  59         [Version number of bsdcat])
  60
  61 # The shell variables here must be the same as the AC_SUBST() variables
  62 # below, but the shell variable names apparently cannot be the same as
  63 # the m4 macro names above.  Why?  Ask autoconf.
  64 BSDCPIO_VERSION_STRING=BSDCPIO_VERSION_S()
  65 BSDTAR_VERSION_STRING=BSDTAR_VERSION_S()
  66 BSDCAT_VERSION_STRING=BSDCAT_VERSION_S()
  67 LIBARCHIVE_VERSION_STRING=LIBARCHIVE_VERSION_S()
  68 LIBARCHIVE_VERSION_NUMBER=LIBARCHIVE_VERSION_N()
  69
  70 # Substitute the above version numbers into the various files below.
  71 # Yes, I believe this is the fourth time we define what are essentially
  72 # the same symbols.  Why? Ask autoconf.
  73 AC_SUBST(ARCHIVE_LIBTOOL_VERSION)
  74 AC_SUBST(BSDCPIO_VERSION_STRING)
  75 AC_SUBST(BSDTAR_VERSION_STRING)
  76 AC_SUBST(BSDCAT_VERSION_STRING)
  77 AC_SUBST(LIBARCHIVE_VERSION_STRING)
  78 AC_SUBST(LIBARCHIVE_VERSION_NUMBER)
  79
  80 AC_CONFIG_HEADERS([config.h])
  81 AC_CONFIG_FILES([Makefile])
  82 AC_CONFIG_FILES([build/pkgconfig/libarchive.pc])
  83
  84 # Check for host type
  85 AC_CANONICAL_HOST
  86
  87 dnl Compilation on mingw and Cygwin needs special Makefile rules
  88 inc_windows_files=no
  89 inc_cygwin_files=no
  90 case "$host_os" in
  91   *mingw* ) inc_windows_files=yes ;;
  92   *cygwin*) inc_cygwin_files=yes ;;
  93 esac
  94 AM_CONDITIONAL([INC_WINDOWS_FILES], [test $inc_windows_files = yes])
  95 AM_CONDITIONAL([INC_CYGWIN_FILES], [test $inc_cygwin_files = yes])
  96
  97 dnl Defines that are required for specific platforms (e.g. -D_POSIX_SOURCE, etc)
  98 PLATFORMCPPFLAGS=
  99 case "$host_os" in
 100   *mingw* ) PLATFORMCPPFLAGS=-D__USE_MINGW_ANSI_STDIO ;;
 101 esac
 102 AC_SUBST(PLATFORMCPPFLAGS)
 103
 104 # Checks for programs.
 105 AC_PROG_CC
 106 AM_PROG_CC_C_O
 107 AC_USE_SYSTEM_EXTENSIONS
 108 AC_LIBTOOL_WIN32_DLL
 109 AC_PROG_LIBTOOL
 110 AC_CHECK_TOOL([STRIP],[strip])
 111 AC_PROG_MKDIR_P
 112
 113 #
 114 # Options for building bsdtar.
 115 #
 116 # Default is to build bsdtar, but allow people to override that.
 117 #
 118 AC_ARG_ENABLE([bsdtar],
 119         [AS_HELP_STRING([--enable-bsdtar], [enable build of bsdtar (default)])
 120         AS_HELP_STRING([--enable-bsdtar=static], [force static build of bsdtar])
 121         AS_HELP_STRING([--enable-bsdtar=shared], [force dynamic build of bsdtar])
 122 AS_HELP_STRING([--disable-bsdtar], [disable build of bsdtar])],
 123         [], [enable_bsdtar=yes])
 124
 125 case "$enable_bsdtar" in
 126 yes)
 127         if test "$enable_static" = "no"; then
 128                 static_bsdtar=no
 129         else
 130                 static_bsdtar=yes
 131         fi
 132         build_bsdtar=yes
 133         ;;
 134 dynamic|shared)
 135         if test "$enable_shared" = "no"; then
 136                 AC_MSG_FAILURE([Shared linking of bsdtar requires shared libarchive])
 137         fi
 138         build_bsdtar=yes
 139         static_bsdtar=no
 140         ;;
 141 static)
 142         build_bsdtar=yes
 143         static_bsdtar=yes
 144         ;;
 145 no)
 146         build_bsdtar=no
 147         static_bsdtar=no
 148         ;;
 149 *)
 150         AC_MSG_FAILURE([Unsupported value for --enable-bsdtar])
 151         ;;
 152 esac
 153
 154 AM_CONDITIONAL([BUILD_BSDTAR], [ test "$build_bsdtar" = yes ])
 155 AM_CONDITIONAL([STATIC_BSDTAR], [ test "$static_bsdtar" = yes ])
 156
 157 #
 158 # Options for building bsdcat.
 159 #
 160 # Default is to build bsdcat, but allow people to override that.
 161 #
 162 AC_ARG_ENABLE([bsdcat],
 163         [AS_HELP_STRING([--enable-bsdcat], [enable build of bsdcat (default)])
 164         AS_HELP_STRING([--enable-bsdcat=static], [force static build of bsdcat])
 165         AS_HELP_STRING([--enable-bsdcat=shared], [force dynamic build of bsdcat])
 166 AS_HELP_STRING([--disable-bsdcat], [disable build of bsdcat])],
 167         [], [enable_bsdcat=yes])
 168
 169 case "$enable_bsdcat" in
 170 yes)
 171         if test "$enable_static" = "no"; then
 172                 static_bsdcat=no
 173         else
 174                 static_bsdcat=yes
 175         fi
 176         build_bsdcat=yes
 177         ;;
 178 dynamic|shared)
 179         if test "$enable_shared" = "no"; then
 180                 AC_MSG_FAILURE([Shared linking of bsdcat requires shared libarchive])
 181         fi
 182         build_bsdcat=yes
 183         static_bsdcat=no
 184         ;;
 185 static)
 186         build_bsdcat=yes
 187         static_bsdcat=yes
 188         ;;
 189 no)
 190         build_bsdcat=no
 191         static_bsdcat=no
 192         ;;
 193 *)
 194         AC_MSG_FAILURE([Unsupported value for --enable-bsdcat])
 195         ;;
 196 esac
 197
 198 AM_CONDITIONAL([BUILD_BSDCAT], [ test "$build_bsdcat" = yes ])
 199 AM_CONDITIONAL([STATIC_BSDCAT], [ test "$static_bsdcat" = yes ])
 200
 201 #
 202 # Options for building bsdcpio.
 203 #
 204 # Default is not to build bsdcpio, but that can be overridden.
 205 #
 206 AC_ARG_ENABLE([bsdcpio],
 207         [AS_HELP_STRING([--enable-bsdcpio], [enable build of bsdcpio (default)])
 208         AS_HELP_STRING([--enable-bsdcpio=static], [static build of bsdcpio])
 209         AS_HELP_STRING([--enable-bsdcpio=shared], [dynamic build of bsdcpio])
 210 AS_HELP_STRING([--disable-bsdcpio], [disable build of bsdcpio])],
 211         [], [enable_bsdcpio=yes])
 212
 213 case "$enable_bsdcpio" in
 214 yes)
 215         if test "$enable_static" = "no"; then
 216            static_bsdcpio=no
 217         else
 218            static_bsdcpio=yes
 219         fi
 220         build_bsdcpio=yes
 221         ;;
 222 dynamic|shared)
 223         if test "$enabled_shared" = "no"; then
 224            AC_MSG_FAILURE([Shared linking of bsdcpio requires shared libarchive])
 225         fi
 226         build_bsdcpio=yes
 227         ;;
 228 static)
 229         build_bsdcpio=yes
 230         static_bsdcpio=yes
 231         ;;
 232 no)
 233         build_bsdcpio=no
 234         static_bsdcpio=no
 235         ;;
 236 *)
 237         AC_MSG_FAILURE([Unsupported value for --enable-bsdcpio])
 238         ;;
 239 esac
 240
 241 AM_CONDITIONAL([BUILD_BSDCPIO], [ test "$build_bsdcpio" = yes ])
 242 AM_CONDITIONAL([STATIC_BSDCPIO], [ test "$static_bsdcpio" = yes ])
 243
 244 # Set up defines needed before including any headers
 245 case $host in
 246   *mingw* | *cygwin* )
 247   AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 248   AC_DEFINE([WINVER], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 249   AC_DEFINE([NTDDI_VERSION], 0x05020000, [Define to '0x05020000' for Windows Server 2003 APIs.])
 250   ;;
 251 esac
 252
 253 # Checks for header files.
 254 AC_HEADER_DIRENT
 255 AC_HEADER_SYS_WAIT
 256 AC_CHECK_HEADERS([copyfile.h ctype.h])
 257 AC_CHECK_HEADERS([errno.h ext2fs/ext2_fs.h fcntl.h grp.h])
 258
 259 AC_CACHE_CHECK([whether EXT2_IOC_GETFLAGS is usable],
 260     [ac_cv_have_decl_EXT2_IOC_GETFLAGS],
 261     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 262 @%:@include <ext2fs/ext2_fs.h>],
 263                                    [int x = EXT2_IOC_GETFLAGS])],
 264                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes])],
 265                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [no])])])
 266
 267 AS_VAR_IF([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes],
 268     [AC_DEFINE_UNQUOTED([HAVE_WORKING_EXT2_IOC_GETFLAGS], [1],
 269                     [Define to 1 if you have a working EXT2_IOC_GETFLAGS])])
 270
 271 AC_CHECK_HEADERS([inttypes.h io.h langinfo.h limits.h])
 272 AC_CHECK_HEADERS([linux/fiemap.h linux/fs.h linux/magic.h linux/types.h])
 273 AC_CHECK_HEADERS([locale.h paths.h poll.h pthread.h pwd.h])
 274 AC_CHECK_HEADERS([readpassphrase.h signal.h spawn.h])
 275 AC_CHECK_HEADERS([stdarg.h stdint.h stdlib.h string.h])
 276 AC_CHECK_HEADERS([sys/cdefs.h sys/extattr.h])
 277 AC_CHECK_HEADERS([sys/ioctl.h sys/mkdev.h sys/mount.h])
 278 AC_CHECK_HEADERS([sys/param.h sys/poll.h sys/select.h sys/statfs.h sys/statvfs.h])
 279 AC_CHECK_HEADERS([sys/time.h sys/utime.h sys/utsname.h sys/vfs.h])
 280 AC_CHECK_HEADERS([time.h unistd.h utime.h wchar.h wctype.h])
 281 AC_CHECK_HEADERS([windows.h])
 282 AC_CHECK_HEADERS([Bcrypt.h])
 283 # check windows.h first; the other headers require it.
 284 AC_CHECK_HEADERS([wincrypt.h winioctl.h],[],[],
 285 [[#ifdef HAVE_WINDOWS_H
 286 # include <windows.h>
 287 #endif
 288 ]])
 289
 290 # Checks for libraries.
 291 AC_ARG_WITH([zlib],
 292   AS_HELP_STRING([--without-zlib], [Don't build support for gzip through zlib]))
 293
 294 if test "x$with_zlib" != "xno"; then
 295   AC_CHECK_HEADERS([zlib.h])
 296   AC_CHECK_LIB(z,inflate)
 297 fi
 298
 299 AC_ARG_WITH([bz2lib],
 300   AS_HELP_STRING([--without-bz2lib], [Don't build support for bzip2 through bz2lib]))
 301
 302 if test "x$with_bz2lib" != "xno"; then
 303   AC_CHECK_HEADERS([bzlib.h])
 304   case "$host_os" in
 305     *mingw* | *cygwin*)
 306       dnl AC_CHECK_LIB cannot be used on the Windows port of libbz2, therefore
 307           dnl use AC_LINK_IFELSE.
 308           AC_MSG_CHECKING([for BZ2_bzDecompressInit in -lbz2])
 309       old_LIBS="$LIBS"
 310       LIBS="-lbz2 $LIBS"
 311       AC_LINK_IFELSE(
 312         [AC_LANG_SOURCE(#include <bzlib.h>
 313           int main() { return BZ2_bzDecompressInit(NULL, 0, 0); })],
 314         [ac_cv_lib_bz2_BZ2_bzDecompressInit=yes],
 315         [ac_cv_lib_bz2_BZ2_bzDecompressInit=no])
 316       LIBS="$old_LIBS"
 317           AC_MSG_RESULT($ac_cv_lib_bz2_BZ2_bzDecompressInit)
 318       if test "x$ac_cv_lib_bz2_BZ2_bzDecompressInit" = xyes; then
 319         AC_DEFINE([HAVE_LIBBZ2], [1], [Define to 1 if you have the `bz2' library (-lbz2).])
 320         LIBS="-lbz2 $LIBS"
 321       fi
 322     ;;
 323     *)
 324       AC_CHECK_LIB(bz2,BZ2_bzDecompressInit)
 325     ;;
 326   esac
 327 fi
 328
 329 AC_ARG_WITH([lzmadec],
 330   AS_HELP_STRING([--without-lzmadec], [Don't build support for lzma through lzmadec]))
 331
 332 if test "x$with_lzmadec" != "xno"; then
 333   AC_CHECK_HEADERS([lzmadec.h])
 334   AC_CHECK_LIB(lzmadec,lzmadec_decode)
 335 fi
 336
 337 AC_ARG_WITH([iconv],
 338   AS_HELP_STRING([--without-iconv], [Don't try to link against iconv]))
 339
 340 if test "x$with_iconv" != "xno"; then
 341   AM_ICONV
 342   AC_CHECK_HEADERS([iconv.h],[],[],[#include <stdlib.h>])
 343   if test "x$am_cv_func_iconv" = "xyes"; then
 344     AC_CHECK_HEADERS([localcharset.h])
 345     am_save_LIBS="$LIBS"
 346     LIBS="${LIBS} ${LIBICONV}"
 347     AC_CHECK_FUNCS([locale_charset])
 348     LIBS="${am_save_LIBS}"
 349     if test "x$ac_cv_func_locale_charset" != "xyes"; then
 350       # If locale_charset() is not in libiconv, we have to find libcharset.
 351       AC_CHECK_LIB(charset,locale_charset)
 352     fi
 353   fi
 354 fi
 355
 356 AC_ARG_WITH([lz4],
 357   AS_HELP_STRING([--without-lz4], [Don't build support for lz4 through liblz4]))
 358
 359 if test "x$with_lz4" != "xno"; then
 360   AC_CHECK_HEADERS([lz4.h lz4hc.h])
 361   AC_CHECK_LIB(lz4,LZ4_decompress_safe)
 362 fi
 363
 364 AC_ARG_WITH([lzma],
 365   AS_HELP_STRING([--without-lzma], [Don't build support for xz through lzma]))
 366
 367 if test "x$with_lzma" != "xno"; then
 368   AC_CHECK_HEADERS([lzma.h])
 369   AC_CHECK_LIB(lzma,lzma_stream_decoder)
 370   # Some pre-release (but widely distributed) versions of liblzma
 371   # included a disabled version of lzma_stream_encoder_mt that
 372   # fools a naive AC_CHECK_LIB or AC_CHECK_FUNC, so we need
 373   # to do something more complex here:
 374   AC_CACHE_CHECK(
 375     [whether we have multithread support in lzma],
 376     ac_cv_lzma_has_mt,
 377     [AC_COMPILE_IFELSE([
 378       AC_LANG_PROGRAM([[#include <lzma.h>]],
 379                       [[lzma_stream_encoder_mt(0, 0);]])],
 380       [ac_cv_lzma_has_mt=yes], [ac_cv_lzma_has_mt=no])])
 381   if test "x$ac_cv_lzma_has_mt" != xno; then
 382           AC_DEFINE([HAVE_LZMA_STREAM_ENCODER_MT], [1], [Define to 1 if you have the `lzma_stream_encoder_mt' function.])
 383   fi
 384 fi
 385
 386 AC_ARG_WITH([lzo2],
 387   AS_HELP_STRING([--without-lzo2], [Don't build support for lzop through liblzo2]))
 388
 389 if test "x$with_lzo2" != "xno"; then
 390   AC_CHECK_HEADERS([lzo/lzoconf.h lzo/lzo1x.h])
 391   AC_CHECK_LIB(lzo2,lzo1x_decompress_safe)
 392 fi
 393
 394 AC_ARG_WITH([nettle],
 395   AS_HELP_STRING([--without-nettle], [Don't build with crypto support from Nettle]))
 396 AC_ARG_WITH([openssl],
 397   AS_HELP_STRING([--without-openssl], [Don't build support for mtree and xar hashes through openssl]))
 398 case "$host_os" in
 399   *darwin* ) with_openssl=no ;;
 400 esac
 401
 402 AC_ARG_WITH([xml2],
 403   AS_HELP_STRING([--without-xml2], [Don't build support for xar through libxml2]))
 404 AC_ARG_WITH([expat],
 405   AS_HELP_STRING([--without-expat], [Don't build support for xar through expat]))
 406
 407 if test "x$with_xml2" != "xno"; then
 408   PKG_PROG_PKG_CONFIG
 409   PKG_CHECK_MODULES(LIBXML2_PC, [libxml-2.0], [
 410     CPPFLAGS="${CPPFLAGS} ${LIBXML2_PC_CFLAGS}"
 411     LIBS="${LIBS} ${LIBXML2_PC_LIBS}"
 412     AC_CHECK_LIB(xml2,xmlInitParser,[true],AC_MSG_FAILURE(Missing xml2 library))
 413   ], [
 414     AC_CHECK_LIB(xml2,xmlInitParser)
 415   ])
 416   AC_CHECK_HEADERS([libxml/xmlreader.h libxml/xmlwriter.h])
 417 fi
 418 if test "x$ac_cv_header_libxml_xmlreader_h" != "xyes"; then
 419   if test "x$with_expat" != "xno"; then
 420     AC_CHECK_HEADERS([expat.h])
 421     AC_CHECK_LIB(expat,XML_ParserCreate)
 422   fi
 423 fi
 424
 425 AC_ARG_ENABLE([posix-regex-lib],
 426   [AS_HELP_STRING([--enable-posix-regex-lib],
 427     [choose what library to use for POSIX regular expression support (default: auto)])
 428   AS_HELP_STRING([--enable-posix-regex-lib=libc], [use libc POSIX regular expression support])
 429   AS_HELP_STRING([--enable-posix-regex-lib=libregex], [use libregex POSIX regular expression support])
 430   AS_HELP_STRING([--enable-posix-regex-lib=libpcreposix], [use libpcreposix POSIX regular expression support])
 431   AS_HELP_STRING([--disable-posix-regex-lib], [don't enable POSIX regular expression support])],
 432   [], [enable_posix_regex_lib=auto])
 433
 434 posix_regex_lib_found=
 435 if test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libc" || test "$enable_posix_regex_lib" = "libregex"; then
 436   AC_CHECK_HEADERS([regex.h])
 437   if test "x$ac_cv_header_regex_h" != "xno"; then
 438     AC_CHECK_FUNC(regcomp)
 439     if test "x$ac_cv_func_regcomp" = xyes; then
 440       posix_regex_lib_found=1
 441     else
 442       AC_CHECK_LIB(regex,regcomp)
 443       if test "x$ac_cv_lib_regex_regcomp" = xyes; then
 444         posix_regex_lib_found=1
 445       fi
 446     fi
 447   fi
 448 fi
 449 if test -z $posix_regex_lib_found && (test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libpcreposix"); then
 450   AC_CHECK_HEADERS([pcreposix.h])
 451   AC_CHECK_LIB(pcreposix,regcomp)
 452   if test "x$ac_cv_lib_pcreposix_regcomp" != xyes; then
 453     AC_MSG_NOTICE(trying libpcreposix check again with libpcre)
 454         unset ac_cv_lib_pcreposix_regcomp
 455         AC_CHECK_LIB(pcre,pcre_exec)
 456     AC_CHECK_LIB(pcreposix,regcomp)
 457     if test "x$ac_cv_lib_pcre_pcre_exec" = xyes && test "x$ac_cv_lib_pcreposix_regcomp" = xyes; then
 458       AC_MSG_CHECKING(if PCRE_STATIC needs to be defined)
 459       AC_LINK_IFELSE(
 460         [AC_LANG_SOURCE(#include <pcreposix.h>
 461           int main() { return regcomp(NULL, NULL, 0); })],
 462         [without_pcre_static=yes],
 463         [without_pcre_static=no])
 464       AC_LINK_IFELSE(
 465         [AC_LANG_SOURCE(#define PCRE_STATIC
 466           #include <pcreposix.h>
 467           int main() { return regcomp(NULL, NULL, 0); })],
 468         [with_pcre_static=yes],
 469         [with_pcre_static=no])
 470       if test "x$without_pcre_static" != xyes && test "x$with_pcre_static" = xyes; then
 471         AC_MSG_RESULT(yes)
 472         AC_DEFINE([PCRE_STATIC], [1], [Define to 1 if PCRE_STATIC needs to be defined.])
 473       elif test "x$without_pcre_static" = xyes || test "x$with_pcre_static" = xyes; then
 474         AC_MSG_RESULT(no)
 475       fi
 476       posix_regex_lib_found=1
 477     fi
 478   else
 479     posix_regex_lib_found=1
 480   fi
 481 fi
 482
 483 # TODO: Give the user the option of using a pre-existing system
 484 # libarchive.  This will define HAVE_LIBARCHIVE which will cause
 485 # bsdtar_platform.h to use #include <...> for the libarchive headers.
 486 # Need to include Makefile.am magic to link against system
 487 # -larchive in that case.
 488 #AC_CHECK_LIB(archive,archive_version)
 489
 490 # Checks for supported compiler flags
 491 AX_APPEND_COMPILE_FLAGS([-Wall -Wformat -Wformat-security])
 492
 493 # Checks for typedefs, structures, and compiler characteristics.
 494 AC_C_CONST
 495 # la_TYPE_UID_T defaults to "int", which is incorrect for MinGW
 496 # and MSVC. Use a customized version.
 497 la_TYPE_UID_T
 498 AC_TYPE_MODE_T
 499 # AC_TYPE_OFF_T defaults to "long", which limits us to 4GB files on
 500 # most systems... default to "long long" instead.
 501 AC_CHECK_TYPE(off_t, [long long])
 502 AC_TYPE_SIZE_T
 503 AC_CHECK_TYPE(id_t, [unsigned long])
 504 AC_CHECK_TYPE(uintptr_t, [unsigned int])
 505
 506 # Check for tm_gmtoff in struct tm
 507 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,
 508 [
 509 #include <time.h>
 510 ])
 511
 512 # Check for f_namemax in struct statfs
 513 AC_CHECK_MEMBERS([struct statfs.f_namemax],,,
 514 [
 515 #include <sys/param.h>
 516 #include <sys/mount.h>
 517 ])
 518
 519 # Check for f_iosize in struct statvfs
 520 AC_CHECK_MEMBERS([struct statvfs.f_iosize],,,
 521 [
 522 #include <sys/statvfs.h>
 523 ])
 524
 525 # Check for birthtime in struct stat
 526 AC_CHECK_MEMBERS([struct stat.st_birthtime])
 527
 528 # Check for high-resolution timestamps in struct stat
 529 AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec])
 530 AC_CHECK_MEMBERS([struct stat.st_mtimespec.tv_nsec])
 531 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 532 AC_CHECK_MEMBERS([struct stat.st_mtime_n]) # AIX
 533 AC_CHECK_MEMBERS([struct stat.st_umtime]) # Tru64
 534 AC_CHECK_MEMBERS([struct stat.st_mtime_usec]) # Hurd
 535 # Check for block size support in struct stat
 536 AC_CHECK_MEMBERS([struct stat.st_blksize])
 537 # Check for st_flags in struct stat (BSD fflags)
 538 AC_CHECK_MEMBERS([struct stat.st_flags])
 539
 540 # If you have uintmax_t, we assume printf supports %ju
 541 # If you have unsigned long long, we assume printf supports %llu
 542 # TODO: Check for %ju and %llu support directly.
 543 AC_CHECK_TYPES([uintmax_t, unsigned long long])
 544
 545 # We use C99-style integer types
 546 # Declare them if the local platform doesn't already do so.
 547 AC_TYPE_INTMAX_T
 548 AC_TYPE_UINTMAX_T
 549 AC_TYPE_INT64_T
 550 AC_TYPE_UINT64_T
 551 AC_TYPE_INT32_T
 552 AC_TYPE_UINT32_T
 553 AC_TYPE_INT16_T
 554 AC_TYPE_UINT16_T
 555 AC_TYPE_UINT8_T
 556
 557 AC_CHECK_DECLS([SIZE_MAX, INT32_MAX, INT32_MIN])
 558 AC_CHECK_DECLS([INT64_MAX, INT64_MIN, UINT64_MAX, UINT32_MAX])
 559 AC_CHECK_DECLS([INTMAX_MAX, INTMAX_MIN, UINTMAX_MAX])
 560
 561 AC_CHECK_DECL([SSIZE_MAX],
 562                 [AC_DEFINE(HAVE_DECL_SSIZE_MAX, 1, [Define to 1 if you have the declaration of `SSIZE_MAX', and to 0 if you don't.])],
 563                 [],
 564                 [#include <limits.h>])
 565
 566 AC_CHECK_DECL([EFTYPE],
 567                 [AC_DEFINE(HAVE_EFTYPE, 1, [A possible errno value for invalid file format errors])],
 568                 [],
 569                 [#include <errno.h>])
 570 AC_CHECK_DECL([EILSEQ],
 571                 [AC_DEFINE(HAVE_EILSEQ, 1, [A possible errno value for invalid file format errors])],
 572                 [],
 573                 [#include <errno.h>])
 574 AC_CHECK_TYPE([wchar_t],
 575                 [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]wchar_t), 1, [Define to 1 if the system has the type `wchar_t'.])dnl
 576                 AC_CHECK_SIZEOF([wchar_t])],
 577                 [])
 578
 579 AC_HEADER_TIME
 580
 581 # Checks for library functions.
 582 AC_PROG_GCC_TRADITIONAL
 583 AC_HEADER_MAJOR
 584 AC_FUNC_FSEEKO
 585 AC_FUNC_MEMCMP
 586 AC_FUNC_LSTAT
 587 AC_FUNC_STAT
 588 AC_FUNC_STRERROR_R
 589 AC_FUNC_STRFTIME
 590 AC_FUNC_VPRINTF
 591 # check for:
 592 #   CreateHardLinkA(LPCSTR, LPCSTR, LPSECURITY_ATTRIBUTES)
 593 # To avoid necessity for including windows.h or special forward declaration
 594 # workarounds, we use 'void *' for 'struct SECURITY_ATTRIBUTES *'
 595 AC_CHECK_STDCALL_FUNC([CreateHardLinkA],[const char *, const char *, void *])
 596 AC_CHECK_FUNCS([arc4random_buf chflags chown chroot ctime_r dirfd])
 597 AC_CHECK_FUNCS([fchdir fchflags fchmod fchown fcntl fdopendir fork])
 598 AC_CHECK_FUNCS([fstat fstatat fstatfs fstatvfs ftruncate])
 599 AC_CHECK_FUNCS([futimens futimes futimesat])
 600 AC_CHECK_FUNCS([geteuid getpid getgrgid_r getgrnam_r])
 601 AC_CHECK_FUNCS([getpwnam_r getpwuid_r getvfsbyname gmtime_r])
 602 AC_CHECK_FUNCS([lchflags lchmod lchown link localtime_r lstat lutimes])
 603 AC_CHECK_FUNCS([mbrtowc memmove memset])
 604 AC_CHECK_FUNCS([mkdir mkfifo mknod mkstemp])
 605 AC_CHECK_FUNCS([nl_langinfo openat pipe poll posix_spawnp readlink readlinkat])
 606 AC_CHECK_FUNCS([readpassphrase])
 607 AC_CHECK_FUNCS([select setenv setlocale sigaction statfs statvfs])
 608 AC_CHECK_FUNCS([strchr strdup strerror strncpy_s strrchr symlink timegm])
 609 AC_CHECK_FUNCS([tzset unsetenv utime utimensat utimes vfork])
 610 AC_CHECK_FUNCS([wcrtomb wcscmp wcscpy wcslen wctomb wmemcmp wmemcpy wmemmove])
 611 AC_CHECK_FUNCS([_ctime64_s _fseeki64])
 612 AC_CHECK_FUNCS([_get_timezone _localtime64_s _mkgmtime64])
 613 # detects cygwin-1.7, as opposed to older versions
 614 AC_CHECK_FUNCS([cygwin_conv_path])
 615
 616 # There are several variants of readdir_r around; we only
 617 # accept the POSIX-compliant version.
 618 AC_COMPILE_IFELSE(
 619  [AC_LANG_PROGRAM([[#include <dirent.h>]],
 620                   [[DIR *dir; struct dirent e, *r;
 621                     return(readdir_r(dir, &e, &r));]])],
 622  [AC_DEFINE(HAVE_READDIR_R,1,[Define to 1 if you have a POSIX compatible readdir_r])]
 623 )
 624
 625 # FreeBSD's nl_langinfo supports an option to specify whether the
 626 # current locale uses month/day or day/month ordering.  It makes the
 627 # output a little prettier...
 628 AC_CHECK_DECL([D_MD_ORDER],
 629 [AC_DEFINE(HAVE_D_MD_ORDER, 1, [Define to 1 if nl_langinfo supports D_MD_ORDER])],
 630 [],
 631 [#if HAVE_LANGINFO_H
 632 #include <langinfo.h>
 633 #endif
 634 ])
 635
 636 # Check for dirent.d_namlen field explicitly
 637 # (This is a bit more straightforward than, if not quite as portable as,
 638 # the recipe given by the autoconf maintainers.)
 639 AC_CHECK_MEMBER(struct dirent.d_namlen,,,
 640 [#if HAVE_DIRENT_H
 641 #include <dirent.h>
 642 #endif
 643 ])
 644
 645 # Check for Extended Attributes support
 646 AC_ARG_ENABLE([xattr],
 647                 AS_HELP_STRING([--disable-xattr],
 648                 [Disable Extended Attributes support (default: check)]))
 649
 650 if test "x$enable_xattr" != "xno"; then
 651         AC_CHECK_HEADERS([attr/xattr.h])
 652         AC_CHECK_HEADERS([sys/xattr.h sys/ea.h])
 653         AC_SEARCH_LIBS([setxattr], [attr])
 654         AC_CHECK_FUNCS([extattr_get_file extattr_list_file])
 655         AC_CHECK_FUNCS([extattr_set_fd extattr_set_file])
 656         AC_CHECK_FUNCS([fgetxattr flistxattr fsetxattr getxattr])
 657         AC_CHECK_FUNCS([lgetxattr listxattr llistxattr lsetxattr])
 658         AC_CHECK_FUNCS([fgetea flistea fsetea getea])
 659         AC_CHECK_FUNCS([lgetea listea llistea lsetea])
 660         AC_CHECK_DECLS([EXTATTR_NAMESPACE_USER], [], [], [#include <sys/types.h>
 661 #include <sys/extattr.h>
 662 ])
 663 fi
 664
 665 # Check for ACL support
 666 #
 667 # The ACL support in libarchive is written against the POSIX1e draft,
 668 # which was never officially approved and varies quite a bit across
 669 # platforms.  Worse, some systems have completely non-POSIX acl functions,
 670 # which makes the following checks rather more complex than I would like.
 671 #
 672 AC_ARG_ENABLE([acl],
 673                 AS_HELP_STRING([--disable-acl],
 674                 [Disable ACL support (default: check)]))
 675
 676 if test "x$enable_acl" != "xno"; then
 677    AC_CHECK_HEADERS([acl/libacl.h])
 678    AC_CHECK_HEADERS([sys/acl.h])
 679    AC_CHECK_LIB([acl],[acl_get_file])
 680    AC_CHECK_FUNCS([acl_create_entry acl_init acl_set_fd acl_set_fd_np acl_set_file])
 681
 682    AC_CHECK_TYPES(acl_permset_t,,,
 683         [#if HAVE_SYS_TYPES_H
 684         #include <sys/types.h>
 685         #endif
 686         #if HAVE_SYS_ACL_H
 687         #include <sys/acl.h>
 688         #endif
 689         ])
 690
 691     # The "acl_get_perm()" function was omitted from the POSIX draft.
 692     # (It's a pretty obvious oversight; otherwise, there's no way to
 693     # test for specific permissions in a permset.)  Linux uses the obvious
 694     # name, FreeBSD adds _np to mark it as "non-Posix extension."
 695     # Test for both as a double-check that we really have POSIX-style ACL support.
 696     AC_CHECK_FUNCS(acl_get_perm_np acl_get_perm acl_get_link acl_get_link_np,,,
 697         [#if HAVE_SYS_TYPES_H
 698         #include <sys/types.h>
 699         #endif
 700         #if HAVE_SYS_ACL_H
 701         #include <sys/acl.h>
 702         #endif
 703         ])
 704
 705     # MacOS has an acl.h that isn't POSIX.  It can be detected by
 706     # checking for ACL_USER
 707     AC_CHECK_DECL([ACL_USER],
 708                 [AC_DEFINE(HAVE_ACL_USER, 1, [True for systems with POSIX ACL support])],
 709                 [],
 710                 [#include <sys/acl.h>])
 711 fi
 712
 713 # Additional requirements
 714 AC_SYS_LARGEFILE
 715
 716 dnl NOTE: Crypto checks must run last.
 717 AC_DEFUN([CRYPTO_CHECK], [
 718   if test "$found_$1" != yes; then
 719     saved_CPPFLAGS="$CPPFLAGS"
 720     CPPFLAGS="$CPPFLAGS -I. -I$srcdir -I$srcdir/libarchive"
 721     touch "check_crypto_md.h"
 722     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_$2])
 723     AC_LINK_IFELSE([AC_LANG_SOURCE([
 724 #define ARCHIVE_$1_COMPILE_TEST
 725 #define ARCHIVE_CRYPTO_$1_$2
 726 #define PLATFORM_CONFIG_H "check_crypto_md.h"
 727
 728 $(cat "$srcdir/libarchive/archive_digest.c")
 729
 730 int
 731 main(int argc, char **argv)
 732 {
 733   archive_$3_ctx ctx;
 734   archive_$3_init(&ctx);
 735   archive_$3_update(&ctx, *argv, argc);
 736   archive_$3_final(&ctx, NULL);
 737   return 0;
 738 }
 739 ])],
 740     [ AC_MSG_RESULT([yes])
 741       found_$1=yes
 742       found_$2=yes
 743       AC_DEFINE(ARCHIVE_CRYPTO_$1_$2, 1, [ $1 via ARCHIVE_CRYPTO_$1_$2 supported.])
 744     ],
 745     [ AC_MSG_RESULT([no])])
 746     CPPFLAGS="$saved_CPPFLAGS"
 747     rm "check_crypto_md.h"
 748   fi
 749 ])
 750
 751 AC_DEFUN([CRYPTO_CHECK_WIN], [
 752   if test "$found_$1" != yes; then
 753     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_WIN])
 754     AC_LINK_IFELSE([AC_LANG_SOURCE([
 755 #define ARCHIVE_$1_COMPILE_TEST
 756 #include <windows.h>
 757 #include <wincrypt.h>
 758
 759 int
 760 main(int argc, char **argv)
 761 {
 762         (void)argc;
 763         (void)argv;
 764
 765         return ($2);
 766 }
 767 ])],
 768     [ AC_MSG_RESULT([yes])
 769       found_$1=yes
 770       found_WIN=yes
 771       AC_DEFINE(ARCHIVE_CRYPTO_$1_WIN, 1, [ $1 via ARCHIVE_CRYPTO_$1_WIN supported.])
 772     ],
 773     [ AC_MSG_RESULT([no])])
 774   fi
 775 ])
 776
 777 case "$host_os" in
 778   *mingw* | *cygwin*)
 779         ;;
 780   *)
 781         CRYPTO_CHECK(MD5, LIBC, md5)
 782         CRYPTO_CHECK(MD5, LIBSYSTEM, md5)
 783         CRYPTO_CHECK(RMD160, LIBC, rmd160)
 784         CRYPTO_CHECK(SHA1, LIBC, sha1)
 785         CRYPTO_CHECK(SHA1, LIBSYSTEM, sha1)
 786         CRYPTO_CHECK(SHA256, LIBC, sha256)
 787         CRYPTO_CHECK(SHA256, LIBC2, sha256)
 788         CRYPTO_CHECK(SHA256, LIBC3, sha256)
 789         CRYPTO_CHECK(SHA256, LIBSYSTEM, sha256)
 790         CRYPTO_CHECK(SHA384, LIBC, sha384)
 791         CRYPTO_CHECK(SHA384, LIBC2, sha384)
 792         CRYPTO_CHECK(SHA384, LIBC3, sha384)
 793         CRYPTO_CHECK(SHA384, LIBSYSTEM, sha384)
 794         CRYPTO_CHECK(SHA512, LIBC, sha512)
 795         CRYPTO_CHECK(SHA512, LIBC2, sha512)
 796         CRYPTO_CHECK(SHA512, LIBC3, sha512)
 797         CRYPTO_CHECK(SHA512, LIBSYSTEM, sha512)
 798         ;;
 799 esac
 800
 801 if test "x$with_nettle" != "xno"; then
 802     AC_CHECK_HEADERS([nettle/md5.h nettle/ripemd160.h nettle/sha.h])
 803     AC_CHECK_HEADERS([nettle/pbkdf2.h nettle/aes.h nettle/hmac.h])
 804     saved_LIBS=$LIBS
 805     AC_CHECK_LIB(nettle,nettle_sha1_init)
 806     CRYPTO_CHECK(MD5, NETTLE, md5)
 807     CRYPTO_CHECK(RMD160, NETTLE, rmd160)
 808     CRYPTO_CHECK(SHA1, NETTLE, sha1)
 809     CRYPTO_CHECK(SHA256, NETTLE, sha256)
 810     CRYPTO_CHECK(SHA384, NETTLE, sha384)
 811     CRYPTO_CHECK(SHA512, NETTLE, sha512)
 812     if test "x$found_NETTLE" != "xyes"; then
 813       LIBS=$saved_LIBS
 814     fi
 815 fi
 816
 817 if test "x$with_openssl" != "xno"; then
 818     AC_CHECK_HEADERS([openssl/evp.h])
 819     saved_LIBS=$LIBS
 820     case "$host_os" in
 821       *mingw* | *cygwin*)
 822         case "$host_cpu" in
 823           x86_64)
 824             AC_CHECK_LIB(eay64,OPENSSL_config)
 825             if test "x$ac_cv_lib_eay64_main" != "xyes"; then
 826               AC_CHECK_LIB(eay32,OPENSSL_config)
 827             fi
 828             ;;
 829           *)
 830             AC_CHECK_LIB(eay32,OPENSSL_config)
 831             ;;
 832         esac
 833         ;;
 834       *)
 835         AC_CHECK_LIB(crypto,OPENSSL_config)
 836         ;;
 837     esac
 838     CRYPTO_CHECK(MD5, OPENSSL, md5)
 839     CRYPTO_CHECK(RMD160, OPENSSL, rmd160)
 840     CRYPTO_CHECK(SHA1, OPENSSL, sha1)
 841     CRYPTO_CHECK(SHA256, OPENSSL, sha256)
 842     CRYPTO_CHECK(SHA384, OPENSSL, sha384)
 843     CRYPTO_CHECK(SHA512, OPENSSL, sha512)
 844     if test "x$found_OPENSSL" != "xyes"; then
 845       LIBS=$saved_LIBS
 846     else
 847       AC_CHECK_FUNCS([PKCS5_PBKDF2_HMAC_SHA1])
 848     fi
 849     AC_CHECK_LIB(crypto,EVP_CIPHER_CTX_init)
 850 fi
 851
 852 # Probe libmd AFTER OpenSSL/libcrypto.
 853 # The two are incompatible and OpenSSL is more complete.
 854 AC_CHECK_HEADERS([md5.h ripemd.h sha.h sha256.h sha512.h])
 855 saved_LIBS=$LIBS
 856 AC_CHECK_LIB(md,MD5Init)
 857 CRYPTO_CHECK(MD5, LIBMD, md5)
 858 CRYPTO_CHECK(RMD160, LIBMD, rmd160)
 859 CRYPTO_CHECK(SHA1, LIBMD, sha1)
 860 CRYPTO_CHECK(SHA256, LIBMD, sha256)
 861 CRYPTO_CHECK(SHA512, LIBMD, sha512)
 862 if test "x$found_LIBMD" != "xyes"; then
 863   LIBS=$saved_LIBS
 864 fi
 865
 866 case "$host_os" in
 867   *mingw* | *cygwin*)
 868         CRYPTO_CHECK_WIN(MD5, CALG_MD5)
 869         CRYPTO_CHECK_WIN(SHA1, CALG_SHA1)
 870         CRYPTO_CHECK_WIN(SHA256, CALG_SHA_256)
 871         CRYPTO_CHECK_WIN(SHA384, CALG_SHA_384)
 872         CRYPTO_CHECK_WIN(SHA512, CALG_SHA_512)
 873         ;;
 874 esac
 875
 876 # Ensure test directories are present if building out-of-tree
 877 AC_CONFIG_COMMANDS([mkdirs],
 878                    [mkdir -p libarchive/test tar/test cat/test cpio/test])
 879
 880 AC_OUTPUT