configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[8])
  14 m4_define([VERSION_MICRO],[0])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=8
  21 LIBUNBOUND_REVISION=0
  22 LIBUNBOUND_AGE=0
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.7.4 had 8:0:0 # changes the event callback function signature
  85
  86 #   Current  -- the number of the binary API that we're implementing
  87 #   Revision -- which iteration of the implementation of the binary
  88 #               API are we supplying?
  89 #   Age      -- How many previous binary API versions do we also
  90 #               support?
  91 #
  92 # If we release a new version that does not change the binary API,
  93 # increment Revision.
  94 #
  95 # If we release a new version that changes the binary API, but does
  96 # not break programs compiled against the old binary API, increment
  97 # Current and Age.  Set Revision to 0, since this is the first
  98 # implementation of the new API.
  99 #
 100 # Otherwise, we're changing the binary API and breaking backward
 101 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 102 # since we're backward compatible with no previous APIs.  Set Revision
 103 # to 0 too.
 104 AC_SUBST(LIBUNBOUND_CURRENT)
 105 AC_SUBST(LIBUNBOUND_REVISION)
 106 AC_SUBST(LIBUNBOUND_AGE)
 107
 108 CFLAGS="$CFLAGS"
 109 AC_AIX
 110 if test "$ac_cv_header_minix_config_h" = "yes"; then
 111         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 112 fi
 113
 114 dnl
 115 dnl By default set prefix to /usr/local
 116 dnl
 117 case "$prefix" in
 118         NONE)
 119                 prefix="/usr/local"
 120         ;;
 121 esac
 122 case "$exec_prefix" in
 123         NONE)
 124                 exec_prefix="$prefix"
 125         ;;
 126 esac
 127
 128 # are we on MinGW?
 129 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 130 else
 131         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 132         else on_mingw="no"; fi
 133 fi
 134
 135 #
 136 # Determine configuration file
 137 # the eval is to evaluate shell expansion twice
 138 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 139 AC_SUBST(UNBOUND_SBIN_DIR)
 140 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 141 AC_SUBST(UNBOUND_SYSCONF_DIR)
 142 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 143 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 144 if test $on_mingw = "no"; then
 145   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 146 else
 147   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 148 fi
 149 AC_ARG_WITH([conf_file],
 150         AC_HELP_STRING([--with-conf-file=path],
 151         [Pathname to the Unbound configuration file]),
 152         [ub_conf_file="$withval"])
 153 AC_SUBST(ub_conf_file)
 154 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 155 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 156 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 157 AC_SUBST(ub_conf_dir)
 158
 159 # Determine run, chroot directory and pidfile locations
 160 AC_ARG_WITH(run-dir,
 161     AC_HELP_STRING([--with-run-dir=path],
 162     [set default directory to chdir to (by default dir part of cfg file)]),
 163     UNBOUND_RUN_DIR="$withval",
 164 if test $on_mingw = no; then
 165     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 166 else
 167     UNBOUND_RUN_DIR=""
 168 fi
 169 )
 170 AC_SUBST(UNBOUND_RUN_DIR)
 171 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 172 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 173
 174 AC_ARG_WITH(chroot-dir,
 175     AC_HELP_STRING([--with-chroot-dir=path],
 176     [set default directory to chroot to (by default same as run-dir)]),
 177     UNBOUND_CHROOT_DIR="$withval",
 178 if test $on_mingw = no; then
 179     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 180 else
 181     UNBOUND_CHROOT_DIR=""
 182 fi
 183 )
 184 AC_SUBST(UNBOUND_CHROOT_DIR)
 185 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 186 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 187
 188 AC_ARG_WITH(share-dir,
 189     AC_HELP_STRING([--with-share-dir=path],
 190     [set default directory with shared data (by default same as share/unbound)]),
 191     UNBOUND_SHARE_DIR="$withval",
 192     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 193 AC_SUBST(UNBOUND_SHARE_DIR)
 194 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 195
 196 AC_ARG_WITH(pidfile,
 197     AC_HELP_STRING([--with-pidfile=filename],
 198     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 199     UNBOUND_PIDFILE="$withval",
 200 if test $on_mingw = no; then
 201     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 202 else
 203     UNBOUND_PIDFILE=""
 204 fi
 205 )
 206 AC_SUBST(UNBOUND_PIDFILE)
 207 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 208 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 209
 210 AC_ARG_WITH(rootkey-file,
 211     AC_HELP_STRING([--with-rootkey-file=filename],
 212     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 213     UNBOUND_ROOTKEY_FILE="$withval",
 214 if test $on_mingw = no; then
 215     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 216 else
 217     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 218 fi
 219 )
 220 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 221 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 222 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 223
 224 AC_ARG_WITH(rootcert-file,
 225     AC_HELP_STRING([--with-rootcert-file=filename],
 226     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 227     UNBOUND_ROOTCERT_FILE="$withval",
 228 if test $on_mingw = no; then
 229     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 230 else
 231     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 232 fi
 233 )
 234 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 235 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 236 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 237
 238 AC_ARG_WITH(username,
 239     AC_HELP_STRING([--with-username=user],
 240     [set default user that unbound changes to (default user is unbound)]),
 241     UNBOUND_USERNAME="$withval",
 242     UNBOUND_USERNAME="unbound")
 243 AC_SUBST(UNBOUND_USERNAME)
 244 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 245
 246 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 247 ACX_RSRC_VERSION(wnvs)
 248 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 249
 250 # Checks for typedefs, structures, and compiler characteristics.
 251 AC_C_CONST
 252 AC_LANG_C
 253 # allow user to override the -g -O2 flags.
 254 default_cflags=no
 255 if test "x$CFLAGS" = "x" ; then
 256 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 257 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 258 default_cflags=yes
 259 fi
 260 AC_PROG_CC
 261 ACX_DEPFLAG
 262 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 263
 264 # debug mode flags warnings
 265 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 266 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 267 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 268 else debug_enabled="$enable_checking"; fi
 269 AC_SUBST(debug_enabled)
 270 case "$debug_enabled" in
 271         yes)
 272                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 273                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 274                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 275                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 276                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 277                 ;;
 278         no|*)
 279                 # nothing to do.
 280                 ;;
 281 esac
 282 if test "$default_cflags" = "yes"; then
 283         # only when CFLAGS was "" at the start, if the users wants to
 284         # override we shouldn't add default cflags, because they wouldn't
 285         # be able to turn off these options and set the CFLAGS wanted.
 286         ACX_CHECK_FLTO
 287         ACX_CHECK_PIE
 288         ACX_CHECK_RELRO_NOW
 289 fi
 290
 291 AC_C_INLINE
 292 ACX_CHECK_FORMAT_ATTRIBUTE
 293 ACX_CHECK_UNUSED_ATTRIBUTE
 294
 295 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 296 [AC_REQUIRE([AC_PROG_CC])
 297 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 298 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 299 [ac_cv_c_weak_attribute=no
 300 AC_TRY_COMPILE(
 301 [ #include <stdio.h>
 302 __attribute__((weak)) void f(int x) { printf("%d", x); }
 303 ], [
 304    f(1);
 305 ],
 306 [ac_cv_c_weak_attribute="yes"],
 307 [ac_cv_c_weak_attribute="no"])
 308 ])
 309
 310 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 311 if test $ac_cv_c_weak_attribute = yes; then
 312   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 313 fi
 314 ])dnl End of CHECK_WEAK_ATTRIBUTE
 315
 316 CHECK_WEAK_ATTRIBUTE
 317
 318 if test "$srcdir" != "."; then
 319         CPPFLAGS="$CPPFLAGS -I$srcdir"
 320 fi
 321
 322 AC_DEFUN([ACX_YYLEX_DESTROY], [
 323         AC_MSG_CHECKING([for yylex_destroy])
 324         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 325                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 326                 AC_MSG_RESULT(yes)
 327         else AC_MSG_RESULT(no);
 328                 LEX=":"
 329         fi
 330 ])
 331
 332 AC_DEFUN([ACX_YYLEX_OPTION], [
 333         AC_MSG_CHECKING([for lex %option])
 334         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 335 %option nounput
 336 %%
 337 EOF
 338                 AC_MSG_RESULT(yes)
 339         else AC_MSG_RESULT(no);
 340                 LEX=":"
 341         fi
 342 ])
 343
 344 AC_PROG_LEX
 345 if test "$LEX" != "" -a "$LEX" != ":"; then
 346 ACX_YYLEX_DESTROY
 347 fi
 348 if test "$LEX" != "" -a "$LEX" != ":"; then
 349 ACX_YYLEX_OPTION
 350 fi
 351 AC_PROG_YACC
 352 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 353 AC_CHECK_TOOL(STRIP, strip)
 354 ACX_LIBTOOL_C_ONLY
 355
 356 # Checks for header files.
 357 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 358
 359 # check for types.
 360 # Using own tests for int64* because autoconf builtin only give 32bit.
 361 AC_CHECK_TYPE(int8_t, signed char)
 362 AC_CHECK_TYPE(int16_t, short)
 363 AC_CHECK_TYPE(int32_t, int)
 364 AC_CHECK_TYPE(int64_t, long long)
 365 AC_CHECK_TYPE(uint8_t, unsigned char)
 366 AC_CHECK_TYPE(uint16_t, unsigned short)
 367 AC_CHECK_TYPE(uint32_t, unsigned int)
 368 AC_CHECK_TYPE(uint64_t, unsigned long long)
 369 AC_TYPE_SIZE_T
 370 AC_CHECK_TYPE(ssize_t, int)
 371 AC_TYPE_UID_T
 372 AC_TYPE_PID_T
 373 AC_TYPE_OFF_T
 374 ACX_TYPE_U_CHAR
 375 ACX_TYPE_RLIM_T
 376 ACX_TYPE_SOCKLEN_T
 377 ACX_TYPE_IN_ADDR_T
 378 ACX_TYPE_IN_PORT_T
 379 ACX_CHECK_MEMCMP_SIGNED
 380
 381 AC_CHECK_SIZEOF(time_t,,[
 382 AC_INCLUDES_DEFAULT
 383 #ifdef TIME_WITH_SYS_TIME
 384 # include <sys/time.h>
 385 # include <time.h>
 386 #else
 387 # ifdef HAVE_SYS_TIME_H
 388 #  include <sys/time.h>
 389 # else
 390 #  include <time.h>
 391 # endif
 392 #endif
 393 ])
 394
 395 # add option to disable the evil rpath
 396 ACX_ARG_RPATH
 397 AC_SUBST(RUNTIME_PATH)
 398
 399 # check to see if libraries are needed for these functions.
 400 AC_SEARCH_LIBS([inet_pton], [nsl])
 401 AC_SEARCH_LIBS([socket], [socket])
 402
 403 # check wether strptime also works
 404 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 405 [AC_REQUIRE([AC_PROG_CC])
 406 AC_MSG_CHECKING(whether strptime works)
 407 if test c${cross_compiling} = cno; then
 408 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 409 #define _XOPEN_SOURCE 600
 410 #include <time.h>
 411 int main(void) { struct tm tm; char *res;
 412 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 413 if (!res) return 2;
 414 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 415 if (!res) return 1; return 0; }
 416 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 417 else
 418 eval "ac_cv_c_strptime_works=maybe"
 419 fi
 420 AC_MSG_RESULT($ac_cv_c_strptime_works)
 421 if test $ac_cv_c_strptime_works = no; then
 422 AC_LIBOBJ(strptime)
 423 else
 424 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 425 fi
 426 ])dnl
 427
 428 # check some functions of the OS before linking libs (while still runnable).
 429 AC_FUNC_CHOWN
 430 AC_FUNC_FORK
 431 AC_TYPE_SIGNAL
 432 AC_FUNC_FSEEKO
 433 ACX_SYS_LARGEFILE
 434 ACX_CHECK_NONBLOCKING_BROKEN
 435 ACX_MKDIR_ONE_ARG
 436 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 437
 438 # set memory allocation checking if requested
 439 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 440         [ enable to memory allocation statistics, for debug purposes ]),
 441         , )
 442 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 443         [ enable for lightweight alloc assertions, for debug purposes ]),
 444         , )
 445 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 446         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 447         , )
 448 if test x_$enable_alloc_nonregional = x_yes; then
 449         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 450 fi
 451 if test x_$enable_alloc_checks = x_yes; then
 452         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 453 else
 454         if test x_$enable_alloc_lite = x_yes; then
 455                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 456         else
 457                 ACX_FUNC_MALLOC([unbound])
 458         fi
 459 fi
 460
 461 # check windows threads (we use them, not pthreads, on windows).
 462 if test "$on_mingw" = "yes"; then
 463 # check windows threads
 464         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 465         AC_MSG_CHECKING([for CreateThread])
 466         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 467 #ifdef HAVE_WINDOWS_H
 468 #include <windows.h>
 469 #endif
 470 ], [
 471         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 472 ])],
 473         AC_MSG_RESULT(yes)
 474         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 475 ,
 476         AC_MSG_RESULT(no)
 477 )
 478
 479 else
 480 # not on mingw, check thread libraries.
 481
 482 # check for thread library.
 483 # check this first, so that the pthread lib does not get linked in via
 484 # libssl or libpython, and thus distorts the tests, and we end up using
 485 # the non-threadsafe C libraries.
 486 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 487  [use pthreads library, or --without-pthreads to disable threading support.]),
 488  [ ],[ withval="yes" ])
 489 ub_have_pthreads=no
 490 if test x_$withval != x_no; then
 491         AX_PTHREAD([
 492                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 493                 if test -n "$PTHREAD_LIBS"; then
 494                   LIBS="$PTHREAD_LIBS $LIBS"
 495                 fi
 496                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 497                 CC="$PTHREAD_CC"
 498                 ub_have_pthreads=yes
 499                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 500
 501                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 502                 AC_MSG_CHECKING([if -pthread unused during linking])
 503                 # catch clang warning 'argument unused during compilation'
 504                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 505 [[
 506 int main(void) {return 0;}
 507 ]])])
 508                 pthread_unused="yes"
 509                 # first compile
 510                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 511                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 512                 if test $? = 0; then
 513                         # then link
 514                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 515                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 516                         if test $? -ne 0; then
 517                                 AC_MSG_RESULT(yes)
 518                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 519                                 PTHREAD_CFLAGS_ONLY="-pthread"
 520                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 521                         else
 522                                 AC_MSG_RESULT(no)
 523                         fi
 524                 else
 525                         AC_MSG_RESULT(no)
 526                 fi # endif cc successful
 527                 rm -f conftest conftest.c conftest.o
 528                 fi # endif -pthread in CFLAGS
 529
 530                 ])
 531 fi
 532
 533 # check solaris thread library
 534 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 535         [use solaris native thread library.]), [ ],[ withval="no" ])
 536 ub_have_sol_threads=no
 537 if test x_$withval != x_no; then
 538         if test x_$ub_have_pthreads != x_no; then
 539             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 540         else
 541         AC_SEARCH_LIBS(thr_create, [thread],
 542         [
 543                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 544
 545                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 546                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 547                 ub_have_sol_threads=yes
 548         ] , [
 549                 AC_ERROR([no solaris threads found.])
 550         ])
 551         fi
 552 fi
 553
 554 fi # end of non-mingw check of thread libraries
 555
 556 # Check for PyUnbound
 557 AC_ARG_WITH(pyunbound,
 558    AC_HELP_STRING([--with-pyunbound],
 559    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 560    [], [ withval="no" ])
 561
 562 ub_test_python=no
 563 ub_with_pyunbound=no
 564 if test x_$withval != x_no; then
 565    ub_with_pyunbound=yes
 566    ub_test_python=yes
 567 fi
 568
 569 # Check for Python module
 570 AC_ARG_WITH(pythonmodule,
 571    AC_HELP_STRING([--with-pythonmodule],
 572    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 573    [], [ withval="no" ])
 574
 575 ub_with_pythonmod=no
 576 if test x_$withval != x_no; then
 577    ub_with_pythonmod=yes
 578    ub_test_python=yes
 579 fi
 580
 581 # Check for Python & SWIG only on PyUnbound or PyModule
 582 if test x_$ub_test_python != x_no; then
 583
 584    # Check for Python
 585    ub_have_python=no
 586    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 587    AC_PYTHON_DEVEL
 588    if test ! -z "$PYTHON_VERSION"; then
 589         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 590                 AC_ERROR([Python version >= 2.4.0 is required])
 591         fi
 592
 593       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 594       AC_SUBST(PY_MAJOR_VERSION)
 595       # Have Python
 596       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 597       if test -n "$LIBS"; then
 598         LIBS="$PYTHON_LDFLAGS $LIBS"
 599       else
 600         LIBS="$PYTHON_LDFLAGS"
 601       fi
 602       if test -n "$CPPFLAGS"; then
 603         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 604       else
 605         CPPFLAGS="$PYTHON_CPPFLAGS"
 606       fi
 607       ub_have_python=yes
 608       PKG_PROG_PKG_CONFIG
 609       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 610                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 611                        [PC_PY_DEPENDENCY="python"])
 612       AC_SUBST(PC_PY_DEPENDENCY)
 613
 614       # Check for SWIG
 615       ub_have_swig=no
 616       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 617       if test "$enable_swig_version_check" = "yes"; then
 618         AC_PROG_SWIG(2.0.1)
 619       else
 620         AC_PROG_SWIG
 621       fi
 622       AC_MSG_CHECKING(SWIG)
 623       if test ! -x "$SWIG"; then
 624          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 625       else
 626          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 627          AC_SUBST(swig, "$SWIG")
 628          AC_MSG_RESULT(present)
 629
 630          # If have Python & SWIG
 631          # Declare PythonMod
 632          if test x_$ub_with_pythonmod != x_no; then
 633             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 634             WITH_PYTHONMODULE=yes
 635             AC_SUBST(WITH_PYTHONMODULE)
 636             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 637             AC_SUBST(PYTHONMOD_OBJ)
 638             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 639             AC_SUBST(PYTHONMOD_HEADER)
 640             PYTHONMOD_INSTALL=pythonmod-install
 641             AC_SUBST(PYTHONMOD_INSTALL)
 642             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 643             AC_SUBST(PYTHONMOD_UNINSTALL)
 644          fi
 645
 646          # Declare PyUnbound
 647          if test x_$ub_with_pyunbound != x_no; then
 648             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 649             WITH_PYUNBOUND=yes
 650             AC_SUBST(WITH_PYUNBOUND)
 651             PYUNBOUND_OBJ="libunbound_wrap.lo"
 652             AC_SUBST(PYUNBOUND_OBJ)
 653             PYUNBOUND_TARGET="_unbound.la"
 654             AC_SUBST(PYUNBOUND_TARGET)
 655             PYUNBOUND_INSTALL=pyunbound-install
 656             AC_SUBST(PYUNBOUND_INSTALL)
 657             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 658             AC_SUBST(PYUNBOUND_UNINSTALL)
 659          fi
 660       fi
 661    else
 662       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 663       ub_with_pyunbound=no
 664       ub_with_pythonmod=no
 665    fi
 666 fi
 667
 668 if test "`uname`" = "NetBSD"; then
 669         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 670         AC_SUBST(NETBSD_LINTFLAGS)
 671 fi
 672 CONFIG_DATE=`date +%Y%m%d`
 673 AC_SUBST(CONFIG_DATE)
 674
 675 # Checks for libraries.
 676
 677 # libnss
 678 USE_NSS="no"
 679 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 680         [use libnss instead of openssl, installed at path.]),
 681         [
 682         USE_NSS="yes"
 683         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 684         if test "$withval" != "" -a "$withval" != "yes"; then
 685                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 686                 LDFLAGS="$LDFLAGS -L$withval/lib"
 687                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 688                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 689         else
 690                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 691                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 692         fi
 693         LIBS="$LIBS -lnss3 -lnspr4"
 694         SSLLIB=""
 695         ]
 696 )
 697
 698 # libnettle
 699 USE_NETTLE="no"
 700 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 701         [use libnettle as crypto library, installed at path.]),
 702         [
 703         USE_NETTLE="yes"
 704         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 705         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 706         if test "$withval" != "" -a "$withval" != "yes"; then
 707                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 708                 LDFLAGS="$LDFLAGS -L$withval/lib"
 709                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 710         else
 711                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 712         fi
 713         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 714         SSLLIB=""
 715         ]
 716 )
 717
 718 # openssl
 719 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 720 ACX_WITH_SSL
 721 ACX_LIB_SSL
 722 SSLLIB="-lssl"
 723
 724 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 725 BAKLIBS="$LIBS"
 726 LIBS="-lssl $LIBS"
 727 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 728 AC_TRY_LINK_FUNC([HMAC_Update], [
 729         AC_MSG_RESULT([no])
 730         LIBS="$BAKLIBS"
 731 ], [
 732         AC_MSG_RESULT([yes])
 733         LIBS="$BAKLIBS"
 734         LIBS="$LIBS -lcrypt32"
 735 ])
 736
 737 AC_MSG_CHECKING([for LibreSSL])
 738 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 739         AC_MSG_RESULT([yes])
 740         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 741         # libressl provides these compat functions, but they may also be
 742         # declared by the OS in libc.  See if they have been declared.
 743         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 744 else
 745         AC_MSG_RESULT([no])
 746 fi
 747 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 748 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 749
 750 # these check_funcs need -lssl
 751 BAKLIBS="$LIBS"
 752 LIBS="-lssl $LIBS"
 753 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername])
 754 LIBS="$BAKLIBS"
 755
 756 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 757 AC_INCLUDES_DEFAULT
 758 #ifdef HAVE_OPENSSL_ERR_H
 759 #include <openssl/err.h>
 760 #endif
 761
 762 #ifdef HAVE_OPENSSL_RAND_H
 763 #include <openssl/rand.h>
 764 #endif
 765
 766 #ifdef HAVE_OPENSSL_CONF_H
 767 #include <openssl/conf.h>
 768 #endif
 769
 770 #ifdef HAVE_OPENSSL_ENGINE_H
 771 #include <openssl/engine.h>
 772 #endif
 773 #include <openssl/ssl.h>
 774 #include <openssl/evp.h>
 775 ])
 776 fi
 777 AC_SUBST(SSLLIB)
 778
 779
 780 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 781 case "$enable_sha1" in
 782         no)
 783         ;;
 784         yes|*)
 785         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 786         ;;
 787 esac
 788
 789
 790 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 791 case "$enable_sha2" in
 792         no)
 793         ;;
 794         yes|*)
 795         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 796         ;;
 797 esac
 798
 799 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 800 case "$enable_subnet" in
 801         yes)
 802         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 803         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 804         AC_SUBST(SUBNET_OBJ)
 805         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 806         AC_SUBST(SUBNET_HEADER)
 807         ;;
 808         no|*)
 809         ;;
 810 esac
 811
 812 # check wether gost also works
 813 AC_DEFUN([AC_CHECK_GOST_WORKS],
 814 [AC_REQUIRE([AC_PROG_CC])
 815 AC_MSG_CHECKING([if GOST works])
 816 if test c${cross_compiling} = cno; then
 817 BAKCFLAGS="$CFLAGS"
 818 if test -n "$ssldir"; then
 819         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 820 fi
 821 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 822 #include <string.h>
 823 #include <openssl/ssl.h>
 824 #include <openssl/evp.h>
 825 #include <openssl/engine.h>
 826 #include <openssl/conf.h>
 827 /* routine to load gost (from sldns) */
 828 int load_gost_id(void)
 829 {
 830         static int gost_id = 0;
 831         const EVP_PKEY_ASN1_METHOD* meth;
 832         ENGINE* e;
 833
 834         if(gost_id) return gost_id;
 835
 836         /* see if configuration loaded gost implementation from other engine*/
 837         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 838         if(meth) {
 839                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 840                 return gost_id;
 841         }
 842
 843         /* see if engine can be loaded already */
 844         e = ENGINE_by_id("gost");
 845         if(!e) {
 846                 /* load it ourself, in case statically linked */
 847                 ENGINE_load_builtin_engines();
 848                 ENGINE_load_dynamic();
 849                 e = ENGINE_by_id("gost");
 850         }
 851         if(!e) {
 852                 /* no gost engine in openssl */
 853                 return 0;
 854         }
 855         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 856                 ENGINE_finish(e);
 857                 ENGINE_free(e);
 858                 return 0;
 859         }
 860
 861         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 862         if(!meth) {
 863                 /* algo not found */
 864                 ENGINE_finish(e);
 865                 ENGINE_free(e);
 866                 return 0;
 867         }
 868         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 869         return gost_id;
 870 }
 871 int main(void) {
 872         EVP_MD_CTX* ctx;
 873         const EVP_MD* md;
 874         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 875         const char* str = "Hello world";
 876         const unsigned char check[] = {
 877                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 878                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 879                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 880                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 881         };
 882         OPENSSL_config(NULL);
 883         (void)load_gost_id();
 884         md = EVP_get_digestbyname("md_gost94");
 885         if(!md) return 1;
 886         memset(digest, 0, sizeof(digest));
 887         ctx = EVP_MD_CTX_create();
 888         if(!ctx) return 2;
 889         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 890         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 891         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 892         /* uncomment to see the hash calculated.
 893                 {int i;
 894                 for(i=0; i<32; i++)
 895                         printf(" %2.2x", (int)digest[i]);
 896                 printf("\n");}
 897         */
 898         if(memcmp(digest, check, sizeof(check)) != 0)
 899                 return 6;
 900         return 0;
 901 }
 902 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 903 CFLAGS="$BAKCFLAGS"
 904 else
 905 eval "ac_cv_c_gost_works=maybe"
 906 fi
 907 AC_MSG_RESULT($ac_cv_c_gost_works)
 908 ])dnl
 909
 910 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 911 use_gost="no"
 912 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 913 case "$enable_gost" in
 914         no)
 915         ;;
 916         *)
 917         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 918         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 919         AC_CHECK_GOST_WORKS
 920         if test "$ac_cv_c_gost_works" != no; then
 921                 use_gost="yes"
 922                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 923         fi
 924         ;;
 925 esac
 926 fi dnl !USE_NSS && !USE_NETTLE
 927
 928 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 929 use_ecdsa="no"
 930 case "$enable_ecdsa" in
 931     no)
 932       ;;
 933     *)
 934       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 935               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 936               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 937               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 938 #include <openssl/evp.h>
 939               ])
 940               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 941               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 942               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 943                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 944                   AC_MSG_RESULT([no])
 945                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 946                 else
 947                   AC_MSG_RESULT([yes])
 948                 fi
 949               else
 950                 # not OpenSSL, thus likely LibreSSL, which supports it
 951                 AC_MSG_RESULT([yes])
 952               fi
 953       fi
 954       # we now know we have ECDSA and the required curves.
 955       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 956       use_ecdsa="yes"
 957       ;;
 958 esac
 959
 960 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 961 use_dsa="no"
 962 case "$enable_dsa" in
 963     no)
 964       ;;
 965     *)
 966       # detect if DSA is supported, and turn it off if not.
 967       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 968       AC_CHECK_FUNC(DSA_SIG_new, [
 969       AC_CHECK_TYPE(DSA_SIG*, [
 970       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 971       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 972                fi ], [
 973 AC_INCLUDES_DEFAULT
 974 #ifdef HAVE_OPENSSL_ERR_H
 975 #include <openssl/err.h>
 976 #endif
 977
 978 #ifdef HAVE_OPENSSL_RAND_H
 979 #include <openssl/rand.h>
 980 #endif
 981
 982 #ifdef HAVE_OPENSSL_CONF_H
 983 #include <openssl/conf.h>
 984 #endif
 985
 986 #ifdef HAVE_OPENSSL_ENGINE_H
 987 #include <openssl/engine.h>
 988 #endif
 989       ])
 990       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 991                fi ])
 992       else
 993       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 994       fi
 995       ;;
 996 esac
 997
 998 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
 999 use_ed25519="no"
