configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8
   9 # must be numbers. ac_defun because of later processing
  10 m4_define([VERSION_MAJOR],[1])
  11 m4_define([VERSION_MINOR],[4])
  12 m4_define([VERSION_MICRO],[22])
  13 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  14 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  15 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  16 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  17
  18 LIBUNBOUND_CURRENT=4
  19 LIBUNBOUND_REVISION=1
  20 LIBUNBOUND_AGE=2
  21 # 1.0.0 had 0:12:0
  22 # 1.0.1 had 0:13:0
  23 # 1.0.2 had 0:14:0
  24 # 1.1.0 had 0:15:0
  25 # 1.1.1 had 0:16:0
  26 # 1.2.0 had 0:17:0
  27 # 1.2.1 had 0:18:0
  28 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  29 # 1.3.1 had 1:1:0
  30 # 1.3.2 had 1:2:0
  31 # 1.3.3 had 1:3:0
  32 # 1.3.4 had 1:4:0
  33 # 1.4.0-snapshots had 1:5:0
  34 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  35 # 1.4.1 had 2:1:0
  36 # 1.4.2 had 2:2:0
  37 # 1.4.3 had 2:3:0
  38 # 1.4.4 had 2:4:0
  39 # 1.4.5 had 2:5:0
  40 # 1.4.6 had 2:6:0
  41 # 1.4.7 had 2:7:0
  42 # 1.4.8 had 2:8:0
  43 # 1.4.9 had 2:9:0
  44 # 1.4.10 had 2:10:0
  45 # 1.4.11 had 2:11:0
  46 # 1.4.12 had 2:12:0
  47 # 1.4.13 had 2:13:0
  48 # and 1.4.13p1 and 1.4.13.p2
  49 # 1.4.14 had 2:14:0
  50 # 1.4.15 had 3:0:1 # adds ub_version()
  51 # 1.4.16 had 3:1:1
  52 # 1.4.17 had 3:2:1
  53 # 1.4.18 had 3:3:1
  54 # 1.4.19 had 3:4:1
  55 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  56 # 1.4.21 had 4:1:2
  57
  58 #   Current  -- the number of the binary API that we're implementing
  59 #   Revision -- which iteration of the implementation of the binary
  60 #               API are we supplying?
  61 #   Age      -- How many previous binary API versions do we also
  62 #               support?
  63 #
  64 # If we release a new version that does not change the binary API,
  65 # increment Revision.
  66 #
  67 # If we release a new version that changes the binary API, but does
  68 # not break programs compiled against the old binary API, increment
  69 # Current and Age.  Set Revision to 0, since this is the first
  70 # implementation of the new API.
  71 #
  72 # Otherwise, we're changing the binary API and breaking bakward
  73 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  74 # since we're backward compatible with no previous APIs.  Set Revision
  75 # to 0 too.
  76 AC_SUBST(LIBUNBOUND_CURRENT)
  77 AC_SUBST(LIBUNBOUND_REVISION)
  78 AC_SUBST(LIBUNBOUND_AGE)
  79
  80 pretty_cmdline() {
  81         cmdline=""
  82         while test -n "$1"; do
  83                 cmdline="$cmdline '"`echo $1 | sed -e 's/\\\\/\\\\\\\\/g' | sed -e 's/"/\\\\"/g' `"'"
  84                 shift
  85         done
  86 }
  87 pretty_cmdline $@
  88 AC_DEFINE_UNQUOTED(CONFIGURE_BUILD_WITH, ["$cmdline"], [configure flags])
  89 AC_CANONICAL_TARGET
  90 AC_DEFINE_UNQUOTED(CONFIGURE_TARGET, ["$target"], [configure target system])
  91 AC_DEFINE_UNQUOTED(CONFIGURE_DATE, ["`date`"], [configure date])
  92
  93 CFLAGS="$CFLAGS"
  94 AC_AIX
  95 if test "$ac_cv_header_minix_config_h" = "yes"; then
  96         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
  97 fi
  98
  99 dnl
 100 dnl By default set prefix to /usr/local
 101 dnl
 102 case "$prefix" in
 103         NONE)
 104                 prefix="/usr/local"
 105         ;;
 106 esac
 107
 108 # are we on MinGW?
 109 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 110 else
 111         if echo $target | grep mingw32 >/dev/null; then on_mingw="yes"
 112         else on_mingw="no"; fi
 113 fi
 114
 115 #
 116 # Determine configuration file
 117 # the eval is to evaluate shell expansion twice
 118 if test $on_mingw = "no"; then
 119   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 120 else
 121   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 122 fi
 123 AC_ARG_WITH([conf_file],
 124         AC_HELP_STRING([--with-conf-file=path],
 125         [Pathname to the Unbound configuration file]),
 126         [ub_conf_file="$withval"])
 127 AC_SUBST(ub_conf_file)
 128 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 129 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 130
 131 # Determine run, chroot directory and pidfile locations
 132 AC_ARG_WITH(run-dir,
 133     AC_HELP_STRING([--with-run-dir=path],
 134     [set default directory to chdir to (by default dir part of cfg file)]),
 135     UNBOUND_RUN_DIR="$withval",
 136 if test $on_mingw = no; then
 137     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 138 else
 139     UNBOUND_RUN_DIR=""
 140 fi
 141 )
 142 AC_SUBST(UNBOUND_RUN_DIR)
 143 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 144 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 145
 146 AC_ARG_WITH(chroot-dir,
 147     AC_HELP_STRING([--with-chroot-dir=path],
 148     [set default directory to chroot to (by default same as run-dir)]),
 149     UNBOUND_CHROOT_DIR="$withval",
 150 if test $on_mingw = no; then
 151     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 152 else
 153     UNBOUND_CHROOT_DIR=""
 154 fi
 155 )
 156 AC_SUBST(UNBOUND_CHROOT_DIR)
 157 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 158 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 159
 160 AC_ARG_WITH(share-dir,
 161     AC_HELP_STRING([--with-share-dir=path],
 162     [set default directory with shared data (by default same as share/unbound)]),
 163     UNBOUND_SHARE_DIR="$withval",
 164     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 165 AC_SUBST(UNBOUND_SHARE_DIR)
 166 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 167
 168 AC_ARG_WITH(pidfile,
 169     AC_HELP_STRING([--with-pidfile=filename],
 170     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 171     UNBOUND_PIDFILE="$withval",
 172 if test $on_mingw = no; then
 173     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 174 else
 175     UNBOUND_PIDFILE=""
 176 fi
 177 )
 178 AC_SUBST(UNBOUND_PIDFILE)
 179 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 180 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 181
 182 AC_ARG_WITH(rootkey-file,
 183     AC_HELP_STRING([--with-rootkey-file=filename],
 184     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 185     UNBOUND_ROOTKEY_FILE="$withval",
 186 if test $on_mingw = no; then
 187     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 188 else
 189     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 190 fi
 191 )
 192 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 193 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 194 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 195
 196 AC_ARG_WITH(rootcert-file,
 197     AC_HELP_STRING([--with-rootcert-file=filename],
 198     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 199     UNBOUND_ROOTCERT_FILE="$withval",
 200 if test $on_mingw = no; then
 201     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 202 else
 203     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 204 fi
 205 )
 206 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 207 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 208 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 209
 210 AC_ARG_WITH(username,
 211     AC_HELP_STRING([--with-username=user],
 212     [set default user that unbound changes to (default user is unbound)]),
 213     UNBOUND_USERNAME="$withval",
 214     UNBOUND_USERNAME="unbound")
 215 AC_SUBST(UNBOUND_USERNAME)
 216 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 217
 218 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 219 ACX_RSRC_VERSION(wnvs)
 220 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 221
 222 # Checks for typedefs, structures, and compiler characteristics.
 223 AC_C_CONST
 224 AC_LANG_C
 225 # allow user to override the -g -O2 flags.
 226 if test "x$CFLAGS" = "x" ; then
 227 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 228 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 229 fi
 230 AC_PROG_CC
 231 ACX_DEPFLAG
 232 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 233
 234 # debug mode flags warnings
 235 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 236 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 237 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 238 else debug_enabled="$enable_checking"; fi
 239 AC_SUBST(debug_enabled)
 240 case "$debug_enabled" in
 241         yes)
 242                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 243                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 244                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 245                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 246                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 247                 ;;
 248         no|*)
 249                 # nothing to do.
 250                 ;;
 251 esac
 252 ACX_CHECK_FLTO
 253
 254 AC_C_INLINE
 255 ACX_CHECK_FORMAT_ATTRIBUTE
 256 ACX_CHECK_UNUSED_ATTRIBUTE
 257
 258 if test "$srcdir" != "."; then
 259         CPPFLAGS="$CPPFLAGS -I$srcdir"
 260 fi
 261
 262 AC_DEFUN([ACX_YYLEX_DESTROY], [
 263         AC_MSG_CHECKING([for yylex_destroy])
 264         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 265                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 266                 AC_MSG_RESULT(yes)
 267         else AC_MSG_RESULT(no); fi
 268 ])
 269
 270 AC_PROG_LEX
 271 ACX_YYLEX_DESTROY
 272 AC_PROG_YACC
 273 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 274 AC_CHECK_TOOL(STRIP, strip)
 275 ACX_LIBTOOL_C_ONLY
 276
 277 # Checks for header files.
 278 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h sys/param.h sys/socket.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h],,, [AC_INCLUDES_DEFAULT])
 279
 280 # check for types.
 281 # Using own tests for int64* because autoconf builtin only give 32bit.
 282 AC_CHECK_TYPE(int8_t, signed char)
 283 AC_CHECK_TYPE(int16_t, short)
 284 AC_CHECK_TYPE(int32_t, int)
 285 AC_CHECK_TYPE(int64_t, long long)
 286 AC_CHECK_TYPE(uint8_t, unsigned char)
 287 AC_CHECK_TYPE(uint16_t, unsigned short)
 288 AC_CHECK_TYPE(uint32_t, unsigned int)
 289 AC_CHECK_TYPE(uint64_t, unsigned long long)
 290 AC_TYPE_SIZE_T
 291 AC_CHECK_TYPE(ssize_t, int)
 292 AC_TYPE_UID_T
 293 AC_TYPE_PID_T
 294 AC_TYPE_OFF_T
 295 ACX_TYPE_U_CHAR
 296 ACX_TYPE_RLIM_T
 297 ACX_TYPE_SOCKLEN_T
 298 ACX_TYPE_IN_ADDR_T
 299 ACX_TYPE_IN_PORT_T
 300 ACX_CHECK_MEMCMP_SIGNED
 301
 302 AC_CHECK_SIZEOF(time_t,,[
 303 AC_INCLUDES_DEFAULT
 304 #ifdef TIME_WITH_SYS_TIME
 305 # include <sys/time.h>
 306 # include <time.h>
 307 #else
 308 # ifdef HAVE_SYS_TIME_H
 309 #  include <sys/time.h>
 310 # else
 311 #  include <time.h>
 312 # endif
 313 #endif
 314 ])
 315
 316 # add option to disable the evil rpath
 317 ACX_ARG_RPATH
 318 AC_SUBST(RUNTIME_PATH)
 319
 320 # check to see if libraries are needed for these functions.
 321 AC_SEARCH_LIBS([inet_pton], [nsl])
 322 AC_SEARCH_LIBS([socket], [socket])
 323
 324 # check wether strptime also works
 325 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 326 [AC_REQUIRE([AC_PROG_CC])
 327 AC_MSG_CHECKING(whether strptime works)
 328 if test c${cross_compiling} = cno; then
 329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 330 #define _XOPEN_SOURCE
 331 #include <time.h>
 332 int main(void) { struct tm tm; char *res;
 333 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 334 if (!res) return 2;
 335 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 336 if (!res) return 1; return 0; }
 337 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 338 else
 339 eval "ac_cv_c_strptime_works=maybe"
 340 fi
 341 AC_MSG_RESULT($ac_cv_c_strptime_works)
 342 if test $ac_cv_c_strptime_works = no; then
 343 AC_LIBOBJ(strptime)
 344 else
 345 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 346 fi
 347 ])dnl
 348
 349 # check some functions of the OS before linking libs (while still runnable).
 350 AC_FUNC_CHOWN
 351 AC_FUNC_FORK
 352 AC_TYPE_SIGNAL
 353 AC_FUNC_FSEEKO
 354 ACX_SYS_LARGEFILE
 355 ACX_CHECK_NONBLOCKING_BROKEN
 356 ACX_MKDIR_ONE_ARG
 357 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 358
 359 # set memory allocation checking if requested
 360 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 361         [ enable to memory allocation statistics, for debug purposes ]),
 362         , )
 363 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 364         [ enable for lightweight alloc assertions, for debug purposes ]),
 365         , )
 366 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 367         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 368         , )
 369 if test x_$enable_alloc_nonregional = x_yes; then
 370         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 371 fi
 372 if test x_$enable_alloc_checks = x_yes; then
 373         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 374 else
 375         if test x_$enable_alloc_lite = x_yes; then
 376                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 377         else
 378                 ACX_FUNC_MALLOC([unbound])
 379         fi
 380 fi
 381
 382 # check windows threads (we use them, not pthreads, on windows).
 383 if test "$on_mingw" = "yes"; then
 384 # check windows threads
 385         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 386         AC_MSG_CHECKING([for CreateThread])
 387         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 388 #ifdef HAVE_WINDOWS_H
 389 #include <windows.h>
 390 #endif
 391 ], [
 392         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 393 ])],
 394         AC_MSG_RESULT(yes)
 395         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 396 ,
 397         AC_MSG_RESULT(no)
 398 )
 399
 400 else
 401 # not on mingw, check thread libraries.
 402
 403 # check for thread library.
 404 # check this first, so that the pthread lib does not get linked in via
 405 # libssl or libpython, and thus distorts the tests, and we end up using
 406 # the non-threadsafe C libraries.
 407 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 408  [use pthreads library, or --without-pthreads to disable threading support.]),
 409  [ ],[ withval="yes" ])
 410 ub_have_pthreads=no
 411 if test x_$withval != x_no; then
 412         AX_PTHREAD([
 413                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 414                 LIBS="$PTHREAD_LIBS $LIBS"
 415                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 416                 CC="$PTHREAD_CC"
 417                 ub_have_pthreads=yes
 418                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 419                 ])
 420 fi
 421
 422 # check solaris thread library
 423 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 424         [use solaris native thread library.]), [ ],[ withval="no" ])
 425 ub_have_sol_threads=no
 426 if test x_$withval != x_no; then
 427         if test x_$ub_have_pthreads != x_no; then
 428             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 429         else
 430         AC_SEARCH_LIBS(thr_create, [thread],
 431         [
 432                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 433
 434                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 435                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 436                 ub_have_sol_threads=yes
 437         ] , [
 438                 AC_ERROR([no solaris threads found.])
 439         ])
 440         fi
 441 fi
 442
 443 fi # end of non-mingw check of thread libraries
 444
 445 # Check for PyUnbound
 446 AC_ARG_WITH(pyunbound,
 447    AC_HELP_STRING([--with-pyunbound],
 448    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 449    [], [ withval="no" ])
 450
 451 ub_test_python=no
 452 ub_with_pyunbound=no
 453 if test x_$withval != x_no; then
 454    ub_with_pyunbound=yes
 455    ub_test_python=yes
 456 fi
 457
 458 # Check for Python module
 459 AC_ARG_WITH(pythonmodule,
 460    AC_HELP_STRING([--with-pythonmodule],
 461    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 462    [], [ withval="no" ])
 463
 464 ub_with_pythonmod=no
 465 if test x_$withval != x_no; then
 466    ub_with_pythonmod=yes
 467    ub_test_python=yes
 468 fi
 469
 470 # Check for Python & SWIG only on PyUnbound or PyModule
 471 if test x_$ub_test_python != x_no; then
 472
 473    # Check for Python
 474    ub_have_python=no
 475    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 476    AC_PYTHON_DEVEL
 477    if test ! -z "$PYTHON_VERSION"; then
 478         if test `$PYTHON -c "print '$PYTHON_VERSION' >= '2.4.0'"` = "False"; then
 479                 AC_ERROR([Python version >= 2.4.0 is required])
 480         fi
 481
 482       # Have Python
 483       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 484       LIBS="$PYTHON_LDFLAGS $LIBS"
 485       CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 486       ub_have_python=yes
 487
 488       # Check for SWIG
 489       ub_have_swig=no
 490       AC_PROG_SWIG
 491       AC_MSG_CHECKING(SWIG)
 492       if test ! -x "$SWIG"; then
 493          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 494       else
 495          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 496          AC_SUBST(swig, "$SWIG")
 497          AC_MSG_RESULT(present)
 498
 499          # If have Python & SWIG
 500          # Declare PythonMod
 501          if test x_$ub_with_pythonmod != x_no; then
 502             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 503             WITH_PYTHONMODULE=yes
 504             AC_SUBST(WITH_PYTHONMODULE)
 505             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 506             AC_SUBST(PYTHONMOD_OBJ)
 507             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 508             AC_SUBST(PYTHONMOD_HEADER)
 509             PYTHONMOD_INSTALL=pythonmod-install
 510             AC_SUBST(PYTHONMOD_INSTALL)
 511             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 512             AC_SUBST(PYTHONMOD_UNINSTALL)
 513          fi
 514
 515          # Declare PyUnbound
 516          if test x_$ub_with_pyunbound != x_no; then
 517             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 518             WITH_PYUNBOUND=yes
 519             AC_SUBST(WITH_PYUNBOUND)
 520             PYUNBOUND_OBJ="libunbound_wrap.lo"
 521             AC_SUBST(PYUNBOUND_OBJ)
 522             PYUNBOUND_TARGET="_unbound.la"
 523             AC_SUBST(PYUNBOUND_TARGET)
 524             PYUNBOUND_INSTALL=pyunbound-install
 525             AC_SUBST(PYUNBOUND_INSTALL)
 526             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 527             AC_SUBST(PYUNBOUND_UNINSTALL)
 528          fi
 529       fi
 530    else
 531       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 532       ub_with_pyunbound=no
 533       ub_with_pythonmod=no
 534    fi
 535 fi
 536
 537 if test "`uname`" = "NetBSD"; then
 538         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 539         AC_SUBST(NETBSD_LINTFLAGS)
 540 fi
 541 CONFIG_DATE=`date +%Y%m%d`
 542 AC_SUBST(CONFIG_DATE)
 543
 544 # Checks for libraries.
 545
 546 # libnss
 547 USE_NSS="no"
 548 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 549         [use libnss instead of openssl, installed at path.]),
 550         [
 551         USE_NSS="yes"
 552         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 553         if test "$withval" != "" -a "$withval" != "yes"; then
 554                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 555                 LDFLAGS="$LDFLAGS -L$withval/lib"
 556                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 557                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 558         else
 559                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 560                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 561         fi
 562         LIBS="$LIBS -lnss3 -lnspr4"
 563         ]
 564 )
 565
 566 # openssl
 567 if test $USE_NSS = "no"; then
 568 ACX_WITH_SSL
 569 ACX_LIB_SSL
 570 AC_CHECK_HEADERS([openssl/conf.h],,, [AC_INCLUDES_DEFAULT])
 571 AC_CHECK_HEADERS([openssl/engine.h],,, [AC_INCLUDES_DEFAULT])
 572 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode])
 573 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free], [], [], [
 574 AC_INCLUDES_DEFAULT
 575 #ifdef HAVE_OPENSSL_ERR_H
 576 #include <openssl/err.h>
 577 #endif
 578
 579 #ifdef HAVE_OPENSSL_RAND_H
 580 #include <openssl/rand.h>
 581 #endif
 582
 583 #ifdef HAVE_OPENSSL_CONF_H
 584 #include <openssl/conf.h>
 585 #endif
 586
 587 #ifdef HAVE_OPENSSL_ENGINE_H
 588 #include <openssl/engine.h>
 589 #endif
 590 #include <openssl/ssl.h>
 591 #include <openssl/evp.h>
 592 ])
 593 fi
 594
 595
 596 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 597 case "$enable_sha2" in
 598         no)
 599         ;;
 600         yes|*)
 601         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 602         ;;
 603 esac
 604
 605 # check wether gost also works
 606 AC_DEFUN([AC_CHECK_GOST_WORKS],
 607 [AC_REQUIRE([AC_PROG_CC])
 608 AC_MSG_CHECKING([if GOST works])
 609 if test c${cross_compiling} = cno; then
 610 BAKCFLAGS="$CFLAGS"
 611 if test -n "$ssldir"; then
 612         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 613 fi
 614 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 615 #include <string.h>
 616 #include <openssl/ssl.h>
 617 #include <openssl/evp.h>
 618 #include <openssl/engine.h>
 619 #include <openssl/conf.h>
 620 /* routine to load gost (from sldns) */
 621 int load_gost_id(void)
 622 {
 623         static int gost_id = 0;
 624         const EVP_PKEY_ASN1_METHOD* meth;
 625         ENGINE* e;
 626
 627         if(gost_id) return gost_id;
 628
 629         /* see if configuration loaded gost implementation from other engine*/
 630         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 631         if(meth) {
 632                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 633                 return gost_id;
 634         }
 635
 636         /* see if engine can be loaded already */
 637         e = ENGINE_by_id("gost");
 638         if(!e) {
 639                 /* load it ourself, in case statically linked */
 640                 ENGINE_load_builtin_engines();
 641                 ENGINE_load_dynamic();
 642                 e = ENGINE_by_id("gost");
 643         }
 644         if(!e) {
 645                 /* no gost engine in openssl */
 646                 return 0;
 647         }
 648         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 649                 ENGINE_finish(e);
 650                 ENGINE_free(e);
 651                 return 0;
 652         }
 653
 654         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 655         if(!meth) {
 656                 /* algo not found */
 657                 ENGINE_finish(e);
 658                 ENGINE_free(e);
 659                 return 0;
 660         }
 661         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 662         return gost_id;
 663 }
 664 int main(void) {
 665         EVP_MD_CTX* ctx;
 666         const EVP_MD* md;
 667         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 668         const char* str = "Hello world";
 669         const unsigned char check[] = {
 670                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 671                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 672                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 673                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 674         };
 675         OPENSSL_config(NULL);
 676         (void)load_gost_id();
 677         md = EVP_get_digestbyname("md_gost94");
 678         if(!md) return 1;
 679         memset(digest, 0, sizeof(digest));
 680         ctx = EVP_MD_CTX_create();
 681         if(!ctx) return 2;
 682         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 683         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 684         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 685         /* uncomment to see the hash calculated.
 686                 {int i;
 687                 for(i=0; i<32; i++)
 688                         printf(" %2.2x", (int)digest[i]);
 689                 printf("\n");}
 690         */
 691         if(memcmp(digest, check, sizeof(check)) != 0)
 692                 return 6;
 693         return 0;
 694 }
 695 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 696 CFLAGS="$BAKCFLAGS"
 697 else
 698 eval "ac_cv_c_gost_works=maybe"
 699 fi
 700 AC_MSG_RESULT($ac_cv_c_gost_works)
 701 ])dnl
 702
 703 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 704 use_gost="no"
 705 if test $USE_NSS = "no"; then
 706 case "$enable_gost" in
 707         no)
 708         ;;
 709         *)
 710         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 711         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 712         AC_CHECK_GOST_WORKS
 713         if test "$ac_cv_c_gost_works" != no; then
 714                 use_gost="yes"
 715                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 716         fi
 717         ;;
 718 esac
 719 fi dnl !USE_NSS
 720
 721 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 722 use_ecdsa="no"
 723 case "$enable_ecdsa" in
 724     no)
 725       ;;
 726     *)
 727       if test $USE_NSS = "no"; then
 728               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 729               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 730               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 731 #include <openssl/evp.h>
 732               ])
 733               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 734               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 735               if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 736                 AC_MSG_RESULT([no])
 737                 AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 738               else
 739                 AC_MSG_RESULT([yes])
 740               fi
 741       fi
 742       # we now know we have ECDSA and the required curves.
 743       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 744       use_ecdsa="yes"
 745       ;;
 746 esac
 747
 748 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) libevent-based libunbound API installed to unbound-event.h]))
 749 use_unbound_event="no"
 750 case "$enable_event_api" in
 751     yes)
 752       use_unbound_event="yes"
 753       ;;
 754     *)
 755       ;;
 756 esac
 757
 758 # check for libevent
 759 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
 760     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
 761     [ ],[ withval="no" ])
 762 if test x_$withval = x_yes -o x_$withval != x_no; then
 763         AC_MSG_CHECKING(for libevent)
 764         if test x_$withval = x_ -o x_$withval = x_yes; then
 765             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
 766         fi
 767         for dir in $withval; do
 768             thedir="$dir"
 769             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
 770                 found_libevent="yes"
 771                 dnl assume /usr is in default path.
 772                 if test "$thedir" != "/usr"; then
 773                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
 774                 fi
 775                 break;
 776             fi
 777         done
 778         if test x_$found_libevent != x_yes; then
 779                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
 780                         # libevent source directory
 781                         AC_MSG_RESULT(found in $thedir)
 782                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
 783                         BAK_LDFLAGS_SET="1"
 784                         BAK_LDFLAGS="$LDFLAGS"
 785                         # remove evdns from linking
 786                         mkdir build >/dev/null 2>&1
 787                         mkdir build/libevent >/dev/null 2>&1
 788                         mkdir build/libevent/.libs >/dev/null 2>&1
 789                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 790                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
 791                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 792                         cp $ev_files_o build/libevent
 793                         cp $ev_files_lo build/libevent
 794                         cp $ev_files_libso build/libevent/.libs
 795                         LATE_LDFLAGS="build/libevent/*.lo -lm"
 796                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
 797                 else
 798                         AC_MSG_ERROR([Cannot find the libevent library in $withval
 799 You can restart ./configure --with-libevent=no to use a builtin alternative.
 800 Please note that this alternative is not as capable as libevent when using
 801 large outgoing port ranges.  ])
 802                 fi
 803         else
 804             AC_MSG_RESULT(found in $thedir)
 805             dnl if event2 exists and no event lib in dir itself, use subdir
 806             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
 807                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
 808                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
 809             else
 810                     dnl assume /usr is in default path, do not add "".
 811                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
 812                         LDFLAGS="$LDFLAGS -L$thedir/lib"
 813                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
 814                     fi
 815             fi
 816         fi
 817         # check for library used by libevent after 1.3c
 818         AC_SEARCH_LIBS([clock_gettime], [rt])
 819
 820         # is the event.h header libev or libevent?
 821         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
 822         AC_CHECK_DECL(EV_VERSION_MAJOR, [
 823                 AC_SEARCH_LIBS(event_set, [ev])
 824         ],[
 825                 AC_SEARCH_LIBS(event_set, [event])
 826         ],[AC_INCLUDES_DEFAULT
 827 #include <event.h>
 828         ])
 829         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
 830         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
 831         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
 832         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
 833         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
 834         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
 835         if test -n "$BAK_LDFLAGS_SET"; then
 836                 LDFLAGS="$BAK_LDFLAGS"
 837         fi
 838         if test "$use_unbound_event" = "yes"; then
 839                 AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 840                 AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 841         fi
 842 else
 843         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
 844 fi
 845
 846 # check for libexpat
 847 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
 848     [specify explicit path for libexpat.]),
 849     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
 850 AC_MSG_CHECKING(for libexpat)
 851 found_libexpat="no"
 852 for dir in $withval ; do
 853             if test -f "$dir/include/expat.h"; then
 854                 found_libexpat="yes"
 855                 dnl assume /usr is in default path.
 856                 if test "$dir" != "/usr"; then
 857                     CPPFLAGS="$CPPFLAGS -I$dir/include"
 858                     LDFLAGS="$LDFLAGS -L$dir/lib"
 859                 fi
 860                 AC_MSG_RESULT(found in $dir)
 861                 break;
 862             fi
 863 done
 864 if test x_$found_libexpat != x_yes; then
 865         AC_ERROR([Could not find libexpat, expat.h])
 866 fi
 867 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
 868
 869 # set static linking if requested
 870 AC_SUBST(staticexe)
 871 staticexe=""
 872 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
 873         [ enable to compile executables statically against (event) libs, for debug purposes ]),
 874         , )
 875 if test x_$enable_static_exe = x_yes; then
 876         staticexe="-static"
 877         if test "$on_mingw" = yes; then
 878                 staticexe="-all-static"
 879                 # for static crosscompile, include gdi32 and zlib here.
 880                 if test "`uname`" = "Linux"; then
 881                         LIBS="$LIBS -lgdi32 -lz"
 882                 fi
 883         fi
 884 fi
 885
 886 # set lock checking if requested
 887 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
 888         [ enable to check lock and unlock calls, for debug purposes ]),
 889         , )
 890 if test x_$enable_lock_checks = x_yes; then
 891         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
 892         CHECKLOCK_OBJ="checklocks.lo"
 893         AC_SUBST(CHECKLOCK_OBJ)
 894 fi
 895
 896 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
 897 if test "$USE_WINSOCK" = 1; then
 898         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
 899         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
 900 #include <windows.h>
 901         ])
 902         AC_CHECK_TOOL(WINDRES, windres)
 903         LIBS="$LIBS -liphlpapi"
 904         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
 905         AC_SUBST(WINAPPS)
 906         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
 907         AC_SUBST(WIN_DAEMON_SRC)
 908         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
 909         AC_SUBST(WIN_DAEMON_OBJ)
 910         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
 911         AC_SUBST(WIN_DAEMON_OBJ_LINK)
 912         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
 913         AC_SUBST(WIN_HOST_OBJ_LINK)
 914         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
 915         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
 916         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
 917         AC_SUBST(WIN_CONTROL_OBJ_LINK)
 918         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
 919         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
 920 fi
 921 if test $ac_cv_func_getaddrinfo = no; then
 922         AC_LIBOBJ([fake-rfc2553])
 923 fi
 924 # check after getaddrinfo for its libraries
 925 ACX_FUNC_IOCTLSOCKET
 926
 927 # see if daemon(3) exists, and if it is deprecated.
 928 AC_CHECK_FUNCS([daemon])
 929 if test $ac_cv_func_daemon = yes; then
 930         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
 931 #include <stdlib.h>
 932 ])
 933 fi
 934
 935 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
 936 AC_INCLUDES_DEFAULT
 937 #if HAVE_SYS_PARAM_H
 938 #include <sys/param.h>
 939 #endif
 940
 941 #ifdef HAVE_SYS_SOCKET_H
 942 #include <sys/socket.h>
 943 #endif
 944
 945 #ifdef HAVE_SYS_UIO_H
 946 #include <sys/uio.h>
 947 #endif
 948
 949 #ifdef HAVE_NETINET_IN_H
 950 #include <netinet/in.h>
 951 #endif
 952
 953 #ifdef HAVE_ARPA_INET_H
 954 #include <arpa/inet.h>
 955 #endif
 956
 957 #ifdef HAVE_WINSOCK2_H
 958 #include <winsock2.h>
 959 #endif
 960
 961 #ifdef HAVE_WS2TCPIP_H
 962 #include <ws2tcpip.h>
 963 #endif
 964 ])
 965 AC_SEARCH_LIBS([setusercontext], [util])
 966 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam getrlimit setrlimit setsid sbrk chroot kill sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent])
 967 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
 968 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
 969
 970 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
 971 if echo $build_os | grep darwin8 > /dev/null; then
 972         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
 973 fi
 974 AC_REPLACE_FUNCS(inet_aton)
 975 AC_REPLACE_FUNCS(inet_pton)
 976 AC_REPLACE_FUNCS(inet_ntop)
 977 AC_REPLACE_FUNCS(snprintf)
 978 AC_REPLACE_FUNCS(strlcat)
 979 AC_REPLACE_FUNCS(strlcpy)
 980 AC_REPLACE_FUNCS(memmove)
 981 AC_REPLACE_FUNCS(gmtime_r)
 982 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
 983 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
 984 AC_REPLACE_FUNCS(ctime_r)
 985
 986 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
 987 case "$enable_allsymbols" in
 988         yes)
 989         COMMON_OBJ_ALL_SYMBOLS=""
 990         UBSYMS=""
 991         EXTRALINK="-L. -L.libs -lunbound"
 992         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
 993         ;;
 994         no|*)
 995         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
 996         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
 997         EXTRALINK=""
 998         ;;
 999 esac
