configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[6])
  14 m4_define([VERSION_MICRO],[6])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=5
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78
  79 #   Current  -- the number of the binary API that we're implementing
  80 #   Revision -- which iteration of the implementation of the binary
  81 #               API are we supplying?
  82 #   Age      -- How many previous binary API versions do we also
  83 #               support?
  84 #
  85 # If we release a new version that does not change the binary API,
  86 # increment Revision.
  87 #
  88 # If we release a new version that changes the binary API, but does
  89 # not break programs compiled against the old binary API, increment
  90 # Current and Age.  Set Revision to 0, since this is the first
  91 # implementation of the new API.
  92 #
  93 # Otherwise, we're changing the binary API and breaking bakward
  94 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  95 # since we're backward compatible with no previous APIs.  Set Revision
  96 # to 0 too.
  97 AC_SUBST(LIBUNBOUND_CURRENT)
  98 AC_SUBST(LIBUNBOUND_REVISION)
  99 AC_SUBST(LIBUNBOUND_AGE)
 100
 101 CFLAGS="$CFLAGS"
 102 AC_AIX
 103 if test "$ac_cv_header_minix_config_h" = "yes"; then
 104         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 105 fi
 106
 107 dnl
 108 dnl By default set prefix to /usr/local
 109 dnl
 110 case "$prefix" in
 111         NONE)
 112                 prefix="/usr/local"
 113         ;;
 114 esac
 115 case "$exec_prefix" in
 116         NONE)
 117                 exec_prefix="$prefix"
 118         ;;
 119 esac
 120
 121 # are we on MinGW?
 122 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 123 else
 124         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 125         else on_mingw="no"; fi
 126 fi
 127
 128 #
 129 # Determine configuration file
 130 # the eval is to evaluate shell expansion twice
 131 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 132 AC_SUBST(UNBOUND_SBIN_DIR)
 133 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 134 AC_SUBST(UNBOUND_SYSCONF_DIR)
 135 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 136 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 137 if test $on_mingw = "no"; then
 138   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 139 else
 140   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 141 fi
 142 AC_ARG_WITH([conf_file],
 143         AC_HELP_STRING([--with-conf-file=path],
 144         [Pathname to the Unbound configuration file]),
 145         [ub_conf_file="$withval"])
 146 AC_SUBST(ub_conf_file)
 147 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 148 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 149 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 150 AC_SUBST(ub_conf_dir)
 151
 152 # Determine run, chroot directory and pidfile locations
 153 AC_ARG_WITH(run-dir,
 154     AC_HELP_STRING([--with-run-dir=path],
 155     [set default directory to chdir to (by default dir part of cfg file)]),
 156     UNBOUND_RUN_DIR="$withval",
 157 if test $on_mingw = no; then
 158     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 159 else
 160     UNBOUND_RUN_DIR=""
 161 fi
 162 )
 163 AC_SUBST(UNBOUND_RUN_DIR)
 164 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 165 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 166
 167 AC_ARG_WITH(chroot-dir,
 168     AC_HELP_STRING([--with-chroot-dir=path],
 169     [set default directory to chroot to (by default same as run-dir)]),
 170     UNBOUND_CHROOT_DIR="$withval",
 171 if test $on_mingw = no; then
 172     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 173 else
 174     UNBOUND_CHROOT_DIR=""
 175 fi
 176 )
 177 AC_SUBST(UNBOUND_CHROOT_DIR)
 178 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 179 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 180
 181 AC_ARG_WITH(share-dir,
 182     AC_HELP_STRING([--with-share-dir=path],
 183     [set default directory with shared data (by default same as share/unbound)]),
 184     UNBOUND_SHARE_DIR="$withval",
 185     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 186 AC_SUBST(UNBOUND_SHARE_DIR)
 187 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 188
 189 AC_ARG_WITH(pidfile,
 190     AC_HELP_STRING([--with-pidfile=filename],
 191     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 192     UNBOUND_PIDFILE="$withval",
 193 if test $on_mingw = no; then
 194     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 195 else
 196     UNBOUND_PIDFILE=""
 197 fi
 198 )
 199 AC_SUBST(UNBOUND_PIDFILE)
 200 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 201 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 202
 203 AC_ARG_WITH(rootkey-file,
 204     AC_HELP_STRING([--with-rootkey-file=filename],
 205     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 206     UNBOUND_ROOTKEY_FILE="$withval",
 207 if test $on_mingw = no; then
 208     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 209 else
 210     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 211 fi
 212 )
 213 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 214 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 215 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 216
 217 AC_ARG_WITH(rootcert-file,
 218     AC_HELP_STRING([--with-rootcert-file=filename],
 219     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 220     UNBOUND_ROOTCERT_FILE="$withval",
 221 if test $on_mingw = no; then
 222     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 223 else
 224     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 225 fi
 226 )
 227 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 228 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 229 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 230
 231 AC_ARG_WITH(username,
 232     AC_HELP_STRING([--with-username=user],
 233     [set default user that unbound changes to (default user is unbound)]),
 234     UNBOUND_USERNAME="$withval",
 235     UNBOUND_USERNAME="unbound")
 236 AC_SUBST(UNBOUND_USERNAME)
 237 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 238
 239 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 240 ACX_RSRC_VERSION(wnvs)
 241 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 242
 243 # Checks for typedefs, structures, and compiler characteristics.
 244 AC_C_CONST
 245 AC_LANG_C
 246 # allow user to override the -g -O2 flags.
 247 if test "x$CFLAGS" = "x" ; then
 248 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 249 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 250 fi
 251 AC_PROG_CC
 252 ACX_DEPFLAG
 253 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 254
 255 # debug mode flags warnings
 256 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 257 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 258 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 259 else debug_enabled="$enable_checking"; fi
 260 AC_SUBST(debug_enabled)
 261 case "$debug_enabled" in
 262         yes)
 263                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 264                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 265                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 266                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 267                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 268                 ;;
 269         no|*)
 270                 # nothing to do.
 271                 ;;
 272 esac
 273 ACX_CHECK_FLTO
 274 ACX_CHECK_PIE
 275 ACX_CHECK_RELRO_NOW
 276
 277 AC_C_INLINE
 278 ACX_CHECK_FORMAT_ATTRIBUTE
 279 ACX_CHECK_UNUSED_ATTRIBUTE
 280
 281 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 282 [AC_REQUIRE([AC_PROG_CC])
 283 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 284 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 285 [ac_cv_c_weak_attribute=no
 286 AC_TRY_COMPILE(
 287 [ #include <stdio.h>
 288 __attribute__((weak)) void f(int x) { printf("%d", x); }
 289 ], [
 290    f(1);
 291 ],
 292 [ac_cv_c_weak_attribute="yes"],
 293 [ac_cv_c_weak_attribute="no"])
 294 ])
 295
 296 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 297 if test $ac_cv_c_weak_attribute = yes; then
 298   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 299 fi
 300 ])dnl End of CHECK_WEAK_ATTRIBUTE
 301
 302 CHECK_WEAK_ATTRIBUTE
 303
 304 if test "$srcdir" != "."; then
 305         CPPFLAGS="$CPPFLAGS -I$srcdir"
 306 fi
 307
 308 AC_DEFUN([ACX_YYLEX_DESTROY], [
 309         AC_MSG_CHECKING([for yylex_destroy])
 310         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 311                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 312                 AC_MSG_RESULT(yes)
 313         else AC_MSG_RESULT(no); fi
 314 ])
 315
 316 AC_PROG_LEX
 317 ACX_YYLEX_DESTROY
 318 AC_PROG_YACC
 319 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 320 AC_CHECK_TOOL(STRIP, strip)
 321 ACX_LIBTOOL_C_ONLY
 322
 323 # Checks for header files.
 324 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 325
 326 # check for types.
 327 # Using own tests for int64* because autoconf builtin only give 32bit.
 328 AC_CHECK_TYPE(int8_t, signed char)
 329 AC_CHECK_TYPE(int16_t, short)
 330 AC_CHECK_TYPE(int32_t, int)
 331 AC_CHECK_TYPE(int64_t, long long)
 332 AC_CHECK_TYPE(uint8_t, unsigned char)
 333 AC_CHECK_TYPE(uint16_t, unsigned short)
 334 AC_CHECK_TYPE(uint32_t, unsigned int)
 335 AC_CHECK_TYPE(uint64_t, unsigned long long)
 336 AC_TYPE_SIZE_T
 337 AC_CHECK_TYPE(ssize_t, int)
 338 AC_TYPE_UID_T
 339 AC_TYPE_PID_T
 340 AC_TYPE_OFF_T
 341 ACX_TYPE_U_CHAR
 342 ACX_TYPE_RLIM_T
 343 ACX_TYPE_SOCKLEN_T
 344 ACX_TYPE_IN_ADDR_T
 345 ACX_TYPE_IN_PORT_T
 346 ACX_CHECK_MEMCMP_SIGNED
 347
 348 AC_CHECK_SIZEOF(time_t,,[
 349 AC_INCLUDES_DEFAULT
 350 #ifdef TIME_WITH_SYS_TIME
 351 # include <sys/time.h>
 352 # include <time.h>
 353 #else
 354 # ifdef HAVE_SYS_TIME_H
 355 #  include <sys/time.h>
 356 # else
 357 #  include <time.h>
 358 # endif
 359 #endif
 360 ])
 361
 362 # add option to disable the evil rpath
 363 ACX_ARG_RPATH
 364 AC_SUBST(RUNTIME_PATH)
 365
 366 # check to see if libraries are needed for these functions.
 367 AC_SEARCH_LIBS([inet_pton], [nsl])
 368 AC_SEARCH_LIBS([socket], [socket])
 369
 370 # check wether strptime also works
 371 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 372 [AC_REQUIRE([AC_PROG_CC])
 373 AC_MSG_CHECKING(whether strptime works)
 374 if test c${cross_compiling} = cno; then
 375 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 376 #define _XOPEN_SOURCE 600
 377 #include <time.h>
 378 int main(void) { struct tm tm; char *res;
 379 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 380 if (!res) return 2;
 381 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 382 if (!res) return 1; return 0; }
 383 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 384 else
 385 eval "ac_cv_c_strptime_works=maybe"
 386 fi
 387 AC_MSG_RESULT($ac_cv_c_strptime_works)
 388 if test $ac_cv_c_strptime_works = no; then
 389 AC_LIBOBJ(strptime)
 390 else
 391 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 392 fi
 393 ])dnl
 394
 395 # check some functions of the OS before linking libs (while still runnable).
 396 AC_FUNC_CHOWN
 397 AC_FUNC_FORK
 398 AC_TYPE_SIGNAL
 399 AC_FUNC_FSEEKO
 400 ACX_SYS_LARGEFILE
 401 ACX_CHECK_NONBLOCKING_BROKEN
 402 ACX_MKDIR_ONE_ARG
 403 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 404
 405 # set memory allocation checking if requested
 406 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 407         [ enable to memory allocation statistics, for debug purposes ]),
 408         , )
 409 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 410         [ enable for lightweight alloc assertions, for debug purposes ]),
 411         , )
 412 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 413         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 414         , )
 415 if test x_$enable_alloc_nonregional = x_yes; then
 416         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 417 fi
 418 if test x_$enable_alloc_checks = x_yes; then
 419         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 420 else
 421         if test x_$enable_alloc_lite = x_yes; then
 422                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 423         else
 424                 ACX_FUNC_MALLOC([unbound])
 425         fi
 426 fi
 427
 428 # check windows threads (we use them, not pthreads, on windows).
 429 if test "$on_mingw" = "yes"; then
 430 # check windows threads
 431         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 432         AC_MSG_CHECKING([for CreateThread])
 433         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 434 #ifdef HAVE_WINDOWS_H
 435 #include <windows.h>
 436 #endif
 437 ], [
 438         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 439 ])],
 440         AC_MSG_RESULT(yes)
 441         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 442 ,
 443         AC_MSG_RESULT(no)
 444 )
 445
 446 else
 447 # not on mingw, check thread libraries.
 448
 449 # check for thread library.
 450 # check this first, so that the pthread lib does not get linked in via
 451 # libssl or libpython, and thus distorts the tests, and we end up using
 452 # the non-threadsafe C libraries.
 453 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 454  [use pthreads library, or --without-pthreads to disable threading support.]),
 455  [ ],[ withval="yes" ])
 456 ub_have_pthreads=no
 457 if test x_$withval != x_no; then
 458         AX_PTHREAD([
 459                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 460                 if test -n "$PTHREAD_LIBS"; then
 461                   LIBS="$PTHREAD_LIBS $LIBS"
 462                 fi
 463                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 464                 CC="$PTHREAD_CC"
 465                 ub_have_pthreads=yes
 466                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 467
 468                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 469                 AC_MSG_CHECKING([if -pthread unused during linking])
 470                 # catch clang warning 'argument unused during compilation'
 471                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 472 [[
 473 int main(void) {return 0;}
 474 ]])])
 475                 pthread_unused="yes"
 476                 # first compile
 477                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 478                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 479                 if test $? = 0; then
 480                         # then link
 481                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 482                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 483                         if test $? -ne 0; then
 484                                 AC_MSG_RESULT(yes)
 485                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 486                                 PTHREAD_CFLAGS_ONLY="-pthread"
 487                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 488                         else
 489                                 AC_MSG_RESULT(no)
 490                         fi
 491                 else
 492                         AC_MSG_RESULT(no)
 493                 fi # endif cc successful
 494                 rm -f conftest conftest.c conftest.o
 495                 fi # endif -pthread in CFLAGS
 496
 497                 ])
 498 fi
 499
 500 # check solaris thread library
 501 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 502         [use solaris native thread library.]), [ ],[ withval="no" ])
 503 ub_have_sol_threads=no
 504 if test x_$withval != x_no; then
 505         if test x_$ub_have_pthreads != x_no; then
 506             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 507         else
 508         AC_SEARCH_LIBS(thr_create, [thread],
 509         [
 510                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 511
 512                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 513                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 514                 ub_have_sol_threads=yes
 515         ] , [
 516                 AC_ERROR([no solaris threads found.])
 517         ])
 518         fi
 519 fi
 520
 521 fi # end of non-mingw check of thread libraries
 522
 523 # Check for PyUnbound
 524 AC_ARG_WITH(pyunbound,
 525    AC_HELP_STRING([--with-pyunbound],
 526    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 527    [], [ withval="no" ])
 528
 529 ub_test_python=no
 530 ub_with_pyunbound=no
 531 if test x_$withval != x_no; then
 532    ub_with_pyunbound=yes
 533    ub_test_python=yes
 534 fi
 535
 536 # Check for Python module
 537 AC_ARG_WITH(pythonmodule,
 538    AC_HELP_STRING([--with-pythonmodule],
 539    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 540    [], [ withval="no" ])
 541
 542 ub_with_pythonmod=no
 543 if test x_$withval != x_no; then
 544    ub_with_pythonmod=yes
 545    ub_test_python=yes
 546 fi
 547
 548 # Check for Python & SWIG only on PyUnbound or PyModule
 549 if test x_$ub_test_python != x_no; then
 550
 551    # Check for Python
 552    ub_have_python=no
 553    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 554    AC_PYTHON_DEVEL
 555    if test ! -z "$PYTHON_VERSION"; then
 556         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 557                 AC_ERROR([Python version >= 2.4.0 is required])
 558         fi
 559
 560       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 561       AC_SUBST(PY_MAJOR_VERSION)
 562       # Have Python
 563       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 564       if test -n "$LIBS"; then
 565         LIBS="$PYTHON_LDFLAGS $LIBS"
 566       else
 567         LIBS="$PYTHON_LDFLAGS"
 568       fi
 569       if test -n "$CPPFLAGS"; then
 570         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 571       else
 572         CPPFLAGS="$PYTHON_CPPFLAGS"
 573       fi
 574       ub_have_python=yes
 575       PC_PY_DEPENDENCY="python"
 576       AC_SUBST(PC_PY_DEPENDENCY)
 577
 578       # Check for SWIG
 579       ub_have_swig=no
 580       AC_PROG_SWIG(2.0.1)
 581       AC_MSG_CHECKING(SWIG)
 582       if test ! -x "$SWIG"; then
 583          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 584       else
 585          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 586          AC_SUBST(swig, "$SWIG")
 587          AC_MSG_RESULT(present)
 588
 589          # If have Python & SWIG
 590          # Declare PythonMod
 591          if test x_$ub_with_pythonmod != x_no; then
 592             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 593             WITH_PYTHONMODULE=yes
 594             AC_SUBST(WITH_PYTHONMODULE)
 595             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 596             AC_SUBST(PYTHONMOD_OBJ)
 597             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 598             AC_SUBST(PYTHONMOD_HEADER)
 599             PYTHONMOD_INSTALL=pythonmod-install
 600             AC_SUBST(PYTHONMOD_INSTALL)
 601             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 602             AC_SUBST(PYTHONMOD_UNINSTALL)
 603          fi
 604
 605          # Declare PyUnbound
 606          if test x_$ub_with_pyunbound != x_no; then
 607             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 608             WITH_PYUNBOUND=yes
 609             AC_SUBST(WITH_PYUNBOUND)
 610             PYUNBOUND_OBJ="libunbound_wrap.lo"
 611             AC_SUBST(PYUNBOUND_OBJ)
 612             PYUNBOUND_TARGET="_unbound.la"
 613             AC_SUBST(PYUNBOUND_TARGET)
 614             PYUNBOUND_INSTALL=pyunbound-install
 615             AC_SUBST(PYUNBOUND_INSTALL)
 616             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 617             AC_SUBST(PYUNBOUND_UNINSTALL)
 618          fi
 619       fi
 620    else
 621       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 622       ub_with_pyunbound=no
 623       ub_with_pythonmod=no
 624    fi
 625 fi
 626
 627 if test "`uname`" = "NetBSD"; then
 628         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 629         AC_SUBST(NETBSD_LINTFLAGS)
 630 fi
 631 CONFIG_DATE=`date +%Y%m%d`
 632 AC_SUBST(CONFIG_DATE)
 633
 634 # Checks for libraries.
 635
 636 # libnss
 637 USE_NSS="no"
 638 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 639         [use libnss instead of openssl, installed at path.]),
 640         [
 641         USE_NSS="yes"
 642         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 643         if test "$withval" != "" -a "$withval" != "yes"; then
 644                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 645                 LDFLAGS="$LDFLAGS -L$withval/lib"
 646                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 647                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 648         else
 649                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 650                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 651         fi
 652         LIBS="$LIBS -lnss3 -lnspr4"
 653         SSLLIB=""
 654         ]
 655 )
 656
 657 # libnettle
 658 USE_NETTLE="no"
 659 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 660         [use libnettle as crypto library, installed at path.]),
 661         [
 662         USE_NETTLE="yes"
 663         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 664         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 665         if test "$withval" != "" -a "$withval" != "yes"; then
 666                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 667                 LDFLAGS="$LDFLAGS -L$withval/lib"
 668                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 669         else
 670                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 671         fi
 672         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 673         SSLLIB=""
 674         ]
 675 )
 676
 677 # openssl
 678 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 679 ACX_WITH_SSL
 680 ACX_LIB_SSL
 681 SSLLIB="-lssl"
 682
 683 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 684 BAKLIBS="$LIBS"
 685 LIBS="-lssl $LIBS"
 686 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 687 AC_TRY_LINK_FUNC([HMAC_Update], [
 688         AC_MSG_RESULT([no])
 689         LIBS="$BAKLIBS"
 690 ], [
 691         AC_MSG_RESULT([yes])
 692         LIBS="$BAKLIBS"
 693         LIBS="$LIBS -lcrypt32"
 694 ])
 695
 696 AC_MSG_CHECKING([for LibreSSL])
 697 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 698         AC_MSG_RESULT([yes])
 699         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 700         # libressl provides these compat functions, but they may also be
 701         # declared by the OS in libc.  See if they have been declared.
 702         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 703 else
 704         AC_MSG_RESULT([no])
 705 fi
 706 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 707 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 708
 709 # these check_funcs need -lssl
 710 BAKLIBS="$LIBS"
 711 LIBS="-lssl $LIBS"
 712 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level])
 713 LIBS="$BAKLIBS"
 714
 715 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 716 AC_INCLUDES_DEFAULT
 717 #ifdef HAVE_OPENSSL_ERR_H
 718 #include <openssl/err.h>
 719 #endif
 720
 721 #ifdef HAVE_OPENSSL_RAND_H
 722 #include <openssl/rand.h>
 723 #endif
 724
 725 #ifdef HAVE_OPENSSL_CONF_H
 726 #include <openssl/conf.h>
 727 #endif
 728
 729 #ifdef HAVE_OPENSSL_ENGINE_H
 730 #include <openssl/engine.h>
 731 #endif
 732 #include <openssl/ssl.h>
 733 #include <openssl/evp.h>
 734 ])
 735 fi
 736 AC_SUBST(SSLLIB)
 737
 738
 739 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 740 case "$enable_sha1" in
 741         no)
 742         ;;
 743         yes|*)
 744         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 745         ;;
 746 esac
 747
 748
 749 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 750 case "$enable_sha2" in
 751         no)
 752         ;;
 753         yes|*)
 754         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 755         ;;
 756 esac
 757
 758 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 759 case "$enable_subnet" in
 760         yes)
 761         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 762         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 763         AC_SUBST(SUBNET_OBJ)
 764         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 765         AC_SUBST(SUBNET_HEADER)
 766         ;;
 767         no|*)
 768         ;;
 769 esac
 770
 771 # check wether gost also works
 772 AC_DEFUN([AC_CHECK_GOST_WORKS],
 773 [AC_REQUIRE([AC_PROG_CC])
 774 AC_MSG_CHECKING([if GOST works])
 775 if test c${cross_compiling} = cno; then
 776 BAKCFLAGS="$CFLAGS"
 777 if test -n "$ssldir"; then
 778         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 779 fi
 780 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 781 #include <string.h>
 782 #include <openssl/ssl.h>
 783 #include <openssl/evp.h>
 784 #include <openssl/engine.h>
 785 #include <openssl/conf.h>
 786 /* routine to load gost (from sldns) */
 787 int load_gost_id(void)
 788 {
 789         static int gost_id = 0;
 790         const EVP_PKEY_ASN1_METHOD* meth;
 791         ENGINE* e;
 792
 793         if(gost_id) return gost_id;
 794
 795         /* see if configuration loaded gost implementation from other engine*/
 796         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 797         if(meth) {
 798                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 799                 return gost_id;
 800         }
 801
 802         /* see if engine can be loaded already */
 803         e = ENGINE_by_id("gost");
 804         if(!e) {
 805                 /* load it ourself, in case statically linked */
 806                 ENGINE_load_builtin_engines();
 807                 ENGINE_load_dynamic();
 808                 e = ENGINE_by_id("gost");
 809         }
 810         if(!e) {
 811                 /* no gost engine in openssl */
 812                 return 0;
 813         }
 814         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 815                 ENGINE_finish(e);
 816                 ENGINE_free(e);
 817                 return 0;
 818         }
 819
 820         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 821         if(!meth) {
 822                 /* algo not found */
 823                 ENGINE_finish(e);
 824                 ENGINE_free(e);
 825                 return 0;
 826         }
 827         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 828         return gost_id;
 829 }
 830 int main(void) {
 831         EVP_MD_CTX* ctx;
 832         const EVP_MD* md;
 833         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 834         const char* str = "Hello world";
 835         const unsigned char check[] = {
 836                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 837                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 838                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 839                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 840         };
 841         OPENSSL_config(NULL);
 842         (void)load_gost_id();
 843         md = EVP_get_digestbyname("md_gost94");
 844         if(!md) return 1;
 845         memset(digest, 0, sizeof(digest));
 846         ctx = EVP_MD_CTX_create();
 847         if(!ctx) return 2;
 848         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 849         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 850         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 851         /* uncomment to see the hash calculated.
 852                 {int i;
 853                 for(i=0; i<32; i++)
 854                         printf(" %2.2x", (int)digest[i]);
 855                 printf("\n");}
 856         */
 857         if(memcmp(digest, check, sizeof(check)) != 0)
 858                 return 6;
 859         return 0;
 860 }
 861 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 862 CFLAGS="$BAKCFLAGS"
 863 else
 864 eval "ac_cv_c_gost_works=maybe"
 865 fi
 866 AC_MSG_RESULT($ac_cv_c_gost_works)
 867 ])dnl
 868
 869 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 870 use_gost="no"
 871 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 872 case "$enable_gost" in
 873         no)
 874         ;;
 875         *)
 876         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 877         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 878         AC_CHECK_GOST_WORKS
 879         if test "$ac_cv_c_gost_works" != no; then
 880                 use_gost="yes"
 881                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 882         fi
 883         ;;
 884 esac
 885 fi dnl !USE_NSS && !USE_NETTLE
 886
 887 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 888 use_ecdsa="no"
 889 case "$enable_ecdsa" in
 890     no)
 891       ;;
 892     *)
 893       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 894               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 895               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 896               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 897 #include <openssl/evp.h>
 898               ])
 899               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 900               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 901               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 902                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 903                   AC_MSG_RESULT([no])
 904                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 905                 else
 906                   AC_MSG_RESULT([yes])
 907                 fi
 908               else
 909                 # not OpenSSL, thus likely LibreSSL, which supports it
 910                 AC_MSG_RESULT([yes])
 911               fi
 912       fi
 913       # we now know we have ECDSA and the required curves.
 914       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 915       use_ecdsa="yes"
 916       ;;
 917 esac
 918
 919 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 920 use_dsa="no"
 921 case "$enable_dsa" in
 922     no)
 923       ;;
 924     *)
 925       # detect if DSA is supported, and turn it off if not.
 926       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 927       AC_CHECK_FUNC(DSA_SIG_new, [
 928       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 929       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 930                fi ])
 931       else
 932       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 933       fi
 934       ;;
 935 esac
 936
 937 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
 938 use_ed25519="no"
 939 case "$enable_ed25519" in
 940     no)
 941       ;;
 942     *)
 943       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 944               AC_CHECK_DECLS([NID_ED25519], [
 945                 use_ed25519="yes"
 946               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
 947                 fi ], [AC_INCLUDES_DEFAULT
 948 #include <openssl/evp.h>
 949               ])
 950       fi
 951       if test $USE_NETTLE = "yes"; then
 952                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
 953       fi
 954       if test $use_ed25519 = "yes"; then
 955                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
 956       fi
 957       ;;
 958 esac
 959
 960 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
 961 case "$enable_event_api" in
 962     yes)
 963       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 964       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 965       ;;
 966     *)
 967       ;;
 968 esac
 969
 970 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
 971 case "$enable_tfo_client" in
 972         yes)
 973                 case `uname` in
 974                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 975                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 976                                              [AC_INCLUDES_DEFAULT
 977 #include <netinet/tcp.h>
 978 ])
 979                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 980                           ;;
 981                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 982                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 983                                               [AC_INCLUDES_DEFAULT
 984 #include <sys/socket.h>
 985 ])
 986                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 987                           ;;
 988                 esac
 989         ;;
 990         no|*)
 991                 ;;
 992 esac
 993
 994 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
 995 case "$enable_tfo_server" in
 996         yes)
 997               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
 998 #include <netinet/tcp.h>
 999               ])
