contrib/compiler-rt/lib/builtins/arm/aeabi_cfcmp.S

   1 //===-- aeabi_cfcmp.S - EABI cfcmp* implementation ------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is dual licensed under the MIT and the University of Illinois Open
   6 // Source Licenses. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 #include "../assembly.h"
  11
  12 #if __BYTE_ORDER__ != __ORDER_LITTLE_ENDIAN__
  13 #error big endian support not implemented
  14 #endif
  15
  16 #define APSR_Z (1 << 30)
  17 #define APSR_C (1 << 29)
  18
  19 // void __aeabi_cfcmpeq(float a, float b) {
  20 //   if (isnan(a) || isnan(b)) {
  21 //     Z = 0; C = 1;
  22 //   } else {
  23 //     __aeabi_cfcmple(a, b);
  24 //   }
  25 // }
  26
  27         .syntax unified
  28         .p2align 2
  29 DEFINE_COMPILERRT_FUNCTION(__aeabi_cfcmpeq)
  30         push {r0-r3, lr}
  31         bl __aeabi_cfcmpeq_check_nan
  32         cmp r0, #1
  33 #if __ARM_ARCH_ISA_THUMB == 1
  34         beq 1f
  35         // NaN has been ruled out, so __aeabi_cfcmple can't trap
  36         mov r0, sp
  37         ldm r0, {r0-r3}
  38         bl __aeabi_cfcmple
  39         pop {r0-r3, pc}
  40 1:
  41         // Z = 0, C = 1
  42         movs r0, #0xF
  43         lsls r0, r0, #31
  44         pop {r0-r3, pc}
  45 #else
  46         pop {r0-r3, lr}
  47
  48         // NaN has been ruled out, so __aeabi_cfcmple can't trap
  49         bne __aeabi_cfcmple
  50
  51         msr CPSR_f, #APSR_C
  52         JMP(lr)
  53 #endif
  54 END_COMPILERRT_FUNCTION(__aeabi_cfcmpeq)
  55
  56
  57 // void __aeabi_cfcmple(float a, float b) {
  58 //   if (__aeabi_fcmplt(a, b)) {
  59 //     Z = 0; C = 0;
  60 //   } else if (__aeabi_fcmpeq(a, b)) {
  61 //     Z = 1; C = 1;
  62 //   } else {
  63 //     Z = 0; C = 1;
  64 //   }
  65 // }
  66
  67         .syntax unified
  68         .p2align 2
  69 DEFINE_COMPILERRT_FUNCTION(__aeabi_cfcmple)
  70         // Per the RTABI, this function must preserve r0-r11.
  71         // Save lr in the same instruction for compactness
  72         push {r0-r3, lr}
  73
  74         bl __aeabi_fcmplt
  75         cmp r0, #1
  76 #if __ARM_ARCH_ISA_THUMB == 1
  77         bne 1f
  78         // Z = 0, C = 0
  79         movs r0, #1
  80         lsls r0, r0, #1
  81         pop {r0-r3, pc}
  82 1:
  83         mov r0, sp
  84         ldm r0, {r0-r3}
  85         bl __aeabi_fcmpeq
  86         cmp r0, #1
  87         bne 2f
  88         // Z = 1, C = 1
  89         movs r0, #2
  90         lsls r0, r0, #31
  91         pop {r0-r3, pc}
  92 2:
  93         // Z = 0, C = 1
  94         movs r0, #0xF
  95         lsls r0, r0, #31
  96         pop {r0-r3, pc}
  97 #else
  98         moveq ip, #0
  99         beq 1f
 100
 101         ldm sp, {r0-r3}
 102         bl __aeabi_fcmpeq
 103         cmp r0, #1
 104         moveq ip, #(APSR_C | APSR_Z)
 105         movne ip, #(APSR_C)
 106
 107 1:
 108         msr CPSR_f, ip
 109         pop {r0-r3}
 110         POP_PC()
 111 #endif
 112 END_COMPILERRT_FUNCTION(__aeabi_cfcmple)
 113
 114 // int __aeabi_cfrcmple(float a, float b) {
 115 //   return __aeabi_cfcmple(b, a);
 116 // }
 117
 118         .syntax unified
 119         .p2align 2
 120 DEFINE_COMPILERRT_FUNCTION(__aeabi_cfrcmple)
 121         // Swap r0 and r1
 122         mov ip, r0
 123         mov r0, r1
 124         mov r1, ip
 125
 126         b __aeabi_cfcmple
 127 END_COMPILERRT_FUNCTION(__aeabi_cfrcmple)
 128
 129 NO_EXEC_STACK_DIRECTIVE
 130