configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[9])
  14 m4_define([VERSION_MICRO],[1])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=1
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.9.0 had 9:0:1 # add ub_ctx_set_tls
  89 # 1.9.1 had 9:1:1
  90
  91 #   Current  -- the number of the binary API that we're implementing
  92 #   Revision -- which iteration of the implementation of the binary
  93 #               API are we supplying?
  94 #   Age      -- How many previous binary API versions do we also
  95 #               support?
  96 #
  97 # If we release a new version that does not change the binary API,
  98 # increment Revision.
  99 #
 100 # If we release a new version that changes the binary API, but does
 101 # not break programs compiled against the old binary API, increment
 102 # Current and Age.  Set Revision to 0, since this is the first
 103 # implementation of the new API.
 104 #
 105 # Otherwise, we're changing the binary API and breaking backward
 106 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 107 # since we're backward compatible with no previous APIs.  Set Revision
 108 # to 0 too.
 109 AC_SUBST(LIBUNBOUND_CURRENT)
 110 AC_SUBST(LIBUNBOUND_REVISION)
 111 AC_SUBST(LIBUNBOUND_AGE)
 112
 113 CFLAGS="$CFLAGS"
 114 AC_AIX
 115 if test "$ac_cv_header_minix_config_h" = "yes"; then
 116         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 117 fi
 118
 119 dnl
 120 dnl By default set prefix to /usr/local
 121 dnl
 122 case "$prefix" in
 123         NONE)
 124                 prefix="/usr/local"
 125         ;;
 126 esac
 127 case "$exec_prefix" in
 128         NONE)
 129                 exec_prefix="$prefix"
 130         ;;
 131 esac
 132
 133 # are we on MinGW?
 134 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 135 else
 136         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 137         else on_mingw="no"; fi
 138 fi
 139
 140 #
 141 # Determine configuration file
 142 # the eval is to evaluate shell expansion twice
 143 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 144 AC_SUBST(UNBOUND_SBIN_DIR)
 145 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 146 AC_SUBST(UNBOUND_SYSCONF_DIR)
 147 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 148 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 149 if test $on_mingw = "no"; then
 150   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 151 else
 152   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 153 fi
 154 AC_ARG_WITH([conf_file],
 155         AC_HELP_STRING([--with-conf-file=path],
 156         [Pathname to the Unbound configuration file]),
 157         [ub_conf_file="$withval"])
 158 AC_SUBST(ub_conf_file)
 159 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 160 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 161 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 162 AC_SUBST(ub_conf_dir)
 163
 164 # Determine run, chroot directory and pidfile locations
 165 AC_ARG_WITH(run-dir,
 166     AC_HELP_STRING([--with-run-dir=path],
 167     [set default directory to chdir to (by default dir part of cfg file)]),
 168     UNBOUND_RUN_DIR="$withval",
 169 if test $on_mingw = no; then
 170     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 171 else
 172     UNBOUND_RUN_DIR=""
 173 fi
 174 )
 175 AC_SUBST(UNBOUND_RUN_DIR)
 176 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 177 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 178
 179 AC_ARG_WITH(chroot-dir,
 180     AC_HELP_STRING([--with-chroot-dir=path],
 181     [set default directory to chroot to (by default same as run-dir)]),
 182     UNBOUND_CHROOT_DIR="$withval",
 183 if test $on_mingw = no; then
 184     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 185 else
 186     UNBOUND_CHROOT_DIR=""
 187 fi
 188 )
 189 AC_SUBST(UNBOUND_CHROOT_DIR)
 190 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 191 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 192
 193 AC_ARG_WITH(share-dir,
 194     AC_HELP_STRING([--with-share-dir=path],
 195     [set default directory with shared data (by default same as share/unbound)]),
 196     UNBOUND_SHARE_DIR="$withval",
 197     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 198 AC_SUBST(UNBOUND_SHARE_DIR)
 199 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 200
 201 AC_ARG_WITH(pidfile,
 202     AC_HELP_STRING([--with-pidfile=filename],
 203     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 204     UNBOUND_PIDFILE="$withval",
 205 if test $on_mingw = no; then
 206     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 207 else
 208     UNBOUND_PIDFILE=""
 209 fi
 210 )
 211 AC_SUBST(UNBOUND_PIDFILE)
 212 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 213 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 214
 215 AC_ARG_WITH(rootkey-file,
 216     AC_HELP_STRING([--with-rootkey-file=filename],
 217     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 218     UNBOUND_ROOTKEY_FILE="$withval",
 219 if test $on_mingw = no; then
 220     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 221 else
 222     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 223 fi
 224 )
 225 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 226 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 227 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 228
 229 AC_ARG_WITH(rootcert-file,
 230     AC_HELP_STRING([--with-rootcert-file=filename],
 231     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 232     UNBOUND_ROOTCERT_FILE="$withval",
 233 if test $on_mingw = no; then
 234     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 235 else
 236     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 237 fi
 238 )
 239 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 240 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 241 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 242
 243 AC_ARG_WITH(username,
 244     AC_HELP_STRING([--with-username=user],
 245     [set default user that unbound changes to (default user is unbound)]),
 246     UNBOUND_USERNAME="$withval",
 247     UNBOUND_USERNAME="unbound")
 248 AC_SUBST(UNBOUND_USERNAME)
 249 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 250
 251 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 252 ACX_RSRC_VERSION(wnvs)
 253 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 254
 255 # Checks for typedefs, structures, and compiler characteristics.
 256 AC_C_CONST
 257 AC_LANG_C
 258 # allow user to override the -g -O2 flags.
 259 default_cflags=no
 260 if test "x$CFLAGS" = "x" ; then
 261 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 262 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 263 default_cflags=yes
 264 fi
 265 AC_PROG_CC
 266 ACX_DEPFLAG
 267 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 268
 269 # debug mode flags warnings
 270 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 271 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 272 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 273 else debug_enabled="$enable_checking"; fi
 274 AC_SUBST(debug_enabled)
 275 case "$debug_enabled" in
 276         yes)
 277                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 278                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 279                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 280                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 281                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 282                 ;;
 283         no|*)
 284                 # nothing to do.
 285                 ;;
 286 esac
 287 if test "$default_cflags" = "yes"; then
 288         # only when CFLAGS was "" at the start, if the users wants to
 289         # override we shouldn't add default cflags, because they wouldn't
 290         # be able to turn off these options and set the CFLAGS wanted.
 291         ACX_CHECK_FLTO
 292         ACX_CHECK_PIE
 293         ACX_CHECK_RELRO_NOW
 294 fi
 295
 296 AC_C_INLINE
 297 ACX_CHECK_FORMAT_ATTRIBUTE
 298 ACX_CHECK_UNUSED_ATTRIBUTE
 299
 300 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 301 [AC_REQUIRE([AC_PROG_CC])
 302 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 303 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 304 [ac_cv_c_weak_attribute=no
 305 AC_TRY_COMPILE(
 306 [ #include <stdio.h>
 307 __attribute__((weak)) void f(int x) { printf("%d", x); }
 308 ], [
 309    f(1);
 310 ],
 311 [ac_cv_c_weak_attribute="yes"],
 312 [ac_cv_c_weak_attribute="no"])
 313 ])
 314
 315 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 316 if test $ac_cv_c_weak_attribute = yes; then
 317   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 318   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 319 fi
 320 ])dnl End of CHECK_WEAK_ATTRIBUTE
 321
 322 CHECK_WEAK_ATTRIBUTE
 323
 324 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 325 [AC_REQUIRE([AC_PROG_CC])
 326 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 327 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 328 [ac_cv_c_noreturn_attribute=no
 329 AC_TRY_COMPILE(
 330 [ #include <stdio.h>
 331 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 332 ], [
 333    f(1);
 334 ],
 335 [ac_cv_c_noreturn_attribute="yes"],
 336 [ac_cv_c_noreturn_attribute="no"])
 337 ])
 338
 339 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 340 if test $ac_cv_c_noreturn_attribute = yes; then
 341   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 342   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 343 fi
 344 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 345
 346 CHECK_NORETURN_ATTRIBUTE
 347
 348 if test "$srcdir" != "."; then
 349         CPPFLAGS="$CPPFLAGS -I$srcdir"
 350 fi
 351
 352 AC_DEFUN([ACX_YYLEX_DESTROY], [
 353         AC_MSG_CHECKING([for yylex_destroy])
 354         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 355                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 356                 AC_MSG_RESULT(yes)
 357         else AC_MSG_RESULT(no);
 358                 LEX=":"
 359         fi
 360 ])
 361
 362 AC_DEFUN([ACX_YYLEX_OPTION], [
 363         AC_MSG_CHECKING([for lex %option])
 364         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 365 %option nounput
 366 %%
 367 EOF
 368                 AC_MSG_RESULT(yes)
 369         else AC_MSG_RESULT(no);
 370                 LEX=":"
 371         fi
 372 ])
 373
 374 AC_PROG_LEX
 375 if test "$LEX" != "" -a "$LEX" != ":"; then
 376 ACX_YYLEX_DESTROY
 377 fi
 378 if test "$LEX" != "" -a "$LEX" != ":"; then
 379 ACX_YYLEX_OPTION
 380 fi
 381 AC_PROG_YACC
 382 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 383 AC_CHECK_TOOL(STRIP, strip)
 384 ACX_LIBTOOL_C_ONLY
 385
 386 PKG_PROG_PKG_CONFIG
 387
 388 # Checks for header files.
 389 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 390
 391 # check for types.
 392 # Using own tests for int64* because autoconf builtin only give 32bit.
 393 AC_CHECK_TYPE(int8_t, signed char)
 394 AC_CHECK_TYPE(int16_t, short)
 395 AC_CHECK_TYPE(int32_t, int)
 396 AC_CHECK_TYPE(int64_t, long long)
 397 AC_CHECK_TYPE(uint8_t, unsigned char)
 398 AC_CHECK_TYPE(uint16_t, unsigned short)
 399 AC_CHECK_TYPE(uint32_t, unsigned int)
 400 AC_CHECK_TYPE(uint64_t, unsigned long long)
 401 AC_TYPE_SIZE_T
 402 AC_CHECK_TYPE(ssize_t, int)
 403 AC_TYPE_UID_T
 404 AC_TYPE_PID_T
 405 AC_TYPE_OFF_T
 406 ACX_TYPE_U_CHAR
 407 ACX_TYPE_RLIM_T
 408 ACX_TYPE_SOCKLEN_T
 409 ACX_TYPE_IN_ADDR_T
 410 ACX_TYPE_IN_PORT_T
 411 ACX_CHECK_MEMCMP_SIGNED
 412
 413 AC_CHECK_SIZEOF(time_t,,[
 414 AC_INCLUDES_DEFAULT
 415 #ifdef TIME_WITH_SYS_TIME
 416 # include <sys/time.h>
 417 # include <time.h>
 418 #else
 419 # ifdef HAVE_SYS_TIME_H
 420 #  include <sys/time.h>
 421 # else
 422 #  include <time.h>
 423 # endif
 424 #endif
 425 ])
 426
 427 # add option to disable the evil rpath
 428 ACX_ARG_RPATH
 429 AC_SUBST(RUNTIME_PATH)
 430
 431 # check to see if libraries are needed for these functions.
 432 AC_SEARCH_LIBS([inet_pton], [nsl])
 433 AC_SEARCH_LIBS([socket], [socket])
 434
 435 # check wether strptime also works
 436 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 437 [AC_REQUIRE([AC_PROG_CC])
 438 AC_MSG_CHECKING(whether strptime works)
 439 if test c${cross_compiling} = cno; then
 440 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 441 #define _XOPEN_SOURCE 600
 442 #include <time.h>
 443 int main(void) { struct tm tm; char *res;
 444 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 445 if (!res) return 2;
 446 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 447 if (!res) return 1; return 0; }
 448 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 449 else
 450 eval "ac_cv_c_strptime_works=maybe"
 451 fi
 452 AC_MSG_RESULT($ac_cv_c_strptime_works)
 453 if test $ac_cv_c_strptime_works = no; then
 454 AC_LIBOBJ(strptime)
 455 else
 456 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 457 fi
 458 ])dnl
 459
 460 # check some functions of the OS before linking libs (while still runnable).
 461 AC_FUNC_CHOWN
 462 AC_FUNC_FORK
 463 AC_TYPE_SIGNAL
 464 AC_FUNC_FSEEKO
 465 ACX_SYS_LARGEFILE
 466 ACX_CHECK_NONBLOCKING_BROKEN
 467 ACX_MKDIR_ONE_ARG
 468 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 469
 470 # check if we can use SO_REUSEPORT
 471 if echo "$host" | grep -i -e linux -e dragonfly >/dev/null; then
 472         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 473 else
 474         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 475 fi
 476
 477 # set memory allocation checking if requested
 478 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 479         [ enable to memory allocation statistics, for debug purposes ]),
 480         , )
 481 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 482         [ enable for lightweight alloc assertions, for debug purposes ]),
 483         , )
 484 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 485         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 486         , )
 487 if test x_$enable_alloc_nonregional = x_yes; then
 488         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 489 fi
 490 if test x_$enable_alloc_checks = x_yes; then
 491         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 492 else
 493         if test x_$enable_alloc_lite = x_yes; then
 494                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 495         else
 496                 ACX_FUNC_MALLOC([unbound])
 497         fi
 498 fi
 499
 500 # check windows threads (we use them, not pthreads, on windows).
 501 if test "$on_mingw" = "yes"; then
 502 # check windows threads
 503         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 504         AC_MSG_CHECKING([for CreateThread])
 505         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 506 #ifdef HAVE_WINDOWS_H
 507 #include <windows.h>
 508 #endif
 509 ], [
 510         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 511 ])],
 512         AC_MSG_RESULT(yes)
 513         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 514 ,
 515         AC_MSG_RESULT(no)
 516 )
 517
 518 else
 519 # not on mingw, check thread libraries.
 520
 521 # check for thread library.
 522 # check this first, so that the pthread lib does not get linked in via
 523 # libssl or libpython, and thus distorts the tests, and we end up using
 524 # the non-threadsafe C libraries.
 525 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 526  [use pthreads library, or --without-pthreads to disable threading support.]),
 527  [ ],[ withval="yes" ])
 528 ub_have_pthreads=no
 529 if test x_$withval != x_no; then
 530         AX_PTHREAD([
 531                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 532                 if test -n "$PTHREAD_LIBS"; then
 533                   LIBS="$PTHREAD_LIBS $LIBS"
 534                 fi
 535                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 536                 CC="$PTHREAD_CC"
 537                 ub_have_pthreads=yes
 538                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 539
 540                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 541                 AC_MSG_CHECKING([if -pthread unused during linking])
 542                 # catch clang warning 'argument unused during compilation'
 543                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 544 [[
 545 int main(void) {return 0;}
 546 ]])])
 547                 pthread_unused="yes"
 548                 # first compile
 549                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 550                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 551                 if test $? = 0; then
 552                         # then link
 553                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 554                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 555                         if test $? -ne 0; then
 556                                 AC_MSG_RESULT(yes)
 557                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 558                                 PTHREAD_CFLAGS_ONLY="-pthread"
 559                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 560                         else
 561                                 AC_MSG_RESULT(no)
 562                         fi
 563                 else
 564                         AC_MSG_RESULT(no)
 565                 fi # endif cc successful
 566                 rm -f conftest conftest.c conftest.o
 567                 fi # endif -pthread in CFLAGS
 568
 569                 ])
 570 fi
 571
 572 # check solaris thread library
 573 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 574         [use solaris native thread library.]), [ ],[ withval="no" ])
 575 ub_have_sol_threads=no
 576 if test x_$withval != x_no; then
 577         if test x_$ub_have_pthreads != x_no; then
 578             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 579         else
 580         AC_SEARCH_LIBS(thr_create, [thread],
 581         [
 582                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 583
 584                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 585                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 586                 ub_have_sol_threads=yes
 587         ] , [
 588                 AC_ERROR([no solaris threads found.])
 589         ])
 590         fi
 591 fi
 592
 593 fi # end of non-mingw check of thread libraries
 594
 595 # Check for PyUnbound
 596 AC_ARG_WITH(pyunbound,
 597    AC_HELP_STRING([--with-pyunbound],
 598    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 599    [], [ withval="no" ])
 600
 601 ub_test_python=no
 602 ub_with_pyunbound=no
 603 if test x_$withval != x_no; then
 604    ub_with_pyunbound=yes
 605    ub_test_python=yes
 606 fi
 607
 608 # Check for Python module
 609 AC_ARG_WITH(pythonmodule,
 610    AC_HELP_STRING([--with-pythonmodule],
 611    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 612    [], [ withval="no" ])
 613
 614 ub_with_pythonmod=no
 615 if test x_$withval != x_no; then
 616    ub_with_pythonmod=yes
 617    ub_test_python=yes
 618 fi
 619
 620 # Check for Python & SWIG only on PyUnbound or PyModule
 621 if test x_$ub_test_python != x_no; then
 622
 623    # Check for Python
 624    ub_have_python=no
 625    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 626    AC_PYTHON_DEVEL
 627    if test ! -z "$PYTHON_VERSION"; then
 628         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 629                 AC_ERROR([Python version >= 2.4.0 is required])
 630         fi
 631
 632       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 633       AC_SUBST(PY_MAJOR_VERSION)
 634       # Have Python
 635       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 636       if test -n "$LIBS"; then
 637         LIBS="$PYTHON_LDFLAGS $LIBS"
 638       else
 639         LIBS="$PYTHON_LDFLAGS"
 640       fi
 641       if test -n "$CPPFLAGS"; then
 642         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 643       else
 644         CPPFLAGS="$PYTHON_CPPFLAGS"
 645       fi
 646       ub_have_python=yes
 647       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 648                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 649                        [PC_PY_DEPENDENCY="python"])
 650       AC_SUBST(PC_PY_DEPENDENCY)
 651
 652       # Check for SWIG
 653       ub_have_swig=no
 654       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 655       if test "$enable_swig_version_check" = "yes"; then
 656         AC_PROG_SWIG(2.0.1)
 657       else
 658         AC_PROG_SWIG
 659       fi
 660       AC_MSG_CHECKING(SWIG)
 661       if test ! -x "$SWIG"; then
 662          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 663       else
 664          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 665          AC_SUBST(swig, "$SWIG")
 666          AC_MSG_RESULT(present)
 667
 668          # If have Python & SWIG
 669          # Declare PythonMod
 670          if test x_$ub_with_pythonmod != x_no; then
 671             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 672             WITH_PYTHONMODULE=yes
 673             AC_SUBST(WITH_PYTHONMODULE)
 674             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 675             AC_SUBST(PYTHONMOD_OBJ)
 676             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 677             AC_SUBST(PYTHONMOD_HEADER)
 678             PYTHONMOD_INSTALL=pythonmod-install
 679             AC_SUBST(PYTHONMOD_INSTALL)
 680             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 681             AC_SUBST(PYTHONMOD_UNINSTALL)
 682          fi
 683
 684          # Declare PyUnbound
 685          if test x_$ub_with_pyunbound != x_no; then
 686             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 687             WITH_PYUNBOUND=yes
 688             AC_SUBST(WITH_PYUNBOUND)
 689             PYUNBOUND_OBJ="libunbound_wrap.lo"
 690             AC_SUBST(PYUNBOUND_OBJ)
 691             PYUNBOUND_TARGET="_unbound.la"
 692             AC_SUBST(PYUNBOUND_TARGET)
 693             PYUNBOUND_INSTALL=pyunbound-install
 694             AC_SUBST(PYUNBOUND_INSTALL)
 695             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 696             AC_SUBST(PYUNBOUND_UNINSTALL)
 697          fi
 698       fi
 699    else
 700       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 701       ub_with_pyunbound=no
 702       ub_with_pythonmod=no
 703    fi
 704 fi
 705
 706 if test "`uname`" = "NetBSD"; then
 707         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 708         AC_SUBST(NETBSD_LINTFLAGS)
 709 fi
 710 CONFIG_DATE=`date +%Y%m%d`
 711 AC_SUBST(CONFIG_DATE)
 712
 713 # Checks for libraries.
 714
 715 # libnss
 716 USE_NSS="no"
 717 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 718         [use libnss instead of openssl, installed at path.]),
 719         [
 720         USE_NSS="yes"
 721         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 722         if test "$withval" != "" -a "$withval" != "yes"; then
 723                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 724                 LDFLAGS="$LDFLAGS -L$withval/lib"
 725                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 726                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 727         else
 728                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 729                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 730         fi
 731         LIBS="$LIBS -lnss3 -lnspr4"
 732         SSLLIB=""
 733         ]
 734 )
 735
 736 # libnettle
 737 USE_NETTLE="no"
 738 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 739         [use libnettle as crypto library, installed at path.]),
 740         [
 741         USE_NETTLE="yes"
 742         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 743         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 744         if test "$withval" != "" -a "$withval" != "yes"; then
 745                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 746                 LDFLAGS="$LDFLAGS -L$withval/lib"
 747                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 748         else
 749                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 750         fi
 751         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 752         SSLLIB=""
 753         ]
 754 )
 755
 756 # openssl
 757 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 758 ACX_WITH_SSL
 759 ACX_LIB_SSL
 760 SSLLIB="-lssl"
 761
 762 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 763 BAKLIBS="$LIBS"
 764 LIBS="-lssl $LIBS"
 765 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 766 AC_TRY_LINK_FUNC([HMAC_Update], [
 767         AC_MSG_RESULT([no])
 768         LIBS="$BAKLIBS"
 769 ], [
 770         AC_MSG_RESULT([yes])
 771         LIBS="$BAKLIBS"
 772         LIBS="$LIBS -lcrypt32"
 773 ])
 774
 775 AC_MSG_CHECKING([for LibreSSL])
 776 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 777         AC_MSG_RESULT([yes])
 778         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 779         # libressl provides these compat functions, but they may also be
 780         # declared by the OS in libc.  See if they have been declared.
 781         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 782 else
 783         AC_MSG_RESULT([no])
 784 fi
 785 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 786 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify SSL_CTX_set_tlsext_ticket_key_cb EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex CRYPTO_THREADID_set_callback])
 787
 788 # these check_funcs need -lssl
 789 BAKLIBS="$LIBS"
 790 LIBS="-lssl $LIBS"
 791 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites])
 792 LIBS="$BAKLIBS"
 793
 794 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 795 AC_INCLUDES_DEFAULT
 796 #ifdef HAVE_OPENSSL_ERR_H
 797 #include <openssl/err.h>
 798 #endif
 799
 800 #ifdef HAVE_OPENSSL_RAND_H
 801 #include <openssl/rand.h>
 802 #endif
 803
 804 #ifdef HAVE_OPENSSL_CONF_H
 805 #include <openssl/conf.h>
 806 #endif
 807
 808 #ifdef HAVE_OPENSSL_ENGINE_H
 809 #include <openssl/engine.h>
 810 #endif
 811 #include <openssl/ssl.h>
 812 #include <openssl/evp.h>
 813 ])
 814 fi
 815 AC_SUBST(SSLLIB)
 816
 817
 818 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 819 case "$enable_sha1" in
 820         no)
 821         ;;
 822         yes|*)
 823         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 824         ;;
 825 esac
 826
 827
 828 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 829 case "$enable_sha2" in
 830         no)
 831         ;;
 832         yes|*)
 833         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 834         ;;
 835 esac
 836
 837 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 838 case "$enable_subnet" in
 839         yes)
 840         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 841         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 842         AC_SUBST(SUBNET_OBJ)
 843         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 844         AC_SUBST(SUBNET_HEADER)
 845         ;;
 846         no|*)
 847         ;;
 848 esac
 849
 850 # check wether gost also works
 851 AC_DEFUN([AC_CHECK_GOST_WORKS],
 852 [AC_REQUIRE([AC_PROG_CC])
 853 AC_MSG_CHECKING([if GOST works])
 854 if test c${cross_compiling} = cno; then
 855 BAKCFLAGS="$CFLAGS"
 856 if test -n "$ssldir"; then
 857         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 858 fi
 859 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 860 #include <string.h>
 861 #include <openssl/ssl.h>
 862 #include <openssl/evp.h>
 863 #include <openssl/engine.h>
 864 #include <openssl/conf.h>
 865 /* routine to load gost (from sldns) */
 866 int load_gost_id(void)
 867 {
 868         static int gost_id = 0;
 869         const EVP_PKEY_ASN1_METHOD* meth;
 870         ENGINE* e;
 871
 872         if(gost_id) return gost_id;
 873
 874         /* see if configuration loaded gost implementation from other engine*/
 875         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 876         if(meth) {
 877                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 878                 return gost_id;
 879         }
 880
 881         /* see if engine can be loaded already */
 882         e = ENGINE_by_id("gost");
 883         if(!e) {
 884                 /* load it ourself, in case statically linked */
 885                 ENGINE_load_builtin_engines();
 886                 ENGINE_load_dynamic();
 887                 e = ENGINE_by_id("gost");
 888         }
 889         if(!e) {
 890                 /* no gost engine in openssl */
 891                 return 0;
 892         }
 893         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 894                 ENGINE_finish(e);
 895                 ENGINE_free(e);
 896                 return 0;
 897         }
 898
 899         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 900         if(!meth) {
 901                 /* algo not found */
 902                 ENGINE_finish(e);
 903                 ENGINE_free(e);
 904                 return 0;
 905         }
 906         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 907         return gost_id;
 908 }
 909 int main(void) {
 910         EVP_MD_CTX* ctx;
 911         const EVP_MD* md;
 912         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 913         const char* str = "Hello world";
 914         const unsigned char check[] = {
 915                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 916                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 917                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 918                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 919         };
 920         OPENSSL_config(NULL);
 921         (void)load_gost_id();
 922         md = EVP_get_digestbyname("md_gost94");
 923         if(!md) return 1;
 924         memset(digest, 0, sizeof(digest));
 925         ctx = EVP_MD_CTX_create();
 926         if(!ctx) return 2;
 927         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 928         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 929         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 930         /* uncomment to see the hash calculated.
 931                 {int i;
 932                 for(i=0; i<32; i++)
 933                         printf(" %2.2x", (int)digest[i]);
 934                 printf("\n");}
 935         */
 936         if(memcmp(digest, check, sizeof(check)) != 0)
 937                 return 6;
 938         return 0;
 939 }
 940 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 941 CFLAGS="$BAKCFLAGS"
 942 else
 943 eval "ac_cv_c_gost_works=maybe"
 944 fi
 945 AC_MSG_RESULT($ac_cv_c_gost_works)
 946 ])dnl
 947
 948 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 949 use_gost="no"
 950 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 951 case "$enable_gost" in
 952         no)
 953         ;;
 954         *)
 955         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 956         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 957         AC_CHECK_GOST_WORKS
 958         if test "$ac_cv_c_gost_works" != no; then
 959                 use_gost="yes"
 960                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 961         fi
 962         ;;
 963 esac
 964 fi dnl !USE_NSS && !USE_NETTLE
 965
 966 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 967 use_ecdsa="no"
 968 case "$enable_ecdsa" in
 969     no)
 970       ;;
 971     *)
 972       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 973               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 974               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 975               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 976 #include <openssl/evp.h>
 977               ])
 978               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 979               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 980               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 981                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 982                   AC_MSG_RESULT([no])
 983                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 984                 else
 985                   AC_MSG_RESULT([yes])
 986                 fi
 987               else
 988                 # not OpenSSL, thus likely LibreSSL, which supports it
 989                 AC_MSG_RESULT([yes])
 990               fi
 991       fi
 992       # we now know we have ECDSA and the required curves.
 993       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 994       use_ecdsa="yes"
 995       ;;
 996 esac
 997
 998 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 999 use_dsa="no"
