configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9
  10 # must be numbers. ac_defun because of later processing
  11 m4_define([VERSION_MAJOR],[1])
  12 m4_define([VERSION_MINOR],[5])
  13 m4_define([VERSION_MICRO],[9])
  14 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  15 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  16 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  17 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  18
  19 LIBUNBOUND_CURRENT=6
  20 LIBUNBOUND_REVISION=1
  21 LIBUNBOUND_AGE=4
  22 # 1.0.0 had 0:12:0
  23 # 1.0.1 had 0:13:0
  24 # 1.0.2 had 0:14:0
  25 # 1.1.0 had 0:15:0
  26 # 1.1.1 had 0:16:0
  27 # 1.2.0 had 0:17:0
  28 # 1.2.1 had 0:18:0
  29 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  30 # 1.3.1 had 1:1:0
  31 # 1.3.2 had 1:2:0
  32 # 1.3.3 had 1:3:0
  33 # 1.3.4 had 1:4:0
  34 # 1.4.0-snapshots had 1:5:0
  35 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  36 # 1.4.1 had 2:1:0
  37 # 1.4.2 had 2:2:0
  38 # 1.4.3 had 2:3:0
  39 # 1.4.4 had 2:4:0
  40 # 1.4.5 had 2:5:0
  41 # 1.4.6 had 2:6:0
  42 # 1.4.7 had 2:7:0
  43 # 1.4.8 had 2:8:0
  44 # 1.4.9 had 2:9:0
  45 # 1.4.10 had 2:10:0
  46 # 1.4.11 had 2:11:0
  47 # 1.4.12 had 2:12:0
  48 # 1.4.13 had 2:13:0
  49 # and 1.4.13p1 and 1.4.13.p2
  50 # 1.4.14 had 2:14:0
  51 # 1.4.15 had 3:0:1 # adds ub_version()
  52 # 1.4.16 had 3:1:1
  53 # 1.4.17 had 3:2:1
  54 # 1.4.18 had 3:3:1
  55 # 1.4.19 had 3:4:1
  56 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  57 # 1.4.21 had 4:1:2
  58 # 1.4.22 had 4:1:2
  59 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  60 # 1.5.1 had 5:3:3
  61 # 1.5.2 had 5:5:3
  62 # 1.5.3 had 5:6:3
  63 # 1.5.4 had 5:7:3
  64 # 1.5.5 had 5:8:3
  65 # 1.5.6 had 5:9:3
  66 # 1.5.7 had 5:10:3
  67 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  68 # 1.5.9 had 6:1:4
  69
  70 #   Current  -- the number of the binary API that we're implementing
  71 #   Revision -- which iteration of the implementation of the binary
  72 #               API are we supplying?
  73 #   Age      -- How many previous binary API versions do we also
  74 #               support?
  75 #
  76 # If we release a new version that does not change the binary API,
  77 # increment Revision.
  78 #
  79 # If we release a new version that changes the binary API, but does
  80 # not break programs compiled against the old binary API, increment
  81 # Current and Age.  Set Revision to 0, since this is the first
  82 # implementation of the new API.
  83 #
  84 # Otherwise, we're changing the binary API and breaking bakward
  85 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  86 # since we're backward compatible with no previous APIs.  Set Revision
  87 # to 0 too.
  88 AC_SUBST(LIBUNBOUND_CURRENT)
  89 AC_SUBST(LIBUNBOUND_REVISION)
  90 AC_SUBST(LIBUNBOUND_AGE)
  91
  92 CFLAGS="$CFLAGS"
  93 AC_AIX
  94 if test "$ac_cv_header_minix_config_h" = "yes"; then
  95         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
  96 fi
  97
  98 dnl
  99 dnl By default set prefix to /usr/local
 100 dnl
 101 case "$prefix" in
 102         NONE)
 103                 prefix="/usr/local"
 104         ;;
 105 esac
 106
 107 # are we on MinGW?
 108 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 109 else
 110         if echo $target | grep mingw32 >/dev/null; then on_mingw="yes"
 111         else on_mingw="no"; fi
 112 fi
 113
 114 #
 115 # Determine configuration file
 116 # the eval is to evaluate shell expansion twice
 117 if test $on_mingw = "no"; then
 118   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 119 else
 120   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 121 fi
 122 AC_ARG_WITH([conf_file],
 123         AC_HELP_STRING([--with-conf-file=path],
 124         [Pathname to the Unbound configuration file]),
 125         [ub_conf_file="$withval"])
 126 AC_SUBST(ub_conf_file)
 127 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 128 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 129 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 130 AC_SUBST(ub_conf_dir)
 131
 132 # Determine run, chroot directory and pidfile locations
 133 AC_ARG_WITH(run-dir,
 134     AC_HELP_STRING([--with-run-dir=path],
 135     [set default directory to chdir to (by default dir part of cfg file)]),
 136     UNBOUND_RUN_DIR="$withval",
 137 if test $on_mingw = no; then
 138     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 139 else
 140     UNBOUND_RUN_DIR=""
 141 fi
 142 )
 143 AC_SUBST(UNBOUND_RUN_DIR)
 144 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 145 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 146
 147 AC_ARG_WITH(chroot-dir,
 148     AC_HELP_STRING([--with-chroot-dir=path],
 149     [set default directory to chroot to (by default same as run-dir)]),
 150     UNBOUND_CHROOT_DIR="$withval",
 151 if test $on_mingw = no; then
 152     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 153 else
 154     UNBOUND_CHROOT_DIR=""
 155 fi
 156 )
 157 AC_SUBST(UNBOUND_CHROOT_DIR)
 158 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 159 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 160
 161 AC_ARG_WITH(share-dir,
 162     AC_HELP_STRING([--with-share-dir=path],
 163     [set default directory with shared data (by default same as share/unbound)]),
 164     UNBOUND_SHARE_DIR="$withval",
 165     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 166 AC_SUBST(UNBOUND_SHARE_DIR)
 167 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 168
 169 AC_ARG_WITH(pidfile,
 170     AC_HELP_STRING([--with-pidfile=filename],
 171     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 172     UNBOUND_PIDFILE="$withval",
 173 if test $on_mingw = no; then
 174     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 175 else
 176     UNBOUND_PIDFILE=""
 177 fi
 178 )
 179 AC_SUBST(UNBOUND_PIDFILE)
 180 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 181 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 182
 183 AC_ARG_WITH(rootkey-file,
 184     AC_HELP_STRING([--with-rootkey-file=filename],
 185     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 186     UNBOUND_ROOTKEY_FILE="$withval",
 187 if test $on_mingw = no; then
 188     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 189 else
 190     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 191 fi
 192 )
 193 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 194 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 195 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 196
 197 AC_ARG_WITH(rootcert-file,
 198     AC_HELP_STRING([--with-rootcert-file=filename],
 199     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 200     UNBOUND_ROOTCERT_FILE="$withval",
 201 if test $on_mingw = no; then
 202     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 203 else
 204     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 205 fi
 206 )
 207 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 208 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 209 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 210
 211 AC_ARG_WITH(username,
 212     AC_HELP_STRING([--with-username=user],
 213     [set default user that unbound changes to (default user is unbound)]),
 214     UNBOUND_USERNAME="$withval",
 215     UNBOUND_USERNAME="unbound")
 216 AC_SUBST(UNBOUND_USERNAME)
 217 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 218
 219 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 220 ACX_RSRC_VERSION(wnvs)
 221 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 222
 223 # Checks for typedefs, structures, and compiler characteristics.
 224 AC_C_CONST
 225 AC_LANG_C
 226 # allow user to override the -g -O2 flags.
 227 if test "x$CFLAGS" = "x" ; then
 228 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 229 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 230 fi
 231 AC_PROG_CC
 232 ACX_DEPFLAG
 233 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 234
 235 # debug mode flags warnings
 236 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 237 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 238 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 239 else debug_enabled="$enable_checking"; fi
 240 AC_SUBST(debug_enabled)
 241 case "$debug_enabled" in
 242         yes)
 243                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 244                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 245                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 246                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 247                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 248                 ;;
 249         no|*)
 250                 # nothing to do.
 251                 ;;
 252 esac
 253 ACX_CHECK_FLTO
 254 ACX_CHECK_PIE
 255 ACX_CHECK_RELRO_NOW
 256
 257 AC_C_INLINE
 258 ACX_CHECK_FORMAT_ATTRIBUTE
 259 ACX_CHECK_UNUSED_ATTRIBUTE
 260
 261 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 262 [AC_REQUIRE([AC_PROG_CC])
 263 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 264 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 265 [ac_cv_c_weak_attribute=no
 266 AC_TRY_COMPILE(
 267 [ #include <stdio.h>
 268 __attribute__((weak)) void f(int x) { printf("%d", x); }
 269 ], [
 270    f(1);
 271 ],
 272 [ac_cv_c_weak_attribute="yes"],
 273 [ac_cv_c_weak_attribute="no"])
 274 ])
 275
 276 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 277 if test $ac_cv_c_weak_attribute = yes; then
 278   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 279 fi
 280 ])dnl End of CHECK_WEAK_ATTRIBUTE
 281
 282 CHECK_WEAK_ATTRIBUTE
 283
 284 if test "$srcdir" != "."; then
 285         CPPFLAGS="$CPPFLAGS -I$srcdir"
 286 fi
 287
 288 AC_DEFUN([ACX_YYLEX_DESTROY], [
 289         AC_MSG_CHECKING([for yylex_destroy])
 290         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 291                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 292                 AC_MSG_RESULT(yes)
 293         else AC_MSG_RESULT(no); fi
 294 ])
 295
 296 AC_PROG_LEX
 297 ACX_YYLEX_DESTROY
 298 AC_PROG_YACC
 299 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 300 AC_CHECK_TOOL(STRIP, strip)
 301 ACX_LIBTOOL_C_ONLY
 302
 303 # Checks for header files.
 304 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h],,, [AC_INCLUDES_DEFAULT])
 305
 306 # check for types.
 307 # Using own tests for int64* because autoconf builtin only give 32bit.
 308 AC_CHECK_TYPE(int8_t, signed char)
 309 AC_CHECK_TYPE(int16_t, short)
 310 AC_CHECK_TYPE(int32_t, int)
 311 AC_CHECK_TYPE(int64_t, long long)
 312 AC_CHECK_TYPE(uint8_t, unsigned char)
 313 AC_CHECK_TYPE(uint16_t, unsigned short)
 314 AC_CHECK_TYPE(uint32_t, unsigned int)
 315 AC_CHECK_TYPE(uint64_t, unsigned long long)
 316 AC_TYPE_SIZE_T
 317 AC_CHECK_TYPE(ssize_t, int)
 318 AC_TYPE_UID_T
 319 AC_TYPE_PID_T
 320 AC_TYPE_OFF_T
 321 ACX_TYPE_U_CHAR
 322 ACX_TYPE_RLIM_T
 323 ACX_TYPE_SOCKLEN_T
 324 ACX_TYPE_IN_ADDR_T
 325 ACX_TYPE_IN_PORT_T
 326 ACX_CHECK_MEMCMP_SIGNED
 327
 328 AC_CHECK_SIZEOF(time_t,,[
 329 AC_INCLUDES_DEFAULT
 330 #ifdef TIME_WITH_SYS_TIME
 331 # include <sys/time.h>
 332 # include <time.h>
 333 #else
 334 # ifdef HAVE_SYS_TIME_H
 335 #  include <sys/time.h>
 336 # else
 337 #  include <time.h>
 338 # endif
 339 #endif
 340 ])
 341
 342 # add option to disable the evil rpath
 343 ACX_ARG_RPATH
 344 AC_SUBST(RUNTIME_PATH)
 345
 346 # check to see if libraries are needed for these functions.
 347 AC_SEARCH_LIBS([inet_pton], [nsl])
 348 AC_SEARCH_LIBS([socket], [socket])
 349
 350 # check wether strptime also works
 351 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 352 [AC_REQUIRE([AC_PROG_CC])
 353 AC_MSG_CHECKING(whether strptime works)
 354 if test c${cross_compiling} = cno; then
 355 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 356 #define _XOPEN_SOURCE 600
 357 #include <time.h>
 358 int main(void) { struct tm tm; char *res;
 359 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 360 if (!res) return 2;
 361 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 362 if (!res) return 1; return 0; }
 363 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 364 else
 365 eval "ac_cv_c_strptime_works=maybe"
 366 fi
 367 AC_MSG_RESULT($ac_cv_c_strptime_works)
 368 if test $ac_cv_c_strptime_works = no; then
 369 AC_LIBOBJ(strptime)
 370 else
 371 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 372 fi
 373 ])dnl
 374
 375 # check some functions of the OS before linking libs (while still runnable).
 376 AC_FUNC_CHOWN
 377 AC_FUNC_FORK
 378 AC_TYPE_SIGNAL
 379 AC_FUNC_FSEEKO
 380 ACX_SYS_LARGEFILE
 381 ACX_CHECK_NONBLOCKING_BROKEN
 382 ACX_MKDIR_ONE_ARG
 383 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 384
 385 # set memory allocation checking if requested
 386 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 387         [ enable to memory allocation statistics, for debug purposes ]),
 388         , )
 389 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 390         [ enable for lightweight alloc assertions, for debug purposes ]),
 391         , )
 392 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 393         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 394         , )
 395 if test x_$enable_alloc_nonregional = x_yes; then
 396         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 397 fi
 398 if test x_$enable_alloc_checks = x_yes; then
 399         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 400 else
 401         if test x_$enable_alloc_lite = x_yes; then
 402                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 403         else
 404                 ACX_FUNC_MALLOC([unbound])
 405         fi
 406 fi
 407
 408 # check windows threads (we use them, not pthreads, on windows).
 409 if test "$on_mingw" = "yes"; then
 410 # check windows threads
 411         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 412         AC_MSG_CHECKING([for CreateThread])
 413         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 414 #ifdef HAVE_WINDOWS_H
 415 #include <windows.h>
 416 #endif
 417 ], [
 418         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 419 ])],
 420         AC_MSG_RESULT(yes)
 421         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 422 ,
 423         AC_MSG_RESULT(no)
 424 )
 425
 426 else
 427 # not on mingw, check thread libraries.
 428
 429 # check for thread library.
 430 # check this first, so that the pthread lib does not get linked in via
 431 # libssl or libpython, and thus distorts the tests, and we end up using
 432 # the non-threadsafe C libraries.
 433 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 434  [use pthreads library, or --without-pthreads to disable threading support.]),
 435  [ ],[ withval="yes" ])
 436 ub_have_pthreads=no
 437 if test x_$withval != x_no; then
 438         AX_PTHREAD([
 439                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 440                 LIBS="$PTHREAD_LIBS $LIBS"
 441                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 442                 CC="$PTHREAD_CC"
 443                 ub_have_pthreads=yes
 444                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 445
 446                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 447                 AC_MSG_CHECKING([if -pthread unused during linking])
 448                 # catch clang warning 'argument unused during compilation'
 449                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 450 [[
 451 int main(void) {return 0;}
 452 ]])])
 453                 pthread_unused="yes"
 454                 # first compile
 455                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 456                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 457                 if test $? = 0; then
 458                         # then link
 459                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 460                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 461                         if test $? -ne 0; then
 462                                 AC_MSG_RESULT(yes)
 463                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 464                                 PTHREAD_CFLAGS_ONLY="-pthread"
 465                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 466                         else
 467                                 AC_MSG_RESULT(no)
 468                         fi
 469                 else
 470                         AC_MSG_RESULT(no)
 471                 fi # endif cc successful
 472                 rm -f conftest conftest.c conftest.o
 473                 fi # endif -pthread in CFLAGS
 474
 475                 ])
 476 fi
 477
 478 # check solaris thread library
 479 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 480         [use solaris native thread library.]), [ ],[ withval="no" ])
 481 ub_have_sol_threads=no
 482 if test x_$withval != x_no; then
 483         if test x_$ub_have_pthreads != x_no; then
 484             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 485         else
 486         AC_SEARCH_LIBS(thr_create, [thread],
 487         [
 488                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 489
 490                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 491                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 492                 ub_have_sol_threads=yes
 493         ] , [
 494                 AC_ERROR([no solaris threads found.])
 495         ])
 496         fi
 497 fi
 498
 499 fi # end of non-mingw check of thread libraries
 500
 501 # Check for PyUnbound
 502 AC_ARG_WITH(pyunbound,
 503    AC_HELP_STRING([--with-pyunbound],
 504    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 505    [], [ withval="no" ])
 506
 507 ub_test_python=no
 508 ub_with_pyunbound=no
 509 if test x_$withval != x_no; then
 510    ub_with_pyunbound=yes
 511    ub_test_python=yes
 512 fi
 513
 514 # Check for Python module
 515 AC_ARG_WITH(pythonmodule,
 516    AC_HELP_STRING([--with-pythonmodule],
 517    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 518    [], [ withval="no" ])
 519
 520 ub_with_pythonmod=no
 521 if test x_$withval != x_no; then
 522    ub_with_pythonmod=yes
 523    ub_test_python=yes
 524 fi
 525
 526 # Check for Python & SWIG only on PyUnbound or PyModule
 527 if test x_$ub_test_python != x_no; then
 528
 529    # Check for Python
 530    ub_have_python=no
 531    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 532    AC_PYTHON_DEVEL
 533    if test ! -z "$PYTHON_VERSION"; then
 534         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 535                 AC_ERROR([Python version >= 2.4.0 is required])
 536         fi
 537
 538       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 539       AC_SUBST(PY_MAJOR_VERSION)
 540       # Have Python
 541       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 542       LIBS="$PYTHON_LDFLAGS $LIBS"
 543       CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 544       ub_have_python=yes
 545
 546       # Check for SWIG
 547       ub_have_swig=no
 548       AC_PROG_SWIG
 549       AC_MSG_CHECKING(SWIG)
 550       if test ! -x "$SWIG"; then
 551          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 552       else
 553          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 554          AC_SUBST(swig, "$SWIG")
 555          AC_MSG_RESULT(present)
 556
 557          # If have Python & SWIG
 558          # Declare PythonMod
 559          if test x_$ub_with_pythonmod != x_no; then
 560             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 561             WITH_PYTHONMODULE=yes
 562             AC_SUBST(WITH_PYTHONMODULE)
 563             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 564             AC_SUBST(PYTHONMOD_OBJ)
 565             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 566             AC_SUBST(PYTHONMOD_HEADER)
 567             PYTHONMOD_INSTALL=pythonmod-install
 568             AC_SUBST(PYTHONMOD_INSTALL)
 569             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 570             AC_SUBST(PYTHONMOD_UNINSTALL)
 571          fi
 572
 573          # Declare PyUnbound
 574          if test x_$ub_with_pyunbound != x_no; then
 575             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 576             WITH_PYUNBOUND=yes
 577             AC_SUBST(WITH_PYUNBOUND)
 578             PYUNBOUND_OBJ="libunbound_wrap.lo"
 579             AC_SUBST(PYUNBOUND_OBJ)
 580             PYUNBOUND_TARGET="_unbound.la"
 581             AC_SUBST(PYUNBOUND_TARGET)
 582             PYUNBOUND_INSTALL=pyunbound-install
 583             AC_SUBST(PYUNBOUND_INSTALL)
 584             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 585             AC_SUBST(PYUNBOUND_UNINSTALL)
 586          fi
 587       fi
 588    else
 589       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 590       ub_with_pyunbound=no
 591       ub_with_pythonmod=no
 592    fi
 593 fi
 594
 595 if test "`uname`" = "NetBSD"; then
 596         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 597         AC_SUBST(NETBSD_LINTFLAGS)
 598 fi
 599 CONFIG_DATE=`date +%Y%m%d`
 600 AC_SUBST(CONFIG_DATE)
 601
 602 # Checks for libraries.
 603
 604 # libnss
 605 USE_NSS="no"
 606 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 607         [use libnss instead of openssl, installed at path.]),
 608         [
 609         USE_NSS="yes"
 610         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 611         if test "$withval" != "" -a "$withval" != "yes"; then
 612                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 613                 LDFLAGS="$LDFLAGS -L$withval/lib"
 614                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 615                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 616         else
 617                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 618                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 619         fi
 620         LIBS="$LIBS -lnss3 -lnspr4"
 621         SSLLIB=""
 622         ]
 623 )
 624
 625 # libnettle
 626 USE_NETTLE="no"
 627 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 628         [use libnettle as crypto library, installed at path.]),
 629         [
 630         USE_NETTLE="yes"
 631         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 632         if test "$withval" != "" -a "$withval" != "yes"; then
 633                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 634                 LDFLAGS="$LDFLAGS -L$withval/lib"
 635                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 636         else
 637                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 638         fi
 639         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 640         SSLLIB=""
 641         ]
 642 )
 643
 644 # openssl
 645 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 646 ACX_WITH_SSL
 647 ACX_LIB_SSL
 648 SSLLIB="-lssl"
 649 AC_MSG_CHECKING([for LibreSSL])
 650 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 651         AC_MSG_RESULT([yes])
 652         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 653         # libressl provides these compat functions, but they may also be
 654         # declared by the OS in libc.  See if they have been declared.
 655         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 656 else
 657         AC_MSG_RESULT([no])
 658 fi
 659 AC_CHECK_HEADERS([openssl/conf.h],,, [AC_INCLUDES_DEFAULT])
 660 AC_CHECK_HEADERS([openssl/engine.h],,, [AC_INCLUDES_DEFAULT])
 661 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new])
 662 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 663 AC_INCLUDES_DEFAULT
 664 #ifdef HAVE_OPENSSL_ERR_H
 665 #include <openssl/err.h>
 666 #endif
 667
 668 #ifdef HAVE_OPENSSL_RAND_H
 669 #include <openssl/rand.h>
 670 #endif
 671
 672 #ifdef HAVE_OPENSSL_CONF_H
 673 #include <openssl/conf.h>
 674 #endif
 675
 676 #ifdef HAVE_OPENSSL_ENGINE_H
 677 #include <openssl/engine.h>
 678 #endif
 679 #include <openssl/ssl.h>
 680 #include <openssl/evp.h>
 681 ])
 682 fi
 683 AC_SUBST(SSLLIB)
 684
 685
 686 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 687 case "$enable_sha2" in
 688         no)
 689         ;;
 690         yes|*)
 691         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 692         ;;
 693 esac
 694
 695 # check wether gost also works
 696 AC_DEFUN([AC_CHECK_GOST_WORKS],
 697 [AC_REQUIRE([AC_PROG_CC])
 698 AC_MSG_CHECKING([if GOST works])
 699 if test c${cross_compiling} = cno; then
 700 BAKCFLAGS="$CFLAGS"
 701 if test -n "$ssldir"; then
 702         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 703 fi
 704 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 705 #include <string.h>
 706 #include <openssl/ssl.h>
 707 #include <openssl/evp.h>
 708 #include <openssl/engine.h>
 709 #include <openssl/conf.h>
 710 /* routine to load gost (from sldns) */
 711 int load_gost_id(void)
 712 {
 713         static int gost_id = 0;
 714         const EVP_PKEY_ASN1_METHOD* meth;
 715         ENGINE* e;
 716
 717         if(gost_id) return gost_id;
 718
 719         /* see if configuration loaded gost implementation from other engine*/
 720         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 721         if(meth) {
 722                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 723                 return gost_id;
 724         }
 725
 726         /* see if engine can be loaded already */
 727         e = ENGINE_by_id("gost");
 728         if(!e) {
 729                 /* load it ourself, in case statically linked */
 730                 ENGINE_load_builtin_engines();
 731                 ENGINE_load_dynamic();
 732                 e = ENGINE_by_id("gost");
 733         }
 734         if(!e) {
 735                 /* no gost engine in openssl */
 736                 return 0;
 737         }
 738         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 739                 ENGINE_finish(e);
 740                 ENGINE_free(e);
 741                 return 0;
 742         }
 743
 744         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 745         if(!meth) {
 746                 /* algo not found */
 747                 ENGINE_finish(e);
 748                 ENGINE_free(e);
 749                 return 0;
 750         }
 751         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 752         return gost_id;
 753 }
 754 int main(void) {
 755         EVP_MD_CTX* ctx;
 756         const EVP_MD* md;
 757         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 758         const char* str = "Hello world";
 759         const unsigned char check[] = {
 760                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 761                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 762                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 763                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 764         };
 765         OPENSSL_config(NULL);
 766         (void)load_gost_id();
 767         md = EVP_get_digestbyname("md_gost94");
 768         if(!md) return 1;
 769         memset(digest, 0, sizeof(digest));
 770         ctx = EVP_MD_CTX_create();
 771         if(!ctx) return 2;
 772         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 773         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 774         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 775         /* uncomment to see the hash calculated.
 776                 {int i;
 777                 for(i=0; i<32; i++)
 778                         printf(" %2.2x", (int)digest[i]);
 779                 printf("\n");}
 780         */
 781         if(memcmp(digest, check, sizeof(check)) != 0)
 782                 return 6;
 783         return 0;
 784 }
 785 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 786 CFLAGS="$BAKCFLAGS"
 787 else
 788 eval "ac_cv_c_gost_works=maybe"
 789 fi
 790 AC_MSG_RESULT($ac_cv_c_gost_works)
 791 ])dnl
 792
 793 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 794 use_gost="no"
 795 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 796 case "$enable_gost" in
 797         no)
 798         ;;
 799         *)
 800         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 801         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 802         AC_CHECK_GOST_WORKS
 803         if test "$ac_cv_c_gost_works" != no; then
 804                 use_gost="yes"
 805                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 806         fi
 807         ;;
 808 esac
 809 fi dnl !USE_NSS && !USE_NETTLE
 810
 811 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 812 use_ecdsa="no"
 813 case "$enable_ecdsa" in
 814     no)
 815       ;;
 816     *)
 817       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 818               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 819               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 820               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 821 #include <openssl/evp.h>
 822               ])
 823               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 824               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 825               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 826                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 827                   AC_MSG_RESULT([no])
 828                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 829                 else
 830                   AC_MSG_RESULT([yes])
 831                 fi
 832               else
 833                 # not OpenSSL, thus likely LibreSSL, which supports it
 834                 AC_MSG_RESULT([yes])
 835               fi
 836       fi
 837       # we now know we have ECDSA and the required curves.
 838       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 839       use_ecdsa="yes"
 840       ;;
 841 esac
 842
 843 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 844 use_dsa="no"
 845 case "$enable_ecdsa" in
 846     no)
 847       ;;
 848     *)
 849       # detect if DSA is supported, and turn it off if not.
 850       AC_CHECK_FUNC(EVP_dss1, [
 851       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 852       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 853                fi ])
 854       ;;
 855 esac
 856
 857
 858 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
 859 case "$enable_event_api" in
 860     yes)
 861       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 862       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 863       ;;
 864     *)
 865       ;;
 866 esac
 867
 868 # check for libevent
 869 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
 870     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
 871     [ ],[ withval="no" ])
 872 if test x_$withval = x_yes -o x_$withval != x_no; then
 873         AC_MSG_CHECKING(for libevent)
 874         if test x_$withval = x_ -o x_$withval = x_yes; then
 875             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
 876         fi
 877         for dir in $withval; do
 878             thedir="$dir"
 879             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
 880                 found_libevent="yes"
 881                 dnl assume /usr is in default path.
 882                 if test "$thedir" != "/usr"; then
 883                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
 884                 fi
 885                 break;
 886             fi
 887         done
 888         if test x_$found_libevent != x_yes; then
 889                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
 890                         # libevent source directory
 891                         AC_MSG_RESULT(found in $thedir)
 892                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
 893                         BAK_LDFLAGS_SET="1"
 894                         BAK_LDFLAGS="$LDFLAGS"
 895                         # remove evdns from linking
 896                         mkdir build >/dev/null 2>&1
 897                         mkdir build/libevent >/dev/null 2>&1
 898                         mkdir build/libevent/.libs >/dev/null 2>&1
 899                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 900                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
 901                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 902                         cp $ev_files_o build/libevent
 903                         cp $ev_files_lo build/libevent
 904                         cp $ev_files_libso build/libevent/.libs
 905                         LATE_LDFLAGS="build/libevent/*.lo -lm"
 906                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
 907                 else
 908                         AC_MSG_ERROR([Cannot find the libevent library in $withval
 909 You can restart ./configure --with-libevent=no to use a builtin alternative.
 910 Please note that this alternative is not as capable as libevent when using
 911 large outgoing port ranges.  ])
 912                 fi
 913         else
 914             AC_MSG_RESULT(found in $thedir)
 915             dnl if event2 exists and no event lib in dir itself, use subdir
 916             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
 917                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
 918                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
 919             else
 920                     dnl assume /usr is in default path, do not add "".
 921                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
 922                         LDFLAGS="$LDFLAGS -L$thedir/lib"
 923                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
 924                     fi
 925             fi
 926         fi
 927         # check for library used by libevent after 1.3c
 928         AC_SEARCH_LIBS([clock_gettime], [rt])
 929
 930         # is the event.h header libev or libevent?
 931         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
 932         AC_CHECK_DECL(EV_VERSION_MAJOR, [
 933                 AC_SEARCH_LIBS(event_set, [ev])
 934         ],[
 935                 AC_SEARCH_LIBS(event_set, [event])
 936         ],[AC_INCLUDES_DEFAULT
 937 #include <event.h>
 938         ])
 939         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
 940         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
 941         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
 942         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
 943         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
 944         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
 945         if test -n "$BAK_LDFLAGS_SET"; then
 946                 LDFLAGS="$BAK_LDFLAGS"
 947         fi
 948 else
 949         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
 950 fi
 951
 952 # check for libexpat
 953 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
 954     [specify explicit path for libexpat.]),
 955     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
 956 AC_MSG_CHECKING(for libexpat)
 957 found_libexpat="no"
 958 for dir in $withval ; do
 959             if test -f "$dir/include/expat.h"; then
 960                 found_libexpat="yes"
 961                 dnl assume /usr is in default path.
 962                 if test "$dir" != "/usr"; then
 963                     CPPFLAGS="$CPPFLAGS -I$dir/include"
 964                     LDFLAGS="$LDFLAGS -L$dir/lib"
 965                 fi
 966                 AC_MSG_RESULT(found in $dir)
 967                 break;
 968             fi
 969 done
 970 if test x_$found_libexpat != x_yes; then
 971         AC_ERROR([Could not find libexpat, expat.h])
 972 fi
 973 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
 974 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
 975 #include <expat.h>
 976 ])
 977
 978 # set static linking if requested
 979 AC_SUBST(staticexe)
 980 staticexe=""
 981 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
 982         [ enable to compile executables statically against (event) libs, for debug purposes ]),
 983         , )
 984 if test x_$enable_static_exe = x_yes; then
 985         staticexe="-static"
 986         if test "$on_mingw" = yes; then
 987                 staticexe="-all-static"
 988                 # for static crosscompile, include gdi32 and zlib here.
 989                 if test "`uname`" = "Linux"; then
 990                         LIBS="$LIBS -lgdi32 -lz"
 991                 fi
 992         fi
 993 fi
 994
 995 # set lock checking if requested
 996 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
 997         [ enable to check lock and unlock calls, for debug purposes ]),
 998         , )
 999 if test x_$enable_lock_checks = x_yes; then