1000 case "$enable_ed25519" in
1001     no)
1002       ;;
1003     *)
1004       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1005               AC_CHECK_DECLS([NID_ED25519], [
1006                 use_ed25519="yes"
1007               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1008                 fi ], [AC_INCLUDES_DEFAULT
1009 #include <openssl/evp.h>
1010               ])
1011       fi
1012       if test $USE_NETTLE = "yes"; then
1013                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1014       fi
1015       if test $use_ed25519 = "yes"; then
1016                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1017       fi
1018       ;;
1019 esac
1020
1021 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1022 use_ed448="no"
1023 case "$enable_ed448" in
1024     no)
1025       ;;
1026     *)
1027       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1028               AC_CHECK_DECLS([NID_ED448], [
1029                 use_ed448="yes"
1030               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1031                 fi ], [AC_INCLUDES_DEFAULT
1032 #include <openssl/evp.h>
1033               ])
1034       fi
1035       if test $use_ed448 = "yes"; then
1036                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1037       fi
1038       ;;
1039 esac
1040
1041 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1042 case "$enable_event_api" in
1043     yes)
1044       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1045       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1046       ;;
1047     *)
1048       ;;
1049 esac
1050
1051 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1052 case "$enable_tfo_client" in
1053         yes)
1054                 case `uname` in
1055                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1056                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1057                                              [AC_INCLUDES_DEFAULT
1058 #include <netinet/tcp.h>
1059 ])
1060                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1061                           ;;
1062                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1063                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1064                                               [AC_INCLUDES_DEFAULT
1065 #include <sys/socket.h>
1066 ])
1067                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1068                           ;;
1069                 esac
1070         ;;
1071         no|*)
1072                 ;;
1073 esac
1074
1075 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1076 case "$enable_tfo_server" in
1077         yes)
1078               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1079 #include <netinet/tcp.h>
1080               ])
1081                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1082                 ;;
1083         no|*)
1084                 ;;
1085 esac
1086
1087 # check for libevent
1088 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1089     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1090     [ ],[ withval="no" ])
1091 if test x_$withval = x_yes -o x_$withval != x_no; then
1092         AC_MSG_CHECKING(for libevent)
1093         if test x_$withval = x_ -o x_$withval = x_yes; then
1094             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1095         fi
1096         for dir in $withval; do
1097             thedir="$dir"
1098             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1099                 found_libevent="yes"
1100                 dnl assume /usr is in default path.
1101                 if test "$thedir" != "/usr"; then
1102                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1103                 fi
1104                 break;
1105             fi
1106         done
1107         if test x_$found_libevent != x_yes; then
1108                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1109                         # libevent source directory
1110                         AC_MSG_RESULT(found in $thedir)
1111                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1112                         BAK_LDFLAGS_SET="1"
1113                         BAK_LDFLAGS="$LDFLAGS"
1114                         # remove evdns from linking
1115                         mkdir build >/dev/null 2>&1
1116                         mkdir build/libevent >/dev/null 2>&1
1117                         mkdir build/libevent/.libs >/dev/null 2>&1
1118                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1119                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1120                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1121                         cp $ev_files_o build/libevent
1122                         cp $ev_files_lo build/libevent
1123                         cp $ev_files_libso build/libevent/.libs
1124                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1125                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1126                 else
1127                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1128 You can restart ./configure --with-libevent=no to use a builtin alternative.
1129 Please note that this alternative is not as capable as libevent when using
1130 large outgoing port ranges.  ])
1131                 fi
1132         else
1133             AC_MSG_RESULT(found in $thedir)
1134             dnl if event2 exists and no event lib in dir itself, use subdir
1135             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1136                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1137                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1138             else
1139                     dnl assume /usr is in default path, do not add "".
1140                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1141                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1142                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1143                     fi
1144             fi
1145         fi
1146         # check for library used by libevent after 1.3c
1147         AC_SEARCH_LIBS([clock_gettime], [rt])
1148
1149         # is the event.h header libev or libevent?
1150         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1151         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1152                 AC_SEARCH_LIBS(event_set, [ev])
1153         ],[
1154                 AC_SEARCH_LIBS(event_set, [event])
1155         ],[AC_INCLUDES_DEFAULT
1156 #include <event.h>
1157         ])
1158         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1159         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1160         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1161         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1162         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1163         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1164         PC_LIBEVENT_DEPENDENCY="libevent"
1165         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1166         if test -n "$BAK_LDFLAGS_SET"; then
1167                 LDFLAGS="$BAK_LDFLAGS"
1168         fi
1169 else
1170         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1171 fi
1172
1173 # check for libexpat
1174 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1175     [specify explicit path for libexpat.]),
1176     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1177 AC_MSG_CHECKING(for libexpat)
1178 found_libexpat="no"
1179 for dir in $withval ; do
1180             if test -f "$dir/include/expat.h"; then
1181                 found_libexpat="yes"
1182                 dnl assume /usr is in default path.
1183                 if test "$dir" != "/usr"; then
1184                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1185                     LDFLAGS="$LDFLAGS -L$dir/lib"
1186                 fi
1187                 AC_MSG_RESULT(found in $dir)
1188                 break;
1189             fi
1190 done
1191 if test x_$found_libexpat != x_yes; then
1192         AC_ERROR([Could not find libexpat, expat.h])
1193 fi
1194 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1195 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1196 #include <expat.h>
1197 ])
1198
1199 # hiredis (redis C client for cachedb)
1200 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1201     [specify explicit path for libhiredis.]),
1202     [ ],[ withval="no" ])
1203 found_libhiredis="no"
1204 if test x_$withval = x_yes -o x_$withval != x_no; then
1205    AC_MSG_CHECKING(for libhiredis)
1206    if test x_$withval = x_ -o x_$withval = x_yes; then
1207             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1208    fi
1209    for dir in $withval ; do
1210             if test -f "$dir/include/hiredis/hiredis.h"; then
1211                 found_libhiredis="yes"
1212                 dnl assume /usr is in default path.
1213                 if test "$dir" != "/usr"; then
1214                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1215                     LDFLAGS="$LDFLAGS -L$dir/lib"
1216                 fi
1217                 AC_MSG_RESULT(found in $dir)
1218                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1219                 LIBS="$LIBS -lhiredis"
1220                 break;
1221             fi
1222     done
1223     if test x_$found_libhiredis != x_yes; then
1224         AC_ERROR([Could not find libhiredis, hiredis.h])
1225     fi
1226     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1227     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1228     #include <hiredis/hiredis.h>
1229     ])
1230 fi
1231
1232 # set static linking if requested
1233 AC_SUBST(staticexe)
1234 staticexe=""
1235 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1236         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1237         , )
1238 if test x_$enable_static_exe = x_yes; then
1239         staticexe="-static"
1240         if test "$on_mingw" = yes; then
1241                 staticexe="-all-static"
1242                 # for static compile, include gdi32 and zlib here.
1243                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1244                         :
1245                 else
1246                         LIBS="$LIBS -lgdi32"
1247                 fi
1248                 LIBS="$LIBS -lz"
1249         fi
1250 fi
1251
1252 # Include systemd.m4 - begin
1253 sinclude(systemd.m4)
1254 # Include systemd.m4 - end
1255
1256 # set lock checking if requested
1257 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1258         [ enable to check lock and unlock calls, for debug purposes ]),
1259         , )
1260 if test x_$enable_lock_checks = x_yes; then
1261         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1262         CHECKLOCK_OBJ="checklocks.lo"
1263         AC_SUBST(CHECKLOCK_OBJ)
1264 fi
1265
1266 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1267 if test "$USE_WINSOCK" = 1; then
1268         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1269         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1270 #include <windows.h>
1271         ])
1272         AC_CHECK_TOOL(WINDRES, windres)
1273         LIBS="$LIBS -liphlpapi -lcrypt32"
1274         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1275         AC_SUBST(WINAPPS)
1276         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1277         AC_SUBST(WIN_DAEMON_SRC)
1278         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1279         AC_SUBST(WIN_DAEMON_OBJ)
1280         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1281         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1282         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1283         AC_SUBST(WIN_HOST_OBJ_LINK)
1284         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1285         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1286         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1287         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1288         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1289         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1290 fi
1291 if test $ac_cv_func_getaddrinfo = no; then
1292         AC_LIBOBJ([fake-rfc2553])
1293 fi
1294 # check after getaddrinfo for its libraries
1295 ACX_FUNC_IOCTLSOCKET
1296
1297 # see if daemon(3) exists, and if it is deprecated.
1298 AC_CHECK_FUNCS([daemon])
1299 if test $ac_cv_func_daemon = yes; then
1300         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1301 #include <stdlib.h>
1302 ])
1303 fi
1304
1305 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1306 AC_INCLUDES_DEFAULT
1307 #ifdef HAVE_SYS_UN_H
1308 #include <sys/un.h>
1309 #endif
1310 ])
1311 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1312 AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_PARAM_H
1314 #include <sys/param.h>
1315 #endif
1316
1317 #ifdef HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif
1320
1321 #ifdef HAVE_SYS_UIO_H
1322 #include <sys/uio.h>
1323 #endif
1324
1325 #ifdef HAVE_NETINET_IN_H
1326 #include <netinet/in.h>
1327 #endif
1328
1329 #ifdef HAVE_NETINET_TCP_H
1330 #include <netinet/tcp.h>
1331 #endif
1332
1333 #ifdef HAVE_ARPA_INET_H
1334 #include <arpa/inet.h>
1335 #endif
1336
1337 #ifdef HAVE_WINSOCK2_H
1338 #include <winsock2.h>
1339 #endif
1340
1341 #ifdef HAVE_WS2TCPIP_H
1342 #include <ws2tcpip.h>
1343 #endif
1344 ])
1345 AC_SEARCH_LIBS([setusercontext], [util])
1346 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1347 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1348 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1349
1350 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1351 if echo $target_os | grep darwin8 > /dev/null; then
1352         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1353 fi
1354 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1355 AC_INCLUDES_DEFAULT
1356 #ifdef HAVE_NETINET_IN_H
1357 #include <netinet/in.h>
1358 #endif
1359
1360 #ifdef HAVE_NETINET_TCP_H
1361 #include <netinet/tcp.h>
1362 #endif
1363
1364 #ifdef HAVE_ARPA_INET_H
1365 #include <arpa/inet.h>
1366 #endif
1367
1368 #ifdef HAVE_WINSOCK2_H
1369 #include <winsock2.h>
1370 #endif
1371
1372 #ifdef HAVE_WS2TCPIP_H
1373 #include <ws2tcpip.h>
1374 #endif
1375 ])
1376 AC_REPLACE_FUNCS(inet_aton)
1377 AC_REPLACE_FUNCS(inet_pton)
1378 AC_REPLACE_FUNCS(inet_ntop)
1379 AC_REPLACE_FUNCS(snprintf)
1380 # test if snprintf return the proper length
1381 if test "x$ac_cv_func_snprintf" = xyes; then
1382     if test c${cross_compiling} = cno; then
1383         AC_MSG_CHECKING([for correct snprintf return value])
1384         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1385 [[
1386 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1387 ]])], [AC_MSG_RESULT(yes)], [
1388                 AC_MSG_RESULT(no)
1389                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1390                 AC_LIBOBJ(snprintf)
1391           ])
1392     fi
1393 fi
1394 AC_REPLACE_FUNCS(strlcat)
1395 AC_REPLACE_FUNCS(strlcpy)
1396 AC_REPLACE_FUNCS(memmove)
1397 AC_REPLACE_FUNCS(gmtime_r)
1398 AC_REPLACE_FUNCS(isblank)
1399 dnl without CTIME, ARC4-functions and without reallocarray.
1400 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1401 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1402 AC_REPLACE_FUNCS(reallocarray)
1403 if test "$USE_NSS" = "no"; then
1404         AC_REPLACE_FUNCS(arc4random)
1405         AC_REPLACE_FUNCS(arc4random_uniform)
1406         if test "$ac_cv_func_arc4random" = "no"; then
1407                 AC_LIBOBJ(explicit_bzero)
1408                 AC_LIBOBJ(arc4_lock)
1409                 AC_CHECK_FUNCS([getentropy],,[
1410                     if test "$USE_WINSOCK" = 1; then
1411                         AC_LIBOBJ(getentropy_win)
1412                     else
1413                         case "$host" in
1414                         Darwin|*darwin*)
1415                                 AC_LIBOBJ(getentropy_osx)
1416                         ;;
1417                         *solaris*|*sunos*|SunOS)
1418                                 AC_LIBOBJ(getentropy_solaris)
1419                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1420                                         AC_CHECK_FUNCS([SHA512_Update],,[
1421                                                 AC_LIBOBJ(sha512)
1422                                         ])
1423                                 ], [AC_INCLUDES_DEFAULT])
1424                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1425                                         # this lib needed for sha2 on solaris
1426                                         LIBS="$LIBS -lmd"
1427                                 fi
1428                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1429                         ;;
1430                         *linux*|Linux|*)
1431                                 AC_LIBOBJ(getentropy_linux)
1432                                 AC_CHECK_FUNCS([SHA512_Update],,[
1433                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1434                                         AC_LIBOBJ(sha512)
1435                                 ])
1436                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1437                                 AC_CHECK_FUNCS([getauxval])
1438                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1439                         ;;
1440                         esac
1441                     fi
1442                 ])
1443         fi
1444 fi
1445 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1446 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1447 AC_REPLACE_FUNCS(ctime_r)
1448 AC_REPLACE_FUNCS(strsep)
1449
1450 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1451 case "$enable_allsymbols" in
1452         yes)
1453         COMMON_OBJ_ALL_SYMBOLS=""
1454         UBSYMS=""
1455         EXTRALINK="-L. -L.libs -lunbound"
1456         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1457         ;;
1458         no|*)
1459         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1460         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1461         EXTRALINK=""
1462         ;;
1463 esac
1464 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1465 AC_SUBST(EXTRALINK)
1466 AC_SUBST(UBSYMS)
1467 if test x_$enable_lock_checks = x_yes; then
1468         UBSYMS="-export-symbols clubsyms.def"
1469         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1470         echo lock_protect >> clubsyms.def
1471         echo lock_unprotect >> clubsyms.def
1472         echo lock_get_mem >> clubsyms.def
1473         echo checklock_start >> clubsyms.def
1474         echo checklock_stop >> clubsyms.def
1475         echo checklock_lock >> clubsyms.def
1476         echo checklock_unlock >> clubsyms.def
1477         echo checklock_init >> clubsyms.def
1478         echo checklock_thrcreate >> clubsyms.def
1479         echo checklock_thrjoin >> clubsyms.def
1480 fi
1481
1482 # check for dnstap if requested
1483 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1484     [
1485         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1486         AC_SUBST([ENABLE_DNSTAP], [1])
1487
1488         AC_SUBST([opt_dnstap_socket_path])
1489         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1490         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1491             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1492
1493         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1494         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1495     ],
1496     [
1497         AC_SUBST([ENABLE_DNSTAP], [0])
1498     ]
1499 )
1500
1501 # check for dnscrypt if requested
1502 dnsc_DNSCRYPT([
1503         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1504         AC_SUBST([ENABLE_DNSCRYPT], [1])
1505
1506         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1507         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1508     ],
1509     [
1510         AC_SUBST([ENABLE_DNSCRYPT], [0])
1511     ]
1512 )
1513
1514 # check for cachedb if requested
1515 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1516 # turn on cachedb when hiredis support is enabled.
1517 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1518 case "$enable_cachedb" in
1519     yes)
1520         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1521         ;;
1522     no|*)
1523         # nothing
1524         ;;
1525 esac
1526
1527 # check for ipsecmod if requested
1528 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1529 case "$enable_ipsecmod" in
1530         yes)
1531                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1532                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1533                 AC_SUBST(IPSECMOD_OBJ)
1534                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1535                 AC_SUBST(IPSECMOD_HEADER)
1536                 ;;
1537         no|*)
1538                 # nothing
1539                 ;;
1540 esac
1541
1542 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1543 # on openBSD, the implicit rule make $< work.
1544 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1545 # gmake works.
1546 cat >conftest.make <<EOF
1547 all:    conftest.lo
1548
1549 conftest.lo foo.lo bla.lo:
1550         if test -f "\$<"; then touch \$@; fi
1551
1552 .SUFFIXES: .lo
1553 .c.lo:
1554         if test -f "\$<"; then touch \$@; fi
1555
1556 conftest.lo:        conftest.dir/conftest.c
1557 EOF
1558 mkdir conftest.dir
1559 touch conftest.dir/conftest.c
1560 rm -f conftest.lo conftest.c
1561 ${MAKE:-make} -f conftest.make >/dev/null
1562 rm -f conftest.make conftest.c conftest.dir/conftest.c
1563 rm -rf conftest.dir
1564 if test ! -f conftest.lo; then
1565         AC_MSG_RESULT(no)
1566         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1567         SOURCEFILE='`cat .source`'
1568 else
1569         AC_MSG_RESULT(yes)
1570         SOURCEDETERMINE=':'
1571         SOURCEFILE='$<'
1572 fi
1573 rm -f conftest.lo
1574 AC_SUBST(SOURCEDETERMINE)
1575 AC_SUBST(SOURCEFILE)
1576
1577 # see if we want to build the library or everything
1578 ALLTARGET="alltargets"
1579 INSTALLTARGET="install-all"
1580 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1581         [do not build daemon and tool programs]),
1582         [
1583         if test "$withval" = "yes"; then
1584                 ALLTARGET="lib"
1585                 INSTALLTARGET="install-lib"
1586         fi
1587 ])
1588 if test $ALLTARGET = "alltargets"; then
1589         if test $USE_NSS = "yes"; then
1590                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1591         fi
1592         if test $USE_NETTLE = "yes"; then
1593                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1594         fi
1595 fi
1596
1597 AC_SUBST(ALLTARGET)
1598 AC_SUBST(INSTALLTARGET)
1599
1600 ACX_STRIP_EXT_FLAGS
1601 if test -n "$LATE_LDFLAGS"; then
1602   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1603 fi
1604 # remove start spaces
1605 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1606 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1607
1608 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1609
1610 AH_BOTTOM(
1611 dnl this must be first AH_CONFIG, to define the flags before any includes.
1612 AHX_CONFIG_EXT_FLAGS
1613
1614 dnl includes
1615 [
1616 #ifndef UNBOUND_DEBUG
1617 #  define NDEBUG
1618 #endif
1619
1620 /** Use small-ldns codebase */
1621 #define USE_SLDNS 1
1622 #ifdef HAVE_SSL
1623 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1624 #endif
1625
1626 #include <stdio.h>
1627 #include <string.h>
1628 #include <unistd.h>
1629 #include <assert.h>
1630
1631 #if STDC_HEADERS
1632 #include <stdlib.h>
1633 #include <stddef.h>
1634 #endif
1635
1636 #ifdef HAVE_STDARG_H
1637 #include <stdarg.h>
1638 #endif
1639
1640 #ifdef HAVE_STDINT_H
1641 #include <stdint.h>
1642 #endif
1643
1644 #include <errno.h>
1645
1646 #if HAVE_SYS_PARAM_H
1647 #include <sys/param.h>
1648 #endif
1649
1650 #ifdef HAVE_SYS_SOCKET_H
1651 #include <sys/socket.h>
1652 #endif
1653
1654 #ifdef HAVE_SYS_UIO_H
1655 #include <sys/uio.h>
1656 #endif
1657
1658 #ifdef HAVE_NETINET_IN_H
1659 #include <netinet/in.h>
1660 #endif
1661
1662 #ifdef HAVE_NETINET_TCP_H
1663 #include <netinet/tcp.h>
1664 #endif
1665
1666 #ifdef HAVE_ARPA_INET_H
1667 #include <arpa/inet.h>
1668 #endif
1669
1670 #ifdef HAVE_WINSOCK2_H
1671 #include <winsock2.h>
1672 #endif
1673
1674 #ifdef HAVE_WS2TCPIP_H
1675 #include <ws2tcpip.h>
1676 #endif
1677
1678 #ifndef USE_WINSOCK
1679 #define ARG_LL "%ll"
1680 #else
1681 #define ARG_LL "%I64"
1682 #endif
1683
1684 #ifndef AF_LOCAL
1685 #define AF_LOCAL AF_UNIX
1686 #endif
1687 ]
1688
1689 AHX_CONFIG_FORMAT_ATTRIBUTE
1690 AHX_CONFIG_UNUSED_ATTRIBUTE
1691 AHX_CONFIG_FSEEKO
1692 AHX_CONFIG_MAXHOSTNAMELEN
1693 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1694 #define snprintf snprintf_unbound
1695 #define vsnprintf vsnprintf_unbound
1696 #include <stdarg.h>
1697 int snprintf (char *str, size_t count, const char *fmt, ...);
1698 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1699 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1700 AHX_CONFIG_INET_PTON(unbound)
1701 AHX_CONFIG_INET_NTOP(unbound)
1702 AHX_CONFIG_INET_ATON(unbound)
1703 AHX_CONFIG_MEMMOVE(unbound)
1704 AHX_CONFIG_STRLCAT(unbound)
1705 AHX_CONFIG_STRLCPY(unbound)
1706 AHX_CONFIG_GMTIME_R(unbound)
1707 AHX_CONFIG_REALLOCARRAY(unbound)
1708 AHX_CONFIG_W32_SLEEP
1709 AHX_CONFIG_W32_USLEEP
1710 AHX_CONFIG_W32_RANDOM
1711 AHX_CONFIG_W32_SRANDOM
1712 AHX_CONFIG_W32_FD_SET_T
1713 AHX_CONFIG_IPV6_MIN_MTU
1714 AHX_MEMCMP_BROKEN(unbound)
1715
1716 [
1717 #ifndef HAVE_CTIME_R
1718 #define ctime_r unbound_ctime_r
1719 char *ctime_r(const time_t *timep, char *buf);
1720 #endif
1721
1722 #ifndef HAVE_STRSEP
1723 #define strsep unbound_strsep
1724 char *strsep(char **stringp, const char *delim);
1725 #endif
1726
1727 #ifndef HAVE_ISBLANK
1728 #define isblank unbound_isblank
1729 int isblank(int c);
1730 #endif
1731
1732 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1733 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1734 #endif
1735
1736 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1737 int inet_pton(int af, const char* src, void* dst);
1738 #endif
1739
1740 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1741 #define strptime unbound_strptime
1742 struct tm;
1743 char *strptime(const char *s, const char *format, struct tm *tm);
1744 #endif
1745
1746 #ifdef HAVE_LIBRESSL
1747 #  if !HAVE_DECL_STRLCPY
1748 size_t strlcpy(char *dst, const char *src, size_t siz);
1749 #  endif
1750 #  if !HAVE_DECL_STRLCAT
1751 size_t strlcat(char *dst, const char *src, size_t siz);
1752 #  endif
1753 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1754 uint32_t arc4random(void);
1755 #  endif
1756 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1757 uint32_t arc4random_uniform(uint32_t upper_bound);
1758 #  endif
1759 #  if !HAVE_DECL_REALLOCARRAY
1760 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1761 #  endif
1762 #endif /* HAVE_LIBRESSL */
1763 #ifndef HAVE_ARC4RANDOM
1764 void explicit_bzero(void* buf, size_t len);
1765 int getentropy(void* buf, size_t len);
1766 uint32_t arc4random(void);
1767 void arc4random_buf(void* buf, size_t n);
1768 void _ARC4_LOCK(void);
1769 void _ARC4_UNLOCK(void);
1770 void _ARC4_LOCK_DESTROY(void);
1771 #endif
1772 #ifndef HAVE_ARC4RANDOM_UNIFORM
1773 uint32_t arc4random_uniform(uint32_t upper_bound);
1774 #endif
1775 #ifdef COMPAT_SHA512
1776 #ifndef SHA512_DIGEST_LENGTH
1777 #define SHA512_BLOCK_LENGTH             128
1778 #define SHA512_DIGEST_LENGTH            64
1779 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1780 typedef struct _SHA512_CTX {
1781         uint64_t        state[8];
1782         uint64_t        bitcount[2];
1783         uint8_t buffer[SHA512_BLOCK_LENGTH];
1784 } SHA512_CTX;
1785 #endif /* SHA512_DIGEST_LENGTH */
1786 void SHA512_Init(SHA512_CTX*);
1787 void SHA512_Update(SHA512_CTX*, void*, size_t);
1788 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1789 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1790 #endif /* COMPAT_SHA512 */
1791
1792
1793
1794 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1795    /* using version of libevent that is not threadsafe. */
1796 #  define LIBEVENT_SIGNAL_PROBLEM 1
1797 #endif
1798
1799 #ifndef CHECKED_INET6
1800 #  define CHECKED_INET6
1801 #  ifdef AF_INET6
1802 #    define INET6
1803 #  else
1804 #    define AF_INET6        28
1805 #  endif
1806 #endif /* CHECKED_INET6 */
1807
1808 #ifndef HAVE_GETADDRINFO
1809 struct sockaddr_storage;
1810 #include "compat/fake-rfc2553.h"
1811 #endif
1812
1813 #ifdef UNBOUND_ALLOC_STATS
1814 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1815 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1816 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1817 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1818 void *unbound_stat_malloc(size_t size);
1819 void *unbound_stat_calloc(size_t nmemb, size_t size);
1820 void unbound_stat_free(void *ptr);
1821 void *unbound_stat_realloc(void *ptr, size_t size);
1822 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1823         const char* func);
1824 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1825         int line, const char* func);
1826 void unbound_stat_free_log(void *ptr, const char* file, int line,
1827         const char* func);
1828 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1829         int line, const char* func);
1830 #elif defined(UNBOUND_ALLOC_LITE)
1831 #  include "util/alloc.h"
1832 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1833
1834 /** default port for DNS traffic. */
1835 #define UNBOUND_DNS_PORT 53
1836 /** default port for DNS over TLS traffic. */
1837 #define UNBOUND_DNS_OVER_TLS_PORT 853
1838 /** default port for unbound control traffic, registered port with IANA,
1839     ub-dns-control  8953/tcp    unbound dns nameserver control */
1840 #define UNBOUND_CONTROL_PORT 8953
1841 /** the version of unbound-control that this software implements */
1842 #define UNBOUND_CONTROL_VERSION 1
1843
1844 ])
1845
1846 dnl if we build from source tree, the man pages need @date@ and @version@
1847 dnl if this is a distro tarball, that was already done by makedist.sh
1848 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1849 AC_SUBST(date, [`date +'%b %e, %Y'`])
1850
1851 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1852 AC_CONFIG_HEADER([config.h])
1853 AC_OUTPUT