contrib/file/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT([file],[5.43],[christos@astron.com])
   3 AM_INIT_AUTOMAKE([subdir-objects foreign])
   4 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   5
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_MSG_CHECKING(for builtin ELF support)
  10 AC_ARG_ENABLE(elf,
  11 [  --disable-elf            disable builtin ELF support],
  12 [if test "${enableval}" = yes; then
  13   AC_MSG_RESULT(yes)
  14   AC_DEFINE([BUILTIN_ELF], 1, [Define if built-in ELF support is used])
  15 else
  16   AC_MSG_RESULT(no)
  17 fi], [
  18   # enable by default
  19   AC_MSG_RESULT(yes)
  20   AC_DEFINE([BUILTIN_ELF], 1, [Define in built-in ELF support is used])
  21 ])
  22
  23 AC_MSG_CHECKING(for ELF core file support)
  24 AC_ARG_ENABLE(elf-core,
  25 [  --disable-elf-core       disable ELF core file support],
  26 [if test "${enableval}" = yes; then
  27   AC_MSG_RESULT(yes)
  28   AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  29 else
  30   AC_MSG_RESULT(no)
  31 fi], [
  32   # enable by default
  33   AC_MSG_RESULT(yes)
  34   AC_DEFINE([ELFCORE], 1, [Define for ELF core file support])
  35 ])
  36
  37 AC_MSG_CHECKING(for zlib support)
  38 AC_ARG_ENABLE([zlib],
  39 [AS_HELP_STRING([--disable-zlib], [disable zlib compression support @<:@default=auto@:>@])])
  40 AC_MSG_RESULT($enable_zlib)
  41
  42 AC_MSG_CHECKING(for bzlib support)
  43 AC_ARG_ENABLE([bzlib],
  44 [AS_HELP_STRING([--disable-bzlib], [disable bz2lib compression support @<:@default=auto@:>@])])
  45 AC_MSG_RESULT($enable_bzlib)
  46
  47 AC_MSG_CHECKING(for xzlib support)
  48 AC_ARG_ENABLE([xzlib],
  49 [AS_HELP_STRING([--disable-xzlib], [disable liblzma/xz compression support @<:@default=auto@:>@])])
  50 AC_MSG_RESULT($enable_xzlib)
  51
  52 AC_MSG_CHECKING(for libseccomp support)
  53 AC_ARG_ENABLE([libseccomp],
  54 [AS_HELP_STRING([--disable-libseccomp], [disable libseccomp sandboxing @<:@default=auto@:>@])])
  55 AC_MSG_RESULT($enable_libseccomp)
  56
  57 AC_MSG_CHECKING(for file formats in man section 5)
  58 AC_ARG_ENABLE(fsect-man5,
  59 [  --enable-fsect-man5      enable file formats in man section 5],
  60 [if test "${enableval}" = yes; then
  61   AC_MSG_RESULT(yes)
  62   fsect=5
  63 else
  64   AC_MSG_RESULT(no)
  65   fsect=4
  66 fi], [
  67   # disable by default
  68   AC_MSG_RESULT(no)
  69   fsect=4
  70 ])
  71
  72 AC_CANONICAL_HOST
  73 case "$host_os" in
  74    mingw32*)
  75       MINGW=1
  76       ;;
  77    *)
  78       MINGW=0
  79       ;;
  80 esac
  81 AC_SUBST(MINGW)
  82 AM_CONDITIONAL(MINGW, test "$MINGW" = 1)
  83
  84 AC_SUBST([pkgdatadir], ['$(datadir)/misc'])
  85 AC_SUBST(fsect)
  86 AM_CONDITIONAL(FSECT5, test x$fsect = x5)
  87
  88 AC_SUBST(WARNINGS)
  89
  90 dnl Checks for programs.
  91 AC_PROG_CC
  92 AC_USE_SYSTEM_EXTENSIONS
  93 AM_PROG_CC_C_O
  94 AC_C_BIGENDIAN
  95 AC_PROG_INSTALL
  96 AC_PROG_LN_S
  97 LT_INIT([disable-static pic-only])
  98 gl_VISIBILITY
  99 dnl Checks for headers
 100 AC_HEADER_MAJOR
 101 AC_HEADER_SYS_WAIT
 102 AC_CHECK_HEADERS(stdint.h fcntl.h inttypes.h unistd.h byteswap.h)
 103 AC_CHECK_HEADERS(spawn.h utime.h wchar.h wctype.h)
 104 AC_CHECK_HEADERS(getopt.h err.h xlocale.h)
 105 AC_CHECK_HEADERS(sys/bswap.h sys/mman.h sys/stat.h sys/types.h sys/utime.h sys/time.h sys/sysmacros.h sys/ioctl.h)
 106 if test "$enable_zlib" != "no"; then
 107   AC_CHECK_HEADERS(zlib.h)
 108 fi
 109 if test "$enable_bzlib" != "no"; then
 110   AC_CHECK_HEADERS(bzlib.h)
 111 fi
 112 if test "$enable_xzlib" != "no"; then
 113   AC_CHECK_HEADERS(lzma.h)
 114 fi
 115 AC_CHECK_TYPE([sig_t],[AC_DEFINE([HAVE_SIG_T],1,[Have sig_t type])],,[#include <signal.h>])
 116
 117 dnl Checks for typedefs, structures, and compiler characteristics.
 118 AC_TYPE_OFF_T
 119 AC_TYPE_SIZE_T
 120 AC_CHECK_MEMBERS([struct stat.st_rdev])
 121
 122 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 123 AC_STRUCT_TIMEZONE
 124 AC_STRUCT_TIMEZONE_DAYLIGHT
 125 AC_SYS_LARGEFILE
 126 AC_FUNC_FSEEKO
 127 AC_TYPE_MBSTATE_T
 128
 129 AC_STRUCT_OPTION_GETOPT_H
 130 AC_TYPE_PID_T
 131 AC_TYPE_UINT8_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_INT32_T
 135 AC_TYPE_UINT64_T
 136 AC_TYPE_INT64_T
 137 AC_TYPE_INTPTR_T
 138 AC_TYPE_UINTPTR_T
 139 AC_FUNC_MMAP
 140 AC_FUNC_FORK
 141 AC_FUNC_MBRTOWC
 142
 143 AC_MSG_CHECKING(for gcc compiler warnings)
 144 AC_ARG_ENABLE(warnings,
 145 [  --disable-warnings   disable compiler warnings],
 146 [if test "${enableval}" = no -o "$GCC" = no; then
 147    AC_MSG_RESULT(no)
 148    WARNINGS=
 149 else
 150    AC_MSG_RESULT(yes)
 151    WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
 152        -Wmissing-declarations -Wredundant-decls -Wnested-externs \
 153        -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
 154        -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
 155 fi], [
 156 if test "$GCC" = yes; then
 157    AC_MSG_RESULT(yes)
 158    WARNINGS="-Wall -Wstrict-prototypes -Wmissing-prototypes -Wpointer-arith \
 159        -Wmissing-declarations -Wredundant-decls -Wnested-externs \
 160        -Wsign-compare -Wreturn-type -Wswitch -Wshadow \
 161        -Wcast-qual -Wwrite-strings -Wextra -Wunused-parameter -Wformat=2"
 162 else
 163    WARNINGS=
 164    AC_MSG_RESULT(no)
 165 fi])
 166
 167 dnl Checks for functions
 168 AC_CHECK_FUNCS(strndup mkstemp mkostemp utimes utime wcwidth strtof newlocale uselocale freelocale memmem pipe2 posix_spawnp)
 169
 170 dnl Provide implementation of some required functions if necessary
 171 AC_REPLACE_FUNCS(getopt_long asprintf vasprintf strlcpy strlcat getline ctime_r asctime_r localtime_r gmtime_r pread strcasestr fmtcheck dprintf)
 172
 173 dnl Checks for libraries
 174 if test "$enable_zlib" != "no"; then
 175   AC_CHECK_LIB(z, gzopen)
 176 fi
 177 if test "$enable_bzlib" != "no"; then
 178   AC_CHECK_LIB(bz2, BZ2_bzCompressInit)
 179 fi
 180 if test "$enable_xzlib" != "no"; then
 181   AC_CHECK_LIB(lzma, lzma_stream_decoder)
 182 fi
 183 if test "$enable_libseccomp" != "no"; then
 184     AC_CHECK_LIB(seccomp, seccomp_init)
 185 fi
 186 if test "$MINGW" = 1; then
 187   AC_CHECK_LIB(gnurx,regexec,,AC_MSG_ERROR([libgnurx is required to build file(1) with MinGW]))
 188 fi
 189
 190 dnl See if we are cross-compiling
 191 AM_CONDITIONAL(IS_CROSS_COMPILE, test "$cross_compiling" = yes)
 192
 193 dnl Final sanity checks
 194 if test "$enable_zlib" = "yes"; then
 195   if test "$ac_cv_header_zlib_h$ac_cv_lib_z_gzopen" != "yesyes"; then
 196     AC_MSG_ERROR([zlib support requested but not found])
 197   fi
 198 fi
 199 if  test "$ac_cv_header_zlib_h$ac_cv_lib_z_gzopen" = "yesyes"; then
 200   AC_DEFINE([ZLIBSUPPORT], 1, [Enable zlib compression support])
 201 fi
 202 if test "$enable_bzlib" = "yes"; then
 203   if test "$ac_cv_header_bzlib_h$ac_cv_lib_bz2_BZ2_bzCompressInit" != "yesyes"; then
 204     AC_MSG_ERROR([bzlib support requested but not found])
 205   fi
 206 fi
 207 if  test "$ac_cv_header_bzlib_h$ac_cv_lib_bz2_BZ2_bzCompressInit" = "yesyes"; then
 208   AC_DEFINE([BZLIBSUPPORT], 1, [Enable bzlib compression support])
 209 fi
 210 if test "$enable_xzlib" = "yes"; then
 211   if test "$ac_cv_header_lzma_h$ac_cv_lib_lzma_lzma_stream_decoder" != "yesyes"; then
 212     AC_MSG_ERROR([xzlib support requested but not found])
 213   fi
 214 fi
 215 if  test "$ac_cv_header_lzma_h$ac_cv_lib_lzma_lzma_stream_decoder" = "yesyes"; then
 216   AC_DEFINE([XZLIBSUPPORT], 1, [Enable xzlib compression support])
 217 fi
 218
 219 AC_CONFIG_FILES([Makefile src/Makefile magic/Makefile tests/Makefile doc/Makefile python/Makefile libmagic.pc])
 220 AC_OUTPUT