configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[6])
  14 m4_define([VERSION_MICRO],[5])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=4
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77
  78 #   Current  -- the number of the binary API that we're implementing
  79 #   Revision -- which iteration of the implementation of the binary
  80 #               API are we supplying?
  81 #   Age      -- How many previous binary API versions do we also
  82 #               support?
  83 #
  84 # If we release a new version that does not change the binary API,
  85 # increment Revision.
  86 #
  87 # If we release a new version that changes the binary API, but does
  88 # not break programs compiled against the old binary API, increment
  89 # Current and Age.  Set Revision to 0, since this is the first
  90 # implementation of the new API.
  91 #
  92 # Otherwise, we're changing the binary API and breaking bakward
  93 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  94 # since we're backward compatible with no previous APIs.  Set Revision
  95 # to 0 too.
  96 AC_SUBST(LIBUNBOUND_CURRENT)
  97 AC_SUBST(LIBUNBOUND_REVISION)
  98 AC_SUBST(LIBUNBOUND_AGE)
  99
 100 CFLAGS="$CFLAGS"
 101 AC_AIX
 102 if test "$ac_cv_header_minix_config_h" = "yes"; then
 103         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 104 fi
 105
 106 dnl
 107 dnl By default set prefix to /usr/local
 108 dnl
 109 case "$prefix" in
 110         NONE)
 111                 prefix="/usr/local"
 112         ;;
 113 esac
 114 case "$exec_prefix" in
 115         NONE)
 116                 exec_prefix="$prefix"
 117         ;;
 118 esac
 119
 120 # are we on MinGW?
 121 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 122 else
 123         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 124         else on_mingw="no"; fi
 125 fi
 126
 127 #
 128 # Determine configuration file
 129 # the eval is to evaluate shell expansion twice
 130 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 131 AC_SUBST(UNBOUND_SBIN_DIR)
 132 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 133 AC_SUBST(UNBOUND_SYSCONF_DIR)
 134 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 135 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 136 if test $on_mingw = "no"; then
 137   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 138 else
 139   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 140 fi
 141 AC_ARG_WITH([conf_file],
 142         AC_HELP_STRING([--with-conf-file=path],
 143         [Pathname to the Unbound configuration file]),
 144         [ub_conf_file="$withval"])
 145 AC_SUBST(ub_conf_file)
 146 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 147 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 148 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 149 AC_SUBST(ub_conf_dir)
 150
 151 # Determine run, chroot directory and pidfile locations
 152 AC_ARG_WITH(run-dir,
 153     AC_HELP_STRING([--with-run-dir=path],
 154     [set default directory to chdir to (by default dir part of cfg file)]),
 155     UNBOUND_RUN_DIR="$withval",
 156 if test $on_mingw = no; then
 157     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 158 else
 159     UNBOUND_RUN_DIR=""
 160 fi
 161 )
 162 AC_SUBST(UNBOUND_RUN_DIR)
 163 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 164 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 165
 166 AC_ARG_WITH(chroot-dir,
 167     AC_HELP_STRING([--with-chroot-dir=path],
 168     [set default directory to chroot to (by default same as run-dir)]),
 169     UNBOUND_CHROOT_DIR="$withval",
 170 if test $on_mingw = no; then
 171     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 172 else
 173     UNBOUND_CHROOT_DIR=""
 174 fi
 175 )
 176 AC_SUBST(UNBOUND_CHROOT_DIR)
 177 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 178 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 179
 180 AC_ARG_WITH(share-dir,
 181     AC_HELP_STRING([--with-share-dir=path],
 182     [set default directory with shared data (by default same as share/unbound)]),
 183     UNBOUND_SHARE_DIR="$withval",
 184     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 185 AC_SUBST(UNBOUND_SHARE_DIR)
 186 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 187
 188 AC_ARG_WITH(pidfile,
 189     AC_HELP_STRING([--with-pidfile=filename],
 190     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 191     UNBOUND_PIDFILE="$withval",
 192 if test $on_mingw = no; then
 193     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 194 else
 195     UNBOUND_PIDFILE=""
 196 fi
 197 )
 198 AC_SUBST(UNBOUND_PIDFILE)
 199 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 200 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 201
 202 AC_ARG_WITH(rootkey-file,
 203     AC_HELP_STRING([--with-rootkey-file=filename],
 204     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 205     UNBOUND_ROOTKEY_FILE="$withval",
 206 if test $on_mingw = no; then
 207     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 208 else
 209     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 210 fi
 211 )
 212 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 213 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 214 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 215
 216 AC_ARG_WITH(rootcert-file,
 217     AC_HELP_STRING([--with-rootcert-file=filename],
 218     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 219     UNBOUND_ROOTCERT_FILE="$withval",
 220 if test $on_mingw = no; then
 221     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 222 else
 223     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 224 fi
 225 )
 226 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 227 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 228 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 229
 230 AC_ARG_WITH(username,
 231     AC_HELP_STRING([--with-username=user],
 232     [set default user that unbound changes to (default user is unbound)]),
 233     UNBOUND_USERNAME="$withval",
 234     UNBOUND_USERNAME="unbound")
 235 AC_SUBST(UNBOUND_USERNAME)
 236 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 237
 238 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 239 ACX_RSRC_VERSION(wnvs)
 240 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 241
 242 # Checks for typedefs, structures, and compiler characteristics.
 243 AC_C_CONST
 244 AC_LANG_C
 245 # allow user to override the -g -O2 flags.
 246 if test "x$CFLAGS" = "x" ; then
 247 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 248 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 249 fi
 250 AC_PROG_CC
 251 ACX_DEPFLAG
 252 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 253
 254 # debug mode flags warnings
 255 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 256 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 257 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 258 else debug_enabled="$enable_checking"; fi
 259 AC_SUBST(debug_enabled)
 260 case "$debug_enabled" in
 261         yes)
 262                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 263                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 264                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 265                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 266                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 267                 ;;
 268         no|*)
 269                 # nothing to do.
 270                 ;;
 271 esac
 272 ACX_CHECK_FLTO
 273 ACX_CHECK_PIE
 274 ACX_CHECK_RELRO_NOW
 275
 276 AC_C_INLINE
 277 ACX_CHECK_FORMAT_ATTRIBUTE
 278 ACX_CHECK_UNUSED_ATTRIBUTE
 279
 280 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 281 [AC_REQUIRE([AC_PROG_CC])
 282 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 283 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 284 [ac_cv_c_weak_attribute=no
 285 AC_TRY_COMPILE(
 286 [ #include <stdio.h>
 287 __attribute__((weak)) void f(int x) { printf("%d", x); }
 288 ], [
 289    f(1);
 290 ],
 291 [ac_cv_c_weak_attribute="yes"],
 292 [ac_cv_c_weak_attribute="no"])
 293 ])
 294
 295 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 296 if test $ac_cv_c_weak_attribute = yes; then
 297   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 298 fi
 299 ])dnl End of CHECK_WEAK_ATTRIBUTE
 300
 301 CHECK_WEAK_ATTRIBUTE
 302
 303 if test "$srcdir" != "."; then
 304         CPPFLAGS="$CPPFLAGS -I$srcdir"
 305 fi
 306
 307 AC_DEFUN([ACX_YYLEX_DESTROY], [
 308         AC_MSG_CHECKING([for yylex_destroy])
 309         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 310                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 311                 AC_MSG_RESULT(yes)
 312         else AC_MSG_RESULT(no); fi
 313 ])
 314
 315 AC_PROG_LEX
 316 ACX_YYLEX_DESTROY
 317 AC_PROG_YACC
 318 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 319 AC_CHECK_TOOL(STRIP, strip)
 320 ACX_LIBTOOL_C_ONLY
 321
 322 # Checks for header files.
 323 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 324
 325 # check for types.
 326 # Using own tests for int64* because autoconf builtin only give 32bit.
 327 AC_CHECK_TYPE(int8_t, signed char)
 328 AC_CHECK_TYPE(int16_t, short)
 329 AC_CHECK_TYPE(int32_t, int)
 330 AC_CHECK_TYPE(int64_t, long long)
 331 AC_CHECK_TYPE(uint8_t, unsigned char)
 332 AC_CHECK_TYPE(uint16_t, unsigned short)
 333 AC_CHECK_TYPE(uint32_t, unsigned int)
 334 AC_CHECK_TYPE(uint64_t, unsigned long long)
 335 AC_TYPE_SIZE_T
 336 AC_CHECK_TYPE(ssize_t, int)
 337 AC_TYPE_UID_T
 338 AC_TYPE_PID_T
 339 AC_TYPE_OFF_T
 340 ACX_TYPE_U_CHAR
 341 ACX_TYPE_RLIM_T
 342 ACX_TYPE_SOCKLEN_T
 343 ACX_TYPE_IN_ADDR_T
 344 ACX_TYPE_IN_PORT_T
 345 ACX_CHECK_MEMCMP_SIGNED
 346
 347 AC_CHECK_SIZEOF(time_t,,[
 348 AC_INCLUDES_DEFAULT
 349 #ifdef TIME_WITH_SYS_TIME
 350 # include <sys/time.h>
 351 # include <time.h>
 352 #else
 353 # ifdef HAVE_SYS_TIME_H
 354 #  include <sys/time.h>
 355 # else
 356 #  include <time.h>
 357 # endif
 358 #endif
 359 ])
 360
 361 # add option to disable the evil rpath
 362 ACX_ARG_RPATH
 363 AC_SUBST(RUNTIME_PATH)
 364
 365 # check to see if libraries are needed for these functions.
 366 AC_SEARCH_LIBS([inet_pton], [nsl])
 367 AC_SEARCH_LIBS([socket], [socket])
 368
 369 # check wether strptime also works
 370 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 371 [AC_REQUIRE([AC_PROG_CC])
 372 AC_MSG_CHECKING(whether strptime works)
 373 if test c${cross_compiling} = cno; then
 374 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 375 #define _XOPEN_SOURCE 600
 376 #include <time.h>
 377 int main(void) { struct tm tm; char *res;
 378 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 379 if (!res) return 2;
 380 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 381 if (!res) return 1; return 0; }
 382 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 383 else
 384 eval "ac_cv_c_strptime_works=maybe"
 385 fi
 386 AC_MSG_RESULT($ac_cv_c_strptime_works)
 387 if test $ac_cv_c_strptime_works = no; then
 388 AC_LIBOBJ(strptime)
 389 else
 390 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 391 fi
 392 ])dnl
 393
 394 # check some functions of the OS before linking libs (while still runnable).
 395 AC_FUNC_CHOWN
 396 AC_FUNC_FORK
 397 AC_TYPE_SIGNAL
 398 AC_FUNC_FSEEKO
 399 ACX_SYS_LARGEFILE
 400 ACX_CHECK_NONBLOCKING_BROKEN
 401 ACX_MKDIR_ONE_ARG
 402 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 403
 404 # set memory allocation checking if requested
 405 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 406         [ enable to memory allocation statistics, for debug purposes ]),
 407         , )
 408 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 409         [ enable for lightweight alloc assertions, for debug purposes ]),
 410         , )
 411 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 412         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 413         , )
 414 if test x_$enable_alloc_nonregional = x_yes; then
 415         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 416 fi
 417 if test x_$enable_alloc_checks = x_yes; then
 418         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 419 else
 420         if test x_$enable_alloc_lite = x_yes; then
 421                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 422         else
 423                 ACX_FUNC_MALLOC([unbound])
 424         fi
 425 fi
 426
 427 # check windows threads (we use them, not pthreads, on windows).
 428 if test "$on_mingw" = "yes"; then
 429 # check windows threads
 430         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 431         AC_MSG_CHECKING([for CreateThread])
 432         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 433 #ifdef HAVE_WINDOWS_H
 434 #include <windows.h>
 435 #endif
 436 ], [
 437         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 438 ])],
 439         AC_MSG_RESULT(yes)
 440         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 441 ,
 442         AC_MSG_RESULT(no)
 443 )
 444
 445 else
 446 # not on mingw, check thread libraries.
 447
 448 # check for thread library.
 449 # check this first, so that the pthread lib does not get linked in via
 450 # libssl or libpython, and thus distorts the tests, and we end up using
 451 # the non-threadsafe C libraries.
 452 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 453  [use pthreads library, or --without-pthreads to disable threading support.]),
 454  [ ],[ withval="yes" ])
 455 ub_have_pthreads=no
 456 if test x_$withval != x_no; then
 457         AX_PTHREAD([
 458                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 459                 LIBS="$PTHREAD_LIBS $LIBS"
 460                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 461                 CC="$PTHREAD_CC"
 462                 ub_have_pthreads=yes
 463                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 464
 465                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 466                 AC_MSG_CHECKING([if -pthread unused during linking])
 467                 # catch clang warning 'argument unused during compilation'
 468                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 469 [[
 470 int main(void) {return 0;}
 471 ]])])
 472                 pthread_unused="yes"
 473                 # first compile
 474                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 475                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 476                 if test $? = 0; then
 477                         # then link
 478                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 479                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 480                         if test $? -ne 0; then
 481                                 AC_MSG_RESULT(yes)
 482                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 483                                 PTHREAD_CFLAGS_ONLY="-pthread"
 484                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 485                         else
 486                                 AC_MSG_RESULT(no)
 487                         fi
 488                 else
 489                         AC_MSG_RESULT(no)
 490                 fi # endif cc successful
 491                 rm -f conftest conftest.c conftest.o
 492                 fi # endif -pthread in CFLAGS
 493
 494                 ])
 495 fi
 496
 497 # check solaris thread library
 498 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 499         [use solaris native thread library.]), [ ],[ withval="no" ])
 500 ub_have_sol_threads=no
 501 if test x_$withval != x_no; then
 502         if test x_$ub_have_pthreads != x_no; then
 503             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 504         else
 505         AC_SEARCH_LIBS(thr_create, [thread],
 506         [
 507                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 508
 509                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 510                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 511                 ub_have_sol_threads=yes
 512         ] , [
 513                 AC_ERROR([no solaris threads found.])
 514         ])
 515         fi
 516 fi
 517
 518 fi # end of non-mingw check of thread libraries
 519
 520 # Check for PyUnbound
 521 AC_ARG_WITH(pyunbound,
 522    AC_HELP_STRING([--with-pyunbound],
 523    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 524    [], [ withval="no" ])
 525
 526 ub_test_python=no
 527 ub_with_pyunbound=no
 528 if test x_$withval != x_no; then
 529    ub_with_pyunbound=yes
 530    ub_test_python=yes
 531 fi
 532
 533 # Check for Python module
 534 AC_ARG_WITH(pythonmodule,
 535    AC_HELP_STRING([--with-pythonmodule],
 536    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 537    [], [ withval="no" ])
 538
 539 ub_with_pythonmod=no
 540 if test x_$withval != x_no; then
 541    ub_with_pythonmod=yes
 542    ub_test_python=yes
 543 fi
 544
 545 # Check for Python & SWIG only on PyUnbound or PyModule
 546 if test x_$ub_test_python != x_no; then
 547
 548    # Check for Python
 549    ub_have_python=no
 550    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 551    AC_PYTHON_DEVEL
 552    if test ! -z "$PYTHON_VERSION"; then
 553         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 554                 AC_ERROR([Python version >= 2.4.0 is required])
 555         fi
 556
 557       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 558       AC_SUBST(PY_MAJOR_VERSION)
 559       # Have Python
 560       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 561       LIBS="$PYTHON_LDFLAGS $LIBS"
 562       CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 563       ub_have_python=yes
 564       PC_PY_DEPENDENCY="python"
 565       AC_SUBST(PC_PY_DEPENDENCY)
 566
 567       # Check for SWIG
 568       ub_have_swig=no
 569       AC_PROG_SWIG(2.0.1)
 570       AC_MSG_CHECKING(SWIG)
 571       if test ! -x "$SWIG"; then
 572          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 573       else
 574          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 575          AC_SUBST(swig, "$SWIG")
 576          AC_MSG_RESULT(present)
 577
 578          # If have Python & SWIG
 579          # Declare PythonMod
 580          if test x_$ub_with_pythonmod != x_no; then
 581             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 582             WITH_PYTHONMODULE=yes
 583             AC_SUBST(WITH_PYTHONMODULE)
 584             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 585             AC_SUBST(PYTHONMOD_OBJ)
 586             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 587             AC_SUBST(PYTHONMOD_HEADER)
 588             PYTHONMOD_INSTALL=pythonmod-install
 589             AC_SUBST(PYTHONMOD_INSTALL)
 590             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 591             AC_SUBST(PYTHONMOD_UNINSTALL)
 592          fi
 593
 594          # Declare PyUnbound
 595          if test x_$ub_with_pyunbound != x_no; then
 596             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 597             WITH_PYUNBOUND=yes
 598             AC_SUBST(WITH_PYUNBOUND)
 599             PYUNBOUND_OBJ="libunbound_wrap.lo"
 600             AC_SUBST(PYUNBOUND_OBJ)
 601             PYUNBOUND_TARGET="_unbound.la"
 602             AC_SUBST(PYUNBOUND_TARGET)
 603             PYUNBOUND_INSTALL=pyunbound-install
 604             AC_SUBST(PYUNBOUND_INSTALL)
 605             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 606             AC_SUBST(PYUNBOUND_UNINSTALL)
 607          fi
 608       fi
 609    else
 610       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 611       ub_with_pyunbound=no
 612       ub_with_pythonmod=no
 613    fi
 614 fi
 615
 616 if test "`uname`" = "NetBSD"; then
 617         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 618         AC_SUBST(NETBSD_LINTFLAGS)
 619 fi
 620 CONFIG_DATE=`date +%Y%m%d`
 621 AC_SUBST(CONFIG_DATE)
 622
 623 # Checks for libraries.
 624
 625 # libnss
 626 USE_NSS="no"
 627 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 628         [use libnss instead of openssl, installed at path.]),
 629         [
 630         USE_NSS="yes"
 631         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 632         if test "$withval" != "" -a "$withval" != "yes"; then
 633                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 634                 LDFLAGS="$LDFLAGS -L$withval/lib"
 635                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 636                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 637         else
 638                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 639                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 640         fi
 641         LIBS="$LIBS -lnss3 -lnspr4"
 642         SSLLIB=""
 643         ]
 644 )
 645
 646 # libnettle
 647 USE_NETTLE="no"
 648 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 649         [use libnettle as crypto library, installed at path.]),
 650         [
 651         USE_NETTLE="yes"
 652         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 653         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 654         if test "$withval" != "" -a "$withval" != "yes"; then
 655                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 656                 LDFLAGS="$LDFLAGS -L$withval/lib"
 657                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 658         else
 659                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 660         fi
 661         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 662         SSLLIB=""
 663         ]
 664 )
 665
 666 # openssl
 667 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 668 ACX_WITH_SSL
 669 ACX_LIB_SSL
 670 SSLLIB="-lssl"
 671
 672 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 673 BAKLIBS="$LIBS"
 674 LIBS="-lssl $LIBS"
 675 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 676 AC_TRY_LINK_FUNC([HMAC_Update], [
 677         AC_MSG_RESULT([no])
 678         LIBS="$BAKLIBS"
 679 ], [
 680         AC_MSG_RESULT([yes])
 681         LIBS="$BAKLIBS"
 682         LIBS="$LIBS -lcrypt32"
 683 ])
 684
 685 AC_MSG_CHECKING([for LibreSSL])
 686 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 687         AC_MSG_RESULT([yes])
 688         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 689         # libressl provides these compat functions, but they may also be
 690         # declared by the OS in libc.  See if they have been declared.
 691         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 692 else
 693         AC_MSG_RESULT([no])
 694 fi
 695 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 696 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 697
 698 # these check_funcs need -lssl
 699 BAKLIBS="$LIBS"
 700 LIBS="-lssl $LIBS"
 701 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level])
 702 LIBS="$BAKLIBS"
 703
 704 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 705 AC_INCLUDES_DEFAULT
 706 #ifdef HAVE_OPENSSL_ERR_H
 707 #include <openssl/err.h>
 708 #endif
 709
 710 #ifdef HAVE_OPENSSL_RAND_H
 711 #include <openssl/rand.h>
 712 #endif
 713
 714 #ifdef HAVE_OPENSSL_CONF_H
 715 #include <openssl/conf.h>
 716 #endif
 717
 718 #ifdef HAVE_OPENSSL_ENGINE_H
 719 #include <openssl/engine.h>
 720 #endif
 721 #include <openssl/ssl.h>
 722 #include <openssl/evp.h>
 723 ])
 724 fi
 725 AC_SUBST(SSLLIB)
 726
 727
 728 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 729 case "$enable_sha1" in
 730         no)
 731         ;;
 732         yes|*)
 733         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 734         ;;
 735 esac
 736
 737
 738 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 739 case "$enable_sha2" in
 740         no)
 741         ;;
 742         yes|*)
 743         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 744         ;;
 745 esac
 746
 747 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 748 case "$enable_subnet" in
 749         yes)
 750         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 751         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 752         AC_SUBST(SUBNET_OBJ)
 753         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 754         AC_SUBST(SUBNET_HEADER)
 755         ;;
 756         no|*)
 757         ;;
 758 esac
 759
 760 # check wether gost also works
 761 AC_DEFUN([AC_CHECK_GOST_WORKS],
 762 [AC_REQUIRE([AC_PROG_CC])
 763 AC_MSG_CHECKING([if GOST works])
 764 if test c${cross_compiling} = cno; then
 765 BAKCFLAGS="$CFLAGS"
 766 if test -n "$ssldir"; then
 767         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 768 fi
 769 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 770 #include <string.h>
 771 #include <openssl/ssl.h>
 772 #include <openssl/evp.h>
 773 #include <openssl/engine.h>
 774 #include <openssl/conf.h>
 775 /* routine to load gost (from sldns) */
 776 int load_gost_id(void)
 777 {
 778         static int gost_id = 0;
 779         const EVP_PKEY_ASN1_METHOD* meth;
 780         ENGINE* e;
 781
 782         if(gost_id) return gost_id;
 783
 784         /* see if configuration loaded gost implementation from other engine*/
 785         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 786         if(meth) {
 787                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 788                 return gost_id;
 789         }
 790
 791         /* see if engine can be loaded already */
 792         e = ENGINE_by_id("gost");
 793         if(!e) {
 794                 /* load it ourself, in case statically linked */
 795                 ENGINE_load_builtin_engines();
 796                 ENGINE_load_dynamic();
 797                 e = ENGINE_by_id("gost");
 798         }
 799         if(!e) {
 800                 /* no gost engine in openssl */
 801                 return 0;
 802         }
 803         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 804                 ENGINE_finish(e);
 805                 ENGINE_free(e);
 806                 return 0;
 807         }
 808
 809         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 810         if(!meth) {
 811                 /* algo not found */
 812                 ENGINE_finish(e);
 813                 ENGINE_free(e);
 814                 return 0;
 815         }
 816         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 817         return gost_id;
 818 }
 819 int main(void) {
 820         EVP_MD_CTX* ctx;
 821         const EVP_MD* md;
 822         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 823         const char* str = "Hello world";
 824         const unsigned char check[] = {
 825                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 826                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 827                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 828                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 829         };
 830         OPENSSL_config(NULL);
 831         (void)load_gost_id();
 832         md = EVP_get_digestbyname("md_gost94");
 833         if(!md) return 1;
 834         memset(digest, 0, sizeof(digest));
 835         ctx = EVP_MD_CTX_create();
 836         if(!ctx) return 2;
 837         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 838         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 839         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 840         /* uncomment to see the hash calculated.
 841                 {int i;
 842                 for(i=0; i<32; i++)
 843                         printf(" %2.2x", (int)digest[i]);
 844                 printf("\n");}
 845         */
 846         if(memcmp(digest, check, sizeof(check)) != 0)
 847                 return 6;
 848         return 0;
 849 }
 850 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 851 CFLAGS="$BAKCFLAGS"
 852 else
 853 eval "ac_cv_c_gost_works=maybe"
 854 fi
 855 AC_MSG_RESULT($ac_cv_c_gost_works)
 856 ])dnl
 857
 858 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 859 use_gost="no"
 860 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 861 case "$enable_gost" in
 862         no)
 863         ;;
 864         *)
 865         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 866         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 867         AC_CHECK_GOST_WORKS
 868         if test "$ac_cv_c_gost_works" != no; then
 869                 use_gost="yes"
 870                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 871         fi
 872         ;;
 873 esac
 874 fi dnl !USE_NSS && !USE_NETTLE
 875
 876 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 877 use_ecdsa="no"
 878 case "$enable_ecdsa" in
 879     no)
 880       ;;
 881     *)
 882       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 883               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 884               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 885               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 886 #include <openssl/evp.h>
 887               ])
 888               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 889               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 890               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 891                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 892                   AC_MSG_RESULT([no])
 893                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 894                 else
 895                   AC_MSG_RESULT([yes])
 896                 fi
 897               else
 898                 # not OpenSSL, thus likely LibreSSL, which supports it
 899                 AC_MSG_RESULT([yes])
 900               fi
 901       fi
 902       # we now know we have ECDSA and the required curves.
 903       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 904       use_ecdsa="yes"
 905       ;;
 906 esac
 907
 908 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 909 use_dsa="no"
 910 case "$enable_dsa" in
 911     no)
 912       ;;
 913     *)
 914       # detect if DSA is supported, and turn it off if not.
 915       AC_CHECK_FUNC(DSA_SIG_new, [
 916       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 917       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 918                fi ])
 919       ;;
 920 esac
 921
 922 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
 923 use_ed25519="no"
 924 case "$enable_ed25519" in
 925     no)
 926       ;;
 927     *)
 928       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 929               AC_CHECK_DECLS([NID_ED25519], [
 930                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
 931                 use_ed25519="yes"
 932               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
 933                 fi ], [AC_INCLUDES_DEFAULT
 934 #include <openssl/evp.h>
 935               ])
 936       fi
 937       ;;
 938 esac
 939
 940 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
 941 case "$enable_event_api" in
 942     yes)
 943       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 944       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 945       ;;
 946     *)
 947       ;;
 948 esac
 949
 950 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
 951 case "$enable_tfo_client" in
 952         yes)
 953                 case `uname` in
 954                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 955                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 956                                              [AC_INCLUDES_DEFAULT
 957 #include <netinet/tcp.h>
 958 ])
 959                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 960                           ;;
 961                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 962                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 963                                               [AC_INCLUDES_DEFAULT
 964 #include <sys/socket.h>
 965 ])
 966                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 967                           ;;
 968                 esac
 969         ;;
 970         no|*)
 971                 ;;
 972 esac
 973
 974 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
 975 case "$enable_tfo_server" in
 976         yes)
 977               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
 978 #include <netinet/tcp.h>
 979               ])
 980                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
 981                 ;;
 982         no|*)
 983                 ;;
 984 esac
 985
 986 # check for libevent
 987 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
 988     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
 989     [ ],[ withval="no" ])
 990 if test x_$withval = x_yes -o x_$withval != x_no; then
 991         AC_MSG_CHECKING(for libevent)
 992         if test x_$withval = x_ -o x_$withval = x_yes; then
 993             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
 994         fi
 995         for dir in $withval; do
 996             thedir="$dir"
 997             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
 998                 found_libevent="yes"
 999                 dnl assume /usr is in default path.
