configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[9])
  14 m4_define([VERSION_MICRO],[0])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=9
  21 LIBUNBOUND_REVISION=0
  22 LIBUNBOUND_AGE=1
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86 # 1.8.2 had 8:2:0
  87 # 1.8.3 had 8:3:0
  88 # 1.8.4 had 9:0:1 # add ub_ctx_set_tls
  89
  90 #   Current  -- the number of the binary API that we're implementing
  91 #   Revision -- which iteration of the implementation of the binary
  92 #               API are we supplying?
  93 #   Age      -- How many previous binary API versions do we also
  94 #               support?
  95 #
  96 # If we release a new version that does not change the binary API,
  97 # increment Revision.
  98 #
  99 # If we release a new version that changes the binary API, but does
 100 # not break programs compiled against the old binary API, increment
 101 # Current and Age.  Set Revision to 0, since this is the first
 102 # implementation of the new API.
 103 #
 104 # Otherwise, we're changing the binary API and breaking backward
 105 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 106 # since we're backward compatible with no previous APIs.  Set Revision
 107 # to 0 too.
 108 AC_SUBST(LIBUNBOUND_CURRENT)
 109 AC_SUBST(LIBUNBOUND_REVISION)
 110 AC_SUBST(LIBUNBOUND_AGE)
 111
 112 CFLAGS="$CFLAGS"
 113 AC_AIX
 114 if test "$ac_cv_header_minix_config_h" = "yes"; then
 115         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 116 fi
 117
 118 dnl
 119 dnl By default set prefix to /usr/local
 120 dnl
 121 case "$prefix" in
 122         NONE)
 123                 prefix="/usr/local"
 124         ;;
 125 esac
 126 case "$exec_prefix" in
 127         NONE)
 128                 exec_prefix="$prefix"
 129         ;;
 130 esac
 131
 132 # are we on MinGW?
 133 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 134 else
 135         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 136         else on_mingw="no"; fi
 137 fi
 138
 139 #
 140 # Determine configuration file
 141 # the eval is to evaluate shell expansion twice
 142 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 143 AC_SUBST(UNBOUND_SBIN_DIR)
 144 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 145 AC_SUBST(UNBOUND_SYSCONF_DIR)
 146 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 147 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 148 if test $on_mingw = "no"; then
 149   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 150 else
 151   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 152 fi
 153 AC_ARG_WITH([conf_file],
 154         AC_HELP_STRING([--with-conf-file=path],
 155         [Pathname to the Unbound configuration file]),
 156         [ub_conf_file="$withval"])
 157 AC_SUBST(ub_conf_file)
 158 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 159 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 160 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 161 AC_SUBST(ub_conf_dir)
 162
 163 # Determine run, chroot directory and pidfile locations
 164 AC_ARG_WITH(run-dir,
 165     AC_HELP_STRING([--with-run-dir=path],
 166     [set default directory to chdir to (by default dir part of cfg file)]),
 167     UNBOUND_RUN_DIR="$withval",
 168 if test $on_mingw = no; then
 169     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 170 else
 171     UNBOUND_RUN_DIR=""
 172 fi
 173 )
 174 AC_SUBST(UNBOUND_RUN_DIR)
 175 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 176 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 177
 178 AC_ARG_WITH(chroot-dir,
 179     AC_HELP_STRING([--with-chroot-dir=path],
 180     [set default directory to chroot to (by default same as run-dir)]),
 181     UNBOUND_CHROOT_DIR="$withval",
 182 if test $on_mingw = no; then
 183     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 184 else
 185     UNBOUND_CHROOT_DIR=""
 186 fi
 187 )
 188 AC_SUBST(UNBOUND_CHROOT_DIR)
 189 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 190 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 191
 192 AC_ARG_WITH(share-dir,
 193     AC_HELP_STRING([--with-share-dir=path],
 194     [set default directory with shared data (by default same as share/unbound)]),
 195     UNBOUND_SHARE_DIR="$withval",
 196     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 197 AC_SUBST(UNBOUND_SHARE_DIR)
 198 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 199
 200 AC_ARG_WITH(pidfile,
 201     AC_HELP_STRING([--with-pidfile=filename],
 202     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 203     UNBOUND_PIDFILE="$withval",
 204 if test $on_mingw = no; then
 205     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 206 else
 207     UNBOUND_PIDFILE=""
 208 fi
 209 )
 210 AC_SUBST(UNBOUND_PIDFILE)
 211 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 212 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 213
 214 AC_ARG_WITH(rootkey-file,
 215     AC_HELP_STRING([--with-rootkey-file=filename],
 216     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 217     UNBOUND_ROOTKEY_FILE="$withval",
 218 if test $on_mingw = no; then
 219     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 220 else
 221     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 222 fi
 223 )
 224 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 225 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 226 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 227
 228 AC_ARG_WITH(rootcert-file,
 229     AC_HELP_STRING([--with-rootcert-file=filename],
 230     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 231     UNBOUND_ROOTCERT_FILE="$withval",
 232 if test $on_mingw = no; then
 233     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 234 else
 235     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 236 fi
 237 )
 238 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 239 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 240 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 241
 242 AC_ARG_WITH(username,
 243     AC_HELP_STRING([--with-username=user],
 244     [set default user that unbound changes to (default user is unbound)]),
 245     UNBOUND_USERNAME="$withval",
 246     UNBOUND_USERNAME="unbound")
 247 AC_SUBST(UNBOUND_USERNAME)
 248 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 249
 250 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 251 ACX_RSRC_VERSION(wnvs)
 252 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 253
 254 # Checks for typedefs, structures, and compiler characteristics.
 255 AC_C_CONST
 256 AC_LANG_C
 257 # allow user to override the -g -O2 flags.
 258 default_cflags=no
 259 if test "x$CFLAGS" = "x" ; then
 260 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 261 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 262 default_cflags=yes
 263 fi
 264 AC_PROG_CC
 265 ACX_DEPFLAG
 266 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 267
 268 # debug mode flags warnings
 269 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 270 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 271 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 272 else debug_enabled="$enable_checking"; fi
 273 AC_SUBST(debug_enabled)
 274 case "$debug_enabled" in
 275         yes)
 276                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 277                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 278                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 279                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 280                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 281                 ;;
 282         no|*)
 283                 # nothing to do.
 284                 ;;
 285 esac
 286 if test "$default_cflags" = "yes"; then
 287         # only when CFLAGS was "" at the start, if the users wants to
 288         # override we shouldn't add default cflags, because they wouldn't
 289         # be able to turn off these options and set the CFLAGS wanted.
 290         ACX_CHECK_FLTO
 291         ACX_CHECK_PIE
 292         ACX_CHECK_RELRO_NOW
 293 fi
 294
 295 AC_C_INLINE
 296 ACX_CHECK_FORMAT_ATTRIBUTE
 297 ACX_CHECK_UNUSED_ATTRIBUTE
 298
 299 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 300 [AC_REQUIRE([AC_PROG_CC])
 301 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 302 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 303 [ac_cv_c_weak_attribute=no
 304 AC_TRY_COMPILE(
 305 [ #include <stdio.h>
 306 __attribute__((weak)) void f(int x) { printf("%d", x); }
 307 ], [
 308    f(1);
 309 ],
 310 [ac_cv_c_weak_attribute="yes"],
 311 [ac_cv_c_weak_attribute="no"])
 312 ])
 313
 314 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 315 if test $ac_cv_c_weak_attribute = yes; then
 316   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 317   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 318 fi
 319 ])dnl End of CHECK_WEAK_ATTRIBUTE
 320
 321 CHECK_WEAK_ATTRIBUTE
 322
 323 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 324 [AC_REQUIRE([AC_PROG_CC])
 325 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 326 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 327 [ac_cv_c_noreturn_attribute=no
 328 AC_TRY_COMPILE(
 329 [ #include <stdio.h>
 330 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 331 ], [
 332    f(1);
 333 ],
 334 [ac_cv_c_noreturn_attribute="yes"],
 335 [ac_cv_c_noreturn_attribute="no"])
 336 ])
 337
 338 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 339 if test $ac_cv_c_noreturn_attribute = yes; then
 340   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 341   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 342 fi
 343 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 344
 345 CHECK_NORETURN_ATTRIBUTE
 346
 347 if test "$srcdir" != "."; then
 348         CPPFLAGS="$CPPFLAGS -I$srcdir"
 349 fi
 350
 351 AC_DEFUN([ACX_YYLEX_DESTROY], [
 352         AC_MSG_CHECKING([for yylex_destroy])
 353         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 354                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 355                 AC_MSG_RESULT(yes)
 356         else AC_MSG_RESULT(no);
 357                 LEX=":"
 358         fi
 359 ])
 360
 361 AC_DEFUN([ACX_YYLEX_OPTION], [
 362         AC_MSG_CHECKING([for lex %option])
 363         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 364 %option nounput
 365 %%
 366 EOF
 367                 AC_MSG_RESULT(yes)
 368         else AC_MSG_RESULT(no);
 369                 LEX=":"
 370         fi
 371 ])
 372
 373 AC_PROG_LEX
 374 if test "$LEX" != "" -a "$LEX" != ":"; then
 375 ACX_YYLEX_DESTROY
 376 fi
 377 if test "$LEX" != "" -a "$LEX" != ":"; then
 378 ACX_YYLEX_OPTION
 379 fi
 380 AC_PROG_YACC
 381 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 382 AC_CHECK_TOOL(STRIP, strip)
 383 ACX_LIBTOOL_C_ONLY
 384
 385 # Checks for header files.
 386 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 387
 388 # check for types.
 389 # Using own tests for int64* because autoconf builtin only give 32bit.
 390 AC_CHECK_TYPE(int8_t, signed char)
 391 AC_CHECK_TYPE(int16_t, short)
 392 AC_CHECK_TYPE(int32_t, int)
 393 AC_CHECK_TYPE(int64_t, long long)
 394 AC_CHECK_TYPE(uint8_t, unsigned char)
 395 AC_CHECK_TYPE(uint16_t, unsigned short)
 396 AC_CHECK_TYPE(uint32_t, unsigned int)
 397 AC_CHECK_TYPE(uint64_t, unsigned long long)
 398 AC_TYPE_SIZE_T
 399 AC_CHECK_TYPE(ssize_t, int)
 400 AC_TYPE_UID_T
 401 AC_TYPE_PID_T
 402 AC_TYPE_OFF_T
 403 ACX_TYPE_U_CHAR
 404 ACX_TYPE_RLIM_T
 405 ACX_TYPE_SOCKLEN_T
 406 ACX_TYPE_IN_ADDR_T
 407 ACX_TYPE_IN_PORT_T
 408 ACX_CHECK_MEMCMP_SIGNED
 409
 410 AC_CHECK_SIZEOF(time_t,,[
 411 AC_INCLUDES_DEFAULT
 412 #ifdef TIME_WITH_SYS_TIME
 413 # include <sys/time.h>
 414 # include <time.h>
 415 #else
 416 # ifdef HAVE_SYS_TIME_H
 417 #  include <sys/time.h>
 418 # else
 419 #  include <time.h>
 420 # endif
 421 #endif
 422 ])
 423
 424 # add option to disable the evil rpath
 425 ACX_ARG_RPATH
 426 AC_SUBST(RUNTIME_PATH)
 427
 428 # check to see if libraries are needed for these functions.
 429 AC_SEARCH_LIBS([inet_pton], [nsl])
 430 AC_SEARCH_LIBS([socket], [socket])
 431
 432 # check wether strptime also works
 433 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 434 [AC_REQUIRE([AC_PROG_CC])
 435 AC_MSG_CHECKING(whether strptime works)
 436 if test c${cross_compiling} = cno; then
 437 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 438 #define _XOPEN_SOURCE 600
 439 #include <time.h>
 440 int main(void) { struct tm tm; char *res;
 441 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 442 if (!res) return 2;
 443 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 444 if (!res) return 1; return 0; }
 445 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 446 else
 447 eval "ac_cv_c_strptime_works=maybe"
 448 fi
 449 AC_MSG_RESULT($ac_cv_c_strptime_works)
 450 if test $ac_cv_c_strptime_works = no; then
 451 AC_LIBOBJ(strptime)
 452 else
 453 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 454 fi
 455 ])dnl
 456
 457 # check some functions of the OS before linking libs (while still runnable).
 458 AC_FUNC_CHOWN
 459 AC_FUNC_FORK
 460 AC_TYPE_SIGNAL
 461 AC_FUNC_FSEEKO
 462 ACX_SYS_LARGEFILE
 463 ACX_CHECK_NONBLOCKING_BROKEN
 464 ACX_MKDIR_ONE_ARG
 465 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 466
 467 # check if we can use SO_REUSEPORT
 468 if echo "$host" | grep -i -e linux -e dragonfly >/dev/null; then
 469         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 470 else
 471         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 472 fi
 473
 474 # set memory allocation checking if requested
 475 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 476         [ enable to memory allocation statistics, for debug purposes ]),
 477         , )
 478 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 479         [ enable for lightweight alloc assertions, for debug purposes ]),
 480         , )
 481 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 482         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 483         , )
 484 if test x_$enable_alloc_nonregional = x_yes; then
 485         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 486 fi
 487 if test x_$enable_alloc_checks = x_yes; then
 488         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 489 else
 490         if test x_$enable_alloc_lite = x_yes; then
 491                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 492         else
 493                 ACX_FUNC_MALLOC([unbound])
 494         fi
 495 fi
 496
 497 # check windows threads (we use them, not pthreads, on windows).
 498 if test "$on_mingw" = "yes"; then
 499 # check windows threads
 500         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 501         AC_MSG_CHECKING([for CreateThread])
 502         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 503 #ifdef HAVE_WINDOWS_H
 504 #include <windows.h>
 505 #endif
 506 ], [
 507         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 508 ])],
 509         AC_MSG_RESULT(yes)
 510         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 511 ,
 512         AC_MSG_RESULT(no)
 513 )
 514
 515 else
 516 # not on mingw, check thread libraries.
 517
 518 # check for thread library.
 519 # check this first, so that the pthread lib does not get linked in via
 520 # libssl or libpython, and thus distorts the tests, and we end up using
 521 # the non-threadsafe C libraries.
 522 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 523  [use pthreads library, or --without-pthreads to disable threading support.]),
 524  [ ],[ withval="yes" ])
 525 ub_have_pthreads=no
 526 if test x_$withval != x_no; then
 527         AX_PTHREAD([
 528                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 529                 if test -n "$PTHREAD_LIBS"; then
 530                   LIBS="$PTHREAD_LIBS $LIBS"
 531                 fi
 532                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 533                 CC="$PTHREAD_CC"
 534                 ub_have_pthreads=yes
 535                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 536
 537                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 538                 AC_MSG_CHECKING([if -pthread unused during linking])
 539                 # catch clang warning 'argument unused during compilation'
 540                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 541 [[
 542 int main(void) {return 0;}
 543 ]])])
 544                 pthread_unused="yes"
 545                 # first compile
 546                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 547                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 548                 if test $? = 0; then
 549                         # then link
 550                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 551                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 552                         if test $? -ne 0; then
 553                                 AC_MSG_RESULT(yes)
 554                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 555                                 PTHREAD_CFLAGS_ONLY="-pthread"
 556                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 557                         else
 558                                 AC_MSG_RESULT(no)
 559                         fi
 560                 else
 561                         AC_MSG_RESULT(no)
 562                 fi # endif cc successful
 563                 rm -f conftest conftest.c conftest.o
 564                 fi # endif -pthread in CFLAGS
 565
 566                 ])
 567 fi
 568
 569 # check solaris thread library
 570 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 571         [use solaris native thread library.]), [ ],[ withval="no" ])
 572 ub_have_sol_threads=no
 573 if test x_$withval != x_no; then
 574         if test x_$ub_have_pthreads != x_no; then
 575             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 576         else
 577         AC_SEARCH_LIBS(thr_create, [thread],
 578         [
 579                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 580
 581                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 582                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 583                 ub_have_sol_threads=yes
 584         ] , [
 585                 AC_ERROR([no solaris threads found.])
 586         ])
 587         fi
 588 fi
 589
 590 fi # end of non-mingw check of thread libraries
 591
 592 # Check for PyUnbound
 593 AC_ARG_WITH(pyunbound,
 594    AC_HELP_STRING([--with-pyunbound],
 595    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 596    [], [ withval="no" ])
 597
 598 ub_test_python=no
 599 ub_with_pyunbound=no
 600 if test x_$withval != x_no; then
 601    ub_with_pyunbound=yes
 602    ub_test_python=yes
 603 fi
 604
 605 # Check for Python module
 606 AC_ARG_WITH(pythonmodule,
 607    AC_HELP_STRING([--with-pythonmodule],
 608    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 609    [], [ withval="no" ])
 610
 611 ub_with_pythonmod=no
 612 if test x_$withval != x_no; then
 613    ub_with_pythonmod=yes
 614    ub_test_python=yes
 615 fi
 616
 617 # Check for Python & SWIG only on PyUnbound or PyModule
 618 if test x_$ub_test_python != x_no; then
 619
 620    # Check for Python
 621    ub_have_python=no
 622    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 623    AC_PYTHON_DEVEL
 624    if test ! -z "$PYTHON_VERSION"; then
 625         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 626                 AC_ERROR([Python version >= 2.4.0 is required])
 627         fi
 628
 629       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 630       AC_SUBST(PY_MAJOR_VERSION)
 631       # Have Python
 632       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 633       if test -n "$LIBS"; then
 634         LIBS="$PYTHON_LDFLAGS $LIBS"
 635       else
 636         LIBS="$PYTHON_LDFLAGS"
 637       fi
 638       if test -n "$CPPFLAGS"; then
 639         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 640       else
 641         CPPFLAGS="$PYTHON_CPPFLAGS"
 642       fi
 643       ub_have_python=yes
 644       PKG_PROG_PKG_CONFIG
 645       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 646                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 647                        [PC_PY_DEPENDENCY="python"])
 648       AC_SUBST(PC_PY_DEPENDENCY)
 649
 650       # Check for SWIG
 651       ub_have_swig=no
 652       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 653       if test "$enable_swig_version_check" = "yes"; then
 654         AC_PROG_SWIG(2.0.1)
 655       else
 656         AC_PROG_SWIG
 657       fi
 658       AC_MSG_CHECKING(SWIG)
 659       if test ! -x "$SWIG"; then
 660          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 661       else
 662          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 663          AC_SUBST(swig, "$SWIG")
 664          AC_MSG_RESULT(present)
 665
 666          # If have Python & SWIG
 667          # Declare PythonMod
 668          if test x_$ub_with_pythonmod != x_no; then
 669             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 670             WITH_PYTHONMODULE=yes
 671             AC_SUBST(WITH_PYTHONMODULE)
 672             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 673             AC_SUBST(PYTHONMOD_OBJ)
 674             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 675             AC_SUBST(PYTHONMOD_HEADER)
 676             PYTHONMOD_INSTALL=pythonmod-install
 677             AC_SUBST(PYTHONMOD_INSTALL)
 678             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 679             AC_SUBST(PYTHONMOD_UNINSTALL)
 680          fi
 681
 682          # Declare PyUnbound
 683          if test x_$ub_with_pyunbound != x_no; then
 684             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 685             WITH_PYUNBOUND=yes
 686             AC_SUBST(WITH_PYUNBOUND)
 687             PYUNBOUND_OBJ="libunbound_wrap.lo"
 688             AC_SUBST(PYUNBOUND_OBJ)
 689             PYUNBOUND_TARGET="_unbound.la"
 690             AC_SUBST(PYUNBOUND_TARGET)
 691             PYUNBOUND_INSTALL=pyunbound-install
 692             AC_SUBST(PYUNBOUND_INSTALL)
 693             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 694             AC_SUBST(PYUNBOUND_UNINSTALL)
 695          fi
 696       fi
 697    else
 698       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 699       ub_with_pyunbound=no
 700       ub_with_pythonmod=no
 701    fi
 702 fi
 703
 704 if test "`uname`" = "NetBSD"; then
 705         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 706         AC_SUBST(NETBSD_LINTFLAGS)
 707 fi
 708 CONFIG_DATE=`date +%Y%m%d`
 709 AC_SUBST(CONFIG_DATE)
 710
 711 # Checks for libraries.
 712
 713 # libnss
 714 USE_NSS="no"
 715 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 716         [use libnss instead of openssl, installed at path.]),
 717         [
 718         USE_NSS="yes"
 719         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 720         if test "$withval" != "" -a "$withval" != "yes"; then
 721                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 722                 LDFLAGS="$LDFLAGS -L$withval/lib"
 723                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 724                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 725         else
 726                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 727                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 728         fi
 729         LIBS="$LIBS -lnss3 -lnspr4"
 730         SSLLIB=""
 731         ]
 732 )
 733
 734 # libnettle
 735 USE_NETTLE="no"
 736 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 737         [use libnettle as crypto library, installed at path.]),
 738         [
 739         USE_NETTLE="yes"
 740         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 741         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 742         if test "$withval" != "" -a "$withval" != "yes"; then
 743                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 744                 LDFLAGS="$LDFLAGS -L$withval/lib"
 745                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 746         else
 747                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 748         fi
 749         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 750         SSLLIB=""
 751         ]
 752 )
 753
 754 # openssl
 755 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 756 ACX_WITH_SSL
 757 ACX_LIB_SSL
 758 SSLLIB="-lssl"
 759
 760 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 761 BAKLIBS="$LIBS"
 762 LIBS="-lssl $LIBS"
 763 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 764 AC_TRY_LINK_FUNC([HMAC_Update], [
 765         AC_MSG_RESULT([no])
 766         LIBS="$BAKLIBS"
 767 ], [
 768         AC_MSG_RESULT([yes])
 769         LIBS="$BAKLIBS"
 770         LIBS="$LIBS -lcrypt32"
 771 ])
 772
 773 AC_MSG_CHECKING([for LibreSSL])
 774 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 775         AC_MSG_RESULT([yes])
 776         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 777         # libressl provides these compat functions, but they may also be
 778         # declared by the OS in libc.  See if they have been declared.
 779         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 780 else
 781         AC_MSG_RESULT([no])
 782 fi
 783 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 784 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify SSL_CTX_set_tlsext_ticket_key_cb EVP_aes_256_cbc EVP_EncryptInit_ex HMAC_Init_ex])
 785
 786 # these check_funcs need -lssl
 787 BAKLIBS="$LIBS"
 788 LIBS="-lssl $LIBS"
 789 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername X509_VERIFY_PARAM_set1_host SSL_CTX_set_ciphersuites])
 790 LIBS="$BAKLIBS"
 791
 792 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 793 AC_INCLUDES_DEFAULT
 794 #ifdef HAVE_OPENSSL_ERR_H
 795 #include <openssl/err.h>
 796 #endif
 797
 798 #ifdef HAVE_OPENSSL_RAND_H
 799 #include <openssl/rand.h>
 800 #endif
 801
 802 #ifdef HAVE_OPENSSL_CONF_H
 803 #include <openssl/conf.h>
 804 #endif
 805
 806 #ifdef HAVE_OPENSSL_ENGINE_H
 807 #include <openssl/engine.h>
 808 #endif
 809 #include <openssl/ssl.h>
 810 #include <openssl/evp.h>
 811 ])
 812 fi
 813 AC_SUBST(SSLLIB)
 814
 815
 816 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 817 case "$enable_sha1" in
 818         no)
 819         ;;
 820         yes|*)
 821         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 822         ;;
 823 esac
 824
 825
 826 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 827 case "$enable_sha2" in
 828         no)
 829         ;;
 830         yes|*)
 831         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 832         ;;
 833 esac
 834
 835 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 836 case "$enable_subnet" in
 837         yes)
 838         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 839         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 840         AC_SUBST(SUBNET_OBJ)
 841         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 842         AC_SUBST(SUBNET_HEADER)
 843         ;;
 844         no|*)
 845         ;;
 846 esac
 847
 848 # check wether gost also works
 849 AC_DEFUN([AC_CHECK_GOST_WORKS],
 850 [AC_REQUIRE([AC_PROG_CC])
 851 AC_MSG_CHECKING([if GOST works])
 852 if test c${cross_compiling} = cno; then
 853 BAKCFLAGS="$CFLAGS"
 854 if test -n "$ssldir"; then
 855         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 856 fi
 857 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 858 #include <string.h>
 859 #include <openssl/ssl.h>
 860 #include <openssl/evp.h>
 861 #include <openssl/engine.h>
 862 #include <openssl/conf.h>
 863 /* routine to load gost (from sldns) */
 864 int load_gost_id(void)
 865 {
 866         static int gost_id = 0;
 867         const EVP_PKEY_ASN1_METHOD* meth;
 868         ENGINE* e;
 869
 870         if(gost_id) return gost_id;
 871
 872         /* see if configuration loaded gost implementation from other engine*/
 873         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 874         if(meth) {
 875                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 876                 return gost_id;
 877         }
 878
 879         /* see if engine can be loaded already */
 880         e = ENGINE_by_id("gost");
 881         if(!e) {
 882                 /* load it ourself, in case statically linked */
 883                 ENGINE_load_builtin_engines();
 884                 ENGINE_load_dynamic();
 885                 e = ENGINE_by_id("gost");
 886         }
 887         if(!e) {
 888                 /* no gost engine in openssl */
 889                 return 0;
 890         }
 891         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 892                 ENGINE_finish(e);
 893                 ENGINE_free(e);
 894                 return 0;
 895         }
 896
 897         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 898         if(!meth) {
 899                 /* algo not found */
 900                 ENGINE_finish(e);
 901                 ENGINE_free(e);
 902                 return 0;
 903         }
 904         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 905         return gost_id;
 906 }
 907 int main(void) {
 908         EVP_MD_CTX* ctx;
 909         const EVP_MD* md;
 910         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 911         const char* str = "Hello world";
 912         const unsigned char check[] = {
 913                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 914                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 915                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 916                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 917         };
 918         OPENSSL_config(NULL);
 919         (void)load_gost_id();
 920         md = EVP_get_digestbyname("md_gost94");
 921         if(!md) return 1;
 922         memset(digest, 0, sizeof(digest));
 923         ctx = EVP_MD_CTX_create();
 924         if(!ctx) return 2;
 925         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 926         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 927         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 928         /* uncomment to see the hash calculated.
 929                 {int i;
 930                 for(i=0; i<32; i++)
 931                         printf(" %2.2x", (int)digest[i]);
 932                 printf("\n");}
 933         */
 934         if(memcmp(digest, check, sizeof(check)) != 0)
 935                 return 6;
 936         return 0;
 937 }
 938 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 939 CFLAGS="$BAKCFLAGS"
 940 else
 941 eval "ac_cv_c_gost_works=maybe"
 942 fi
 943 AC_MSG_RESULT($ac_cv_c_gost_works)
 944 ])dnl
 945
 946 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 947 use_gost="no"
 948 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 949 case "$enable_gost" in
 950         no)
 951         ;;
 952         *)
 953         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 954         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 955         AC_CHECK_GOST_WORKS
 956         if test "$ac_cv_c_gost_works" != no; then
 957                 use_gost="yes"
 958                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 959         fi
 960         ;;
 961 esac
 962 fi dnl !USE_NSS && !USE_NETTLE
 963
 964 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 965 use_ecdsa="no"
 966 case "$enable_ecdsa" in
 967     no)
 968       ;;
 969     *)
 970       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 971               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 972               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 973               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 974 #include <openssl/evp.h>
 975               ])
 976               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 977               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 978               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 979                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 980                   AC_MSG_RESULT([no])
 981                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 982                 else
 983                   AC_MSG_RESULT([yes])
 984                 fi
 985               else
 986                 # not OpenSSL, thus likely LibreSSL, which supports it
 987                 AC_MSG_RESULT([yes])
 988               fi
 989       fi
 990       # we now know we have ECDSA and the required curves.
 991       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 992       use_ecdsa="yes"
 993       ;;
 994 esac
 995
 996 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 997 use_dsa="no"
 998 case "$enable_dsa" in
 999     no)
