configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[6])
  14 m4_define([VERSION_MICRO],[2])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=1
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74
  75 #   Current  -- the number of the binary API that we're implementing
  76 #   Revision -- which iteration of the implementation of the binary
  77 #               API are we supplying?
  78 #   Age      -- How many previous binary API versions do we also
  79 #               support?
  80 #
  81 # If we release a new version that does not change the binary API,
  82 # increment Revision.
  83 #
  84 # If we release a new version that changes the binary API, but does
  85 # not break programs compiled against the old binary API, increment
  86 # Current and Age.  Set Revision to 0, since this is the first
  87 # implementation of the new API.
  88 #
  89 # Otherwise, we're changing the binary API and breaking bakward
  90 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  91 # since we're backward compatible with no previous APIs.  Set Revision
  92 # to 0 too.
  93 AC_SUBST(LIBUNBOUND_CURRENT)
  94 AC_SUBST(LIBUNBOUND_REVISION)
  95 AC_SUBST(LIBUNBOUND_AGE)
  96
  97 CFLAGS="$CFLAGS"
  98 AC_AIX
  99 if test "$ac_cv_header_minix_config_h" = "yes"; then
 100         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 101 fi
 102
 103 dnl
 104 dnl By default set prefix to /usr/local
 105 dnl
 106 case "$prefix" in
 107         NONE)
 108                 prefix="/usr/local"
 109         ;;
 110 esac
 111
 112 # are we on MinGW?
 113 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 114 else
 115         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 116         else on_mingw="no"; fi
 117 fi
 118
 119 #
 120 # Determine configuration file
 121 # the eval is to evaluate shell expansion twice
 122 if test $on_mingw = "no"; then
 123   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 124 else
 125   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 126 fi
 127 AC_ARG_WITH([conf_file],
 128         AC_HELP_STRING([--with-conf-file=path],
 129         [Pathname to the Unbound configuration file]),
 130         [ub_conf_file="$withval"])
 131 AC_SUBST(ub_conf_file)
 132 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 133 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 134 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 135 AC_SUBST(ub_conf_dir)
 136
 137 # Determine run, chroot directory and pidfile locations
 138 AC_ARG_WITH(run-dir,
 139     AC_HELP_STRING([--with-run-dir=path],
 140     [set default directory to chdir to (by default dir part of cfg file)]),
 141     UNBOUND_RUN_DIR="$withval",
 142 if test $on_mingw = no; then
 143     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 144 else
 145     UNBOUND_RUN_DIR=""
 146 fi
 147 )
 148 AC_SUBST(UNBOUND_RUN_DIR)
 149 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 150 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 151
 152 AC_ARG_WITH(chroot-dir,
 153     AC_HELP_STRING([--with-chroot-dir=path],
 154     [set default directory to chroot to (by default same as run-dir)]),
 155     UNBOUND_CHROOT_DIR="$withval",
 156 if test $on_mingw = no; then
 157     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 158 else
 159     UNBOUND_CHROOT_DIR=""
 160 fi
 161 )
 162 AC_SUBST(UNBOUND_CHROOT_DIR)
 163 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 164 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 165
 166 AC_ARG_WITH(share-dir,
 167     AC_HELP_STRING([--with-share-dir=path],
 168     [set default directory with shared data (by default same as share/unbound)]),
 169     UNBOUND_SHARE_DIR="$withval",
 170     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 171 AC_SUBST(UNBOUND_SHARE_DIR)
 172 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 173
 174 AC_ARG_WITH(pidfile,
 175     AC_HELP_STRING([--with-pidfile=filename],
 176     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 177     UNBOUND_PIDFILE="$withval",
 178 if test $on_mingw = no; then
 179     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 180 else
 181     UNBOUND_PIDFILE=""
 182 fi
 183 )
 184 AC_SUBST(UNBOUND_PIDFILE)
 185 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 186 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 187
 188 AC_ARG_WITH(rootkey-file,
 189     AC_HELP_STRING([--with-rootkey-file=filename],
 190     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 191     UNBOUND_ROOTKEY_FILE="$withval",
 192 if test $on_mingw = no; then
 193     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 194 else
 195     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 196 fi
 197 )
 198 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 199 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 200 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 201
 202 AC_ARG_WITH(rootcert-file,
 203     AC_HELP_STRING([--with-rootcert-file=filename],
 204     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 205     UNBOUND_ROOTCERT_FILE="$withval",
 206 if test $on_mingw = no; then
 207     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 208 else
 209     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 210 fi
 211 )
 212 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 213 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 214 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 215
 216 AC_ARG_WITH(username,
 217     AC_HELP_STRING([--with-username=user],
 218     [set default user that unbound changes to (default user is unbound)]),
 219     UNBOUND_USERNAME="$withval",
 220     UNBOUND_USERNAME="unbound")
 221 AC_SUBST(UNBOUND_USERNAME)
 222 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 223
 224 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 225 ACX_RSRC_VERSION(wnvs)
 226 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 227
 228 # Checks for typedefs, structures, and compiler characteristics.
 229 AC_C_CONST
 230 AC_LANG_C
 231 # allow user to override the -g -O2 flags.
 232 if test "x$CFLAGS" = "x" ; then
 233 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 234 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 235 fi
 236 AC_PROG_CC
 237 ACX_DEPFLAG
 238 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 239
 240 # debug mode flags warnings
 241 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 242 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 243 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 244 else debug_enabled="$enable_checking"; fi
 245 AC_SUBST(debug_enabled)
 246 case "$debug_enabled" in
 247         yes)
 248                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 249                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 250                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 251                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 252                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 253                 ;;
 254         no|*)
 255                 # nothing to do.
 256                 ;;
 257 esac
 258 ACX_CHECK_FLTO
 259 ACX_CHECK_PIE
 260 ACX_CHECK_RELRO_NOW
 261
 262 AC_C_INLINE
 263 ACX_CHECK_FORMAT_ATTRIBUTE
 264 ACX_CHECK_UNUSED_ATTRIBUTE
 265
 266 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 267 [AC_REQUIRE([AC_PROG_CC])
 268 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 269 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 270 [ac_cv_c_weak_attribute=no
 271 AC_TRY_COMPILE(
 272 [ #include <stdio.h>
 273 __attribute__((weak)) void f(int x) { printf("%d", x); }
 274 ], [
 275    f(1);
 276 ],
 277 [ac_cv_c_weak_attribute="yes"],
 278 [ac_cv_c_weak_attribute="no"])
 279 ])
 280
 281 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 282 if test $ac_cv_c_weak_attribute = yes; then
 283   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 284 fi
 285 ])dnl End of CHECK_WEAK_ATTRIBUTE
 286
 287 CHECK_WEAK_ATTRIBUTE
 288
 289 if test "$srcdir" != "."; then
 290         CPPFLAGS="$CPPFLAGS -I$srcdir"
 291 fi
 292
 293 AC_DEFUN([ACX_YYLEX_DESTROY], [
 294         AC_MSG_CHECKING([for yylex_destroy])
 295         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 296                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 297                 AC_MSG_RESULT(yes)
 298         else AC_MSG_RESULT(no); fi
 299 ])
 300
 301 AC_PROG_LEX
 302 ACX_YYLEX_DESTROY
 303 AC_PROG_YACC
 304 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 305 AC_CHECK_TOOL(STRIP, strip)
 306 ACX_LIBTOOL_C_ONLY
 307
 308 # Checks for header files.
 309 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 310
 311 # check for types.
 312 # Using own tests for int64* because autoconf builtin only give 32bit.
 313 AC_CHECK_TYPE(int8_t, signed char)
 314 AC_CHECK_TYPE(int16_t, short)
 315 AC_CHECK_TYPE(int32_t, int)
 316 AC_CHECK_TYPE(int64_t, long long)
 317 AC_CHECK_TYPE(uint8_t, unsigned char)
 318 AC_CHECK_TYPE(uint16_t, unsigned short)
 319 AC_CHECK_TYPE(uint32_t, unsigned int)
 320 AC_CHECK_TYPE(uint64_t, unsigned long long)
 321 AC_TYPE_SIZE_T
 322 AC_CHECK_TYPE(ssize_t, int)
 323 AC_TYPE_UID_T
 324 AC_TYPE_PID_T
 325 AC_TYPE_OFF_T
 326 ACX_TYPE_U_CHAR
 327 ACX_TYPE_RLIM_T
 328 ACX_TYPE_SOCKLEN_T
 329 ACX_TYPE_IN_ADDR_T
 330 ACX_TYPE_IN_PORT_T
 331 ACX_CHECK_MEMCMP_SIGNED
 332
 333 AC_CHECK_SIZEOF(time_t,,[
 334 AC_INCLUDES_DEFAULT
 335 #ifdef TIME_WITH_SYS_TIME
 336 # include <sys/time.h>
 337 # include <time.h>
 338 #else
 339 # ifdef HAVE_SYS_TIME_H
 340 #  include <sys/time.h>
 341 # else
 342 #  include <time.h>
 343 # endif
 344 #endif
 345 ])
 346
 347 # add option to disable the evil rpath
 348 ACX_ARG_RPATH
 349 AC_SUBST(RUNTIME_PATH)
 350
 351 # check to see if libraries are needed for these functions.
 352 AC_SEARCH_LIBS([inet_pton], [nsl])
 353 AC_SEARCH_LIBS([socket], [socket])
 354
 355 # check wether strptime also works
 356 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 357 [AC_REQUIRE([AC_PROG_CC])
 358 AC_MSG_CHECKING(whether strptime works)
 359 if test c${cross_compiling} = cno; then
 360 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 361 #define _XOPEN_SOURCE 600
 362 #include <time.h>
 363 int main(void) { struct tm tm; char *res;
 364 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 365 if (!res) return 2;
 366 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 367 if (!res) return 1; return 0; }
 368 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 369 else
 370 eval "ac_cv_c_strptime_works=maybe"
 371 fi
 372 AC_MSG_RESULT($ac_cv_c_strptime_works)
 373 if test $ac_cv_c_strptime_works = no; then
 374 AC_LIBOBJ(strptime)
 375 else
 376 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 377 fi
 378 ])dnl
 379
 380 # check some functions of the OS before linking libs (while still runnable).
 381 AC_FUNC_CHOWN
 382 AC_FUNC_FORK
 383 AC_TYPE_SIGNAL
 384 AC_FUNC_FSEEKO
 385 ACX_SYS_LARGEFILE
 386 ACX_CHECK_NONBLOCKING_BROKEN
 387 ACX_MKDIR_ONE_ARG
 388 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 389
 390 # set memory allocation checking if requested
 391 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 392         [ enable to memory allocation statistics, for debug purposes ]),
 393         , )
 394 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 395         [ enable for lightweight alloc assertions, for debug purposes ]),
 396         , )
 397 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 398         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 399         , )
 400 if test x_$enable_alloc_nonregional = x_yes; then
 401         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 402 fi
 403 if test x_$enable_alloc_checks = x_yes; then
 404         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 405 else
 406         if test x_$enable_alloc_lite = x_yes; then
 407                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 408         else
 409                 ACX_FUNC_MALLOC([unbound])
 410         fi
 411 fi
 412
 413 # check windows threads (we use them, not pthreads, on windows).
 414 if test "$on_mingw" = "yes"; then
 415 # check windows threads
 416         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 417         AC_MSG_CHECKING([for CreateThread])
 418         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 419 #ifdef HAVE_WINDOWS_H
 420 #include <windows.h>
 421 #endif
 422 ], [
 423         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 424 ])],
 425         AC_MSG_RESULT(yes)
 426         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 427 ,
 428         AC_MSG_RESULT(no)
 429 )
 430
 431 else
 432 # not on mingw, check thread libraries.
 433
 434 # check for thread library.
 435 # check this first, so that the pthread lib does not get linked in via
 436 # libssl or libpython, and thus distorts the tests, and we end up using
 437 # the non-threadsafe C libraries.
 438 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 439  [use pthreads library, or --without-pthreads to disable threading support.]),
 440  [ ],[ withval="yes" ])
 441 ub_have_pthreads=no
 442 if test x_$withval != x_no; then
 443         AX_PTHREAD([
 444                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 445                 LIBS="$PTHREAD_LIBS $LIBS"
 446                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 447                 CC="$PTHREAD_CC"
 448                 ub_have_pthreads=yes
 449                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 450
 451                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 452                 AC_MSG_CHECKING([if -pthread unused during linking])
 453                 # catch clang warning 'argument unused during compilation'
 454                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 455 [[
 456 int main(void) {return 0;}
 457 ]])])
 458                 pthread_unused="yes"
 459                 # first compile
 460                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 461                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 462                 if test $? = 0; then
 463                         # then link
 464                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 465                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 466                         if test $? -ne 0; then
 467                                 AC_MSG_RESULT(yes)
 468                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 469                                 PTHREAD_CFLAGS_ONLY="-pthread"
 470                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 471                         else
 472                                 AC_MSG_RESULT(no)
 473                         fi
 474                 else
 475                         AC_MSG_RESULT(no)
 476                 fi # endif cc successful
 477                 rm -f conftest conftest.c conftest.o
 478                 fi # endif -pthread in CFLAGS
 479
 480                 ])
 481 fi
 482
 483 # check solaris thread library
 484 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 485         [use solaris native thread library.]), [ ],[ withval="no" ])
 486 ub_have_sol_threads=no
 487 if test x_$withval != x_no; then
 488         if test x_$ub_have_pthreads != x_no; then
 489             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 490         else
 491         AC_SEARCH_LIBS(thr_create, [thread],
 492         [
 493                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 494
 495                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 496                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 497                 ub_have_sol_threads=yes
 498         ] , [
 499                 AC_ERROR([no solaris threads found.])
 500         ])
 501         fi
 502 fi
 503
 504 fi # end of non-mingw check of thread libraries
 505
 506 # Check for PyUnbound
 507 AC_ARG_WITH(pyunbound,
 508    AC_HELP_STRING([--with-pyunbound],
 509    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 510    [], [ withval="no" ])
 511
 512 ub_test_python=no
 513 ub_with_pyunbound=no
 514 if test x_$withval != x_no; then
 515    ub_with_pyunbound=yes
 516    ub_test_python=yes
 517 fi
 518
 519 # Check for Python module
 520 AC_ARG_WITH(pythonmodule,
 521    AC_HELP_STRING([--with-pythonmodule],
 522    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 523    [], [ withval="no" ])
 524
 525 ub_with_pythonmod=no
 526 if test x_$withval != x_no; then
 527    ub_with_pythonmod=yes
 528    ub_test_python=yes
 529 fi
 530
 531 # Check for Python & SWIG only on PyUnbound or PyModule
 532 if test x_$ub_test_python != x_no; then
 533
 534    # Check for Python
 535    ub_have_python=no
 536    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 537    AC_PYTHON_DEVEL
 538    if test ! -z "$PYTHON_VERSION"; then
 539         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 540                 AC_ERROR([Python version >= 2.4.0 is required])
 541         fi
 542
 543       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 544       AC_SUBST(PY_MAJOR_VERSION)
 545       # Have Python
 546       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 547       LIBS="$PYTHON_LDFLAGS $LIBS"
 548       CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 549       ub_have_python=yes
 550       PC_PY_DEPENDENCY="python"
 551       AC_SUBST(PC_PY_DEPENDENCY)
 552
 553       # Check for SWIG
 554       ub_have_swig=no
 555       AC_PROG_SWIG(2.0.1)
 556       AC_MSG_CHECKING(SWIG)
 557       if test ! -x "$SWIG"; then
 558          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 559       else
 560          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 561          AC_SUBST(swig, "$SWIG")
 562          AC_MSG_RESULT(present)
 563
 564          # If have Python & SWIG
 565          # Declare PythonMod
 566          if test x_$ub_with_pythonmod != x_no; then
 567             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 568             WITH_PYTHONMODULE=yes
 569             AC_SUBST(WITH_PYTHONMODULE)
 570             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 571             AC_SUBST(PYTHONMOD_OBJ)
 572             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 573             AC_SUBST(PYTHONMOD_HEADER)
 574             PYTHONMOD_INSTALL=pythonmod-install
 575             AC_SUBST(PYTHONMOD_INSTALL)
 576             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 577             AC_SUBST(PYTHONMOD_UNINSTALL)
 578          fi
 579
 580          # Declare PyUnbound
 581          if test x_$ub_with_pyunbound != x_no; then
 582             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 583             WITH_PYUNBOUND=yes
 584             AC_SUBST(WITH_PYUNBOUND)
 585             PYUNBOUND_OBJ="libunbound_wrap.lo"
 586             AC_SUBST(PYUNBOUND_OBJ)
 587             PYUNBOUND_TARGET="_unbound.la"
 588             AC_SUBST(PYUNBOUND_TARGET)
 589             PYUNBOUND_INSTALL=pyunbound-install
 590             AC_SUBST(PYUNBOUND_INSTALL)
 591             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 592             AC_SUBST(PYUNBOUND_UNINSTALL)
 593          fi
 594       fi
 595    else
 596       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 597       ub_with_pyunbound=no
 598       ub_with_pythonmod=no
 599    fi
 600 fi
 601
 602 if test "`uname`" = "NetBSD"; then
 603         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 604         AC_SUBST(NETBSD_LINTFLAGS)
 605 fi
 606 CONFIG_DATE=`date +%Y%m%d`
 607 AC_SUBST(CONFIG_DATE)
 608
 609 # Checks for libraries.
 610
 611 # libnss
 612 USE_NSS="no"
 613 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 614         [use libnss instead of openssl, installed at path.]),
 615         [
 616         USE_NSS="yes"
 617         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 618         if test "$withval" != "" -a "$withval" != "yes"; then
 619                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 620                 LDFLAGS="$LDFLAGS -L$withval/lib"
 621                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 622                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 623         else
 624                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 625                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 626         fi
 627         LIBS="$LIBS -lnss3 -lnspr4"
 628         SSLLIB=""
 629         ]
 630 )
 631
 632 # libnettle
 633 USE_NETTLE="no"
 634 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 635         [use libnettle as crypto library, installed at path.]),
 636         [
 637         USE_NETTLE="yes"
 638         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 639         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 640         if test "$withval" != "" -a "$withval" != "yes"; then
 641                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 642                 LDFLAGS="$LDFLAGS -L$withval/lib"
 643                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 644         else
 645                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 646         fi
 647         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 648         SSLLIB=""
 649         ]
 650 )
 651
 652 # openssl
 653 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 654 ACX_WITH_SSL
 655 ACX_LIB_SSL
 656 SSLLIB="-lssl"
 657
 658 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 659 BAKLIBS="$LIBS"
 660 LIBS="-lssl $LIBS"
 661 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 662 AC_TRY_LINK_FUNC([HMAC_Update], [
 663         AC_MSG_RESULT([no])
 664         LIBS="$BAKLIBS"
 665 ], [
 666         AC_MSG_RESULT([yes])
 667         LIBS="$BAKLIBS"
 668         LIBS="$LIBS -lcrypt32"
 669 ])
 670
 671 AC_MSG_CHECKING([for LibreSSL])
 672 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 673         AC_MSG_RESULT([yes])
 674         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 675         # libressl provides these compat functions, but they may also be
 676         # declared by the OS in libc.  See if they have been declared.
 677         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 678 else
 679         AC_MSG_RESULT([no])
 680 fi
 681 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 682 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1])
 683
 684 # these check_funcs need -lssl
 685 BAKLIBS="$LIBS"
 686 LIBS="-lssl $LIBS"
 687 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level])
 688 LIBS="$BAKLIBS"
 689
 690 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 691 AC_INCLUDES_DEFAULT
 692 #ifdef HAVE_OPENSSL_ERR_H
 693 #include <openssl/err.h>
 694 #endif
 695
 696 #ifdef HAVE_OPENSSL_RAND_H
 697 #include <openssl/rand.h>
 698 #endif
 699
 700 #ifdef HAVE_OPENSSL_CONF_H
 701 #include <openssl/conf.h>
 702 #endif
 703
 704 #ifdef HAVE_OPENSSL_ENGINE_H
 705 #include <openssl/engine.h>
 706 #endif
 707 #include <openssl/ssl.h>
 708 #include <openssl/evp.h>
 709 ])
 710 fi
 711 AC_SUBST(SSLLIB)
 712
 713
 714 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 715 case "$enable_sha1" in
 716         no)
 717         ;;
 718         yes|*)
 719         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 720         ;;
 721 esac
 722
 723
 724 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 725 case "$enable_sha2" in
 726         no)
 727         ;;
 728         yes|*)
 729         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 730         ;;
 731 esac
 732
 733 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 734 case "$enable_subnet" in
 735         yes)
 736         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 737         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 738         AC_SUBST(SUBNET_OBJ)
 739         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 740         AC_SUBST(SUBNET_HEADER)
 741         ;;
 742         no|*)
 743         ;;
 744 esac
 745
 746 # check wether gost also works
 747 AC_DEFUN([AC_CHECK_GOST_WORKS],
 748 [AC_REQUIRE([AC_PROG_CC])
 749 AC_MSG_CHECKING([if GOST works])
 750 if test c${cross_compiling} = cno; then
 751 BAKCFLAGS="$CFLAGS"
 752 if test -n "$ssldir"; then
 753         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 754 fi
 755 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 756 #include <string.h>
 757 #include <openssl/ssl.h>
 758 #include <openssl/evp.h>
 759 #include <openssl/engine.h>
 760 #include <openssl/conf.h>
 761 /* routine to load gost (from sldns) */
 762 int load_gost_id(void)
 763 {
 764         static int gost_id = 0;
 765         const EVP_PKEY_ASN1_METHOD* meth;
 766         ENGINE* e;
 767
 768         if(gost_id) return gost_id;
 769
 770         /* see if configuration loaded gost implementation from other engine*/
 771         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 772         if(meth) {
 773                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 774                 return gost_id;
 775         }
 776
 777         /* see if engine can be loaded already */
 778         e = ENGINE_by_id("gost");
 779         if(!e) {
 780                 /* load it ourself, in case statically linked */
 781                 ENGINE_load_builtin_engines();
 782                 ENGINE_load_dynamic();
 783                 e = ENGINE_by_id("gost");
 784         }
 785         if(!e) {
 786                 /* no gost engine in openssl */
 787                 return 0;
 788         }
 789         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 790                 ENGINE_finish(e);
 791                 ENGINE_free(e);
 792                 return 0;
 793         }
 794
 795         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 796         if(!meth) {
 797                 /* algo not found */
 798                 ENGINE_finish(e);
 799                 ENGINE_free(e);
 800                 return 0;
 801         }
 802         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 803         return gost_id;
 804 }
 805 int main(void) {
 806         EVP_MD_CTX* ctx;
 807         const EVP_MD* md;
 808         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 809         const char* str = "Hello world";
 810         const unsigned char check[] = {
 811                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 812                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 813                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 814                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 815         };
 816         OPENSSL_config(NULL);
 817         (void)load_gost_id();
 818         md = EVP_get_digestbyname("md_gost94");
 819         if(!md) return 1;
 820         memset(digest, 0, sizeof(digest));
 821         ctx = EVP_MD_CTX_create();
 822         if(!ctx) return 2;
 823         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 824         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 825         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 826         /* uncomment to see the hash calculated.
 827                 {int i;
 828                 for(i=0; i<32; i++)
 829                         printf(" %2.2x", (int)digest[i]);
 830                 printf("\n");}
 831         */
 832         if(memcmp(digest, check, sizeof(check)) != 0)
 833                 return 6;
 834         return 0;
 835 }
 836 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 837 CFLAGS="$BAKCFLAGS"
 838 else
 839 eval "ac_cv_c_gost_works=maybe"
 840 fi
 841 AC_MSG_RESULT($ac_cv_c_gost_works)
 842 ])dnl
 843
 844 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 845 use_gost="no"
 846 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 847 case "$enable_gost" in
 848         no)
 849         ;;
 850         *)
 851         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 852         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 853         AC_CHECK_GOST_WORKS
 854         if test "$ac_cv_c_gost_works" != no; then
 855                 use_gost="yes"
 856                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 857         fi
 858         ;;
 859 esac
 860 fi dnl !USE_NSS && !USE_NETTLE
 861
 862 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 863 use_ecdsa="no"
 864 case "$enable_ecdsa" in
 865     no)
 866       ;;
 867     *)
 868       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 869               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 870               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 871               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 872 #include <openssl/evp.h>
 873               ])
 874               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 875               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 876               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 877                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 878                   AC_MSG_RESULT([no])
 879                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 880                 else
 881                   AC_MSG_RESULT([yes])
 882                 fi
 883               else
 884                 # not OpenSSL, thus likely LibreSSL, which supports it
 885                 AC_MSG_RESULT([yes])
 886               fi
 887       fi
 888       # we now know we have ECDSA and the required curves.
 889       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 890       use_ecdsa="yes"
 891       ;;
 892 esac
 893
 894 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 895 use_dsa="no"
 896 case "$enable_dsa" in
 897     no)
 898       ;;
 899     *)
 900       # detect if DSA is supported, and turn it off if not.
 901       AC_CHECK_FUNC(DSA_SIG_new, [
 902       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 903       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 904                fi ])
 905       ;;
 906 esac
 907
 908
 909 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
 910 case "$enable_event_api" in
 911     yes)
 912       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 913       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 914       ;;
 915     *)
 916       ;;
 917 esac
 918
 919 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
 920 case "$enable_tfo_client" in
 921         yes)
 922                 case `uname` in
 923                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 924                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 925                                              [AC_INCLUDES_DEFAULT
 926 #include <netinet/tcp.h>
 927 ])
 928                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 929                           ;;
 930                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 931                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 932                                               [AC_INCLUDES_DEFAULT
 933 #include <sys/socket.h>
 934 ])
 935                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 936                           ;;
 937                 esac
 938         ;;
 939         no|*)
 940                 ;;
 941 esac
 942
 943 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
 944 case "$enable_tfo_server" in
 945         yes)
 946               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
 947 #include <netinet/tcp.h>
 948               ])
 949                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
 950                 ;;
 951         no|*)
 952                 ;;
 953 esac
 954
 955 # check for libevent
 956 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
 957     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
 958     [ ],[ withval="no" ])
 959 if test x_$withval = x_yes -o x_$withval != x_no; then
 960         AC_MSG_CHECKING(for libevent)
 961         if test x_$withval = x_ -o x_$withval = x_yes; then
 962             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
 963         fi
 964         for dir in $withval; do
 965             thedir="$dir"
 966             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
 967                 found_libevent="yes"
 968                 dnl assume /usr is in default path.
 969                 if test "$thedir" != "/usr"; then
 970                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
 971                 fi
 972                 break;
 973             fi
 974         done
 975         if test x_$found_libevent != x_yes; then
 976                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
 977                         # libevent source directory
 978                         AC_MSG_RESULT(found in $thedir)
 979                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
 980                         BAK_LDFLAGS_SET="1"
 981                         BAK_LDFLAGS="$LDFLAGS"
 982                         # remove evdns from linking
 983                         mkdir build >/dev/null 2>&1
 984                         mkdir build/libevent >/dev/null 2>&1
 985                         mkdir build/libevent/.libs >/dev/null 2>&1
 986                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 987                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
 988                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 989                         cp $ev_files_o build/libevent
 990                         cp $ev_files_lo build/libevent
 991                         cp $ev_files_libso build/libevent/.libs
 992                         LATE_LDFLAGS="build/libevent/*.lo -lm"
 993                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
 994                 else
 995                         AC_MSG_ERROR([Cannot find the libevent library in $withval
 996 You can restart ./configure --with-libevent=no to use a builtin alternative.
 997 Please note that this alternative is not as capable as libevent when using
 998 large outgoing port ranges.  ])
 999                 fi