1000         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1001         CHECKLOCK_OBJ="checklocks.lo"
1002         AC_SUBST(CHECKLOCK_OBJ)
1003 fi
1004
1005 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1006 if test "$USE_WINSOCK" = 1; then
1007         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1008         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1009 #include <windows.h>
1010         ])
1011         AC_CHECK_TOOL(WINDRES, windres)
1012         LIBS="$LIBS -liphlpapi"
1013         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1014         AC_SUBST(WINAPPS)
1015         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1016         AC_SUBST(WIN_DAEMON_SRC)
1017         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1018         AC_SUBST(WIN_DAEMON_OBJ)
1019         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1020         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1021         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1022         AC_SUBST(WIN_HOST_OBJ_LINK)
1023         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1024         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1025         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1026         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1027         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1028         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1029 fi
1030 if test $ac_cv_func_getaddrinfo = no; then
1031         AC_LIBOBJ([fake-rfc2553])
1032 fi
1033 # check after getaddrinfo for its libraries
1034 ACX_FUNC_IOCTLSOCKET
1035
1036 # see if daemon(3) exists, and if it is deprecated.
1037 AC_CHECK_FUNCS([daemon])
1038 if test $ac_cv_func_daemon = yes; then
1039         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1040 #include <stdlib.h>
1041 ])
1042 fi
1043
1044 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1045 AC_INCLUDES_DEFAULT
1046 #ifdef HAVE_SYS_UN_H
1047 #include <sys/un.h>
1048 #endif
1049 ])
1050 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1051 AC_INCLUDES_DEFAULT
1052 #if HAVE_SYS_PARAM_H
1053 #include <sys/param.h>
1054 #endif
1055
1056 #ifdef HAVE_SYS_SOCKET_H
1057 #include <sys/socket.h>
1058 #endif
1059
1060 #ifdef HAVE_SYS_UIO_H
1061 #include <sys/uio.h>
1062 #endif
1063
1064 #ifdef HAVE_NETINET_IN_H
1065 #include <netinet/in.h>
1066 #endif
1067
1068 #ifdef HAVE_NETINET_TCP_H
1069 #include <netinet/tcp.h>
1070 #endif
1071
1072 #ifdef HAVE_ARPA_INET_H
1073 #include <arpa/inet.h>
1074 #endif
1075
1076 #ifdef HAVE_WINSOCK2_H
1077 #include <winsock2.h>
1078 #endif
1079
1080 #ifdef HAVE_WS2TCPIP_H
1081 #include <ws2tcpip.h>
1082 #endif
1083 ])
1084 AC_SEARCH_LIBS([setusercontext], [util])
1085 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync])
1086 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1087 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1088
1089 AC_MSG_CHECKING([for sbrk])
1090 # catch the warning of deprecated sbrk
1091 old_cflags="$CFLAGS"
1092 CFLAGS="$CFLAGS -Werror"
1093 AC_COMPILE_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1094 [[
1095 int main(void) { void* cur = sbrk(0); printf("%u\n", (unsigned)(size_t)((char*)cur - (char*)sbrk(0))); return 0; }
1096 ]])], [
1097         AC_MSG_RESULT(yes)
1098         AC_DEFINE(HAVE_SBRK, 1, [define if you have the sbrk() call])
1099     ], [AC_MSG_RESULT(no)])
1100 CFLAGS="$old_cflags"
1101
1102 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1103 if echo $build_os | grep darwin8 > /dev/null; then
1104         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1105 fi
1106 AC_REPLACE_FUNCS(inet_aton)
1107 AC_REPLACE_FUNCS(inet_pton)
1108 AC_REPLACE_FUNCS(inet_ntop)
1109 AC_REPLACE_FUNCS(snprintf)
1110 # test if snprintf return the proper length
1111 if test "x$ac_cv_func_snprintf" = xyes; then
1112     if test c${cross_compiling} = cno; then
1113         AC_MSG_CHECKING([for correct snprintf return value])
1114         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1115 [[
1116 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1117 ]])], [AC_MSG_RESULT(yes)], [
1118                 AC_MSG_RESULT(no)
1119                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1120                 AC_LIBOBJ(snprintf)
1121           ])
1122     fi
1123 fi
1124 AC_REPLACE_FUNCS(strlcat)
1125 AC_REPLACE_FUNCS(strlcpy)
1126 AC_REPLACE_FUNCS(memmove)
1127 AC_REPLACE_FUNCS(gmtime_r)
1128 AC_REPLACE_FUNCS(isblank)
1129 dnl without CTIME, ARC4-functions and without reallocarray.
1130 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1131 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1132 AC_REPLACE_FUNCS(reallocarray)
1133 if test "$USE_NSS" = "no"; then
1134         AC_REPLACE_FUNCS(arc4random)
1135         AC_REPLACE_FUNCS(arc4random_uniform)
1136         if test "$ac_cv_func_arc4random" = "no"; then
1137                 AC_LIBOBJ(explicit_bzero)
1138                 AC_LIBOBJ(arc4_lock)
1139                 AC_CHECK_FUNCS([getentropy],,[
1140                     if test "$USE_WINSOCK" = 1; then
1141                         AC_LIBOBJ(getentropy_win)
1142                     else
1143                         case `uname` in
1144                         Darwin)
1145                                 AC_LIBOBJ(getentropy_osx)
1146                         ;;
1147                         SunOS)
1148                                 AC_LIBOBJ(getentropy_solaris)
1149                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1150                                         AC_CHECK_FUNCS([SHA512_Update],,[
1151                                                 AC_LIBOBJ(sha512)
1152                                         ])
1153                                 ], [AC_INCLUDES_DEFAULT])
1154                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1155                                         # this lib needed for sha2 on solaris
1156                                         LIBS="$LIBS -lmd"
1157                                 fi
1158                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1159                         ;;
1160                         Linux|*)
1161                                 AC_LIBOBJ(getentropy_linux)
1162                                 AC_CHECK_FUNCS([SHA512_Update],,[
1163                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1164                                         AC_LIBOBJ(sha512)
1165                                 ])
1166                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1167                                 AC_CHECK_FUNCS([getauxval])
1168                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1169                         ;;
1170                         esac
1171                     fi
1172                 ])
1173         fi
1174 fi
1175 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1176 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1177 AC_REPLACE_FUNCS(ctime_r)
1178 AC_REPLACE_FUNCS(strsep)
1179
1180 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1181 case "$enable_allsymbols" in
1182         yes)
1183         COMMON_OBJ_ALL_SYMBOLS=""
1184         UBSYMS=""
1185         EXTRALINK="-L. -L.libs -lunbound"
1186         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1187         ;;
1188         no|*)
1189         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1190         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1191         EXTRALINK=""
1192         ;;
1193 esac
1194 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1195 AC_SUBST(EXTRALINK)
1196 AC_SUBST(UBSYMS)
1197 if test x_$enable_lock_checks = x_yes; then
1198         UBSYMS="-export-symbols clubsyms.def"
1199         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1200         echo lock_protect >> clubsyms.def
1201         echo lock_unprotect >> clubsyms.def
1202         echo lock_get_mem >> clubsyms.def
1203         echo checklock_start >> clubsyms.def
1204         echo checklock_stop >> clubsyms.def
1205         echo checklock_lock >> clubsyms.def
1206         echo checklock_unlock >> clubsyms.def
1207         echo checklock_init >> clubsyms.def
1208         echo checklock_thrcreate >> clubsyms.def
1209         echo checklock_thrjoin >> clubsyms.def
1210 fi
1211
1212 # check for dnstap if requested
1213 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1214     [
1215         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1216         AC_SUBST([ENABLE_DNSTAP], [1])
1217
1218         AC_SUBST([opt_dnstap_socket_path])
1219         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1220         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1221             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1222
1223         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1224         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1225     ],
1226     [
1227         AC_SUBST([ENABLE_DNSTAP], [0])
1228     ]
1229 )
1230
1231 # check for cachedb if requested
1232 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1233 case "$enable_cachedb" in
1234     yes)
1235         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1236         ;;
1237     no|*)
1238         # nothing
1239         ;;
1240 esac
1241
1242 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1243 # on openBSD, the implicit rule make $< work.
1244 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1245 # gmake works.
1246 cat >conftest.make <<EOF
1247 all:    conftest.lo
1248
1249 conftest.lo foo.lo bla.lo:
1250         if test -f "\$<"; then touch \$@; fi
1251
1252 .SUFFIXES: .lo
1253 .c.lo:
1254         if test -f "\$<"; then touch \$@; fi
1255
1256 conftest.lo:        conftest.dir/conftest.c
1257 EOF
1258 mkdir conftest.dir
1259 touch conftest.dir/conftest.c
1260 rm -f conftest.lo conftest.c
1261 ${MAKE:-make} -f conftest.make >/dev/null
1262 rm -f conftest.make conftest.c conftest.dir/conftest.c
1263 rm -rf conftest.dir
1264 if test ! -f conftest.lo; then
1265         AC_MSG_RESULT(no)
1266         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1267         SOURCEFILE='`cat .source`'
1268 else
1269         AC_MSG_RESULT(yes)
1270         SOURCEDETERMINE=':'
1271         SOURCEFILE='$<'
1272 fi
1273 rm -f conftest.lo
1274 AC_SUBST(SOURCEDETERMINE)
1275 AC_SUBST(SOURCEFILE)
1276
1277 # see if we want to build the library or everything
1278 ALLTARGET="alltargets"
1279 INSTALLTARGET="install-all"
1280 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1281         [do not build daemon and tool programs]),
1282         [
1283         if test "$withval" = "yes"; then
1284                 ALLTARGET="lib"
1285                 INSTALLTARGET="install-lib"
1286         fi
1287 ])
1288 AC_SUBST(ALLTARGET)
1289 AC_SUBST(INSTALLTARGET)
1290
1291 ACX_STRIP_EXT_FLAGS
1292 LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1293
1294 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1295
1296 AH_BOTTOM(
1297 dnl this must be first AH_CONFIG, to define the flags before any includes.
1298 AHX_CONFIG_EXT_FLAGS
1299
1300 dnl includes
1301 [
1302 #ifndef UNBOUND_DEBUG
1303 #  define NDEBUG
1304 #endif
1305
1306 /** Use small-ldns codebase */
1307 #define USE_SLDNS 1
1308 #ifdef HAVE_SSL
1309 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1310 #endif
1311
1312 #include <stdio.h>
1313 #include <string.h>
1314 #include <unistd.h>
1315 #include <assert.h>
1316
1317 #if STDC_HEADERS
1318 #include <stdlib.h>
1319 #include <stddef.h>
1320 #endif
1321
1322 #ifdef HAVE_STDARG_H
1323 #include <stdarg.h>
1324 #endif
1325
1326 #ifdef HAVE_STDINT_H
1327 #include <stdint.h>
1328 #endif
1329
1330 #include <errno.h>
1331
1332 #if HAVE_SYS_PARAM_H
1333 #include <sys/param.h>
1334 #endif
1335
1336 #ifdef HAVE_SYS_SOCKET_H
1337 #include <sys/socket.h>
1338 #endif
1339
1340 #ifdef HAVE_SYS_UIO_H
1341 #include <sys/uio.h>
1342 #endif
1343
1344 #ifdef HAVE_NETINET_IN_H
1345 #include <netinet/in.h>
1346 #endif
1347
1348 #ifdef HAVE_NETINET_TCP_H
1349 #include <netinet/tcp.h>
1350 #endif
1351
1352 #ifdef HAVE_ARPA_INET_H
1353 #include <arpa/inet.h>
1354 #endif
1355
1356 #ifdef HAVE_WINSOCK2_H
1357 #include <winsock2.h>
1358 #endif
1359
1360 #ifdef HAVE_WS2TCPIP_H
1361 #include <ws2tcpip.h>
1362 #endif
1363
1364 #ifndef USE_WINSOCK
1365 #define ARG_LL "%ll"
1366 #else
1367 #define ARG_LL "%I64"
1368 #endif
1369
1370 #ifndef AF_LOCAL
1371 #define AF_LOCAL AF_UNIX
1372 #endif
1373 ]
1374
1375 AHX_CONFIG_FORMAT_ATTRIBUTE
1376 AHX_CONFIG_UNUSED_ATTRIBUTE
1377 AHX_CONFIG_FSEEKO
1378 AHX_CONFIG_MAXHOSTNAMELEN
1379 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1380 #define snprintf snprintf_unbound
1381 #define vsnprintf vsnprintf_unbound
1382 #include <stdarg.h>
1383 int snprintf (char *str, size_t count, const char *fmt, ...);
1384 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1385 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1386 AHX_CONFIG_INET_PTON(unbound)
1387 AHX_CONFIG_INET_NTOP(unbound)
1388 AHX_CONFIG_INET_ATON(unbound)
1389 AHX_CONFIG_MEMMOVE(unbound)
1390 AHX_CONFIG_STRLCAT(unbound)
1391 AHX_CONFIG_STRLCPY(unbound)
1392 AHX_CONFIG_GMTIME_R(unbound)
1393 AHX_CONFIG_REALLOCARRAY(unbound)
1394 AHX_CONFIG_W32_SLEEP
1395 AHX_CONFIG_W32_USLEEP
1396 AHX_CONFIG_W32_RANDOM
1397 AHX_CONFIG_W32_SRANDOM
1398 AHX_CONFIG_W32_FD_SET_T
1399 AHX_CONFIG_IPV6_MIN_MTU
1400 AHX_MEMCMP_BROKEN(unbound)
1401
1402 [
1403 #ifndef HAVE_CTIME_R
1404 #define ctime_r unbound_ctime_r
1405 char *ctime_r(const time_t *timep, char *buf);
1406 #endif
1407
1408 #ifndef HAVE_STRSEP
1409 #define strsep unbound_strsep
1410 char *strsep(char **stringp, const char *delim);
1411 #endif
1412
1413 #ifndef HAVE_ISBLANK
1414 #define isblank unbound_isblank
1415 int isblank(int c);
1416 #endif
1417
1418 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1419 #define strptime unbound_strptime
1420 struct tm;
1421 char *strptime(const char *s, const char *format, struct tm *tm);
1422 #endif
1423
1424 #ifdef HAVE_LIBRESSL
1425 #  if !HAVE_DECL_STRLCPY
1426 size_t strlcpy(char *dst, const char *src, size_t siz);
1427 #  endif
1428 #  if !HAVE_DECL_STRLCAT
1429 size_t strlcat(char *dst, const char *src, size_t siz);
1430 #  endif
1431 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1432 uint32_t arc4random(void);
1433 #  endif
1434 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1435 uint32_t arc4random_uniform(uint32_t upper_bound);
1436 #  endif
1437 #  if !HAVE_DECL_REALLOCARRAY
1438 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1439 #  endif
1440 #endif /* HAVE_LIBRESSL */
1441 #ifndef HAVE_ARC4RANDOM
1442 void explicit_bzero(void* buf, size_t len);
1443 int getentropy(void* buf, size_t len);
1444 uint32_t arc4random(void);
1445 void arc4random_buf(void* buf, size_t n);
1446 void _ARC4_LOCK(void);
1447 void _ARC4_UNLOCK(void);
1448 #endif
1449 #ifndef HAVE_ARC4RANDOM_UNIFORM
1450 uint32_t arc4random_uniform(uint32_t upper_bound);
1451 #endif
1452 #ifdef COMPAT_SHA512
1453 #ifndef SHA512_DIGEST_LENGTH
1454 #define SHA512_BLOCK_LENGTH             128
1455 #define SHA512_DIGEST_LENGTH            64
1456 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1457 typedef struct _SHA512_CTX {
1458         uint64_t        state[8];
1459         uint64_t        bitcount[2];
1460         uint8_t buffer[SHA512_BLOCK_LENGTH];
1461 } SHA512_CTX;
1462 #endif /* SHA512_DIGEST_LENGTH */
1463 void SHA512_Init(SHA512_CTX*);
1464 void SHA512_Update(SHA512_CTX*, void*, size_t);
1465 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1466 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1467 #endif /* COMPAT_SHA512 */
1468
1469
1470
1471 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1472    /* using version of libevent that is not threadsafe. */
1473 #  define LIBEVENT_SIGNAL_PROBLEM 1
1474 #endif
1475
1476 #ifndef CHECKED_INET6
1477 #  define CHECKED_INET6
1478 #  ifdef AF_INET6
1479 #    define INET6
1480 #  else
1481 #    define AF_INET6        28
1482 #  endif
1483 #endif /* CHECKED_INET6 */
1484
1485 #ifndef HAVE_GETADDRINFO
1486 struct sockaddr_storage;
1487 #include "compat/fake-rfc2553.h"
1488 #endif
1489
1490 #ifdef UNBOUND_ALLOC_STATS
1491 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1492 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1493 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1494 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1495 void *unbound_stat_malloc(size_t size);
1496 void *unbound_stat_calloc(size_t nmemb, size_t size);
1497 void unbound_stat_free(void *ptr);
1498 void *unbound_stat_realloc(void *ptr, size_t size);
1499 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1500         const char* func);
1501 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1502         int line, const char* func);
1503 void unbound_stat_free_log(void *ptr, const char* file, int line,
1504         const char* func);
1505 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1506         int line, const char* func);
1507 #elif defined(UNBOUND_ALLOC_LITE)
1508 #  include "util/alloc.h"
1509 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1510
1511 /** default port for DNS traffic. */
1512 #define UNBOUND_DNS_PORT 53
1513 /** default port for unbound control traffic, registered port with IANA,
1514     ub-dns-control  8953/tcp    unbound dns nameserver control */
1515 #define UNBOUND_CONTROL_PORT 8953
1516 /** the version of unbound-control that this software implements */
1517 #define UNBOUND_CONTROL_VERSION 1
1518
1519 ])
1520
1521 dnl if we build from source tree, the man pages need @date@ and @version@
1522 dnl if this is a distro tarball, that was already done by makedist.sh
1523 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1524 AC_SUBST(date, [`date +'%b %e, %Y'`])
1525
1526 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h])
1527 AC_CONFIG_HEADER([config.h])
1528 AC_OUTPUT