contrib/bmake/configure.in

   1 dnl
   2 dnl RCSid:
   3 dnl     $Id: configure.in,v 1.65 2020/05/25 01:11:40 sjg Exp $
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script
   6 dnl
   7 AC_PREREQ(2.50)
   8 AC_INIT([bmake], [20200524], [sjg@NetBSD.org])
   9 AC_CONFIG_HEADERS(config.h)
  10
  11 dnl make srcdir absolute
  12 case "$srcdir" in
  13 /*) ;;
  14 *) srcdir=`cd $srcdir && pwd`;;
  15 esac
  16
  17 dnl get _MAKE_VERSION
  18 . $srcdir/VERSION
  19 OS=`uname -s`
  20
  21 dnl
  22 AC_ARG_WITH(defshell,
  23 [  --with-defshell=SHELL  use SHELL by default - must be sh compatible, use sh or ksh to pick the internal definitions],
  24 [case "${withval}" in
  25 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake DEFSHELL) ;;
  26 no)    ;;
  27 *)     case "$with_defshell" in
  28        sh)  DEFSHELL_INDEX=DEFSHELL_INDEX_SH;;  # it's the default anyway
  29        ksh) DEFSHELL_INDEX=DEFSHELL_INDEX_KSH;;
  30        csh) DEFSHELL_INDEX=DEFSHELL_INDEX_CSH;; # kidding right?
  31        *)   defshell_path=$with_defshell;;      # better be sh compatible!
  32        esac
  33        ;;
  34        esac])
  35 dnl
  36 case "$OS" in
  37 CYGWIN*|MINGW*) use_makefile=no;;
  38 *) use_makefile=yes;;
  39 esac
  40 AC_ARG_WITH(makefile,
  41 [ --without-makefile dissable use of generated makefile],
  42 [case "${withval}" in
  43 yes|no) use_makefile=${withval};;
  44 *) AC_MSG_ERROR(bad value ${withval} given for makefile) ;;
  45 esac])
  46 dnl
  47 use_meta=yes
  48 AC_ARG_WITH(meta,
  49 [ --without-meta dissable use of meta-mode],
  50 [case "${withval}" in
  51 yes|no) use_meta=${withval};;
  52 *) AC_MSG_ERROR(bad value ${withval} given for meta) ;;
  53 esac])
  54 dnl
  55 AC_ARG_WITH(filemon,
  56 [ --with-filemon={no,dev,ktrace,path/filemon.h} indicate filemon method for meta-mode. Path to filemon.h implies dev],
  57 [ case "/${withval}" in
  58 /no) use_filemon=no;;
  59 /*trace) filemon_h=no use_filemon="${withval}";;
  60 */filemon.h) filemon_h="${withval}";;
  61 */filemon*) filemon_h="${withval}/filemon.h";;
  62 *) AC_MSG_ERROR(bad value ${withval} given for filemon) ;;
  63 esac
  64 case "$use_filemon,$filemon_h" in
  65 ,*.h) use_filemon=dev;;
  66 esac
  67 ],
  68 [
  69 case "$OS" in
  70 NetBSD) filemon_h=no use_filemon=ktrace;;
  71 *)
  72     for d in "/usr/include/dev/filemon" "$prefix/include/dev/filemon" "$srcdir/../../sys/dev/filemon"
  73     do
  74         for x in "/$OS" ""
  75         do
  76             filemon_h="$d$x/filemon.h"
  77             test -s "$filemon_h" && break
  78         done
  79         test -s "$filemon_h" && { use_filemon=dev; break; }
  80     done
  81     ;;
  82 esac
  83 use_filemon=${use_filemon:-no}
  84 case "$use_filemon" in
  85 dev) ;;
  86 *) filemon_h=no;;
  87 esac
  88 ])
  89 dnl echo "Note: use_meta=$use_meta use_filemon=$use_filemon filemon_h=$filemon_h" >&6
  90 case "$use_meta" in
  91 yes)
  92         case "$use_filemon" in
  93         no) ;;
  94         *) echo "Using: filemon_${use_filemon}.c" >&6;;
  95         esac
  96         ;;
  97 esac
  98 dnl
  99 dnl Check for OS problems
 100 dnl Solaris's signal.h only privides sigset_t etc if one of
 101 dnl _EXTENSIONS_ _POSIX_C_SOURCE or _XOPEN_SOURCE are defined.
 102 dnl The later two seem to cause more problems than they solve so if we
 103 dnl see _EXTENSIONS_ we use it.
 104 AC_USE_SYSTEM_EXTENSIONS
 105 dnl Checks for programs.
 106 AC_PROG_CC
 107 AC_PROG_CC_C99
 108 dnl AC_PROG_GCC_TRADITIONAL
 109 AC_PROG_INSTALL
 110 dnl Executable suffix - normally empty; .exe on os2.
 111 AC_SUBST(ac_exe_suffix)dnl
 112 dnl
 113 dnl Hurd refuses to define PATH_MAX or MAXPATHLEN
 114 if test -x /usr/bin/getconf; then
 115    bmake_path_max=`getconf PATH_MAX / 2> /dev/null`
 116    # only a numeric response is useful
 117    test ${bmake_path_max:-0} -gt 0 2> /dev/null || bmake_path_max=
 118 fi
 119 bmake_path_max=${bmake_path_max:-1024}
 120 if test $bmake_path_max -gt 1024; then
 121    # this is all we expect
 122    bmake_path_max=1024
 123 fi
 124 echo "Using: BMAKE_PATH_MAX=$bmake_path_max" >&6
 125 AC_SUBST(bmake_path_max)dnl
 126 dnl
 127 dnl AC_C_CROSS
 128 dnl
 129
 130 dnl Checks for header files.
 131 AC_HEADER_STDC
 132 AC_HEADER_SYS_WAIT
 133 AC_HEADER_DIRENT
 134 dnl Keep this list sorted
 135 AC_CHECK_HEADERS(sys/param.h)
 136 dnl On BSDi at least we really need sys/param.h for sys/sysctl.h
 137 AC_CHECK_HEADERS([sys/sysctl.h], [], [],
 138 [#ifdef HAVE_SYS_PARAM_H
 139 # include <sys/param.h>
 140 # endif
 141 ])
 142
 143 AC_CHECK_HEADERS( \
 144         ar.h \
 145         err.h \
 146         fcntl.h \
 147         libgen.h \
 148         limits.h \
 149         paths.h \
 150         poll.h \
 151         ranlib.h \
 152         string.h \
 153         sys/mman.h \
 154         sys/select.h \
 155         sys/socket.h \
 156         sys/time.h \
 157         sys/uio.h \
 158         unistd.h \
 159         utime.h \
 160         )
 161
 162 dnl Both *BSD and Linux have sys/cdefs.h, most do not.
 163 dnl If it is missing, we add -I${srcdir}/missing to CFLAGS
 164 dnl also if sys/cdefs.h does not have __RCSID we need to use ours
 165 dnl but we need to include the host's one too *sigh*
 166 AC_CHECK_HEADER(sys/cdefs.h,
 167 echo $ECHO_N "checking whether sys/cdefs.h is compatible... $ECHO_C" >&6
 168 AC_EGREP_CPP(yes,
 169 [#include <sys/cdefs.h>
 170 #ifdef __RCSID
 171 yes
 172 #endif
 173 ],
 174 echo yes  >&6,
 175 echo no  >&6; CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd` -DNEED_HOST_CDEFS_H"),
 176 CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd`")
 177
 178 dnl Checks for typedefs, structures, and compiler characteristics.
 179 AC_C___ATTRIBUTE__
 180 AC_C_BIGENDIAN
 181 AC_C_CONST
 182 AC_TYPE_MODE_T
 183 AC_TYPE_OFF_T
 184 AC_TYPE_PID_T
 185 AC_TYPE_SIZE_T
 186 AC_TYPE_UINT32_T
 187 AC_DECL_SYS_SIGLIST
 188 AC_HEADER_TIME
 189 AC_STRUCT_TM
 190
 191 dnl Checks for library functions.
 192 AC_TYPE_SIGNAL
 193 AC_FUNC_VFORK
 194 AC_FUNC_VPRINTF
 195 AC_FUNC_WAIT3
 196 dnl Keep this list sorted
 197 AC_CHECK_FUNCS( \
 198         err \
 199         errx \
 200         getcwd \
 201         getenv \
 202         getopt \
 203         getwd \
 204         killpg \
 205         mmap \
 206         putenv \
 207         select \
 208         setenv \
 209         setpgid \
 210         setsid \
 211         sigaction \
 212         sigvec \
 213         snprintf \
 214         strerror \
 215         strftime \
 216         strsep \
 217         strtod \
 218         strtol \
 219         sysctl \
 220         unsetenv \
 221         vsnprintf \
 222         wait3 \
 223         wait4 \
 224         waitpid \
 225         warn \
 226         warnx \
 227         )
 228
 229 dnl functions which we may need to provide
 230 AC_REPLACE_FUNCS( \
 231         realpath \
 232         dirname \
 233         stresep \
 234         strlcpy \
 235         )
 236
 237 AC_CHECK_LIB([util], [emalloc],
 238     [ AC_CHECK_LIB([util], [erealloc],
 239       [ AC_CHECK_LIB([util], [estrdup],
 240         [ AC_CHECK_LIB([util], [estrndup],
 241           [ LIBS="$LIBS -lutil"
 242             CPPFLAGS="$CPPFLAGS -DUSE_EMALLOC" ])])])])
 243
 244 dnl
 245 dnl Structures
 246 dnl
 247 AC_HEADER_STAT
 248 AC_STRUCT_ST_RDEV
 249 dnl
 250 echo "checking if compiler supports __func__" >&6
 251 AC_LANG(C)
 252 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[[const char *func = __func__;]])],,
 253         AC_DEFINE(__func__, __FUNCTION__, C99 function name))
 254 dnl
 255 dnl we want this for unit-tests/Makefile
 256 echo $ECHO_N "checking if diff -u works... $ECHO_C" >&6
 257 if diff -u /dev/null /dev/null > /dev/null 2>&1; then
 258    diff_u=-u
 259    echo yes >&6
 260 else
 261    diff_u=
 262    echo no >&6
 263 fi
 264 dnl
 265 dnl AC_* don't quite cut it.
 266 dnl
 267 echo "checking for MACHINE & MACHINE_ARCH..." >&6
 268 cat > conftest.$ac_ext <<EOF
 269 #include "confdefs.h"
 270 #include <sys/param.h>
 271 #ifdef MACHINE
 272 machine=MACHINE
 273 #endif
 274 #ifdef MACHINE_ARCH
 275 machine_arch=MACHINE_ARCH
 276 #endif
 277 EOF
 278
 279 default_machine=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 |
 280         egrep machine= | tr -d ' "'`
 281 rm -rf conftest*
 282 if test "$default_machine"; then
 283         eval "$default_machine"
 284 fi
 285 machine=${machine:-`$srcdir/machine.sh`}
 286 machine_arch=${machine_arch:-`$srcdir/machine.sh arch`}
 287 echo "defaults: MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
 288 dnl
 289 dnl now allow overrides
 290 dnl
 291 AC_ARG_WITH(machine,
 292 [  --with-machine=MACHINE  explicitly set MACHINE],
 293 [case "${withval}" in
 294 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE) ;;
 295 no)    ;;
 296 generic) machine=`$srcdir/machine.sh`;;
 297 *)     machine=$with_machine;;
 298 esac])
 299 force_machine=
 300 AC_ARG_WITH(force_machine,
 301 [  --with-force-machine=MACHINE  set FORCE_MACHINE],
 302 [case "${withval}" in
 303 yes)   force_machine=FORCE_;;
 304 no)    ;;
 305 *)     force_machine=FORCE_; machine=$with_force_machine;;
 306 esac])
 307 dnl
 308 force_machine_arch=
 309 AC_ARG_WITH(force_machine_arch,
 310 [  --with-force-machine-arch=MACHINE  set FORCE_MACHINE_ARCH],
 311 [case "${withval}" in
 312 yes)   force_machine_arch=FORCE_;;
 313 no)    ;;
 314 *)     force_machine_arch=FORCE_; machine_arch=$with_force_machine;;
 315 esac])
 316 dnl
 317 AC_ARG_WITH(machine_arch,
 318 [  --with-machine_arch=MACHINE_ARCH  explicitly set MACHINE_ARCH],
 319 [case "${withval}" in
 320 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE_ARCH) ;;
 321 no)    ;;
 322 *)     machine_arch=$with_machine_arch;;
 323 esac])
 324 dnl
 325 dnl Tell them what we ended up with
 326 dnl
 327 echo "Using: ${force_machine}MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
 328 dnl
 329 dnl Allow folk to control _PATH_DEFSYSPATH
 330 dnl
 331 default_sys_path=\${prefix}/share/mk
 332 AC_ARG_WITH(default-sys-path,
 333 [  --with-default-sys-path=PATH:DIR:LIST  use an explicit _PATH_DEFSYSPATH
 334         MAKESYSPATH is a ':' separated list of directories
 335         that bmake will search for system .mk files.
 336         _PATH_DEFSYSPATH is its default value.],
 337 [case "${withval}" in
 338 yes)    AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_DEFSYSPATH) ;;
 339 no)     ;;
 340 *)      default_sys_path="$with_default_sys_path"
 341         ;;
 342 esac])
 343 dnl
 344 dnl Some folk don't like this one
 345 dnl
 346 AC_ARG_WITH(path-objdirprefix,
 347 [  --with-path-objdirprefix=PATH  override _PATH_OBJDIRPREFIX],
 348 [case "${withval}" in
 349 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_OBJDIRPREFIX) ;;
 350 no)    CPPFLAGS="$CPPFLAGS -DNO_PATH_OBJDIRPREFIX" ;;
 351 *)     CPPFLAGS="$CPPFLAGS \"-D_PATH_OBJDIRPREFIX=\\\"$with_path-objdir\\\"\"" ;;
 352 esac])
 353 dnl
 354 dnl And this can be handy to do with out.
 355 dnl
 356 AC_ARG_ENABLE(pwd-override,
 357 [  --disable-pwd-override  disable \$PWD overriding getcwd()],
 358 [case "${enableval}" in
 359 yes)   ;;
 360 no)    CPPFLAGS="$CPPFLAGS -DNO_PWD_OVERRIDE" ;;
 361 *)     AC_MSG_ERROR(bad value ${enableval} given for pwd-override option) ;;
 362 esac])
 363 dnl
 364 dnl Just for grins
 365 dnl
 366 AC_ARG_ENABLE(check-make-chdir,
 367 [  --disable-check-make-chdir disable make trying to guess
 368         when it should automatically cd \${.CURDIR}],
 369 [case "${enableval}" in
 370 yes)   ;;
 371 no)    CPPFLAGS="$CPPFLAGS -DNO_CHECK_MAKE_CHDIR" ;;
 372 *)     AC_MSG_ERROR(bad value ${enableval} given for check-make-chdir option) ;;
 373 esac])
 374 dnl
 375 dnl On non-BSD systems, bootstrap won't work without mk
 376 dnl
 377 AC_ARG_WITH(mksrc,
 378 [  --with-mksrc=PATH tell makefile.boot where to find mk src],
 379 [case "${withval}" in
 380 ""|yes|no) ;;
 381 *) test -s $withval/install-mk && mksrc=$withval ||
 382 AC_MSG_ERROR(bad value ${withval} given for mksrc cannot find install-mk)
 383 ;;
 384 esac
 385 ])
 386 dnl
 387 dnl Now make sure we have a value
 388 dnl
 389 srcdir=`cd $srcdir && pwd`
 390 for mksrc in $mksrc $srcdir/mk $srcdir/../mk mk
 391 do
 392         test -s $mksrc/install-mk || continue
 393         mksrc=`cd $mksrc && pwd`
 394         break
 395 done
 396 mksrc=`echo $mksrc | sed "s,$srcdir,\\\${srcdir},"`
 397 echo "Using: MKSRC=$mksrc" 1>&6
 398 dnl On some systems we want a different default shell by default
 399 if test -x /usr/xpg4/bin/sh; then
 400         defshell_path=${defshell_path:-/usr/xpg4/bin/sh}
 401 fi
 402 if test -n "$defshell_path"; then
 403         echo "Using: SHELL=$defshell_path"  >&6
 404         AC_DEFINE_UNQUOTED(DEFSHELL_CUSTOM, "$defshell_path", Path of default shell)
 405 fi
 406 if test -n "$DEFSHELL_INDEX"; then
 407        AC_DEFINE_UNQUOTED(DEFSHELL_INDEX, $DEFSHELL_INDEX, Shell spec to use by default)
 408 fi
 409 dnl
 410 AC_SUBST(machine)
 411 AC_SUBST(force_machine)
 412 AC_SUBST(machine_arch)
 413 AC_SUBST(mksrc)
 414 AC_SUBST(default_sys_path)
 415 AC_SUBST(INSTALL)
 416 AC_SUBST(GCC)
 417 AC_SUBST(diff_u)
 418 AC_SUBST(use_meta)
 419 AC_SUBST(use_filemon)
 420 AC_SUBST(filemon_h)
 421 AC_SUBST(_MAKE_VERSION)
 422 bm_outfiles="Makefile.config unit-tests/Makefile.config make-bootstrap.sh"
 423 if test $use_makefile = yes; then
 424    bm_outfiles="makefile $bm_outfiles"
 425 fi
 426 AC_OUTPUT($bm_outfiles)
 427 cat <<EOF
 428
 429 You can now run
 430
 431         sh ./make-bootstrap.sh
 432
 433 to produce a fully functional bmake.
 434
 435 EOF