contrib/gdb/opcodes/configure.in

   1 AC_PREREQ(2.0)
   2 AC_INIT(z8k-dis.c)
   3 #    configure.in script for the opcodes library.
   4 #    Copyright (C) 1995, 1996 Free Software Foundation, Inc.
   5 #    Written by Cygnus Support.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 AC_ARG_ENABLE(targets,
  22 [  --enable-targets        alternative target configurations],
  23 [case "${enableval}" in
  24   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  25             ;;
  26   no)       enable_targets= ;;
  27   *)        enable_targets=$enableval ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(shared,
  30 [  --enable-shared         build shared opcodes library],
  31 [case "${enableval}" in
  32   yes) shared=true ;;
  33   no)  shared=false ;;
  34   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes shared option]) ;;
  35 esac])dnl
  36 AC_ARG_ENABLE(commonbfdlib,
  37 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  38 [case "${enableval}" in
  39   yes) commonbfdlib=true ;;
  40   no)  commonbfdlib=false ;;
  41   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  42 esac])dnl
  43
  44 AC_CONFIG_HEADER(config.h:config.in)
  45
  46 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  47 AC_CANONICAL_SYSTEM
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51 AC_ARG_PROGRAM
  52
  53 # host-specific stuff:
  54
  55 ALLLIBS='$(TARGETLIB)'
  56 PICFLAG=
  57 SHLIB=unused-shlib
  58 SHLINK=unused-shlink
  59 if test "${shared}" = "true"; then
  60   ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  61   PICFLAG=-fpic
  62   if test "${commonbfdlib}" = "true"; then
  63 changequote(,)dnl
  64     SHLIB=../bfd/libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/../bfd/VERSION`
  65 changequote([,])dnl
  66     SHLINK=../bfd/libbfd.so
  67   else
  68 changequote(,)dnl
  69     SHLIB=libopcodes.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/../bfd/VERSION`
  70 changequote([,])dnl
  71     SHLINK=libopcodes.so
  72   fi
  73 fi
  74
  75 AC_PROG_CC
  76
  77 . ${srcdir}/../bfd/configure.host
  78
  79 AC_SUBST(HDEFINES)
  80 AC_CHECK_TOOL(AR, ar)
  81 AC_CHECK_TOOL(RANLIB, ranlib, :)
  82 AC_PROG_INSTALL
  83
  84 if test "${shared}" = "true"; then
  85   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  86     AC_MSG_WARN([opcodes --enable-shared only supported when using gcc])
  87     shared=false
  88     ALLLIBS='$(TARGETLIB)'
  89     PICFLAG=
  90     SHLIB=unused-shlib
  91   fi
  92 fi
  93
  94 AC_SUBST(ALLLIBS)
  95 AC_SUBST(PICFLAG)
  96 AC_SUBST(SHLIB)
  97 AC_SUBST(SHLIB_CC)
  98 AC_SUBST(SHLIB_CFLAGS)
  99 if test "${commonbfdlib}" = "true"; then
 100   COMMON_SHLIB=yes
 101   # Rebuild the shared library if libiberty or libbfd changes.
 102   SHLIB_DEP="../libiberty/libiberty.a ../bfd/libbfd.a"
 103 else
 104   COMMON_SHLIB=
 105   SHLIB_DEP=
 106 fi
 107 AC_SUBST(COMMON_SHLIB)
 108 AC_SUBST(SHLIB_DEP)
 109 AC_SUBST(SHLINK)
 110
 111 AC_CHECK_HEADERS(string.h strings.h)
 112
 113 # target-specific stuff:
 114
 115 # Canonicalize the secondary target names.
 116 if test -n "$enable_targets" ; then
 117     for targ in `echo $enable_targets | sed 's/,/ /g'`
 118     do
 119         result=`$ac_config_sub $targ 2>/dev/null`
 120         if test -n "$result" ; then
 121             canon_targets="$canon_targets $result"
 122         else
 123             # Allow targets that config.sub doesn't recognize, like "all".
 124             canon_targets="$canon_targets $targ"
 125         fi
 126     done
 127 fi
 128
 129 all_targets=false
 130 selarchs=
 131 for targ in $target $canon_targets
 132 do
 133     if test "x$targ" = "xall" ; then
 134         all_targets=true
 135     else
 136         . $srcdir/../bfd/config.bfd
 137         selarchs="$selarchs $targ_archs"
 138     fi
 139 done
 140
 141 # We don't do any links based on the target system, just makefile config.
 142
 143 if test x${all_targets} = xfalse ; then
 144
 145     # Target architecture .o files.
 146     ta=
 147
 148     for arch in $selarchs
 149     do
 150         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 151         archdefs="$archdefs -DARCH_$ad"
 152         case "$arch" in
 153         bfd_a29k_arch)          ta="$ta a29k-dis.o" ;;
 154         bfd_alliant_arch)       ;;
 155         bfd_alpha_arch)         ta="$ta alpha-dis.o" ;;
 156         bfd_arm_arch)           ta="$ta arm-dis.o" ;;
 157         bfd_convex_arch)        ;;
 158         bfd_h8300_arch)         ta="$ta h8300-dis.o" ;;
 159         bfd_h8500_arch)         ta="$ta h8500-dis.o" ;;
 160         bfd_hppa_arch)          ta="$ta hppa-dis.o" ;;
 161         bfd_i386_arch)          ta="$ta i386-dis.o" ;;
 162         bfd_i860_arch)          ;;
 163         bfd_i960_arch)          ta="$ta i960-dis.o" ;;
 164         bfd_m68k_arch)          ta="$ta m68k-dis.o m68k-opc.o" ;;
 165         bfd_m88k_arch)          ta="$ta m88k-dis.o" ;;
 166         bfd_mips_arch)          ta="$ta mips-dis.o mips-opc.o" ;;
 167         bfd_ns32k_arch)         ta="$ta ns32k-dis.o" ;;
 168         bfd_powerpc_arch)       ta="$ta ppc-dis.o ppc-opc.o" ;;
 169         bfd_pyramid_arch)       ;;
 170         bfd_romp_arch)          ;;
 171         bfd_rs6000_arch)        ta="$ta ppc-dis.o ppc-opc.o" ;;
 172         bfd_sh_arch)            ta="$ta sh-dis.o" ;;
 173         bfd_sparc_arch)         ta="$ta sparc-dis.o sparc-opc.o" ;;
 174         bfd_tahoe_arch)         ;;
 175         bfd_vax_arch)           ;;
 176         bfd_w65_arch)           ta="$ta w65-dis.o" ;;
 177         bfd_we32k_arch)         ;;
 178         bfd_z8k_arch)           ta="$ta z8k-dis.o" ;;
 179
 180         "")                     ;;
 181         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 182         esac
 183     done
 184
 185     # Weed out duplicate .o files.
 186     f=""
 187     for i in $ta ; do
 188         case " $f " in
 189         *" $i "*) ;;
 190         *) f="$f $i" ;;
 191         esac
 192     done
 193     ta="$f"
 194
 195     # And duplicate -D flags.
 196     f=""
 197     for i in $archdefs ; do
 198         case " $f " in
 199         *" $i "*) ;;
 200         *) f="$f $i" ;;
 201         esac
 202     done
 203     archdefs="$f"
 204
 205     BFD_MACHINES="$ta"
 206
 207 else    # all_targets is true
 208     archdefs=-DARCH_all
 209     BFD_MACHINES='$(ALL_MACHINES)'
 210 fi
 211
 212 AC_SUBST(archdefs)
 213 AC_SUBST(BFD_MACHINES)
 214
 215 AC_OUTPUT(Makefile,
 216 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])