1000 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1001 AC_SUBST(EXTRALINK)
1002 AC_SUBST(UBSYMS)
1003 if test x_$enable_lock_checks = x_yes; then
1004         UBSYMS="-export-symbols clubsyms.def"
1005         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1006         echo lock_protect >> clubsyms.def
1007         echo lock_unprotect >> clubsyms.def
1008         echo lock_get_mem >> clubsyms.def
1009         echo checklock_start >> clubsyms.def
1010         echo checklock_stop >> clubsyms.def
1011         echo checklock_lock >> clubsyms.def
1012         echo checklock_unlock >> clubsyms.def
1013         echo checklock_init >> clubsyms.def
1014         echo checklock_thrcreate >> clubsyms.def
1015         echo checklock_thrjoin >> clubsyms.def
1016 fi
1017
1018 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1019 # on openBSD, the implicit rule make $< work.
1020 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1021 # gmake works.
1022 cat >conftest.make <<EOF
1023 all:    conftest.lo
1024
1025 conftest.lo foo.lo bla.lo:
1026         if test -f "\$<"; then touch \$@; fi
1027
1028 .SUFFIXES: .lo
1029 .c.lo:
1030         if test -f "\$<"; then touch \$@; fi
1031
1032 conftest.lo:        conftest.dir/conftest.c
1033 EOF
1034 mkdir conftest.dir
1035 touch conftest.dir/conftest.c
1036 rm -f conftest.lo conftest.c
1037 ${MAKE:-make} -f conftest.make >/dev/null
1038 rm -f conftest.make conftest.c conftest.dir/conftest.c
1039 rm -rf conftest.dir
1040 if test ! -f conftest.lo; then
1041         AC_MSG_RESULT(no)
1042         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1043         SOURCEFILE='`cat .source`'
1044 else
1045         AC_MSG_RESULT(yes)
1046         SOURCEDETERMINE=':'
1047         SOURCEFILE='$<'
1048 fi
1049 rm -f conftest.lo
1050 AC_SUBST(SOURCEDETERMINE)
1051 AC_SUBST(SOURCEFILE)
1052
1053 # see if we want to build the library or everything
1054 ALLTARGET="alltargets"
1055 INSTALLTARGET="install-all"
1056 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1057         [do not build daemon and tool programs]),
1058         [
1059         if test "$withval" = "yes"; then
1060                 ALLTARGET="lib"
1061                 INSTALLTARGET="install-lib"
1062         fi
1063 ])
1064 AC_SUBST(ALLTARGET)
1065 AC_SUBST(INSTALLTARGET)
1066
1067 ACX_STRIP_EXT_FLAGS
1068 LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1069
1070 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1071
1072 AH_BOTTOM(
1073 dnl this must be first AH_CONFIG, to define the flags before any includes.
1074 AHX_CONFIG_EXT_FLAGS
1075
1076 dnl includes
1077 [
1078 #ifndef UNBOUND_DEBUG
1079 #  define NDEBUG
1080 #endif
1081
1082 /** Use small-ldns codebase */
1083 #define USE_SLDNS 1
1084 #ifdef HAVE_SSL
1085 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1086 #endif
1087
1088 #include <stdio.h>
1089 #include <string.h>
1090 #include <unistd.h>
1091 #include <assert.h>
1092
1093 #if STDC_HEADERS
1094 #include <stdlib.h>
1095 #include <stddef.h>
1096 #endif
1097
1098 #ifdef HAVE_STDARG_H
1099 #include <stdarg.h>
1100 #endif
1101
1102 #ifdef HAVE_STDINT_H
1103 #include <stdint.h>
1104 #endif
1105
1106 #include <errno.h>
1107
1108 #if HAVE_SYS_PARAM_H
1109 #include <sys/param.h>
1110 #endif
1111
1112 #ifdef HAVE_SYS_SOCKET_H
1113 #include <sys/socket.h>
1114 #endif
1115
1116 #ifdef HAVE_SYS_UIO_H
1117 #include <sys/uio.h>
1118 #endif
1119
1120 #ifdef HAVE_NETINET_IN_H
1121 #include <netinet/in.h>
1122 #endif
1123
1124 #ifdef HAVE_ARPA_INET_H
1125 #include <arpa/inet.h>
1126 #endif
1127
1128 #ifdef HAVE_WINSOCK2_H
1129 #include <winsock2.h>
1130 #endif
1131
1132 #ifdef HAVE_WS2TCPIP_H
1133 #include <ws2tcpip.h>
1134 #endif
1135
1136 #ifndef USE_WINSOCK
1137 #define ARG_LL "%ll"
1138 #else
1139 #define ARG_LL "%I64"
1140 #endif
1141 ]
1142
1143 AHX_CONFIG_FORMAT_ATTRIBUTE
1144 AHX_CONFIG_UNUSED_ATTRIBUTE
1145 AHX_CONFIG_FSEEKO
1146 AHX_CONFIG_MAXHOSTNAMELEN
1147 AHX_CONFIG_SNPRINTF(unbound)
1148 AHX_CONFIG_INET_PTON(unbound)
1149 AHX_CONFIG_INET_NTOP(unbound)
1150 AHX_CONFIG_INET_ATON(unbound)
1151 AHX_CONFIG_MEMMOVE(unbound)
1152 AHX_CONFIG_STRLCAT(unbound)
1153 AHX_CONFIG_STRLCPY(unbound)
1154 AHX_CONFIG_GMTIME_R(unbound)
1155 AHX_CONFIG_W32_SLEEP
1156 AHX_CONFIG_W32_USLEEP
1157 AHX_CONFIG_W32_RANDOM
1158 AHX_CONFIG_W32_SRANDOM
1159 AHX_CONFIG_W32_FD_SET_T
1160 AHX_CONFIG_IPV6_MIN_MTU
1161 AHX_MEMCMP_BROKEN(unbound)
1162
1163 [
1164 #ifndef HAVE_CTIME_R
1165 #define ctime_r unbound_ctime_r
1166 char *ctime_r(const time_t *timep, char *buf);
1167 #endif
1168
1169 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1170 #define strptime unbound_strptime
1171 struct tm;
1172 char *strptime(const char *s, const char *format, struct tm *tm);
1173 #endif
1174
1175 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1176    /* using version of libevent that is not threadsafe. */
1177 #  define LIBEVENT_SIGNAL_PROBLEM 1
1178 #endif
1179
1180 #ifndef CHECKED_INET6
1181 #  define CHECKED_INET6
1182 #  ifdef AF_INET6
1183 #    define INET6
1184 #  else
1185 #    define AF_INET6        28
1186 #  endif
1187 #endif /* CHECKED_INET6 */
1188
1189 #ifndef HAVE_GETADDRINFO
1190 struct sockaddr_storage;
1191 #include "compat/fake-rfc2553.h"
1192 #endif
1193
1194 #ifdef UNBOUND_ALLOC_STATS
1195 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1196 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1197 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1198 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1199 void *unbound_stat_malloc(size_t size);
1200 void *unbound_stat_calloc(size_t nmemb, size_t size);
1201 void unbound_stat_free(void *ptr);
1202 void *unbound_stat_realloc(void *ptr, size_t size);
1203 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1204         const char* func);
1205 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1206         int line, const char* func);
1207 void unbound_stat_free_log(void *ptr, const char* file, int line,
1208         const char* func);
1209 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1210         int line, const char* func);
1211 #elif defined(UNBOUND_ALLOC_LITE)
1212 #  include "util/alloc.h"
1213 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1214
1215 /** default port for DNS traffic. */
1216 #define UNBOUND_DNS_PORT 53
1217 /** default port for unbound control traffic, registered port with IANA,
1218     ub-dns-control  8953/tcp    unbound dns nameserver control */
1219 #define UNBOUND_CONTROL_PORT 8953
1220 /** the version of unbound-control that this software implements */
1221 #define UNBOUND_CONTROL_VERSION 1
1222
1223 ])
1224
1225 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8])
1226 AC_CONFIG_HEADER([config.h])
1227 AC_OUTPUT