contrib/compiler-rt/lib/builtins/hexagon/moddi3.S

   1 //===----------------------Hexagon builtin routine ------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is dual licensed under the MIT and the University of Illinois Open
   6 // Source Licenses. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10         .macro FUNCTION_BEGIN name
  11         .text
  12         .p2align 5
  13         .globl \name
  14         .type  \name, @function
  15 \name:
  16         .endm
  17
  18         .macro FUNCTION_END name
  19         .size  \name, . - \name
  20         .endm
  21
  22
  23 FUNCTION_BEGIN __hexagon_moddi3
  24         {
  25                 p3 = tstbit(r1,#31)
  26         }
  27         {
  28                 r1:0 = abs(r1:0)
  29                 r3:2 = abs(r3:2)
  30         }
  31         {
  32                 r6 = cl0(r1:0)              // count leading 0's of dividend (numerator)
  33                 r7 = cl0(r3:2)              // count leading 0's of divisor (denominator)
  34                 r5:4 = r3:2                 // divisor moved into working registers
  35                 r3:2 = r1:0                 // dividend is the initial remainder, r3:2 contains remainder
  36         }
  37         {
  38                 r10 = sub(r7,r6)            // left shift count for bit & divisor
  39                 r1:0 = #0                   // initialize quotient to 0
  40                 r15:14 = #1                 // initialize bit to 1
  41         }
  42         {
  43                 r11 = add(r10,#1)           // loop count is 1 more than shift count
  44                 r13:12 = lsl(r5:4,r10)      // shift divisor msb into same bit position as dividend msb
  45                 r15:14 = lsl(r15:14,r10)    // shift the bit left by same amount as divisor
  46         }
  47         {
  48                 p0 = cmp.gtu(r5:4,r3:2)     // check if divisor > dividend
  49                 loop0(1f,r11)               // register loop
  50         }
  51         {
  52                 if (p0) jump .hexagon_moddi3_return          // if divisor > dividend, we're done, so return
  53         }
  54         .falign
  55 1:
  56         {
  57                 p0 = cmp.gtu(r13:12,r3:2)   // set predicate reg if shifted divisor > current remainder
  58         }
  59         {
  60                 r7:6 = sub(r3:2, r13:12)    // subtract shifted divisor from current remainder
  61                 r9:8 = add(r1:0, r15:14)    // save current quotient to temp (r9:8)
  62         }
  63         {
  64                 r1:0 = vmux(p0, r1:0, r9:8) // choose either current quotient or new quotient (r9:8)
  65                 r3:2 = vmux(p0, r3:2, r7:6) // choose either current remainder or new remainder (r7:6)
  66         }
  67         {
  68                 r15:14 = lsr(r15:14, #1)    // shift bit right by 1 for next iteration
  69                 r13:12 = lsr(r13:12, #1)    // shift "shifted divisor" right by 1 for next iteration
  70         }:endloop0
  71
  72 .hexagon_moddi3_return:
  73         {
  74                 r1:0 = neg(r3:2)
  75         }
  76         {
  77                 r1:0 = vmux(p3,r1:0,r3:2)
  78                 jumpr r31
  79         }
  80 FUNCTION_END __hexagon_moddi3
  81
  82   .globl __qdsp_moddi3
  83   .set   __qdsp_moddi3, __hexagon_moddi3