1000         else
1001             AC_MSG_RESULT(found in $thedir)
1002             dnl if event2 exists and no event lib in dir itself, use subdir
1003             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1004                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1005                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1006             else
1007                     dnl assume /usr is in default path, do not add "".
1008                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1009                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1010                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1011                     fi
1012             fi
1013         fi
1014         # check for library used by libevent after 1.3c
1015         AC_SEARCH_LIBS([clock_gettime], [rt])
1016
1017         # is the event.h header libev or libevent?
1018         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1019         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1020                 AC_SEARCH_LIBS(event_set, [ev])
1021         ],[
1022                 AC_SEARCH_LIBS(event_set, [event])
1023         ],[AC_INCLUDES_DEFAULT
1024 #include <event.h>
1025         ])
1026         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1027         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1028         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1029         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1030         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1031         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1032         PC_LIBEVENT_DEPENDENCY="libevent"
1033         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1034         if test -n "$BAK_LDFLAGS_SET"; then
1035                 LDFLAGS="$BAK_LDFLAGS"
1036         fi
1037 else
1038         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1039 fi
1040
1041 # check for libexpat
1042 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1043     [specify explicit path for libexpat.]),
1044     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1045 AC_MSG_CHECKING(for libexpat)
1046 found_libexpat="no"
1047 for dir in $withval ; do
1048             if test -f "$dir/include/expat.h"; then
1049                 found_libexpat="yes"
1050                 dnl assume /usr is in default path.
1051                 if test "$dir" != "/usr"; then
1052                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1053                     LDFLAGS="$LDFLAGS -L$dir/lib"
1054                 fi
1055                 AC_MSG_RESULT(found in $dir)
1056                 break;
1057             fi
1058 done
1059 if test x_$found_libexpat != x_yes; then
1060         AC_ERROR([Could not find libexpat, expat.h])
1061 fi
1062 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1063 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1064 #include <expat.h>
1065 ])
1066
1067 # set static linking if requested
1068 AC_SUBST(staticexe)
1069 staticexe=""
1070 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1071         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1072         , )
1073 if test x_$enable_static_exe = x_yes; then
1074         staticexe="-static"
1075         if test "$on_mingw" = yes; then
1076                 staticexe="-all-static"
1077                 # for static compile, include gdi32 and zlib here.
1078                 LIBS="$LIBS -lgdi32 -lz"
1079         fi
1080 fi
1081
1082 # Include systemd.m4 - begin
1083 sinclude(systemd.m4)
1084 # Include systemd.m4 - end
1085
1086 # set lock checking if requested
1087 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1088         [ enable to check lock and unlock calls, for debug purposes ]),
1089         , )
1090 if test x_$enable_lock_checks = x_yes; then
1091         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1092         CHECKLOCK_OBJ="checklocks.lo"
1093         AC_SUBST(CHECKLOCK_OBJ)
1094 fi
1095
1096 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1097 if test "$USE_WINSOCK" = 1; then
1098         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1099         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1100 #include <windows.h>
1101         ])
1102         AC_CHECK_TOOL(WINDRES, windres)
1103         LIBS="$LIBS -liphlpapi"
1104         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1105         AC_SUBST(WINAPPS)
1106         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1107         AC_SUBST(WIN_DAEMON_SRC)
1108         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1109         AC_SUBST(WIN_DAEMON_OBJ)
1110         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1111         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1112         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1113         AC_SUBST(WIN_HOST_OBJ_LINK)
1114         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1115         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1116         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1117         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1118         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1119         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1120 fi
1121 if test $ac_cv_func_getaddrinfo = no; then
1122         AC_LIBOBJ([fake-rfc2553])
1123 fi
1124 # check after getaddrinfo for its libraries
1125 ACX_FUNC_IOCTLSOCKET
1126
1127 # see if daemon(3) exists, and if it is deprecated.
1128 AC_CHECK_FUNCS([daemon])
1129 if test $ac_cv_func_daemon = yes; then
1130         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1131 #include <stdlib.h>
1132 ])
1133 fi
1134
1135 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1136 AC_INCLUDES_DEFAULT
1137 #ifdef HAVE_SYS_UN_H
1138 #include <sys/un.h>
1139 #endif
1140 ])
1141 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1142 AC_INCLUDES_DEFAULT
1143 #if HAVE_SYS_PARAM_H
1144 #include <sys/param.h>
1145 #endif
1146
1147 #ifdef HAVE_SYS_SOCKET_H
1148 #include <sys/socket.h>
1149 #endif
1150
1151 #ifdef HAVE_SYS_UIO_H
1152 #include <sys/uio.h>
1153 #endif
1154
1155 #ifdef HAVE_NETINET_IN_H
1156 #include <netinet/in.h>
1157 #endif
1158
1159 #ifdef HAVE_NETINET_TCP_H
1160 #include <netinet/tcp.h>
1161 #endif
1162
1163 #ifdef HAVE_ARPA_INET_H
1164 #include <arpa/inet.h>
1165 #endif
1166
1167 #ifdef HAVE_WINSOCK2_H
1168 #include <winsock2.h>
1169 #endif
1170
1171 #ifdef HAVE_WS2TCPIP_H
1172 #include <ws2tcpip.h>
1173 #endif
1174 ])
1175 AC_SEARCH_LIBS([setusercontext], [util])
1176 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget])
1177 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1178 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1179
1180 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1181 if echo $build_os | grep darwin8 > /dev/null; then
1182         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1183 fi
1184 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1185 AC_INCLUDES_DEFAULT
1186 #ifdef HAVE_NETINET_IN_H
1187 #include <netinet/in.h>
1188 #endif
1189
1190 #ifdef HAVE_NETINET_TCP_H
1191 #include <netinet/tcp.h>
1192 #endif
1193
1194 #ifdef HAVE_ARPA_INET_H
1195 #include <arpa/inet.h>
1196 #endif
1197
1198 #ifdef HAVE_WINSOCK2_H
1199 #include <winsock2.h>
1200 #endif
1201
1202 #ifdef HAVE_WS2TCPIP_H
1203 #include <ws2tcpip.h>
1204 #endif
1205 ])
1206 AC_REPLACE_FUNCS(inet_aton)
1207 AC_REPLACE_FUNCS(inet_pton)
1208 AC_REPLACE_FUNCS(inet_ntop)
1209 AC_REPLACE_FUNCS(snprintf)
1210 # test if snprintf return the proper length
1211 if test "x$ac_cv_func_snprintf" = xyes; then
1212     if test c${cross_compiling} = cno; then
1213         AC_MSG_CHECKING([for correct snprintf return value])
1214         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1215 [[
1216 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1217 ]])], [AC_MSG_RESULT(yes)], [
1218                 AC_MSG_RESULT(no)
1219                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1220                 AC_LIBOBJ(snprintf)
1221           ])
1222     fi
1223 fi
1224 AC_REPLACE_FUNCS(strlcat)
1225 AC_REPLACE_FUNCS(strlcpy)
1226 AC_REPLACE_FUNCS(memmove)
1227 AC_REPLACE_FUNCS(gmtime_r)
1228 AC_REPLACE_FUNCS(isblank)
1229 dnl without CTIME, ARC4-functions and without reallocarray.
1230 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1231 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1232 AC_REPLACE_FUNCS(reallocarray)
1233 if test "$USE_NSS" = "no"; then
1234         AC_REPLACE_FUNCS(arc4random)
1235         AC_REPLACE_FUNCS(arc4random_uniform)
1236         if test "$ac_cv_func_arc4random" = "no"; then
1237                 AC_LIBOBJ(explicit_bzero)
1238                 AC_LIBOBJ(arc4_lock)
1239                 AC_CHECK_FUNCS([getentropy],,[
1240                     if test "$USE_WINSOCK" = 1; then
1241                         AC_LIBOBJ(getentropy_win)
1242                     else
1243                         case "$host" in
1244                         Darwin|*darwin*)
1245                                 AC_LIBOBJ(getentropy_osx)
1246                         ;;
1247                         *solaris*|*sunos*|SunOS)
1248                                 AC_LIBOBJ(getentropy_solaris)
1249                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1250                                         AC_CHECK_FUNCS([SHA512_Update],,[
1251                                                 AC_LIBOBJ(sha512)
1252                                         ])
1253                                 ], [AC_INCLUDES_DEFAULT])
1254                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1255                                         # this lib needed for sha2 on solaris
1256                                         LIBS="$LIBS -lmd"
1257                                 fi
1258                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1259                         ;;
1260                         *linux*|Linux|*)
1261                                 AC_LIBOBJ(getentropy_linux)
1262                                 AC_CHECK_FUNCS([SHA512_Update],,[
1263                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1264                                         AC_LIBOBJ(sha512)
1265                                 ])
1266                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1267                                 AC_CHECK_FUNCS([getauxval])
1268                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1269                         ;;
1270                         esac
1271                     fi
1272                 ])
1273         fi
1274 fi
1275 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1276 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1277 AC_REPLACE_FUNCS(ctime_r)
1278 AC_REPLACE_FUNCS(strsep)
1279
1280 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1281 case "$enable_allsymbols" in
1282         yes)
1283         COMMON_OBJ_ALL_SYMBOLS=""
1284         UBSYMS=""
1285         EXTRALINK="-L. -L.libs -lunbound"
1286         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1287         ;;
1288         no|*)
1289         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1290         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1291         EXTRALINK=""
1292         ;;
1293 esac
1294 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1295 AC_SUBST(EXTRALINK)
1296 AC_SUBST(UBSYMS)
1297 if test x_$enable_lock_checks = x_yes; then
1298         UBSYMS="-export-symbols clubsyms.def"
1299         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1300         echo lock_protect >> clubsyms.def
1301         echo lock_unprotect >> clubsyms.def
1302         echo lock_get_mem >> clubsyms.def
1303         echo checklock_start >> clubsyms.def
1304         echo checklock_stop >> clubsyms.def
1305         echo checklock_lock >> clubsyms.def
1306         echo checklock_unlock >> clubsyms.def
1307         echo checklock_init >> clubsyms.def
1308         echo checklock_thrcreate >> clubsyms.def
1309         echo checklock_thrjoin >> clubsyms.def
1310 fi
1311
1312 # check for dnstap if requested
1313 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1314     [
1315         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1316         AC_SUBST([ENABLE_DNSTAP], [1])
1317
1318         AC_SUBST([opt_dnstap_socket_path])
1319         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1320         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1321             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1322
1323         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1324         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1325     ],
1326     [
1327         AC_SUBST([ENABLE_DNSTAP], [0])
1328     ]
1329 )
1330
1331 # check for dnscrypt if requested
1332 dnsc_DNSCRYPT([
1333         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1334         AC_SUBST([ENABLE_DNSCRYPT], [1])
1335
1336         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1337         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1338     ],
1339     [
1340         AC_SUBST([ENABLE_DNSCRYPT], [0])
1341     ]
1342 )
1343
1344 # check for cachedb if requested
1345 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1346 case "$enable_cachedb" in
1347     yes)
1348         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1349         ;;
1350     no|*)
1351         # nothing
1352         ;;
1353 esac
1354
1355 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1356 # on openBSD, the implicit rule make $< work.
1357 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1358 # gmake works.
1359 cat >conftest.make <<EOF
1360 all:    conftest.lo
1361
1362 conftest.lo foo.lo bla.lo:
1363         if test -f "\$<"; then touch \$@; fi
1364
1365 .SUFFIXES: .lo
1366 .c.lo:
1367         if test -f "\$<"; then touch \$@; fi
1368
1369 conftest.lo:        conftest.dir/conftest.c
1370 EOF
1371 mkdir conftest.dir
1372 touch conftest.dir/conftest.c
1373 rm -f conftest.lo conftest.c
1374 ${MAKE:-make} -f conftest.make >/dev/null
1375 rm -f conftest.make conftest.c conftest.dir/conftest.c
1376 rm -rf conftest.dir
1377 if test ! -f conftest.lo; then
1378         AC_MSG_RESULT(no)
1379         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1380         SOURCEFILE='`cat .source`'
1381 else
1382         AC_MSG_RESULT(yes)
1383         SOURCEDETERMINE=':'
1384         SOURCEFILE='$<'
1385 fi
1386 rm -f conftest.lo
1387 AC_SUBST(SOURCEDETERMINE)
1388 AC_SUBST(SOURCEFILE)
1389
1390 # see if we want to build the library or everything
1391 ALLTARGET="alltargets"
1392 INSTALLTARGET="install-all"
1393 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1394         [do not build daemon and tool programs]),
1395         [
1396         if test "$withval" = "yes"; then
1397                 ALLTARGET="lib"
1398                 INSTALLTARGET="install-lib"
1399         fi
1400 ])
1401 AC_SUBST(ALLTARGET)
1402 AC_SUBST(INSTALLTARGET)
1403
1404 ACX_STRIP_EXT_FLAGS
1405 LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1406
1407 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1408
1409 AH_BOTTOM(
1410 dnl this must be first AH_CONFIG, to define the flags before any includes.
1411 AHX_CONFIG_EXT_FLAGS
1412
1413 dnl includes
1414 [
1415 #ifndef UNBOUND_DEBUG
1416 #  define NDEBUG
1417 #endif
1418
1419 /** Use small-ldns codebase */
1420 #define USE_SLDNS 1
1421 #ifdef HAVE_SSL
1422 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1423 #endif
1424
1425 #include <stdio.h>
1426 #include <string.h>
1427 #include <unistd.h>
1428 #include <assert.h>
1429
1430 #if STDC_HEADERS
1431 #include <stdlib.h>
1432 #include <stddef.h>
1433 #endif
1434
1435 #ifdef HAVE_STDARG_H
1436 #include <stdarg.h>
1437 #endif
1438
1439 #ifdef HAVE_STDINT_H
1440 #include <stdint.h>
1441 #endif
1442
1443 #include <errno.h>
1444
1445 #if HAVE_SYS_PARAM_H
1446 #include <sys/param.h>
1447 #endif
1448
1449 #ifdef HAVE_SYS_SOCKET_H
1450 #include <sys/socket.h>
1451 #endif
1452
1453 #ifdef HAVE_SYS_UIO_H
1454 #include <sys/uio.h>
1455 #endif
1456
1457 #ifdef HAVE_NETINET_IN_H
1458 #include <netinet/in.h>
1459 #endif
1460
1461 #ifdef HAVE_NETINET_TCP_H
1462 #include <netinet/tcp.h>
1463 #endif
1464
1465 #ifdef HAVE_ARPA_INET_H
1466 #include <arpa/inet.h>
1467 #endif
1468
1469 #ifdef HAVE_WINSOCK2_H
1470 #include <winsock2.h>
1471 #endif
1472
1473 #ifdef HAVE_WS2TCPIP_H
1474 #include <ws2tcpip.h>
1475 #endif
1476
1477 #ifndef USE_WINSOCK
1478 #define ARG_LL "%ll"
1479 #else
1480 #define ARG_LL "%I64"
1481 #endif
1482
1483 #ifndef AF_LOCAL
1484 #define AF_LOCAL AF_UNIX
1485 #endif
1486 ]
1487
1488 AHX_CONFIG_FORMAT_ATTRIBUTE
1489 AHX_CONFIG_UNUSED_ATTRIBUTE
1490 AHX_CONFIG_FSEEKO
1491 AHX_CONFIG_MAXHOSTNAMELEN
1492 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1493 #define snprintf snprintf_unbound
1494 #define vsnprintf vsnprintf_unbound
1495 #include <stdarg.h>
1496 int snprintf (char *str, size_t count, const char *fmt, ...);
1497 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1498 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1499 AHX_CONFIG_INET_PTON(unbound)
1500 AHX_CONFIG_INET_NTOP(unbound)
1501 AHX_CONFIG_INET_ATON(unbound)
1502 AHX_CONFIG_MEMMOVE(unbound)
1503 AHX_CONFIG_STRLCAT(unbound)
1504 AHX_CONFIG_STRLCPY(unbound)
1505 AHX_CONFIG_GMTIME_R(unbound)
1506 AHX_CONFIG_REALLOCARRAY(unbound)
1507 AHX_CONFIG_W32_SLEEP
1508 AHX_CONFIG_W32_USLEEP
1509 AHX_CONFIG_W32_RANDOM
1510 AHX_CONFIG_W32_SRANDOM
1511 AHX_CONFIG_W32_FD_SET_T
1512 AHX_CONFIG_IPV6_MIN_MTU
1513 AHX_MEMCMP_BROKEN(unbound)
1514
1515 [
1516 #ifndef HAVE_CTIME_R
1517 #define ctime_r unbound_ctime_r
1518 char *ctime_r(const time_t *timep, char *buf);
1519 #endif
1520
1521 #ifndef HAVE_STRSEP
1522 #define strsep unbound_strsep
1523 char *strsep(char **stringp, const char *delim);
1524 #endif
1525
1526 #ifndef HAVE_ISBLANK
1527 #define isblank unbound_isblank
1528 int isblank(int c);
1529 #endif
1530
1531 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1532 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1533 #endif
1534
1535 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1536 int inet_pton(int af, const char* src, void* dst);
1537 #endif
1538
1539 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1540 #define strptime unbound_strptime
1541 struct tm;
1542 char *strptime(const char *s, const char *format, struct tm *tm);
1543 #endif
1544
1545 #ifdef HAVE_LIBRESSL
1546 #  if !HAVE_DECL_STRLCPY
1547 size_t strlcpy(char *dst, const char *src, size_t siz);
1548 #  endif
1549 #  if !HAVE_DECL_STRLCAT
1550 size_t strlcat(char *dst, const char *src, size_t siz);
1551 #  endif
1552 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1553 uint32_t arc4random(void);
1554 #  endif
1555 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1556 uint32_t arc4random_uniform(uint32_t upper_bound);
1557 #  endif
1558 #  if !HAVE_DECL_REALLOCARRAY
1559 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1560 #  endif
1561 #endif /* HAVE_LIBRESSL */
1562 #ifndef HAVE_ARC4RANDOM
1563 void explicit_bzero(void* buf, size_t len);
1564 int getentropy(void* buf, size_t len);
1565 uint32_t arc4random(void);
1566 void arc4random_buf(void* buf, size_t n);
1567 void _ARC4_LOCK(void);
1568 void _ARC4_UNLOCK(void);
1569 #endif
1570 #ifndef HAVE_ARC4RANDOM_UNIFORM
1571 uint32_t arc4random_uniform(uint32_t upper_bound);
1572 #endif
1573 #ifdef COMPAT_SHA512
1574 #ifndef SHA512_DIGEST_LENGTH
1575 #define SHA512_BLOCK_LENGTH             128
1576 #define SHA512_DIGEST_LENGTH            64
1577 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1578 typedef struct _SHA512_CTX {
1579         uint64_t        state[8];
1580         uint64_t        bitcount[2];
1581         uint8_t buffer[SHA512_BLOCK_LENGTH];
1582 } SHA512_CTX;
1583 #endif /* SHA512_DIGEST_LENGTH */
1584 void SHA512_Init(SHA512_CTX*);
1585 void SHA512_Update(SHA512_CTX*, void*, size_t);
1586 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1587 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1588 #endif /* COMPAT_SHA512 */
1589
1590
1591
1592 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1593    /* using version of libevent that is not threadsafe. */
1594 #  define LIBEVENT_SIGNAL_PROBLEM 1
1595 #endif
1596
1597 #ifndef CHECKED_INET6
1598 #  define CHECKED_INET6
1599 #  ifdef AF_INET6
1600 #    define INET6
1601 #  else
1602 #    define AF_INET6        28
1603 #  endif
1604 #endif /* CHECKED_INET6 */
1605
1606 #ifndef HAVE_GETADDRINFO
1607 struct sockaddr_storage;
1608 #include "compat/fake-rfc2553.h"
1609 #endif
1610
1611 #ifdef UNBOUND_ALLOC_STATS
1612 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1613 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1614 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1615 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1616 void *unbound_stat_malloc(size_t size);
1617 void *unbound_stat_calloc(size_t nmemb, size_t size);
1618 void unbound_stat_free(void *ptr);
1619 void *unbound_stat_realloc(void *ptr, size_t size);
1620 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1621         const char* func);
1622 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1623         int line, const char* func);
1624 void unbound_stat_free_log(void *ptr, const char* file, int line,
1625         const char* func);
1626 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1627         int line, const char* func);
1628 #elif defined(UNBOUND_ALLOC_LITE)
1629 #  include "util/alloc.h"
1630 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1631
1632 /** default port for DNS traffic. */
1633 #define UNBOUND_DNS_PORT 53
1634 /** default port for unbound control traffic, registered port with IANA,
1635     ub-dns-control  8953/tcp    unbound dns nameserver control */
1636 #define UNBOUND_CONTROL_PORT 8953
1637 /** the version of unbound-control that this software implements */
1638 #define UNBOUND_CONTROL_VERSION 1
1639
1640 ])
1641
1642 dnl if we build from source tree, the man pages need @date@ and @version@
1643 dnl if this is a distro tarball, that was already done by makedist.sh
1644 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1645 AC_SUBST(date, [`date +'%b %e, %Y'`])
1646
1647 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1648 AC_CONFIG_HEADER([config.h])
1649 AC_OUTPUT