contrib/apr-util/configure.in

   1 dnl
   2 dnl Process this file with autoconf to produce a configure script
   3 dnl
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT(export_vars.sh.in)
   7
   8 AC_CONFIG_HEADER(include/private/apu_config.h)
   9 AC_CONFIG_AUX_DIR(build)
  10
  11 sinclude(build/apu-conf.m4)
  12 sinclude(build/apu-iconv.m4)
  13 sinclude(build/apu-hints.m4)
  14 sinclude(build/apr_common.m4)
  15 sinclude(build/find_apr.m4)
  16 sinclude(build/crypto.m4)
  17 sinclude(build/dbm.m4)
  18 sinclude(build/dbd.m4)
  19 sinclude(build/dso.m4)
  20
  21 dnl Generate ./config.nice for reproducing runs of configure
  22 dnl
  23 APR_CONFIG_NICE(config.nice)
  24
  25 dnl # Some initial steps for configuration.  We setup the default directory
  26 dnl # and which files are to be configured.
  27
  28 dnl Absolute source/build directory
  29 abs_srcdir=`(cd $srcdir && pwd)`
  30 abs_builddir=`pwd`
  31
  32 if test "$abs_builddir" != "$abs_srcdir"; then
  33   USE_VPATH=1
  34   APU_CONFIG_LOCATION=build
  35 else
  36   APU_CONFIG_LOCATION=source
  37 fi
  38
  39 AC_SUBST(APU_CONFIG_LOCATION)
  40
  41 AC_CANONICAL_SYSTEM
  42
  43 AC_PROG_INSTALL
  44
  45 # Use -no-install to link the test programs on all platforms
  46 # but Darwin, where it would cause the programs to be linked
  47 # against installed versions of libapr instead of those just
  48 # built.
  49 case $host in
  50 *-apple-darwin*) LT_NO_INSTALL="" ;;
  51 *) LT_NO_INSTALL="-no-install" ;;
  52 esac
  53 AC_SUBST(LT_NO_INSTALL)
  54
  55 dnl
  56 dnl compute the top directory of the build
  57 dnl note: this is needed for LIBTOOL and exporting the bundled Expat
  58 dnl
  59 top_builddir="$abs_builddir"
  60 AC_SUBST(top_builddir)
  61 AC_SUBST(abs_srcdir)
  62 AC_SUBST(abs_builddir)
  63
  64 dnl Initialize mkdir -p functionality.
  65 APR_MKDIR_P_CHECK($abs_srcdir/build/mkdir.sh)
  66
  67 dnl get our version information
  68 get_version="$abs_srcdir/build/get-version.sh"
  69 version_hdr="$abs_srcdir/include/apu_version.h"
  70 APRUTIL_MAJOR_VERSION="`$get_version major $version_hdr APU`"
  71 APRUTIL_DOTTED_VERSION="`$get_version all $version_hdr APU`"
  72
  73 APU_LTVERSION="-version-info `$get_version libtool $version_hdr APU`"
  74
  75 AC_SUBST(APRUTIL_DOTTED_VERSION)
  76 AC_SUBST(APRUTIL_MAJOR_VERSION)
  77 AC_SUBST(APU_LTVERSION)
  78
  79 echo "APR-util Version: ${APRUTIL_DOTTED_VERSION}"
  80
  81 dnl Enable the layout handling code, then reparse the prefix-style
  82 dnl arguments due to autoconf being a PITA.
  83 APR_ENABLE_LAYOUT(apr-util)
  84 APR_PARSE_ARGUMENTS
  85
  86 dnl load os-specific hints for apr-util
  87 APU_PRELOAD
  88
  89 dnl
  90 dnl set up the compilation flags and stuff
  91 dnl
  92
  93 APRUTIL_INCLUDES=""
  94 APRUTIL_PRIV_INCLUDES="-I$top_builddir/include -I$top_builddir/include/private"
  95 if test -n "$USE_VPATH"; then
  96     APRUTIL_PRIV_INCLUDES="$APRUTIL_PRIV_INCLUDES -I$abs_srcdir/include/private -I$abs_srcdir/include"
  97 fi
  98
  99 dnl
 100 dnl Find the APR includes directory and (possibly) the source (base) dir.
 101 dnl
 102 APU_FIND_APR
 103
 104 dnl
 105 dnl even though we use apr_rules.mk for building apr-util, we need
 106 dnl to grab CC and CPP ahead of time so that apr-util config tests
 107 dnl use the same compiler as APR; we need the same compiler options
 108 dnl and feature test macros as well
 109 dnl
 110 APR_SETIFNULL(CC, `$apr_config --cc`)
 111 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 112 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 113 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 114 apr_shlibpath_var=`$apr_config --shlib-path-var`
 115 AC_SUBST(apr_shlibpath_var)
 116
 117 dnl
 118 dnl  Find the APR-ICONV directory.
 119 dnl
 120 AC_ARG_WITH(apr-iconv,
 121             [  --with-apr-iconv=DIR    relative path to apr-iconv source],
 122   [ apu_apriconv_dir="$withval"
 123     if test "$apu_apriconv_dir" != "no"; then
 124       if test -d "$apu_apriconv_dir"; then
 125         APR_SUBDIR_CONFIG("$apu_apriconv_dir",
 126                           [$apache_apr_flags \
 127                              --prefix=$prefix \
 128                              --exec-prefix=$exec_prefix \
 129                              --libdir=$libdir \
 130                              --includedir=$includedir \
 131                              --bindir=$bindir \
 132                              --datadir=$datadir \
 133                              --with-installbuilddir=$installbuilddir],
 134                           [--enable-layout=*|\'--enable-layout=*])
 135         APRUTIL_EXPORT_LIBS="$abs_srcdir/$apu_apriconv_dir/lib/libapriconv.la \
 136                              $APRUTIL_EXPORT_LIBS"
 137         APRUTIL_INCLUDES="-I$abs_srcdir/$apu_apriconv_dir/include \
 138                           $APRUTIL_INCLUDES"
 139         APR_ICONV_DIR="$apu_apriconv_dir"
 140       else
 141        APR_ICONV_DIR=""
 142       fi
 143     else
 144       APR_ICONV_DIR=""
 145     fi
 146   ])
 147 AC_SUBST(APR_ICONV_DIR)
 148
 149 dnl Find LDAP library
 150 dnl Determine what DBM backend type to use.
 151 dnl Find Expat
 152 dnl Find an iconv library
 153 APU_CHECK_CRYPTO
 154 APU_CHECK_CRYPTO_OPENSSL
 155 APU_CHECK_CRYPTO_NSS
 156 APU_FIND_LDAP
 157 APU_CHECK_DBM
 158 APU_CHECK_DBD
 159 APU_CHECK_DBD_MYSQL
 160 APU_CHECK_DBD_SQLITE3
 161 APU_CHECK_DBD_SQLITE2
 162 APU_CHECK_DBD_ORACLE
 163 APU_CHECK_DBD_FREETDS
 164 APU_CHECK_DBD_ODBC
 165 APU_FIND_EXPAT
 166 APU_FIND_ICONV
 167
 168 dnl Enable DSO build; must be last:
 169 APU_CHECK_UTIL_DSO
 170
 171 AC_SEARCH_LIBS(crypt, crypt ufc)
 172 AC_MSG_CHECKING(if system crypt() function is threadsafe)
 173 if test "x$apu_crypt_threadsafe" = "x1"; then
 174   AC_DEFINE(APU_CRYPT_THREADSAFE, 1, [Define if the system crypt() function is threadsafe])
 175   msg="yes"
 176 else
 177   msg="no"
 178 fi
 179 AC_MSG_RESULT([$msg])
 180
 181 AC_CHECK_FUNCS(crypt_r, [ crypt_r="1" ], [ crypt_r="0" ])
 182 if test "$crypt_r" = "1"; then
 183   APU_CHECK_CRYPT_R_STYLE
 184 fi
 185
 186 so_ext=$APR_SO_EXT
 187 lib_target=$APR_LIB_TARGET
 188 AC_SUBST(so_ext)
 189 AC_SUBST(lib_target)
 190
 191 APRUTIL_LIBNAME="aprutil${libsuffix}"
 192 AC_SUBST(APRUTIL_LIBNAME)
 193
 194 # Set up destination directory for DSOs.
 195 APU_DSO_LIBDIR="\${libdir}/apr-util-${APRUTIL_MAJOR_VERSION}"
 196 # Set APU_HAVE_MODULES appropriately for the Makefile
 197 if test -n "$APU_MODULES"; then
 198    APU_HAVE_MODULES=yes
 199 else
 200    APU_HAVE_MODULES=no
 201 fi
 202 # Define expanded libdir for apu_config.h
 203 APR_EXPAND_VAR(abs_dso_libdir, $APU_DSO_LIBDIR)
 204 AC_DEFINE_UNQUOTED([APU_DSO_LIBDIR], ["$abs_dso_libdir"],
 205                    [Define to be absolute path to DSO directory])
 206 AC_SUBST(APU_HAVE_MODULES)
 207 AC_SUBST(APU_DSO_LIBDIR)
 208 AC_SUBST(APU_MODULES)
 209 AC_SUBST(EXTRA_OBJECTS)
 210
 211 dnl
 212 dnl Prep all the flags and stuff for compilation and export to other builds
 213 dnl
 214 APR_ADDTO(APRUTIL_LIBS, [$APR_LIBS])
 215
 216 AC_SUBST(APRUTIL_EXPORT_LIBS)
 217 AC_SUBST(APRUTIL_PRIV_INCLUDES)
 218 AC_SUBST(APRUTIL_INCLUDES)
 219 AC_SUBST(APRUTIL_LDFLAGS)
 220 AC_SUBST(APRUTIL_LIBS)
 221 AC_SUBST(LDFLAGS)
 222
 223 dnl copy apr's rules.mk into our build directory.
 224 if test ! -d ./build; then
 225    $mkdir_p build
 226 fi
 227 cp $APR_BUILD_DIR/apr_rules.mk $abs_builddir/build/rules.mk
 228
 229 dnl
 230 dnl BSD/OS (BSDi) needs to use a different include syntax in the Makefiles
 231 dnl
 232 case "$host_alias" in
 233 *bsdi* | BSD/OS)
 234     # Check whether they've installed GNU make
 235     if make --version > /dev/null 2>&1; then
 236         INCLUDE_RULES="include $abs_builddir/build/rules.mk"
 237         INCLUDE_OUTPUTS="include $abs_srcdir/build-outputs.mk"
 238     else
 239         INCLUDE_RULES=".include \"$abs_builddir/build/rules.mk\""
 240         INCLUDE_OUTPUTS=".include \"$abs_srcdir/build-outputs.mk\""
 241     fi
 242     ;;
 243 *)
 244     INCLUDE_RULES="include $abs_builddir/build/rules.mk"
 245     INCLUDE_OUTPUTS="include $abs_srcdir/build-outputs.mk"
 246     ;;
 247 esac
 248 AC_SUBST(INCLUDE_RULES)
 249 AC_SUBST(INCLUDE_OUTPUTS)
 250
 251 for d in include include/private; do
 252     test -d $top_builddir/$d || mkdir $top_builddir/$d
 253 done
 254
 255 AC_CONFIG_FILES([Makefile export_vars.sh
 256                  build/pkg/pkginfo apr-util.pc
 257                  apu-$APRUTIL_MAJOR_VERSION-config:apu-config.in
 258                  include/private/apu_select_dbm.h
 259                  include/apr_ldap.h
 260                  include/apu.h include/apu_want.h])
 261
 262 AC_CONFIG_COMMANDS([default], [
 263 chmod +x apu-$APRUTIL_MAJOR_VERSION-config
 264 ],[
 265 APRUTIL_MAJOR_VERSION=$APRUTIL_MAJOR_VERSION
 266 ])
 267
 268 if test -d $srcdir/test; then
 269     AC_CONFIG_FILES([test/Makefile])
 270 fi
 271
 272 AC_OUTPUT