contrib/compiler-rt/lib/builtins/arm/modsi3.S

   1 /*===-- modsi3.S - 32-bit signed integer modulus --------------------------===//
   2  *
   3  *                     The LLVM Compiler Infrastructure
   4  *
   5  * This file is dual licensed under the MIT and the University of Illinois Open
   6  * Source Licenses. See LICENSE.TXT for details.
   7  *
   8  *===----------------------------------------------------------------------===//
   9  *
  10  * This file implements the __modsi3 (32-bit signed integer modulus) function
  11  * for the ARM architecture as a wrapper around the unsigned routine.
  12  *
  13  *===----------------------------------------------------------------------===*/
  14
  15 #include "../assembly.h"
  16
  17 #define ESTABLISH_FRAME \
  18     push   {r4, r7, lr}    ;\
  19     add     r7,     sp, #4
  20 #define CLEAR_FRAME_AND_RETURN \
  21     pop    {r4, r7, pc}
  22
  23         .syntax unified
  24         .text
  25 #if __ARM_ARCH_ISA_THUMB == 2
  26         .thumb
  27 #endif
  28
  29 @ int __modsi3(int divident, int divisor)
  30 @   Calculate and return the remainder of the (signed) division.
  31
  32         .p2align 3
  33 #if __ARM_ARCH_ISA_THUMB == 2
  34 DEFINE_COMPILERRT_THUMB_FUNCTION(__modsi3)
  35 #else
  36 DEFINE_COMPILERRT_FUNCTION(__modsi3)
  37 #endif
  38 #if __ARM_ARCH_EXT_IDIV__
  39         tst     r1, r1
  40         beq     LOCAL_LABEL(divzero)
  41         sdiv    r2, r0, r1
  42         mls     r0, r2, r1, r0
  43         bx      lr
  44 LOCAL_LABEL(divzero):
  45         mov     r0, #0
  46         bx      lr
  47 #else
  48     ESTABLISH_FRAME
  49     //  Set aside the sign of the dividend.
  50     mov     r4,     r0
  51     //  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
  52     eor     r2,     r0, r0, asr #31
  53     eor     r3,     r1, r1, asr #31
  54     sub     r0,     r2, r0, asr #31
  55     sub     r1,     r3, r1, asr #31
  56     //  abs(a) % abs(b)
  57     bl     SYMBOL_NAME(__umodsi3)
  58     //  Apply sign of dividend to result and return.
  59     eor     r0,     r0, r4, asr #31
  60     sub     r0,     r0, r4, asr #31
  61     CLEAR_FRAME_AND_RETURN
  62 #endif
  63 END_COMPILERRT_FUNCTION(__modsi3)