1000       ;;
1001     *)
1002       # detect if DSA is supported, and turn it off if not.
1003       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1004       AC_CHECK_FUNC(DSA_SIG_new, [
1005       AC_CHECK_TYPE(DSA_SIG*, [
1006       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1007       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1008                fi ], [
1009 AC_INCLUDES_DEFAULT
1010 #ifdef HAVE_OPENSSL_ERR_H
1011 #include <openssl/err.h>
1012 #endif
1013
1014 #ifdef HAVE_OPENSSL_RAND_H
1015 #include <openssl/rand.h>
1016 #endif
1017
1018 #ifdef HAVE_OPENSSL_CONF_H
1019 #include <openssl/conf.h>
1020 #endif
1021
1022 #ifdef HAVE_OPENSSL_ENGINE_H
1023 #include <openssl/engine.h>
1024 #endif
1025       ])
1026       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1027                fi ])
1028       else
1029       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1030       fi
1031       ;;
1032 esac
1033
1034 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1035 use_ed25519="no"
1036 case "$enable_ed25519" in
1037     no)
1038       ;;
1039     *)
1040       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1041               AC_CHECK_DECLS([NID_ED25519], [
1042                 use_ed25519="yes"
1043               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1044                 fi ], [AC_INCLUDES_DEFAULT
1045 #include <openssl/evp.h>
1046               ])
1047       fi
1048       if test $USE_NETTLE = "yes"; then
1049                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1050       fi
1051       if test $use_ed25519 = "yes"; then
1052                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1053       fi
1054       ;;
1055 esac
1056
1057 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1058 use_ed448="no"
1059 case "$enable_ed448" in
1060     no)
1061       ;;
1062     *)
1063       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1064               AC_CHECK_DECLS([NID_ED448], [
1065                 use_ed448="yes"
1066               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1067                 fi ], [AC_INCLUDES_DEFAULT
1068 #include <openssl/evp.h>
1069               ])
1070       fi
1071       if test $use_ed448 = "yes"; then
1072                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1073       fi
1074       ;;
1075 esac
1076
1077 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1078 case "$enable_event_api" in
1079     yes)
1080       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1081       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1082       ;;
1083     *)
1084       ;;
1085 esac
1086
1087 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1088 case "$enable_tfo_client" in
1089         yes)
1090                 case `uname` in
1091                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1092                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1093                                              [AC_INCLUDES_DEFAULT
1094 #include <netinet/tcp.h>
1095 ])
1096                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1097                           ;;
1098                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1099                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1100                                               [AC_INCLUDES_DEFAULT
1101 #include <sys/socket.h>
1102 ])
1103                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1104                           ;;
1105                 esac
1106         ;;
1107         no|*)
1108                 ;;
1109 esac
1110
1111 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1112 case "$enable_tfo_server" in
1113         yes)
1114               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1115 #include <netinet/tcp.h>
1116               ])
1117                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1118                 ;;
1119         no|*)
1120                 ;;
1121 esac
1122
1123 # check for libevent
1124 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1125     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1126     [ ],[ withval="no" ])
1127 if test x_$withval = x_yes -o x_$withval != x_no; then
1128         AC_MSG_CHECKING(for libevent)
1129         if test x_$withval = x_ -o x_$withval = x_yes; then
1130             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1131         fi
1132         for dir in $withval; do
1133             thedir="$dir"
1134             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1135                 found_libevent="yes"
1136                 dnl assume /usr is in default path.
1137                 if test "$thedir" != "/usr"; then
1138                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1139                 fi
1140                 break;
1141             fi
1142         done
1143         if test x_$found_libevent != x_yes; then
1144                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1145                         # libevent source directory
1146                         AC_MSG_RESULT(found in $thedir)
1147                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1148                         BAK_LDFLAGS_SET="1"
1149                         BAK_LDFLAGS="$LDFLAGS"
1150                         # remove evdns from linking
1151                         mkdir build >/dev/null 2>&1
1152                         mkdir build/libevent >/dev/null 2>&1
1153                         mkdir build/libevent/.libs >/dev/null 2>&1
1154                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1155                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1156                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1157                         cp $ev_files_o build/libevent
1158                         cp $ev_files_lo build/libevent
1159                         cp $ev_files_libso build/libevent/.libs
1160                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1161                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1162                 else
1163                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1164 You can restart ./configure --with-libevent=no to use a builtin alternative.
1165 Please note that this alternative is not as capable as libevent when using
1166 large outgoing port ranges.  ])
1167                 fi
1168         else
1169             AC_MSG_RESULT(found in $thedir)
1170             dnl if event2 exists and no event lib in dir itself, use subdir
1171             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1172                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1173                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1174             else
1175                     dnl assume /usr is in default path, do not add "".
1176                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1177                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1178                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1179                     fi
1180             fi
1181         fi
1182         # check for library used by libevent after 1.3c
1183         AC_SEARCH_LIBS([clock_gettime], [rt])
1184
1185         # is the event.h header libev or libevent?
1186         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1187         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1188                 AC_SEARCH_LIBS(event_set, [ev])
1189         ],[
1190                 AC_SEARCH_LIBS(event_set, [event])
1191         ],[AC_INCLUDES_DEFAULT
1192 #include <event.h>
1193         ])
1194         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1195         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1196         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1197         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1198         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1199         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1200         PC_LIBEVENT_DEPENDENCY="libevent"
1201         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1202         if test -n "$BAK_LDFLAGS_SET"; then
1203                 LDFLAGS="$BAK_LDFLAGS"
1204         fi
1205 else
1206         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1207 fi
1208
1209 # check for libexpat
1210 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1211     [specify explicit path for libexpat.]),
1212     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1213 AC_MSG_CHECKING(for libexpat)
1214 found_libexpat="no"
1215 for dir in $withval ; do
1216             if test -f "$dir/include/expat.h"; then
1217                 found_libexpat="yes"
1218                 dnl assume /usr is in default path.
1219                 if test "$dir" != "/usr"; then
1220                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1221                     LDFLAGS="$LDFLAGS -L$dir/lib"
1222                 fi
1223                 AC_MSG_RESULT(found in $dir)
1224                 break;
1225             fi
1226 done
1227 if test x_$found_libexpat != x_yes; then
1228         AC_ERROR([Could not find libexpat, expat.h])
1229 fi
1230 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1231 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1232 #include <expat.h>
1233 ])
1234
1235 # hiredis (redis C client for cachedb)
1236 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1237     [specify explicit path for libhiredis.]),
1238     [ ],[ withval="no" ])
1239 found_libhiredis="no"
1240 if test x_$withval = x_yes -o x_$withval != x_no; then
1241    AC_MSG_CHECKING(for libhiredis)
1242    if test x_$withval = x_ -o x_$withval = x_yes; then
1243             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1244    fi
1245    for dir in $withval ; do
1246             if test -f "$dir/include/hiredis/hiredis.h"; then
1247                 found_libhiredis="yes"
1248                 dnl assume /usr is in default path.
1249                 if test "$dir" != "/usr"; then
1250                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1251                     LDFLAGS="$LDFLAGS -L$dir/lib"
1252                 fi
1253                 AC_MSG_RESULT(found in $dir)
1254                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1255                 LIBS="$LIBS -lhiredis"
1256                 break;
1257             fi
1258     done
1259     if test x_$found_libhiredis != x_yes; then
1260         AC_ERROR([Could not find libhiredis, hiredis.h])
1261     fi
1262     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1263     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1264     #include <hiredis/hiredis.h>
1265     ])
1266 fi
1267
1268 # set static linking if requested
1269 AC_SUBST(staticexe)
1270 staticexe=""
1271 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1272         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1273         , )
1274 if test x_$enable_static_exe = x_yes; then
1275         staticexe="-static"
1276         if test "$on_mingw" = yes; then
1277                 staticexe="-all-static"
1278                 # for static compile, include gdi32 and zlib here.
1279                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1280                         :
1281                 else
1282                         LIBS="$LIBS -lgdi32"
1283                 fi
1284                 LIBS="$LIBS -lz"
1285         fi
1286 fi
1287
1288 # Include systemd.m4 - begin
1289 sinclude(systemd.m4)
1290 # Include systemd.m4 - end
1291
1292 # set lock checking if requested
1293 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1294         [ enable to check lock and unlock calls, for debug purposes ]),
1295         , )
1296 if test x_$enable_lock_checks = x_yes; then
1297         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1298         CHECKLOCK_OBJ="checklocks.lo"
1299         AC_SUBST(CHECKLOCK_OBJ)
1300 fi
1301
1302 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1303 if test "$USE_WINSOCK" = 1; then
1304         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1305         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1306 #include <windows.h>
1307         ])
1308         AC_CHECK_TOOL(WINDRES, windres)
1309         LIBS="$LIBS -liphlpapi -lcrypt32"
1310         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1311         AC_SUBST(WINAPPS)
1312         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1313         AC_SUBST(WIN_DAEMON_SRC)
1314         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1315         AC_SUBST(WIN_DAEMON_OBJ)
1316         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1317         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1318         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1319         AC_SUBST(WIN_HOST_OBJ_LINK)
1320         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1321         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1322         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1323         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1324         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1325         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1326 fi
1327 if test $ac_cv_func_getaddrinfo = no; then
1328         AC_LIBOBJ([fake-rfc2553])
1329 fi
1330 # check after getaddrinfo for its libraries
1331 ACX_FUNC_IOCTLSOCKET
1332
1333 # see if daemon(3) exists, and if it is deprecated.
1334 AC_CHECK_FUNCS([daemon])
1335 if test $ac_cv_func_daemon = yes; then
1336         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1337 #include <stdlib.h>
1338 ])
1339 fi
1340
1341 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1342 AC_INCLUDES_DEFAULT
1343 #ifdef HAVE_SYS_UN_H
1344 #include <sys/un.h>
1345 #endif
1346 ])
1347 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1348 AC_INCLUDES_DEFAULT
1349 #if HAVE_SYS_PARAM_H
1350 #include <sys/param.h>
1351 #endif
1352
1353 #ifdef HAVE_SYS_SOCKET_H
1354 #include <sys/socket.h>
1355 #endif
1356
1357 #ifdef HAVE_SYS_UIO_H
1358 #include <sys/uio.h>
1359 #endif
1360
1361 #ifdef HAVE_NETINET_IN_H
1362 #include <netinet/in.h>
1363 #endif
1364
1365 #ifdef HAVE_NETINET_TCP_H
1366 #include <netinet/tcp.h>
1367 #endif
1368
1369 #ifdef HAVE_ARPA_INET_H
1370 #include <arpa/inet.h>
1371 #endif
1372
1373 #ifdef HAVE_WINSOCK2_H
1374 #include <winsock2.h>
1375 #endif
1376
1377 #ifdef HAVE_WS2TCPIP_H
1378 #include <ws2tcpip.h>
1379 #endif
1380 ])
1381 AC_SEARCH_LIBS([setusercontext], [util])
1382 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1383 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1384 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1385
1386 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1387 if echo $target_os | grep darwin8 > /dev/null; then
1388         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1389 fi
1390 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1391 AC_INCLUDES_DEFAULT
1392 #ifdef HAVE_NETINET_IN_H
1393 #include <netinet/in.h>
1394 #endif
1395
1396 #ifdef HAVE_NETINET_TCP_H
1397 #include <netinet/tcp.h>
1398 #endif
1399
1400 #ifdef HAVE_ARPA_INET_H
1401 #include <arpa/inet.h>
1402 #endif
1403
1404 #ifdef HAVE_WINSOCK2_H
1405 #include <winsock2.h>
1406 #endif
1407
1408 #ifdef HAVE_WS2TCPIP_H
1409 #include <ws2tcpip.h>
1410 #endif
1411 ])
1412 AC_REPLACE_FUNCS(inet_aton)
1413 AC_REPLACE_FUNCS(inet_pton)
1414 AC_REPLACE_FUNCS(inet_ntop)
1415 AC_REPLACE_FUNCS(snprintf)
1416 # test if snprintf return the proper length
1417 if test "x$ac_cv_func_snprintf" = xyes; then
1418     if test c${cross_compiling} = cno; then
1419         AC_MSG_CHECKING([for correct snprintf return value])
1420         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1421 [[
1422 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1423 ]])], [AC_MSG_RESULT(yes)], [
1424                 AC_MSG_RESULT(no)
1425                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1426                 AC_LIBOBJ(snprintf)
1427           ])
1428     fi
1429 fi
1430 AC_REPLACE_FUNCS(strlcat)
1431 AC_REPLACE_FUNCS(strlcpy)
1432 AC_REPLACE_FUNCS(memmove)
1433 AC_REPLACE_FUNCS(gmtime_r)
1434 AC_REPLACE_FUNCS(isblank)
1435 AC_REPLACE_FUNCS(explicit_bzero)
1436 dnl without CTIME, ARC4-functions and without reallocarray.
1437 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1438 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1439 AC_REPLACE_FUNCS(reallocarray)
1440 if test "$USE_NSS" = "no"; then
1441         AC_REPLACE_FUNCS(arc4random)
1442         AC_REPLACE_FUNCS(arc4random_uniform)
1443         if test "$ac_cv_func_arc4random" = "no"; then
1444                 AC_LIBOBJ(arc4_lock)
1445                 AC_CHECK_FUNCS([getentropy],,[
1446                     if test "$USE_WINSOCK" = 1; then
1447                         AC_LIBOBJ(getentropy_win)
1448                     else
1449                         case "$host" in
1450                         Darwin|*darwin*)
1451                                 AC_LIBOBJ(getentropy_osx)
1452                         ;;
1453                         *solaris*|*sunos*|SunOS)
1454                                 AC_LIBOBJ(getentropy_solaris)
1455                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1456                                         AC_CHECK_FUNCS([SHA512_Update],,[
1457                                                 AC_LIBOBJ(sha512)
1458                                         ])
1459                                 ], [AC_INCLUDES_DEFAULT])
1460                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1461                                         # this lib needed for sha2 on solaris
1462                                         LIBS="$LIBS -lmd"
1463                                 fi
1464                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1465                         ;;
1466                         *linux*|Linux|*)
1467                                 AC_LIBOBJ(getentropy_linux)
1468                                 AC_CHECK_FUNCS([SHA512_Update],,[
1469                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1470                                         AC_LIBOBJ(sha512)
1471                                 ])
1472                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1473                                 AC_CHECK_FUNCS([getauxval])
1474                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1475                         ;;
1476                         esac
1477                     fi
1478                 ])
1479         fi
1480 fi
1481 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1482 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1483 AC_REPLACE_FUNCS(ctime_r)
1484 AC_REPLACE_FUNCS(strsep)
1485
1486 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1487 case "$enable_allsymbols" in
1488         yes)
1489         COMMON_OBJ_ALL_SYMBOLS=""
1490         UBSYMS=""
1491         EXTRALINK="-L. -L.libs -lunbound"
1492         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1493         ;;
1494         no|*)
1495         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1496         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1497         EXTRALINK=""
1498         ;;
1499 esac
1500 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1501 AC_SUBST(EXTRALINK)
1502 AC_SUBST(UBSYMS)
1503 if test x_$enable_lock_checks = x_yes; then
1504         UBSYMS="-export-symbols clubsyms.def"
1505         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1506         echo lock_protect >> clubsyms.def
1507         echo lock_unprotect >> clubsyms.def
1508         echo lock_get_mem >> clubsyms.def
1509         echo checklock_start >> clubsyms.def
1510         echo checklock_stop >> clubsyms.def
1511         echo checklock_lock >> clubsyms.def
1512         echo checklock_unlock >> clubsyms.def
1513         echo checklock_init >> clubsyms.def
1514         echo checklock_thrcreate >> clubsyms.def
1515         echo checklock_thrjoin >> clubsyms.def
1516 fi
1517
1518 # check for dnstap if requested
1519 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1520     [
1521         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1522         AC_SUBST([ENABLE_DNSTAP], [1])
1523
1524         AC_SUBST([opt_dnstap_socket_path])
1525         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1526         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1527             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1528
1529         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1530         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1531     ],
1532     [
1533         AC_SUBST([ENABLE_DNSTAP], [0])
1534     ]
1535 )
1536
1537 # check for dnscrypt if requested
1538 dnsc_DNSCRYPT([
1539         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1540         AC_SUBST([ENABLE_DNSCRYPT], [1])
1541
1542         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1543         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1544     ],
1545     [
1546         AC_SUBST([ENABLE_DNSCRYPT], [0])
1547     ]
1548 )
1549
1550 # check for cachedb if requested
1551 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1552 # turn on cachedb when hiredis support is enabled.
1553 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1554 case "$enable_cachedb" in
1555     yes)
1556         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1557         ;;
1558     no|*)
1559         # nothing
1560         ;;
1561 esac
1562
1563 # check for ipsecmod if requested
1564 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1565 case "$enable_ipsecmod" in
1566         yes)
1567                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1568                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1569                 AC_SUBST(IPSECMOD_OBJ)
1570                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1571                 AC_SUBST(IPSECMOD_HEADER)
1572                 ;;
1573         no|*)
1574                 # nothing
1575                 ;;
1576 esac
1577
1578 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1579 # on openBSD, the implicit rule make $< work.
1580 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1581 # gmake works.
1582 cat >conftest.make <<EOF
1583 all:    conftest.lo
1584
1585 conftest.lo foo.lo bla.lo:
1586         if test -f "\$<"; then touch \$@; fi
1587
1588 .SUFFIXES: .lo
1589 .c.lo:
1590         if test -f "\$<"; then touch \$@; fi
1591
1592 conftest.lo:        conftest.dir/conftest.c
1593 EOF
1594 mkdir conftest.dir
1595 touch conftest.dir/conftest.c
1596 rm -f conftest.lo conftest.c
1597 ${MAKE:-make} -f conftest.make >/dev/null
1598 rm -f conftest.make conftest.c conftest.dir/conftest.c
1599 rm -rf conftest.dir
1600 if test ! -f conftest.lo; then
1601         AC_MSG_RESULT(no)
1602         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1603         SOURCEFILE='`cat .source`'
1604 else
1605         AC_MSG_RESULT(yes)
1606         SOURCEDETERMINE=':'
1607         SOURCEFILE='$<'
1608 fi
1609 rm -f conftest.lo
1610 AC_SUBST(SOURCEDETERMINE)
1611 AC_SUBST(SOURCEFILE)
1612
1613 # see if we want to build the library or everything
1614 ALLTARGET="alltargets"
1615 INSTALLTARGET="install-all"
1616 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1617         [do not build daemon and tool programs]),
1618         [
1619         if test "$withval" = "yes"; then
1620                 ALLTARGET="lib"
1621                 INSTALLTARGET="install-lib"
1622         fi
1623 ])
1624 if test $ALLTARGET = "alltargets"; then
1625         if test $USE_NSS = "yes"; then
1626                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1627         fi
1628         if test $USE_NETTLE = "yes"; then
1629                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1630         fi
1631 fi
1632
1633 AC_SUBST(ALLTARGET)
1634 AC_SUBST(INSTALLTARGET)
1635
1636 ACX_STRIP_EXT_FLAGS
1637 if test -n "$LATE_LDFLAGS"; then
1638   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1639 fi
1640 # remove start spaces
1641 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1642 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1643
1644 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1645
1646 AH_BOTTOM(
1647 dnl this must be first AH_CONFIG, to define the flags before any includes.
1648 AHX_CONFIG_EXT_FLAGS
1649
1650 dnl includes
1651 [
1652 #ifndef UNBOUND_DEBUG
1653 #  define NDEBUG
1654 #endif
1655
1656 /** Use small-ldns codebase */
1657 #define USE_SLDNS 1
1658 #ifdef HAVE_SSL
1659 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1660 #endif
1661
1662 #include <stdio.h>
1663 #include <string.h>
1664 #include <unistd.h>
1665 #include <assert.h>
1666
1667 #if STDC_HEADERS
1668 #include <stdlib.h>
1669 #include <stddef.h>
1670 #endif
1671
1672 #ifdef HAVE_STDARG_H
1673 #include <stdarg.h>
1674 #endif
1675
1676 #ifdef HAVE_STDINT_H
1677 #include <stdint.h>
1678 #endif
1679
1680 #include <errno.h>
1681
1682 #if HAVE_SYS_PARAM_H
1683 #include <sys/param.h>
1684 #endif
1685
1686 #ifdef HAVE_SYS_SOCKET_H
1687 #include <sys/socket.h>
1688 #endif
1689
1690 #ifdef HAVE_SYS_UIO_H
1691 #include <sys/uio.h>
1692 #endif
1693
1694 #ifdef HAVE_NETINET_IN_H
1695 #include <netinet/in.h>
1696 #endif
1697
1698 #ifdef HAVE_NETINET_TCP_H
1699 #include <netinet/tcp.h>
1700 #endif
1701
1702 #ifdef HAVE_ARPA_INET_H
1703 #include <arpa/inet.h>
1704 #endif
1705
1706 #ifdef HAVE_WINSOCK2_H
1707 #include <winsock2.h>
1708 #endif
1709
1710 #ifdef HAVE_WS2TCPIP_H
1711 #include <ws2tcpip.h>
1712 #endif
1713
1714 #ifndef USE_WINSOCK
1715 #define ARG_LL "%ll"
1716 #else
1717 #define ARG_LL "%I64"
1718 #endif
1719
1720 #ifndef AF_LOCAL
1721 #define AF_LOCAL AF_UNIX
1722 #endif
1723 ]
1724
1725 AHX_CONFIG_FORMAT_ATTRIBUTE
1726 AHX_CONFIG_UNUSED_ATTRIBUTE
1727 AHX_CONFIG_FSEEKO
1728 AHX_CONFIG_MAXHOSTNAMELEN
1729 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1730 #define snprintf snprintf_unbound
1731 #define vsnprintf vsnprintf_unbound
1732 #include <stdarg.h>
1733 int snprintf (char *str, size_t count, const char *fmt, ...);
1734 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1735 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1736 AHX_CONFIG_INET_PTON(unbound)
1737 AHX_CONFIG_INET_NTOP(unbound)
1738 AHX_CONFIG_INET_ATON(unbound)
1739 AHX_CONFIG_MEMMOVE(unbound)
1740 AHX_CONFIG_STRLCAT(unbound)
1741 AHX_CONFIG_STRLCPY(unbound)
1742 AHX_CONFIG_GMTIME_R(unbound)
1743 AHX_CONFIG_REALLOCARRAY(unbound)
1744 AHX_CONFIG_W32_SLEEP
1745 AHX_CONFIG_W32_USLEEP
1746 AHX_CONFIG_W32_RANDOM
1747 AHX_CONFIG_W32_SRANDOM
1748 AHX_CONFIG_W32_FD_SET_T
1749 AHX_CONFIG_IPV6_MIN_MTU
1750 AHX_MEMCMP_BROKEN(unbound)
1751
1752 [
1753 #ifndef HAVE_CTIME_R
1754 #define ctime_r unbound_ctime_r
1755 char *ctime_r(const time_t *timep, char *buf);
1756 #endif
1757
1758 #ifndef HAVE_STRSEP
1759 #define strsep unbound_strsep
1760 char *strsep(char **stringp, const char *delim);
1761 #endif
1762
1763 #ifndef HAVE_ISBLANK
1764 #define isblank unbound_isblank
1765 int isblank(int c);
1766 #endif
1767
1768 #ifndef HAVE_EXPLICIT_BZERO
1769 #define explicit_bzero unbound_explicit_bzero
1770 void explicit_bzero(void* buf, size_t len);
1771 #endif
1772
1773 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1774 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1775 #endif
1776
1777 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1778 int inet_pton(int af, const char* src, void* dst);
1779 #endif
1780
1781 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1782 #define strptime unbound_strptime
1783 struct tm;
1784 char *strptime(const char *s, const char *format, struct tm *tm);
1785 #endif
1786
1787 #ifdef HAVE_LIBRESSL
1788 #  if !HAVE_DECL_STRLCPY
1789 size_t strlcpy(char *dst, const char *src, size_t siz);
1790 #  endif
1791 #  if !HAVE_DECL_STRLCAT
1792 size_t strlcat(char *dst, const char *src, size_t siz);
1793 #  endif
1794 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1795 uint32_t arc4random(void);
1796 #  endif
1797 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1798 uint32_t arc4random_uniform(uint32_t upper_bound);
1799 #  endif
1800 #  if !HAVE_DECL_REALLOCARRAY
1801 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1802 #  endif
1803 #endif /* HAVE_LIBRESSL */
1804 #ifndef HAVE_ARC4RANDOM
1805 int getentropy(void* buf, size_t len);
1806 uint32_t arc4random(void);
1807 void arc4random_buf(void* buf, size_t n);
1808 void _ARC4_LOCK(void);
1809 void _ARC4_UNLOCK(void);
1810 void _ARC4_LOCK_DESTROY(void);
1811 #endif
1812 #ifndef HAVE_ARC4RANDOM_UNIFORM
1813 uint32_t arc4random_uniform(uint32_t upper_bound);
1814 #endif
1815 #ifdef COMPAT_SHA512
1816 #ifndef SHA512_DIGEST_LENGTH
1817 #define SHA512_BLOCK_LENGTH             128
1818 #define SHA512_DIGEST_LENGTH            64
1819 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1820 typedef struct _SHA512_CTX {
1821         uint64_t        state[8];
1822         uint64_t        bitcount[2];
1823         uint8_t buffer[SHA512_BLOCK_LENGTH];
1824 } SHA512_CTX;
1825 #endif /* SHA512_DIGEST_LENGTH */
1826 void SHA512_Init(SHA512_CTX*);
1827 void SHA512_Update(SHA512_CTX*, void*, size_t);
1828 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1829 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1830 #endif /* COMPAT_SHA512 */
1831
1832
1833
1834 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1835    /* using version of libevent that is not threadsafe. */
1836 #  define LIBEVENT_SIGNAL_PROBLEM 1
1837 #endif
1838
1839 #ifndef CHECKED_INET6
1840 #  define CHECKED_INET6
1841 #  ifdef AF_INET6
1842 #    define INET6
1843 #  else
1844 #    define AF_INET6        28
1845 #  endif
1846 #endif /* CHECKED_INET6 */
1847
1848 #ifndef HAVE_GETADDRINFO
1849 struct sockaddr_storage;
1850 #include "compat/fake-rfc2553.h"
1851 #endif
1852
1853 #ifdef UNBOUND_ALLOC_STATS
1854 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1855 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1856 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1857 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1858 void *unbound_stat_malloc(size_t size);
1859 void *unbound_stat_calloc(size_t nmemb, size_t size);
1860 void unbound_stat_free(void *ptr);
1861 void *unbound_stat_realloc(void *ptr, size_t size);
1862 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1863         const char* func);
1864 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1865         int line, const char* func);
1866 void unbound_stat_free_log(void *ptr, const char* file, int line,
1867         const char* func);
1868 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1869         int line, const char* func);
1870 #elif defined(UNBOUND_ALLOC_LITE)
1871 #  include "util/alloc.h"
1872 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1873
1874 /** default port for DNS traffic. */
1875 #define UNBOUND_DNS_PORT 53
1876 /** default port for DNS over TLS traffic. */
1877 #define UNBOUND_DNS_OVER_TLS_PORT 853
1878 /** default port for unbound control traffic, registered port with IANA,
1879     ub-dns-control  8953/tcp    unbound dns nameserver control */
1880 #define UNBOUND_CONTROL_PORT 8953
1881 /** the version of unbound-control that this software implements */
1882 #define UNBOUND_CONTROL_VERSION 1
1883
1884 ])
1885
1886 dnl if we build from source tree, the man pages need @date@ and @version@
1887 dnl if this is a distro tarball, that was already done by makedist.sh
1888 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1889 AC_SUBST(date, [`date +'%b %e, %Y'`])
1890
1891 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1892 AC_CONFIG_HEADER([config.h])
1893 AC_OUTPUT