1000 case "$enable_dsa" in
1001     no)
1002       ;;
1003     *)
1004       # detect if DSA is supported, and turn it off if not.
1005       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1006       AC_CHECK_FUNC(DSA_SIG_new, [
1007       AC_CHECK_TYPE(DSA_SIG*, [
1008       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1009       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1010                fi ], [
1011 AC_INCLUDES_DEFAULT
1012 #ifdef HAVE_OPENSSL_ERR_H
1013 #include <openssl/err.h>
1014 #endif
1015
1016 #ifdef HAVE_OPENSSL_RAND_H
1017 #include <openssl/rand.h>
1018 #endif
1019
1020 #ifdef HAVE_OPENSSL_CONF_H
1021 #include <openssl/conf.h>
1022 #endif
1023
1024 #ifdef HAVE_OPENSSL_ENGINE_H
1025 #include <openssl/engine.h>
1026 #endif
1027       ])
1028       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1029                fi ])
1030       else
1031       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1032       fi
1033       ;;
1034 esac
1035
1036 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1037 use_ed25519="no"
1038 case "$enable_ed25519" in
1039     no)
1040       ;;
1041     *)
1042       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1043               AC_CHECK_DECLS([NID_ED25519], [
1044                 use_ed25519="yes"
1045               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1046                 fi ], [AC_INCLUDES_DEFAULT
1047 #include <openssl/evp.h>
1048               ])
1049       fi
1050       if test $USE_NETTLE = "yes"; then
1051                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1052       fi
1053       if test $use_ed25519 = "yes"; then
1054                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1055       fi
1056       ;;
1057 esac
1058
1059 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1060 use_ed448="no"
1061 case "$enable_ed448" in
1062     no)
1063       ;;
1064     *)
1065       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1066               AC_CHECK_DECLS([NID_ED448], [
1067                 use_ed448="yes"
1068               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1069                 fi ], [AC_INCLUDES_DEFAULT
1070 #include <openssl/evp.h>
1071               ])
1072       fi
1073       if test $use_ed448 = "yes"; then
1074                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1075       fi
1076       ;;
1077 esac
1078
1079 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1080 case "$enable_event_api" in
1081     yes)
1082       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1083       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1084       ;;
1085     *)
1086       ;;
1087 esac
1088
1089 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1090 case "$enable_tfo_client" in
1091         yes)
1092                 case `uname` in
1093                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1094                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1095                                              [AC_INCLUDES_DEFAULT
1096 #include <netinet/tcp.h>
1097 ])
1098                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1099                           ;;
1100                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1101                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1102                                               [AC_INCLUDES_DEFAULT
1103 #include <sys/socket.h>
1104 ])
1105                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1106                           ;;
1107                 esac
1108         ;;
1109         no|*)
1110                 ;;
1111 esac
1112
1113 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1114 case "$enable_tfo_server" in
1115         yes)
1116               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1117 #include <netinet/tcp.h>
1118               ])
1119                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1120                 ;;
1121         no|*)
1122                 ;;
1123 esac
1124
1125 # check for libevent
1126 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1127     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1128     [ ],[ withval="no" ])
1129 if test x_$withval = x_yes -o x_$withval != x_no; then
1130         AC_MSG_CHECKING(for libevent)
1131         if test x_$withval = x_ -o x_$withval = x_yes; then
1132             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1133         fi
1134         for dir in $withval; do
1135             thedir="$dir"
1136             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1137                 found_libevent="yes"
1138                 dnl assume /usr is in default path.
1139                 if test "$thedir" != "/usr"; then
1140                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1141                 fi
1142                 break;
1143             fi
1144         done
1145         if test x_$found_libevent != x_yes; then
1146                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1147                         # libevent source directory
1148                         AC_MSG_RESULT(found in $thedir)
1149                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1150                         BAK_LDFLAGS_SET="1"
1151                         BAK_LDFLAGS="$LDFLAGS"
1152                         # remove evdns from linking
1153                         mkdir build >/dev/null 2>&1
1154                         mkdir build/libevent >/dev/null 2>&1
1155                         mkdir build/libevent/.libs >/dev/null 2>&1
1156                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1157                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1158                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1159                         cp $ev_files_o build/libevent
1160                         cp $ev_files_lo build/libevent
1161                         cp $ev_files_libso build/libevent/.libs
1162                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1163                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1164                 else
1165                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1166 You can restart ./configure --with-libevent=no to use a builtin alternative.
1167 Please note that this alternative is not as capable as libevent when using
1168 large outgoing port ranges.  ])
1169                 fi
1170         else
1171             AC_MSG_RESULT(found in $thedir)
1172             dnl if event2 exists and no event lib in dir itself, use subdir
1173             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1174                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1175                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1176             else
1177                     dnl assume /usr is in default path, do not add "".
1178                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1179                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1180                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1181                     fi
1182             fi
1183         fi
1184         # check for library used by libevent after 1.3c
1185         AC_SEARCH_LIBS([clock_gettime], [rt])
1186
1187         # is the event.h header libev or libevent?
1188         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1189         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1190                 AC_SEARCH_LIBS(event_set, [ev])
1191         ],[
1192                 AC_SEARCH_LIBS(event_set, [event])
1193         ],[AC_INCLUDES_DEFAULT
1194 #include <event.h>
1195         ])
1196         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1197         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1198         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1199         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1200         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1201         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1202         PC_LIBEVENT_DEPENDENCY="libevent"
1203         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1204         if test -n "$BAK_LDFLAGS_SET"; then
1205                 LDFLAGS="$BAK_LDFLAGS"
1206         fi
1207 else
1208         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1209 fi
1210
1211 # check for libexpat
1212 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1213     [specify explicit path for libexpat.]),
1214     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1215 AC_MSG_CHECKING(for libexpat)
1216 found_libexpat="no"
1217 for dir in $withval ; do
1218             if test -f "$dir/include/expat.h"; then
1219                 found_libexpat="yes"
1220                 dnl assume /usr is in default path.
1221                 if test "$dir" != "/usr"; then
1222                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1223                     LDFLAGS="$LDFLAGS -L$dir/lib"
1224                 fi
1225                 AC_MSG_RESULT(found in $dir)
1226                 break;
1227             fi
1228 done
1229 if test x_$found_libexpat != x_yes; then
1230         AC_ERROR([Could not find libexpat, expat.h])
1231 fi
1232 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1233 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1234 #include <expat.h>
1235 ])
1236
1237 # hiredis (redis C client for cachedb)
1238 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1239     [specify explicit path for libhiredis.]),
1240     [ ],[ withval="no" ])
1241 found_libhiredis="no"
1242 if test x_$withval = x_yes -o x_$withval != x_no; then
1243    AC_MSG_CHECKING(for libhiredis)
1244    if test x_$withval = x_ -o x_$withval = x_yes; then
1245             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1246    fi
1247    for dir in $withval ; do
1248             if test -f "$dir/include/hiredis/hiredis.h"; then
1249                 found_libhiredis="yes"
1250                 dnl assume /usr is in default path.
1251                 if test "$dir" != "/usr"; then
1252                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1253                     LDFLAGS="$LDFLAGS -L$dir/lib"
1254                 fi
1255                 AC_MSG_RESULT(found in $dir)
1256                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1257                 LIBS="$LIBS -lhiredis"
1258                 break;
1259             fi
1260     done
1261     if test x_$found_libhiredis != x_yes; then
1262         AC_ERROR([Could not find libhiredis, hiredis.h])
1263     fi
1264     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1265     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1266     #include <hiredis/hiredis.h>
1267     ])
1268 fi
1269
1270 # set static linking if requested
1271 AC_SUBST(staticexe)
1272 staticexe=""
1273 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1274         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1275         , )
1276 if test x_$enable_static_exe = x_yes; then
1277         staticexe="-static"
1278         if test "$on_mingw" = yes; then
1279                 staticexe="-all-static"
1280                 # for static compile, include gdi32 and zlib here.
1281                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1282                         :
1283                 else
1284                         LIBS="$LIBS -lgdi32"
1285                 fi
1286                 LIBS="$LIBS -lz"
1287         fi
1288 fi
1289
1290 # Include systemd.m4 - begin
1291 sinclude(systemd.m4)
1292 # Include systemd.m4 - end
1293
1294 # set lock checking if requested
1295 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1296         [ enable to check lock and unlock calls, for debug purposes ]),
1297         , )
1298 if test x_$enable_lock_checks = x_yes; then
1299         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1300         CHECKLOCK_OBJ="checklocks.lo"
1301         AC_SUBST(CHECKLOCK_OBJ)
1302 fi
1303
1304 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1305 if test "$USE_WINSOCK" = 1; then
1306         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1307         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1308 #include <windows.h>
1309         ])
1310         AC_CHECK_TOOL(WINDRES, windres)
1311         LIBS="$LIBS -liphlpapi -lcrypt32"
1312         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1313         AC_SUBST(WINAPPS)
1314         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1315         AC_SUBST(WIN_DAEMON_SRC)
1316         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1317         AC_SUBST(WIN_DAEMON_OBJ)
1318         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1319         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1320         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1321         AC_SUBST(WIN_HOST_OBJ_LINK)
1322         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1323         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1324         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1325         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1326         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1327         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1328 fi
1329 if test $ac_cv_func_getaddrinfo = no; then
1330         AC_LIBOBJ([fake-rfc2553])
1331 fi
1332 # check after getaddrinfo for its libraries
1333 ACX_FUNC_IOCTLSOCKET
1334
1335 # see if daemon(3) exists, and if it is deprecated.
1336 AC_CHECK_FUNCS([daemon])
1337 if test $ac_cv_func_daemon = yes; then
1338         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1339 #include <stdlib.h>
1340 ])
1341 fi
1342
1343 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1344 AC_INCLUDES_DEFAULT
1345 #ifdef HAVE_SYS_UN_H
1346 #include <sys/un.h>
1347 #endif
1348 ])
1349 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1350 AC_INCLUDES_DEFAULT
1351 #if HAVE_SYS_PARAM_H
1352 #include <sys/param.h>
1353 #endif
1354
1355 #ifdef HAVE_SYS_SOCKET_H
1356 #include <sys/socket.h>
1357 #endif
1358
1359 #ifdef HAVE_SYS_UIO_H
1360 #include <sys/uio.h>
1361 #endif
1362
1363 #ifdef HAVE_NETINET_IN_H
1364 #include <netinet/in.h>
1365 #endif
1366
1367 #ifdef HAVE_NETINET_TCP_H
1368 #include <netinet/tcp.h>
1369 #endif
1370
1371 #ifdef HAVE_ARPA_INET_H
1372 #include <arpa/inet.h>
1373 #endif
1374
1375 #ifdef HAVE_WINSOCK2_H
1376 #include <winsock2.h>
1377 #endif
1378
1379 #ifdef HAVE_WS2TCPIP_H
1380 #include <ws2tcpip.h>
1381 #endif
1382 ])
1383 AC_SEARCH_LIBS([setusercontext], [util])
1384 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1385 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1386 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1387
1388 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1389 if echo $target_os | grep darwin8 > /dev/null; then
1390         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1391 fi
1392 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1393 AC_INCLUDES_DEFAULT
1394 #ifdef HAVE_NETINET_IN_H
1395 #include <netinet/in.h>
1396 #endif
1397
1398 #ifdef HAVE_NETINET_TCP_H
1399 #include <netinet/tcp.h>
1400 #endif
1401
1402 #ifdef HAVE_ARPA_INET_H
1403 #include <arpa/inet.h>
1404 #endif
1405
1406 #ifdef HAVE_WINSOCK2_H
1407 #include <winsock2.h>
1408 #endif
1409
1410 #ifdef HAVE_WS2TCPIP_H
1411 #include <ws2tcpip.h>
1412 #endif
1413 ])
1414 AC_REPLACE_FUNCS(inet_aton)
1415 AC_REPLACE_FUNCS(inet_pton)
1416 AC_REPLACE_FUNCS(inet_ntop)
1417 AC_REPLACE_FUNCS(snprintf)
1418 # test if snprintf return the proper length
1419 if test "x$ac_cv_func_snprintf" = xyes; then
1420     if test c${cross_compiling} = cno; then
1421         AC_MSG_CHECKING([for correct snprintf return value])
1422         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1423 [[
1424 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1425 ]])], [AC_MSG_RESULT(yes)], [
1426                 AC_MSG_RESULT(no)
1427                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1428                 AC_LIBOBJ(snprintf)
1429           ])
1430     fi
1431 fi
1432 AC_REPLACE_FUNCS(strlcat)
1433 AC_REPLACE_FUNCS(strlcpy)
1434 AC_REPLACE_FUNCS(memmove)
1435 AC_REPLACE_FUNCS(gmtime_r)
1436 AC_REPLACE_FUNCS(isblank)
1437 AC_REPLACE_FUNCS(explicit_bzero)
1438 dnl without CTIME, ARC4-functions and without reallocarray.
1439 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1440 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1441 AC_REPLACE_FUNCS(reallocarray)
1442 if test "$USE_NSS" = "no"; then
1443         AC_REPLACE_FUNCS(arc4random)
1444         AC_REPLACE_FUNCS(arc4random_uniform)
1445         if test "$ac_cv_func_arc4random" = "no"; then
1446                 AC_LIBOBJ(arc4_lock)
1447                 AC_CHECK_FUNCS([getentropy],,[
1448                     if test "$USE_WINSOCK" = 1; then
1449                         AC_LIBOBJ(getentropy_win)
1450                     else
1451                         case "$host" in
1452                         Darwin|*darwin*)
1453                                 AC_LIBOBJ(getentropy_osx)
1454                         ;;
1455                         *solaris*|*sunos*|SunOS)
1456                                 AC_LIBOBJ(getentropy_solaris)
1457                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1458                                         AC_CHECK_FUNCS([SHA512_Update],,[
1459                                                 AC_LIBOBJ(sha512)
1460                                         ])
1461                                 ], [AC_INCLUDES_DEFAULT])
1462                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1463                                         # this lib needed for sha2 on solaris
1464                                         LIBS="$LIBS -lmd"
1465                                 fi
1466                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1467                         ;;
1468                         *linux*|Linux|*)
1469                                 AC_LIBOBJ(getentropy_linux)
1470                                 AC_CHECK_FUNCS([SHA512_Update],,[
1471                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1472                                         AC_LIBOBJ(sha512)
1473                                 ])
1474                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1475                                 AC_CHECK_FUNCS([getauxval])
1476                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1477                         ;;
1478                         esac
1479                     fi
1480                 ])
1481         fi
1482 fi
1483 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1484 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1485 AC_REPLACE_FUNCS(ctime_r)
1486 AC_REPLACE_FUNCS(strsep)
1487
1488 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1489 case "$enable_allsymbols" in
1490         yes)
1491         COMMON_OBJ_ALL_SYMBOLS=""
1492         UBSYMS=""
1493         EXTRALINK="-L. -L.libs -lunbound"
1494         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1495         ;;
1496         no|*)
1497         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1498         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1499         EXTRALINK=""
1500         ;;
1501 esac
1502 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1503 AC_SUBST(EXTRALINK)
1504 AC_SUBST(UBSYMS)
1505 if test x_$enable_lock_checks = x_yes; then
1506         UBSYMS="-export-symbols clubsyms.def"
1507         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1508         echo lock_protect >> clubsyms.def
1509         echo lock_unprotect >> clubsyms.def
1510         echo lock_get_mem >> clubsyms.def
1511         echo checklock_start >> clubsyms.def
1512         echo checklock_stop >> clubsyms.def
1513         echo checklock_lock >> clubsyms.def
1514         echo checklock_unlock >> clubsyms.def
1515         echo checklock_init >> clubsyms.def
1516         echo checklock_thrcreate >> clubsyms.def
1517         echo checklock_thrjoin >> clubsyms.def
1518 fi
1519
1520 # check for dnstap if requested
1521 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1522     [
1523         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1524         AC_SUBST([ENABLE_DNSTAP], [1])
1525
1526         AC_SUBST([opt_dnstap_socket_path])
1527         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1528         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1529             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1530
1531         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1532         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1533     ],
1534     [
1535         AC_SUBST([ENABLE_DNSTAP], [0])
1536     ]
1537 )
1538
1539 # check for dnscrypt if requested
1540 dnsc_DNSCRYPT([
1541         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1542         AC_SUBST([ENABLE_DNSCRYPT], [1])
1543
1544         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1545         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1546     ],
1547     [
1548         AC_SUBST([ENABLE_DNSCRYPT], [0])
1549     ]
1550 )
1551
1552 # check for cachedb if requested
1553 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1554 # turn on cachedb when hiredis support is enabled.
1555 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1556 case "$enable_cachedb" in
1557     yes)
1558         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1559         ;;
1560     no|*)
1561         # nothing
1562         ;;
1563 esac
1564
1565 # check for ipsecmod if requested
1566 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1567 case "$enable_ipsecmod" in
1568         yes)
1569                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1570                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1571                 AC_SUBST(IPSECMOD_OBJ)
1572                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1573                 AC_SUBST(IPSECMOD_HEADER)
1574                 ;;
1575         no|*)
1576                 # nothing
1577                 ;;
1578 esac
1579
1580 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1581 # on openBSD, the implicit rule make $< work.
1582 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1583 # gmake works.
1584 cat >conftest.make <<EOF
1585 all:    conftest.lo
1586
1587 conftest.lo foo.lo bla.lo:
1588         if test -f "\$<"; then touch \$@; fi
1589
1590 .SUFFIXES: .lo
1591 .c.lo:
1592         if test -f "\$<"; then touch \$@; fi
1593
1594 conftest.lo:        conftest.dir/conftest.c
1595 EOF
1596 mkdir conftest.dir
1597 touch conftest.dir/conftest.c
1598 rm -f conftest.lo conftest.c
1599 ${MAKE:-make} -f conftest.make >/dev/null
1600 rm -f conftest.make conftest.c conftest.dir/conftest.c
1601 rm -rf conftest.dir
1602 if test ! -f conftest.lo; then
1603         AC_MSG_RESULT(no)
1604         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1605         SOURCEFILE='`cat .source`'
1606 else
1607         AC_MSG_RESULT(yes)
1608         SOURCEDETERMINE=':'
1609         SOURCEFILE='$<'
1610 fi
1611 rm -f conftest.lo
1612 AC_SUBST(SOURCEDETERMINE)
1613 AC_SUBST(SOURCEFILE)
1614
1615 # see if we want to build the library or everything
1616 ALLTARGET="alltargets"
1617 INSTALLTARGET="install-all"
1618 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1619         [do not build daemon and tool programs]),
1620         [
1621         if test "$withval" = "yes"; then
1622                 ALLTARGET="lib"
1623                 INSTALLTARGET="install-lib"
1624         fi
1625 ])
1626 if test $ALLTARGET = "alltargets"; then
1627         if test $USE_NSS = "yes"; then
1628                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1629         fi
1630         if test $USE_NETTLE = "yes"; then
1631                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1632         fi
1633 fi
1634
1635 AC_SUBST(ALLTARGET)
1636 AC_SUBST(INSTALLTARGET)
1637
1638 ACX_STRIP_EXT_FLAGS
1639 if test -n "$LATE_LDFLAGS"; then
1640   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1641 fi
1642 # remove start spaces
1643 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1644 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1645
1646 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1647
1648 AH_BOTTOM(
1649 dnl this must be first AH_CONFIG, to define the flags before any includes.
1650 AHX_CONFIG_EXT_FLAGS
1651
1652 dnl includes
1653 [
1654 #ifndef UNBOUND_DEBUG
1655 #  define NDEBUG
1656 #endif
1657
1658 /** Use small-ldns codebase */
1659 #define USE_SLDNS 1
1660 #ifdef HAVE_SSL
1661 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1662 #endif
1663
1664 #include <stdio.h>
1665 #include <string.h>
1666 #include <unistd.h>
1667 #include <assert.h>
1668
1669 #if STDC_HEADERS
1670 #include <stdlib.h>
1671 #include <stddef.h>
1672 #endif
1673
1674 #ifdef HAVE_STDARG_H
1675 #include <stdarg.h>
1676 #endif
1677
1678 #ifdef HAVE_STDINT_H
1679 #include <stdint.h>
1680 #endif
1681
1682 #include <errno.h>
1683
1684 #if HAVE_SYS_PARAM_H
1685 #include <sys/param.h>
1686 #endif
1687
1688 #ifdef HAVE_SYS_SOCKET_H
1689 #include <sys/socket.h>
1690 #endif
1691
1692 #ifdef HAVE_SYS_UIO_H
1693 #include <sys/uio.h>
1694 #endif
1695
1696 #ifdef HAVE_NETINET_IN_H
1697 #include <netinet/in.h>
1698 #endif
1699
1700 #ifdef HAVE_NETINET_TCP_H
1701 #include <netinet/tcp.h>
1702 #endif
1703
1704 #ifdef HAVE_ARPA_INET_H
1705 #include <arpa/inet.h>
1706 #endif
1707
1708 #ifdef HAVE_WINSOCK2_H
1709 #include <winsock2.h>
1710 #endif
1711
1712 #ifdef HAVE_WS2TCPIP_H
1713 #include <ws2tcpip.h>
1714 #endif
1715
1716 #ifndef USE_WINSOCK
1717 #define ARG_LL "%ll"
1718 #else
1719 #define ARG_LL "%I64"
1720 #endif
1721
1722 #ifndef AF_LOCAL
1723 #define AF_LOCAL AF_UNIX
1724 #endif
1725 ]
1726
1727 AHX_CONFIG_FORMAT_ATTRIBUTE
1728 AHX_CONFIG_UNUSED_ATTRIBUTE
1729 AHX_CONFIG_FSEEKO
1730 AHX_CONFIG_MAXHOSTNAMELEN
1731 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1732 #define snprintf snprintf_unbound
1733 #define vsnprintf vsnprintf_unbound
1734 #include <stdarg.h>
1735 int snprintf (char *str, size_t count, const char *fmt, ...);
1736 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1737 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1738 AHX_CONFIG_INET_PTON(unbound)
1739 AHX_CONFIG_INET_NTOP(unbound)
1740 AHX_CONFIG_INET_ATON(unbound)
1741 AHX_CONFIG_MEMMOVE(unbound)
1742 AHX_CONFIG_STRLCAT(unbound)
1743 AHX_CONFIG_STRLCPY(unbound)
1744 AHX_CONFIG_GMTIME_R(unbound)
1745 AHX_CONFIG_REALLOCARRAY(unbound)
1746 AHX_CONFIG_W32_SLEEP
1747 AHX_CONFIG_W32_USLEEP
1748 AHX_CONFIG_W32_RANDOM
1749 AHX_CONFIG_W32_SRANDOM
1750 AHX_CONFIG_W32_FD_SET_T
1751 AHX_CONFIG_IPV6_MIN_MTU
1752 AHX_MEMCMP_BROKEN(unbound)
1753
1754 [
1755 #ifndef HAVE_CTIME_R
1756 #define ctime_r unbound_ctime_r
1757 char *ctime_r(const time_t *timep, char *buf);
1758 #endif
1759
1760 #ifndef HAVE_STRSEP
1761 #define strsep unbound_strsep
1762 char *strsep(char **stringp, const char *delim);
1763 #endif
1764
1765 #ifndef HAVE_ISBLANK
1766 #define isblank unbound_isblank
1767 int isblank(int c);
1768 #endif
1769
1770 #ifndef HAVE_EXPLICIT_BZERO
1771 #define explicit_bzero unbound_explicit_bzero
1772 void explicit_bzero(void* buf, size_t len);
1773 #endif
1774
1775 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1776 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1777 #endif
1778
1779 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1780 int inet_pton(int af, const char* src, void* dst);
1781 #endif
1782
1783 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1784 #define strptime unbound_strptime
1785 struct tm;
1786 char *strptime(const char *s, const char *format, struct tm *tm);
1787 #endif
1788
1789 #ifdef HAVE_LIBRESSL
1790 #  if !HAVE_DECL_STRLCPY
1791 size_t strlcpy(char *dst, const char *src, size_t siz);
1792 #  endif
1793 #  if !HAVE_DECL_STRLCAT
1794 size_t strlcat(char *dst, const char *src, size_t siz);
1795 #  endif
1796 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1797 uint32_t arc4random(void);
1798 #  endif
1799 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1800 uint32_t arc4random_uniform(uint32_t upper_bound);
1801 #  endif
1802 #  if !HAVE_DECL_REALLOCARRAY
1803 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1804 #  endif
1805 #endif /* HAVE_LIBRESSL */
1806 #ifndef HAVE_ARC4RANDOM
1807 int getentropy(void* buf, size_t len);
1808 uint32_t arc4random(void);
1809 void arc4random_buf(void* buf, size_t n);
1810 void _ARC4_LOCK(void);
1811 void _ARC4_UNLOCK(void);
1812 void _ARC4_LOCK_DESTROY(void);
1813 #endif
1814 #ifndef HAVE_ARC4RANDOM_UNIFORM
1815 uint32_t arc4random_uniform(uint32_t upper_bound);
1816 #endif
1817 #ifdef COMPAT_SHA512
1818 #ifndef SHA512_DIGEST_LENGTH
1819 #define SHA512_BLOCK_LENGTH             128
1820 #define SHA512_DIGEST_LENGTH            64
1821 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1822 typedef struct _SHA512_CTX {
1823         uint64_t        state[8];
1824         uint64_t        bitcount[2];
1825         uint8_t buffer[SHA512_BLOCK_LENGTH];
1826 } SHA512_CTX;
1827 #endif /* SHA512_DIGEST_LENGTH */
1828 void SHA512_Init(SHA512_CTX*);
1829 void SHA512_Update(SHA512_CTX*, void*, size_t);
1830 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1831 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1832 #endif /* COMPAT_SHA512 */
1833
1834
1835
1836 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1837    /* using version of libevent that is not threadsafe. */
1838 #  define LIBEVENT_SIGNAL_PROBLEM 1
1839 #endif
1840
1841 #ifndef CHECKED_INET6
1842 #  define CHECKED_INET6
1843 #  ifdef AF_INET6
1844 #    define INET6
1845 #  else
1846 #    define AF_INET6        28
1847 #  endif
1848 #endif /* CHECKED_INET6 */
1849
1850 #ifndef HAVE_GETADDRINFO
1851 struct sockaddr_storage;
1852 #include "compat/fake-rfc2553.h"
1853 #endif
1854
1855 #ifdef UNBOUND_ALLOC_STATS
1856 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1857 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1858 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1859 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1860 void *unbound_stat_malloc(size_t size);
1861 void *unbound_stat_calloc(size_t nmemb, size_t size);
1862 void unbound_stat_free(void *ptr);
1863 void *unbound_stat_realloc(void *ptr, size_t size);
1864 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1865         const char* func);
1866 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1867         int line, const char* func);
1868 void unbound_stat_free_log(void *ptr, const char* file, int line,
1869         const char* func);
1870 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1871         int line, const char* func);
1872 #elif defined(UNBOUND_ALLOC_LITE)
1873 #  include "util/alloc.h"
1874 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1875
1876 /** default port for DNS traffic. */
1877 #define UNBOUND_DNS_PORT 53
1878 /** default port for DNS over TLS traffic. */
1879 #define UNBOUND_DNS_OVER_TLS_PORT 853
1880 /** default port for unbound control traffic, registered port with IANA,
1881     ub-dns-control  8953/tcp    unbound dns nameserver control */
1882 #define UNBOUND_CONTROL_PORT 8953
1883 /** the version of unbound-control that this software implements */
1884 #define UNBOUND_CONTROL_VERSION 1
1885
1886 ])
1887
1888 dnl if we build from source tree, the man pages need @date@ and @version@
1889 dnl if this is a distro tarball, that was already done by makedist.sh
1890 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1891 AC_SUBST(date, [`date +'%b %e, %Y'`])
1892
1893 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1894 AC_CONFIG_HEADER([config.h])
1895 AC_OUTPUT