contrib/compiler-rt/lib/builtins/arm/divmodsi4.S

   1 /*===-- divmodsi4.S - 32-bit signed integer divide and modulus ------------===//
   2  *
   3  *                     The LLVM Compiler Infrastructure
   4  *
   5  * This file is dual licensed under the MIT and the University of Illinois Open
   6  * Source Licenses. See LICENSE.TXT for details.
   7  *
   8  *===----------------------------------------------------------------------===//
   9  *
  10  * This file implements the __divmodsi4 (32-bit signed integer divide and
  11  * modulus) function for the ARM architecture.  A naive digit-by-digit
  12  * computation is employed for simplicity.
  13  *
  14  *===----------------------------------------------------------------------===*/
  15
  16 #include "../assembly.h"
  17
  18 #define ESTABLISH_FRAME    \
  19     push   {r4-r7, lr}   ;\
  20     add     r7,     sp, #12
  21 #define CLEAR_FRAME_AND_RETURN \
  22     pop    {r4-r7, pc}
  23
  24         .syntax unified
  25         .text
  26 #if __ARM_ARCH_ISA_THUMB == 2
  27         .thumb
  28 #endif
  29
  30 @ int __divmodsi4(int divident, int divisor, int *remainder)
  31 @   Calculate the quotient and remainder of the (signed) division.  The return
  32 @   value is the quotient, the remainder is placed in the variable.
  33
  34         .p2align 3
  35 #if __ARM_ARCH_ISA_THUMB == 2
  36 DEFINE_COMPILERRT_THUMB_FUNCTION(__divmodsi4)
  37 #else
  38 DEFINE_COMPILERRT_FUNCTION(__divmodsi4)
  39 #endif
  40 #if __ARM_ARCH_EXT_IDIV__
  41         tst     r1, r1
  42         beq     LOCAL_LABEL(divzero)
  43         mov     r3, r0
  44         sdiv    r0, r3, r1
  45         mls     r1, r0, r1, r3
  46         str     r1, [r2]
  47         bx      lr
  48 LOCAL_LABEL(divzero):
  49         mov     r0, #0
  50         bx      lr
  51 #else
  52     ESTABLISH_FRAME
  53 //  Set aside the sign of the quotient and modulus, and the address for the
  54 //  modulus.
  55     eor     r4,     r0, r1
  56     mov     r5,     r0
  57     mov     r6,     r2
  58 //  Take the absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
  59     eor     ip,     r0, r0, asr #31
  60     eor     lr,     r1, r1, asr #31
  61     sub     r0,     ip, r0, asr #31
  62     sub     r1,     lr, r1, asr #31
  63 //  Unsigned divmod:
  64     bl      SYMBOL_NAME(__udivmodsi4)
  65 //  Apply the sign of quotient and modulus
  66     ldr     r1,    [r6]
  67     eor     r0,     r0, r4, asr #31
  68     eor     r1,     r1, r5, asr #31
  69     sub     r0,     r0, r4, asr #31
  70     sub     r1,     r1, r5, asr #31
  71     str     r1,    [r6]
  72     CLEAR_FRAME_AND_RETURN
  73 #endif
  74 END_COMPILERRT_FUNCTION(__divmodsi4)
  75
  76 NO_EXEC_STACK_DIRECTIVE
  77