1000                 if test "$thedir" != "/usr"; then
1001                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1002                 fi
1003                 break;
1004             fi
1005         done
1006         if test x_$found_libevent != x_yes; then
1007                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1008                         # libevent source directory
1009                         AC_MSG_RESULT(found in $thedir)
1010                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1011                         BAK_LDFLAGS_SET="1"
1012                         BAK_LDFLAGS="$LDFLAGS"
1013                         # remove evdns from linking
1014                         mkdir build >/dev/null 2>&1
1015                         mkdir build/libevent >/dev/null 2>&1
1016                         mkdir build/libevent/.libs >/dev/null 2>&1
1017                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1018                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1019                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1020                         cp $ev_files_o build/libevent
1021                         cp $ev_files_lo build/libevent
1022                         cp $ev_files_libso build/libevent/.libs
1023                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1024                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1025                 else
1026                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1027 You can restart ./configure --with-libevent=no to use a builtin alternative.
1028 Please note that this alternative is not as capable as libevent when using
1029 large outgoing port ranges.  ])
1030                 fi
1031         else
1032             AC_MSG_RESULT(found in $thedir)
1033             dnl if event2 exists and no event lib in dir itself, use subdir
1034             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1035                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1036                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1037             else
1038                     dnl assume /usr is in default path, do not add "".
1039                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1040                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1041                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1042                     fi
1043             fi
1044         fi
1045         # check for library used by libevent after 1.3c
1046         AC_SEARCH_LIBS([clock_gettime], [rt])
1047
1048         # is the event.h header libev or libevent?
1049         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1050         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1051                 AC_SEARCH_LIBS(event_set, [ev])
1052         ],[
1053                 AC_SEARCH_LIBS(event_set, [event])
1054         ],[AC_INCLUDES_DEFAULT
1055 #include <event.h>
1056         ])
1057         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1058         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1059         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1060         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1061         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1062         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1063         PC_LIBEVENT_DEPENDENCY="libevent"
1064         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1065         if test -n "$BAK_LDFLAGS_SET"; then
1066                 LDFLAGS="$BAK_LDFLAGS"
1067         fi
1068 else
1069         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1070 fi
1071
1072 # check for libexpat
1073 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1074     [specify explicit path for libexpat.]),
1075     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1076 AC_MSG_CHECKING(for libexpat)
1077 found_libexpat="no"
1078 for dir in $withval ; do
1079             if test -f "$dir/include/expat.h"; then
1080                 found_libexpat="yes"
1081                 dnl assume /usr is in default path.
1082                 if test "$dir" != "/usr"; then
1083                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1084                     LDFLAGS="$LDFLAGS -L$dir/lib"
1085                 fi
1086                 AC_MSG_RESULT(found in $dir)
1087                 break;
1088             fi
1089 done
1090 if test x_$found_libexpat != x_yes; then
1091         AC_ERROR([Could not find libexpat, expat.h])
1092 fi
1093 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1094 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1095 #include <expat.h>
1096 ])
1097
1098 # set static linking if requested
1099 AC_SUBST(staticexe)
1100 staticexe=""
1101 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1102         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1103         , )
1104 if test x_$enable_static_exe = x_yes; then
1105         staticexe="-static"
1106         if test "$on_mingw" = yes; then
1107                 staticexe="-all-static"
1108                 # for static compile, include gdi32 and zlib here.
1109                 LIBS="$LIBS -lgdi32 -lz"
1110         fi
1111 fi
1112
1113 # Include systemd.m4 - begin
1114 sinclude(systemd.m4)
1115 # Include systemd.m4 - end
1116
1117 # set lock checking if requested
1118 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1119         [ enable to check lock and unlock calls, for debug purposes ]),
1120         , )
1121 if test x_$enable_lock_checks = x_yes; then
1122         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1123         CHECKLOCK_OBJ="checklocks.lo"
1124         AC_SUBST(CHECKLOCK_OBJ)
1125 fi
1126
1127 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1128 if test "$USE_WINSOCK" = 1; then
1129         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1130         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1131 #include <windows.h>
1132         ])
1133         AC_CHECK_TOOL(WINDRES, windres)
1134         LIBS="$LIBS -liphlpapi"
1135         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1136         AC_SUBST(WINAPPS)
1137         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1138         AC_SUBST(WIN_DAEMON_SRC)
1139         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1140         AC_SUBST(WIN_DAEMON_OBJ)
1141         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1142         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1143         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1144         AC_SUBST(WIN_HOST_OBJ_LINK)
1145         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1146         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1147         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1148         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1149         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1150         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1151 fi
1152 if test $ac_cv_func_getaddrinfo = no; then
1153         AC_LIBOBJ([fake-rfc2553])
1154 fi
1155 # check after getaddrinfo for its libraries
1156 ACX_FUNC_IOCTLSOCKET
1157
1158 # see if daemon(3) exists, and if it is deprecated.
1159 AC_CHECK_FUNCS([daemon])
1160 if test $ac_cv_func_daemon = yes; then
1161         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1162 #include <stdlib.h>
1163 ])
1164 fi
1165
1166 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1167 AC_INCLUDES_DEFAULT
1168 #ifdef HAVE_SYS_UN_H
1169 #include <sys/un.h>
1170 #endif
1171 ])
1172 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1173 AC_INCLUDES_DEFAULT
1174 #if HAVE_SYS_PARAM_H
1175 #include <sys/param.h>
1176 #endif
1177
1178 #ifdef HAVE_SYS_SOCKET_H
1179 #include <sys/socket.h>
1180 #endif
1181
1182 #ifdef HAVE_SYS_UIO_H
1183 #include <sys/uio.h>
1184 #endif
1185
1186 #ifdef HAVE_NETINET_IN_H
1187 #include <netinet/in.h>
1188 #endif
1189
1190 #ifdef HAVE_NETINET_TCP_H
1191 #include <netinet/tcp.h>
1192 #endif
1193
1194 #ifdef HAVE_ARPA_INET_H
1195 #include <arpa/inet.h>
1196 #endif
1197
1198 #ifdef HAVE_WINSOCK2_H
1199 #include <winsock2.h>
1200 #endif
1201
1202 #ifdef HAVE_WS2TCPIP_H
1203 #include <ws2tcpip.h>
1204 #endif
1205 ])
1206 AC_SEARCH_LIBS([setusercontext], [util])
1207 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget])
1208 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1209 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1210
1211 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1212 if echo $build_os | grep darwin8 > /dev/null; then
1213         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1214 fi
1215 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1216 AC_INCLUDES_DEFAULT
1217 #ifdef HAVE_NETINET_IN_H
1218 #include <netinet/in.h>
1219 #endif
1220
1221 #ifdef HAVE_NETINET_TCP_H
1222 #include <netinet/tcp.h>
1223 #endif
1224
1225 #ifdef HAVE_ARPA_INET_H
1226 #include <arpa/inet.h>
1227 #endif
1228
1229 #ifdef HAVE_WINSOCK2_H
1230 #include <winsock2.h>
1231 #endif
1232
1233 #ifdef HAVE_WS2TCPIP_H
1234 #include <ws2tcpip.h>
1235 #endif
1236 ])
1237 AC_REPLACE_FUNCS(inet_aton)
1238 AC_REPLACE_FUNCS(inet_pton)
1239 AC_REPLACE_FUNCS(inet_ntop)
1240 AC_REPLACE_FUNCS(snprintf)
1241 # test if snprintf return the proper length
1242 if test "x$ac_cv_func_snprintf" = xyes; then
1243     if test c${cross_compiling} = cno; then
1244         AC_MSG_CHECKING([for correct snprintf return value])
1245         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1246 [[
1247 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1248 ]])], [AC_MSG_RESULT(yes)], [
1249                 AC_MSG_RESULT(no)
1250                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1251                 AC_LIBOBJ(snprintf)
1252           ])
1253     fi
1254 fi
1255 AC_REPLACE_FUNCS(strlcat)
1256 AC_REPLACE_FUNCS(strlcpy)
1257 AC_REPLACE_FUNCS(memmove)
1258 AC_REPLACE_FUNCS(gmtime_r)
1259 AC_REPLACE_FUNCS(isblank)
1260 dnl without CTIME, ARC4-functions and without reallocarray.
1261 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1262 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1263 AC_REPLACE_FUNCS(reallocarray)
1264 if test "$USE_NSS" = "no"; then
1265         AC_REPLACE_FUNCS(arc4random)
1266         AC_REPLACE_FUNCS(arc4random_uniform)
1267         if test "$ac_cv_func_arc4random" = "no"; then
1268                 AC_LIBOBJ(explicit_bzero)
1269                 AC_LIBOBJ(arc4_lock)
1270                 AC_CHECK_FUNCS([getentropy],,[
1271                     if test "$USE_WINSOCK" = 1; then
1272                         AC_LIBOBJ(getentropy_win)
1273                     else
1274                         case "$host" in
1275                         Darwin|*darwin*)
1276                                 AC_LIBOBJ(getentropy_osx)
1277                         ;;
1278                         *solaris*|*sunos*|SunOS)
1279                                 AC_LIBOBJ(getentropy_solaris)
1280                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1281                                         AC_CHECK_FUNCS([SHA512_Update],,[
1282                                                 AC_LIBOBJ(sha512)
1283                                         ])
1284                                 ], [AC_INCLUDES_DEFAULT])
1285                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1286                                         # this lib needed for sha2 on solaris
1287                                         LIBS="$LIBS -lmd"
1288                                 fi
1289                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1290                         ;;
1291                         *linux*|Linux|*)
1292                                 AC_LIBOBJ(getentropy_linux)
1293                                 AC_CHECK_FUNCS([SHA512_Update],,[
1294                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1295                                         AC_LIBOBJ(sha512)
1296                                 ])
1297                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1298                                 AC_CHECK_FUNCS([getauxval])
1299                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1300                         ;;
1301                         esac
1302                     fi
1303                 ])
1304         fi
1305 fi
1306 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1307 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1308 AC_REPLACE_FUNCS(ctime_r)
1309 AC_REPLACE_FUNCS(strsep)
1310
1311 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1312 case "$enable_allsymbols" in
1313         yes)
1314         COMMON_OBJ_ALL_SYMBOLS=""
1315         UBSYMS=""
1316         EXTRALINK="-L. -L.libs -lunbound"
1317         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1318         ;;
1319         no|*)
1320         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1321         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1322         EXTRALINK=""
1323         ;;
1324 esac
1325 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1326 AC_SUBST(EXTRALINK)
1327 AC_SUBST(UBSYMS)
1328 if test x_$enable_lock_checks = x_yes; then
1329         UBSYMS="-export-symbols clubsyms.def"
1330         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1331         echo lock_protect >> clubsyms.def
1332         echo lock_unprotect >> clubsyms.def
1333         echo lock_get_mem >> clubsyms.def
1334         echo checklock_start >> clubsyms.def
1335         echo checklock_stop >> clubsyms.def
1336         echo checklock_lock >> clubsyms.def
1337         echo checklock_unlock >> clubsyms.def
1338         echo checklock_init >> clubsyms.def
1339         echo checklock_thrcreate >> clubsyms.def
1340         echo checklock_thrjoin >> clubsyms.def
1341 fi
1342
1343 # check for dnstap if requested
1344 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1345     [
1346         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1347         AC_SUBST([ENABLE_DNSTAP], [1])
1348
1349         AC_SUBST([opt_dnstap_socket_path])
1350         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1351         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1352             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1353
1354         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1355         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1356     ],
1357     [
1358         AC_SUBST([ENABLE_DNSTAP], [0])
1359     ]
1360 )
1361
1362 # check for dnscrypt if requested
1363 dnsc_DNSCRYPT([
1364         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1365         AC_SUBST([ENABLE_DNSCRYPT], [1])
1366
1367         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1368         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1369     ],
1370     [
1371         AC_SUBST([ENABLE_DNSCRYPT], [0])
1372     ]
1373 )
1374
1375 # check for cachedb if requested
1376 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1377 case "$enable_cachedb" in
1378     yes)
1379         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1380         ;;
1381     no|*)
1382         # nothing
1383         ;;
1384 esac
1385
1386 # check for ipsecmod if requested
1387 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1388 case "$enable_ipsecmod" in
1389         yes)
1390                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1391                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1392                 AC_SUBST(IPSECMOD_OBJ)
1393                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1394                 AC_SUBST(IPSECMOD_HEADER)
1395                 ;;
1396         no|*)
1397                 # nothing
1398                 ;;
1399 esac
1400
1401 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1402 # on openBSD, the implicit rule make $< work.
1403 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1404 # gmake works.
1405 cat >conftest.make <<EOF
1406 all:    conftest.lo
1407
1408 conftest.lo foo.lo bla.lo:
1409         if test -f "\$<"; then touch \$@; fi
1410
1411 .SUFFIXES: .lo
1412 .c.lo:
1413         if test -f "\$<"; then touch \$@; fi
1414
1415 conftest.lo:        conftest.dir/conftest.c
1416 EOF
1417 mkdir conftest.dir
1418 touch conftest.dir/conftest.c
1419 rm -f conftest.lo conftest.c
1420 ${MAKE:-make} -f conftest.make >/dev/null
1421 rm -f conftest.make conftest.c conftest.dir/conftest.c
1422 rm -rf conftest.dir
1423 if test ! -f conftest.lo; then
1424         AC_MSG_RESULT(no)
1425         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1426         SOURCEFILE='`cat .source`'
1427 else
1428         AC_MSG_RESULT(yes)
1429         SOURCEDETERMINE=':'
1430         SOURCEFILE='$<'
1431 fi
1432 rm -f conftest.lo
1433 AC_SUBST(SOURCEDETERMINE)
1434 AC_SUBST(SOURCEFILE)
1435
1436 # see if we want to build the library or everything
1437 ALLTARGET="alltargets"
1438 INSTALLTARGET="install-all"
1439 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1440         [do not build daemon and tool programs]),
1441         [
1442         if test "$withval" = "yes"; then
1443                 ALLTARGET="lib"
1444                 INSTALLTARGET="install-lib"
1445         fi
1446 ])
1447 AC_SUBST(ALLTARGET)
1448 AC_SUBST(INSTALLTARGET)
1449
1450 ACX_STRIP_EXT_FLAGS
1451 LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1452
1453 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1454
1455 AH_BOTTOM(
1456 dnl this must be first AH_CONFIG, to define the flags before any includes.
1457 AHX_CONFIG_EXT_FLAGS
1458
1459 dnl includes
1460 [
1461 #ifndef UNBOUND_DEBUG
1462 #  define NDEBUG
1463 #endif
1464
1465 /** Use small-ldns codebase */
1466 #define USE_SLDNS 1
1467 #ifdef HAVE_SSL
1468 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1469 #endif
1470
1471 #include <stdio.h>
1472 #include <string.h>
1473 #include <unistd.h>
1474 #include <assert.h>
1475
1476 #if STDC_HEADERS
1477 #include <stdlib.h>
1478 #include <stddef.h>
1479 #endif
1480
1481 #ifdef HAVE_STDARG_H
1482 #include <stdarg.h>
1483 #endif
1484
1485 #ifdef HAVE_STDINT_H
1486 #include <stdint.h>
1487 #endif
1488
1489 #include <errno.h>
1490
1491 #if HAVE_SYS_PARAM_H
1492 #include <sys/param.h>
1493 #endif
1494
1495 #ifdef HAVE_SYS_SOCKET_H
1496 #include <sys/socket.h>
1497 #endif
1498
1499 #ifdef HAVE_SYS_UIO_H
1500 #include <sys/uio.h>
1501 #endif
1502
1503 #ifdef HAVE_NETINET_IN_H
1504 #include <netinet/in.h>
1505 #endif
1506
1507 #ifdef HAVE_NETINET_TCP_H
1508 #include <netinet/tcp.h>
1509 #endif
1510
1511 #ifdef HAVE_ARPA_INET_H
1512 #include <arpa/inet.h>
1513 #endif
1514
1515 #ifdef HAVE_WINSOCK2_H
1516 #include <winsock2.h>
1517 #endif
1518
1519 #ifdef HAVE_WS2TCPIP_H
1520 #include <ws2tcpip.h>
1521 #endif
1522
1523 #ifndef USE_WINSOCK
1524 #define ARG_LL "%ll"
1525 #else
1526 #define ARG_LL "%I64"
1527 #endif
1528
1529 #ifndef AF_LOCAL
1530 #define AF_LOCAL AF_UNIX
1531 #endif
1532 ]
1533
1534 AHX_CONFIG_FORMAT_ATTRIBUTE
1535 AHX_CONFIG_UNUSED_ATTRIBUTE
1536 AHX_CONFIG_FSEEKO
1537 AHX_CONFIG_MAXHOSTNAMELEN
1538 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1539 #define snprintf snprintf_unbound
1540 #define vsnprintf vsnprintf_unbound
1541 #include <stdarg.h>
1542 int snprintf (char *str, size_t count, const char *fmt, ...);
1543 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1544 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1545 AHX_CONFIG_INET_PTON(unbound)
1546 AHX_CONFIG_INET_NTOP(unbound)
1547 AHX_CONFIG_INET_ATON(unbound)
1548 AHX_CONFIG_MEMMOVE(unbound)
1549 AHX_CONFIG_STRLCAT(unbound)
1550 AHX_CONFIG_STRLCPY(unbound)
1551 AHX_CONFIG_GMTIME_R(unbound)
1552 AHX_CONFIG_REALLOCARRAY(unbound)
1553 AHX_CONFIG_W32_SLEEP
1554 AHX_CONFIG_W32_USLEEP
1555 AHX_CONFIG_W32_RANDOM
1556 AHX_CONFIG_W32_SRANDOM
1557 AHX_CONFIG_W32_FD_SET_T
1558 AHX_CONFIG_IPV6_MIN_MTU
1559 AHX_MEMCMP_BROKEN(unbound)
1560
1561 [
1562 #ifndef HAVE_CTIME_R
1563 #define ctime_r unbound_ctime_r
1564 char *ctime_r(const time_t *timep, char *buf);
1565 #endif
1566
1567 #ifndef HAVE_STRSEP
1568 #define strsep unbound_strsep
1569 char *strsep(char **stringp, const char *delim);
1570 #endif
1571
1572 #ifndef HAVE_ISBLANK
1573 #define isblank unbound_isblank
1574 int isblank(int c);
1575 #endif
1576
1577 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1578 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1579 #endif
1580
1581 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1582 int inet_pton(int af, const char* src, void* dst);
1583 #endif
1584
1585 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1586 #define strptime unbound_strptime
1587 struct tm;
1588 char *strptime(const char *s, const char *format, struct tm *tm);
1589 #endif
1590
1591 #ifdef HAVE_LIBRESSL
1592 #  if !HAVE_DECL_STRLCPY
1593 size_t strlcpy(char *dst, const char *src, size_t siz);
1594 #  endif
1595 #  if !HAVE_DECL_STRLCAT
1596 size_t strlcat(char *dst, const char *src, size_t siz);
1597 #  endif
1598 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1599 uint32_t arc4random(void);
1600 #  endif
1601 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1602 uint32_t arc4random_uniform(uint32_t upper_bound);
1603 #  endif
1604 #  if !HAVE_DECL_REALLOCARRAY
1605 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1606 #  endif
1607 #endif /* HAVE_LIBRESSL */
1608 #ifndef HAVE_ARC4RANDOM
1609 void explicit_bzero(void* buf, size_t len);
1610 int getentropy(void* buf, size_t len);
1611 uint32_t arc4random(void);
1612 void arc4random_buf(void* buf, size_t n);
1613 void _ARC4_LOCK(void);
1614 void _ARC4_UNLOCK(void);
1615 #endif
1616 #ifndef HAVE_ARC4RANDOM_UNIFORM
1617 uint32_t arc4random_uniform(uint32_t upper_bound);
1618 #endif
1619 #ifdef COMPAT_SHA512
1620 #ifndef SHA512_DIGEST_LENGTH
1621 #define SHA512_BLOCK_LENGTH             128
1622 #define SHA512_DIGEST_LENGTH            64
1623 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1624 typedef struct _SHA512_CTX {
1625         uint64_t        state[8];
1626         uint64_t        bitcount[2];
1627         uint8_t buffer[SHA512_BLOCK_LENGTH];
1628 } SHA512_CTX;
1629 #endif /* SHA512_DIGEST_LENGTH */
1630 void SHA512_Init(SHA512_CTX*);
1631 void SHA512_Update(SHA512_CTX*, void*, size_t);
1632 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1633 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1634 #endif /* COMPAT_SHA512 */
1635
1636
1637
1638 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1639    /* using version of libevent that is not threadsafe. */
1640 #  define LIBEVENT_SIGNAL_PROBLEM 1
1641 #endif
1642
1643 #ifndef CHECKED_INET6
1644 #  define CHECKED_INET6
1645 #  ifdef AF_INET6
1646 #    define INET6
1647 #  else
1648 #    define AF_INET6        28
1649 #  endif
1650 #endif /* CHECKED_INET6 */
1651
1652 #ifndef HAVE_GETADDRINFO
1653 struct sockaddr_storage;
1654 #include "compat/fake-rfc2553.h"
1655 #endif
1656
1657 #ifdef UNBOUND_ALLOC_STATS
1658 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1659 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1660 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1661 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1662 void *unbound_stat_malloc(size_t size);
1663 void *unbound_stat_calloc(size_t nmemb, size_t size);
1664 void unbound_stat_free(void *ptr);
1665 void *unbound_stat_realloc(void *ptr, size_t size);
1666 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1667         const char* func);
1668 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1669         int line, const char* func);
1670 void unbound_stat_free_log(void *ptr, const char* file, int line,
1671         const char* func);
1672 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1673         int line, const char* func);
1674 #elif defined(UNBOUND_ALLOC_LITE)
1675 #  include "util/alloc.h"
1676 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1677
1678 /** default port for DNS traffic. */
1679 #define UNBOUND_DNS_PORT 53
1680 /** default port for unbound control traffic, registered port with IANA,
1681     ub-dns-control  8953/tcp    unbound dns nameserver control */
1682 #define UNBOUND_CONTROL_PORT 8953
1683 /** the version of unbound-control that this software implements */
1684 #define UNBOUND_CONTROL_VERSION 1
1685
1686 ])
1687
1688 dnl if we build from source tree, the man pages need @date@ and @version@
1689 dnl if this is a distro tarball, that was already done by makedist.sh
1690 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1691 AC_SUBST(date, [`date +'%b %e, %Y'`])
1692
1693 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1694 AC_CONFIG_HEADER([config.h])
1695 AC_OUTPUT