1000                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1001                 ;;
1002         no|*)
1003                 ;;
1004 esac
1005
1006 # check for libevent
1007 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1008     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1009     [ ],[ withval="no" ])
1010 if test x_$withval = x_yes -o x_$withval != x_no; then
1011         AC_MSG_CHECKING(for libevent)
1012         if test x_$withval = x_ -o x_$withval = x_yes; then
1013             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1014         fi
1015         for dir in $withval; do
1016             thedir="$dir"
1017             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1018                 found_libevent="yes"
1019                 dnl assume /usr is in default path.
1020                 if test "$thedir" != "/usr"; then
1021                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1022                 fi
1023                 break;
1024             fi
1025         done
1026         if test x_$found_libevent != x_yes; then
1027                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1028                         # libevent source directory
1029                         AC_MSG_RESULT(found in $thedir)
1030                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1031                         BAK_LDFLAGS_SET="1"
1032                         BAK_LDFLAGS="$LDFLAGS"
1033                         # remove evdns from linking
1034                         mkdir build >/dev/null 2>&1
1035                         mkdir build/libevent >/dev/null 2>&1
1036                         mkdir build/libevent/.libs >/dev/null 2>&1
1037                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1038                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1039                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1040                         cp $ev_files_o build/libevent
1041                         cp $ev_files_lo build/libevent
1042                         cp $ev_files_libso build/libevent/.libs
1043                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1044                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1045                 else
1046                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1047 You can restart ./configure --with-libevent=no to use a builtin alternative.
1048 Please note that this alternative is not as capable as libevent when using
1049 large outgoing port ranges.  ])
1050                 fi
1051         else
1052             AC_MSG_RESULT(found in $thedir)
1053             dnl if event2 exists and no event lib in dir itself, use subdir
1054             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1055                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1056                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1057             else
1058                     dnl assume /usr is in default path, do not add "".
1059                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1060                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1061                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1062                     fi
1063             fi
1064         fi
1065         # check for library used by libevent after 1.3c
1066         AC_SEARCH_LIBS([clock_gettime], [rt])
1067
1068         # is the event.h header libev or libevent?
1069         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1070         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1071                 AC_SEARCH_LIBS(event_set, [ev])
1072         ],[
1073                 AC_SEARCH_LIBS(event_set, [event])
1074         ],[AC_INCLUDES_DEFAULT
1075 #include <event.h>
1076         ])
1077         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1078         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1079         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1080         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1081         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1082         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1083         PC_LIBEVENT_DEPENDENCY="libevent"
1084         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1085         if test -n "$BAK_LDFLAGS_SET"; then
1086                 LDFLAGS="$BAK_LDFLAGS"
1087         fi
1088 else
1089         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1090 fi
1091
1092 # check for libexpat
1093 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1094     [specify explicit path for libexpat.]),
1095     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1096 AC_MSG_CHECKING(for libexpat)
1097 found_libexpat="no"
1098 for dir in $withval ; do
1099             if test -f "$dir/include/expat.h"; then
1100                 found_libexpat="yes"
1101                 dnl assume /usr is in default path.
1102                 if test "$dir" != "/usr"; then
1103                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1104                     LDFLAGS="$LDFLAGS -L$dir/lib"
1105                 fi
1106                 AC_MSG_RESULT(found in $dir)
1107                 break;
1108             fi
1109 done
1110 if test x_$found_libexpat != x_yes; then
1111         AC_ERROR([Could not find libexpat, expat.h])
1112 fi
1113 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1114 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1115 #include <expat.h>
1116 ])
1117
1118 # set static linking if requested
1119 AC_SUBST(staticexe)
1120 staticexe=""
1121 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1122         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1123         , )
1124 if test x_$enable_static_exe = x_yes; then
1125         staticexe="-static"
1126         if test "$on_mingw" = yes; then
1127                 staticexe="-all-static"
1128                 # for static compile, include gdi32 and zlib here.
1129                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1130                         :
1131                 else
1132                         LIBS="$LIBS -lgdi32"
1133                 fi
1134                 LIBS="$LIBS -lz"
1135         fi
1136 fi
1137
1138 # Include systemd.m4 - begin
1139 sinclude(systemd.m4)
1140 # Include systemd.m4 - end
1141
1142 # set lock checking if requested
1143 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1144         [ enable to check lock and unlock calls, for debug purposes ]),
1145         , )
1146 if test x_$enable_lock_checks = x_yes; then
1147         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1148         CHECKLOCK_OBJ="checklocks.lo"
1149         AC_SUBST(CHECKLOCK_OBJ)
1150 fi
1151
1152 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1153 if test "$USE_WINSOCK" = 1; then
1154         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1155         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1156 #include <windows.h>
1157         ])
1158         AC_CHECK_TOOL(WINDRES, windres)
1159         LIBS="$LIBS -liphlpapi"
1160         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1161         AC_SUBST(WINAPPS)
1162         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1163         AC_SUBST(WIN_DAEMON_SRC)
1164         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1165         AC_SUBST(WIN_DAEMON_OBJ)
1166         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1167         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1168         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1169         AC_SUBST(WIN_HOST_OBJ_LINK)
1170         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1171         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1172         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1173         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1174         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1175         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1176 fi
1177 if test $ac_cv_func_getaddrinfo = no; then
1178         AC_LIBOBJ([fake-rfc2553])
1179 fi
1180 # check after getaddrinfo for its libraries
1181 ACX_FUNC_IOCTLSOCKET
1182
1183 # see if daemon(3) exists, and if it is deprecated.
1184 AC_CHECK_FUNCS([daemon])
1185 if test $ac_cv_func_daemon = yes; then
1186         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1187 #include <stdlib.h>
1188 ])
1189 fi
1190
1191 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1192 AC_INCLUDES_DEFAULT
1193 #ifdef HAVE_SYS_UN_H
1194 #include <sys/un.h>
1195 #endif
1196 ])
1197 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1198 AC_INCLUDES_DEFAULT
1199 #if HAVE_SYS_PARAM_H
1200 #include <sys/param.h>
1201 #endif
1202
1203 #ifdef HAVE_SYS_SOCKET_H
1204 #include <sys/socket.h>
1205 #endif
1206
1207 #ifdef HAVE_SYS_UIO_H
1208 #include <sys/uio.h>
1209 #endif
1210
1211 #ifdef HAVE_NETINET_IN_H
1212 #include <netinet/in.h>
1213 #endif
1214
1215 #ifdef HAVE_NETINET_TCP_H
1216 #include <netinet/tcp.h>
1217 #endif
1218
1219 #ifdef HAVE_ARPA_INET_H
1220 #include <arpa/inet.h>
1221 #endif
1222
1223 #ifdef HAVE_WINSOCK2_H
1224 #include <winsock2.h>
1225 #endif
1226
1227 #ifdef HAVE_WS2TCPIP_H
1228 #include <ws2tcpip.h>
1229 #endif
1230 ])
1231 AC_SEARCH_LIBS([setusercontext], [util])
1232 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget])
1233 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1234 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1235
1236 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1237 if echo $build_os | grep darwin8 > /dev/null; then
1238         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1239 fi
1240 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1241 AC_INCLUDES_DEFAULT
1242 #ifdef HAVE_NETINET_IN_H
1243 #include <netinet/in.h>
1244 #endif
1245
1246 #ifdef HAVE_NETINET_TCP_H
1247 #include <netinet/tcp.h>
1248 #endif
1249
1250 #ifdef HAVE_ARPA_INET_H
1251 #include <arpa/inet.h>
1252 #endif
1253
1254 #ifdef HAVE_WINSOCK2_H
1255 #include <winsock2.h>
1256 #endif
1257
1258 #ifdef HAVE_WS2TCPIP_H
1259 #include <ws2tcpip.h>
1260 #endif
1261 ])
1262 AC_REPLACE_FUNCS(inet_aton)
1263 AC_REPLACE_FUNCS(inet_pton)
1264 AC_REPLACE_FUNCS(inet_ntop)
1265 AC_REPLACE_FUNCS(snprintf)
1266 # test if snprintf return the proper length
1267 if test "x$ac_cv_func_snprintf" = xyes; then
1268     if test c${cross_compiling} = cno; then
1269         AC_MSG_CHECKING([for correct snprintf return value])
1270         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1271 [[
1272 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1273 ]])], [AC_MSG_RESULT(yes)], [
1274                 AC_MSG_RESULT(no)
1275                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1276                 AC_LIBOBJ(snprintf)
1277           ])
1278     fi
1279 fi
1280 AC_REPLACE_FUNCS(strlcat)
1281 AC_REPLACE_FUNCS(strlcpy)
1282 AC_REPLACE_FUNCS(memmove)
1283 AC_REPLACE_FUNCS(gmtime_r)
1284 AC_REPLACE_FUNCS(isblank)
1285 dnl without CTIME, ARC4-functions and without reallocarray.
1286 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1287 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1288 AC_REPLACE_FUNCS(reallocarray)
1289 if test "$USE_NSS" = "no"; then
1290         AC_REPLACE_FUNCS(arc4random)
1291         AC_REPLACE_FUNCS(arc4random_uniform)
1292         if test "$ac_cv_func_arc4random" = "no"; then
1293                 AC_LIBOBJ(explicit_bzero)
1294                 AC_LIBOBJ(arc4_lock)
1295                 AC_CHECK_FUNCS([getentropy],,[
1296                     if test "$USE_WINSOCK" = 1; then
1297                         AC_LIBOBJ(getentropy_win)
1298                     else
1299                         case "$host" in
1300                         Darwin|*darwin*)
1301                                 AC_LIBOBJ(getentropy_osx)
1302                         ;;
1303                         *solaris*|*sunos*|SunOS)
1304                                 AC_LIBOBJ(getentropy_solaris)
1305                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1306                                         AC_CHECK_FUNCS([SHA512_Update],,[
1307                                                 AC_LIBOBJ(sha512)
1308                                         ])
1309                                 ], [AC_INCLUDES_DEFAULT])
1310                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1311                                         # this lib needed for sha2 on solaris
1312                                         LIBS="$LIBS -lmd"
1313                                 fi
1314                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1315                         ;;
1316                         *linux*|Linux|*)
1317                                 AC_LIBOBJ(getentropy_linux)
1318                                 AC_CHECK_FUNCS([SHA512_Update],,[
1319                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1320                                         AC_LIBOBJ(sha512)
1321                                 ])
1322                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1323                                 AC_CHECK_FUNCS([getauxval])
1324                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1325                         ;;
1326                         esac
1327                     fi
1328                 ])
1329         fi
1330 fi
1331 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1332 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1333 AC_REPLACE_FUNCS(ctime_r)
1334 AC_REPLACE_FUNCS(strsep)
1335
1336 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1337 case "$enable_allsymbols" in
1338         yes)
1339         COMMON_OBJ_ALL_SYMBOLS=""
1340         UBSYMS=""
1341         EXTRALINK="-L. -L.libs -lunbound"
1342         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1343         ;;
1344         no|*)
1345         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1346         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1347         EXTRALINK=""
1348         ;;
1349 esac
1350 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1351 AC_SUBST(EXTRALINK)
1352 AC_SUBST(UBSYMS)
1353 if test x_$enable_lock_checks = x_yes; then
1354         UBSYMS="-export-symbols clubsyms.def"
1355         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1356         echo lock_protect >> clubsyms.def
1357         echo lock_unprotect >> clubsyms.def
1358         echo lock_get_mem >> clubsyms.def
1359         echo checklock_start >> clubsyms.def
1360         echo checklock_stop >> clubsyms.def
1361         echo checklock_lock >> clubsyms.def
1362         echo checklock_unlock >> clubsyms.def
1363         echo checklock_init >> clubsyms.def
1364         echo checklock_thrcreate >> clubsyms.def
1365         echo checklock_thrjoin >> clubsyms.def
1366 fi
1367
1368 # check for dnstap if requested
1369 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1370     [
1371         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1372         AC_SUBST([ENABLE_DNSTAP], [1])
1373
1374         AC_SUBST([opt_dnstap_socket_path])
1375         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1376         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1377             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1378
1379         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1380         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1381     ],
1382     [
1383         AC_SUBST([ENABLE_DNSTAP], [0])
1384     ]
1385 )
1386
1387 # check for dnscrypt if requested
1388 dnsc_DNSCRYPT([
1389         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1390         AC_SUBST([ENABLE_DNSCRYPT], [1])
1391
1392         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1393         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1394     ],
1395     [
1396         AC_SUBST([ENABLE_DNSCRYPT], [0])
1397     ]
1398 )
1399
1400 # check for cachedb if requested
1401 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1402 case "$enable_cachedb" in
1403     yes)
1404         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1405         ;;
1406     no|*)
1407         # nothing
1408         ;;
1409 esac
1410
1411 # check for ipsecmod if requested
1412 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1413 case "$enable_ipsecmod" in
1414         yes)
1415                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1416                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1417                 AC_SUBST(IPSECMOD_OBJ)
1418                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1419                 AC_SUBST(IPSECMOD_HEADER)
1420                 ;;
1421         no|*)
1422                 # nothing
1423                 ;;
1424 esac
1425
1426 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1427 # on openBSD, the implicit rule make $< work.
1428 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1429 # gmake works.
1430 cat >conftest.make <<EOF
1431 all:    conftest.lo
1432
1433 conftest.lo foo.lo bla.lo:
1434         if test -f "\$<"; then touch \$@; fi
1435
1436 .SUFFIXES: .lo
1437 .c.lo:
1438         if test -f "\$<"; then touch \$@; fi
1439
1440 conftest.lo:        conftest.dir/conftest.c
1441 EOF
1442 mkdir conftest.dir
1443 touch conftest.dir/conftest.c
1444 rm -f conftest.lo conftest.c
1445 ${MAKE:-make} -f conftest.make >/dev/null
1446 rm -f conftest.make conftest.c conftest.dir/conftest.c
1447 rm -rf conftest.dir
1448 if test ! -f conftest.lo; then
1449         AC_MSG_RESULT(no)
1450         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1451         SOURCEFILE='`cat .source`'
1452 else
1453         AC_MSG_RESULT(yes)
1454         SOURCEDETERMINE=':'
1455         SOURCEFILE='$<'
1456 fi
1457 rm -f conftest.lo
1458 AC_SUBST(SOURCEDETERMINE)
1459 AC_SUBST(SOURCEFILE)
1460
1461 # see if we want to build the library or everything
1462 ALLTARGET="alltargets"
1463 INSTALLTARGET="install-all"
1464 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1465         [do not build daemon and tool programs]),
1466         [
1467         if test "$withval" = "yes"; then
1468                 ALLTARGET="lib"
1469                 INSTALLTARGET="install-lib"
1470         fi
1471 ])
1472 AC_SUBST(ALLTARGET)
1473 AC_SUBST(INSTALLTARGET)
1474
1475 ACX_STRIP_EXT_FLAGS
1476 if test -n "$LATE_LDFLAGS"; then
1477   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1478 fi
1479 # remove start spaces
1480 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1481 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1482
1483 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1484
1485 AH_BOTTOM(
1486 dnl this must be first AH_CONFIG, to define the flags before any includes.
1487 AHX_CONFIG_EXT_FLAGS
1488
1489 dnl includes
1490 [
1491 #ifndef UNBOUND_DEBUG
1492 #  define NDEBUG
1493 #endif
1494
1495 /** Use small-ldns codebase */
1496 #define USE_SLDNS 1
1497 #ifdef HAVE_SSL
1498 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1499 #endif
1500
1501 #include <stdio.h>
1502 #include <string.h>
1503 #include <unistd.h>
1504 #include <assert.h>
1505
1506 #if STDC_HEADERS
1507 #include <stdlib.h>
1508 #include <stddef.h>
1509 #endif
1510
1511 #ifdef HAVE_STDARG_H
1512 #include <stdarg.h>
1513 #endif
1514
1515 #ifdef HAVE_STDINT_H
1516 #include <stdint.h>
1517 #endif
1518
1519 #include <errno.h>
1520
1521 #if HAVE_SYS_PARAM_H
1522 #include <sys/param.h>
1523 #endif
1524
1525 #ifdef HAVE_SYS_SOCKET_H
1526 #include <sys/socket.h>
1527 #endif
1528
1529 #ifdef HAVE_SYS_UIO_H
1530 #include <sys/uio.h>
1531 #endif
1532
1533 #ifdef HAVE_NETINET_IN_H
1534 #include <netinet/in.h>
1535 #endif
1536
1537 #ifdef HAVE_NETINET_TCP_H
1538 #include <netinet/tcp.h>
1539 #endif
1540
1541 #ifdef HAVE_ARPA_INET_H
1542 #include <arpa/inet.h>
1543 #endif
1544
1545 #ifdef HAVE_WINSOCK2_H
1546 #include <winsock2.h>
1547 #endif
1548
1549 #ifdef HAVE_WS2TCPIP_H
1550 #include <ws2tcpip.h>
1551 #endif
1552
1553 #ifndef USE_WINSOCK
1554 #define ARG_LL "%ll"
1555 #else
1556 #define ARG_LL "%I64"
1557 #endif
1558
1559 #ifndef AF_LOCAL
1560 #define AF_LOCAL AF_UNIX
1561 #endif
1562 ]
1563
1564 AHX_CONFIG_FORMAT_ATTRIBUTE
1565 AHX_CONFIG_UNUSED_ATTRIBUTE
1566 AHX_CONFIG_FSEEKO
1567 AHX_CONFIG_MAXHOSTNAMELEN
1568 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1569 #define snprintf snprintf_unbound
1570 #define vsnprintf vsnprintf_unbound
1571 #include <stdarg.h>
1572 int snprintf (char *str, size_t count, const char *fmt, ...);
1573 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1574 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1575 AHX_CONFIG_INET_PTON(unbound)
1576 AHX_CONFIG_INET_NTOP(unbound)
1577 AHX_CONFIG_INET_ATON(unbound)
1578 AHX_CONFIG_MEMMOVE(unbound)
1579 AHX_CONFIG_STRLCAT(unbound)
1580 AHX_CONFIG_STRLCPY(unbound)
1581 AHX_CONFIG_GMTIME_R(unbound)
1582 AHX_CONFIG_REALLOCARRAY(unbound)
1583 AHX_CONFIG_W32_SLEEP
1584 AHX_CONFIG_W32_USLEEP
1585 AHX_CONFIG_W32_RANDOM
1586 AHX_CONFIG_W32_SRANDOM
1587 AHX_CONFIG_W32_FD_SET_T
1588 AHX_CONFIG_IPV6_MIN_MTU
1589 AHX_MEMCMP_BROKEN(unbound)
1590
1591 [
1592 #ifndef HAVE_CTIME_R
1593 #define ctime_r unbound_ctime_r
1594 char *ctime_r(const time_t *timep, char *buf);
1595 #endif
1596
1597 #ifndef HAVE_STRSEP
1598 #define strsep unbound_strsep
1599 char *strsep(char **stringp, const char *delim);
1600 #endif
1601
1602 #ifndef HAVE_ISBLANK
1603 #define isblank unbound_isblank
1604 int isblank(int c);
1605 #endif
1606
1607 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1608 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1609 #endif
1610
1611 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1612 int inet_pton(int af, const char* src, void* dst);
1613 #endif
1614
1615 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1616 #define strptime unbound_strptime
1617 struct tm;
1618 char *strptime(const char *s, const char *format, struct tm *tm);
1619 #endif
1620
1621 #ifdef HAVE_LIBRESSL
1622 #  if !HAVE_DECL_STRLCPY
1623 size_t strlcpy(char *dst, const char *src, size_t siz);
1624 #  endif
1625 #  if !HAVE_DECL_STRLCAT
1626 size_t strlcat(char *dst, const char *src, size_t siz);
1627 #  endif
1628 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1629 uint32_t arc4random(void);
1630 #  endif
1631 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1632 uint32_t arc4random_uniform(uint32_t upper_bound);
1633 #  endif
1634 #  if !HAVE_DECL_REALLOCARRAY
1635 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1636 #  endif
1637 #endif /* HAVE_LIBRESSL */
1638 #ifndef HAVE_ARC4RANDOM
1639 void explicit_bzero(void* buf, size_t len);
1640 int getentropy(void* buf, size_t len);
1641 uint32_t arc4random(void);
1642 void arc4random_buf(void* buf, size_t n);
1643 void _ARC4_LOCK(void);
1644 void _ARC4_UNLOCK(void);
1645 #endif
1646 #ifndef HAVE_ARC4RANDOM_UNIFORM
1647 uint32_t arc4random_uniform(uint32_t upper_bound);
1648 #endif
1649 #ifdef COMPAT_SHA512
1650 #ifndef SHA512_DIGEST_LENGTH
1651 #define SHA512_BLOCK_LENGTH             128
1652 #define SHA512_DIGEST_LENGTH            64
1653 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1654 typedef struct _SHA512_CTX {
1655         uint64_t        state[8];
1656         uint64_t        bitcount[2];
1657         uint8_t buffer[SHA512_BLOCK_LENGTH];
1658 } SHA512_CTX;
1659 #endif /* SHA512_DIGEST_LENGTH */
1660 void SHA512_Init(SHA512_CTX*);
1661 void SHA512_Update(SHA512_CTX*, void*, size_t);
1662 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1663 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1664 #endif /* COMPAT_SHA512 */
1665
1666
1667
1668 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1669    /* using version of libevent that is not threadsafe. */
1670 #  define LIBEVENT_SIGNAL_PROBLEM 1
1671 #endif
1672
1673 #ifndef CHECKED_INET6
1674 #  define CHECKED_INET6
1675 #  ifdef AF_INET6
1676 #    define INET6
1677 #  else
1678 #    define AF_INET6        28
1679 #  endif
1680 #endif /* CHECKED_INET6 */
1681
1682 #ifndef HAVE_GETADDRINFO
1683 struct sockaddr_storage;
1684 #include "compat/fake-rfc2553.h"
1685 #endif
1686
1687 #ifdef UNBOUND_ALLOC_STATS
1688 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1689 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1690 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1691 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1692 void *unbound_stat_malloc(size_t size);
1693 void *unbound_stat_calloc(size_t nmemb, size_t size);
1694 void unbound_stat_free(void *ptr);
1695 void *unbound_stat_realloc(void *ptr, size_t size);
1696 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1697         const char* func);
1698 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1699         int line, const char* func);
1700 void unbound_stat_free_log(void *ptr, const char* file, int line,
1701         const char* func);
1702 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1703         int line, const char* func);
1704 #elif defined(UNBOUND_ALLOC_LITE)
1705 #  include "util/alloc.h"
1706 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1707
1708 /** default port for DNS traffic. */
1709 #define UNBOUND_DNS_PORT 53
1710 /** default port for unbound control traffic, registered port with IANA,
1711     ub-dns-control  8953/tcp    unbound dns nameserver control */
1712 #define UNBOUND_CONTROL_PORT 8953
1713 /** the version of unbound-control that this software implements */
1714 #define UNBOUND_CONTROL_VERSION 1
1715
1716 ])
1717
1718 dnl if we build from source tree, the man pages need @date@ and @version@
1719 dnl if this is a distro tarball, that was already done by makedist.sh
1720 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1721 AC_SUBST(date, [`date +'%b %e, %Y'`])
1722
1723 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1724 AC_CONFIG_HEADER([config.h])
1725 AC_OUTPUT