contrib/compiler-rt/lib/builtins/x86_64/floatundidf.S

   1 //===-- floatundidf.S - Implement __floatundidf for x86_64 ----------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is dual licensed under the MIT and the University of Illinois Open
   6 // Source Licenses. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file implements __floatundidf for the compiler_rt library.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 #include "../assembly.h"
  15
  16 // double __floatundidf(du_int a);
  17
  18 #ifdef __x86_64__
  19
  20 CONST_SECTION
  21
  22         .balign 16
  23 twop52:
  24         .quad 0x4330000000000000
  25
  26         .balign 16
  27 twop84_plus_twop52:
  28         .quad 0x4530000000100000
  29
  30         .balign 16
  31 twop84:
  32         .quad 0x4530000000000000
  33
  34 #define REL_ADDR(_a)    (_a)(%rip)
  35
  36 .text
  37 .balign 4
  38 DEFINE_COMPILERRT_FUNCTION(__floatundidf)
  39         movd    %edi,                                                   %xmm0 // low 32 bits of a
  40         shrq    $32,                                                    %rdi  // high 32 bits of a
  41         orq             REL_ADDR(twop84),                               %rdi  // 0x1p84 + a_hi (no rounding occurs)
  42         orpd    REL_ADDR(twop52),                               %xmm0 // 0x1p52 + a_lo (no rounding occurs)
  43         movd    %rdi,                                                   %xmm1
  44         subsd   REL_ADDR(twop84_plus_twop52),   %xmm1 // a_hi - 0x1p52 (no rounding occurs)
  45         addsd   %xmm1,                                                  %xmm0 // a_hi + a_lo   (round happens here)
  46         ret
  47 END_COMPILERRT_FUNCTION(__floatundidf)
  48
  49 #endif // __x86_64__