contrib/libedit/makelist

   1 #!/bin/sh -
   2 #       $NetBSD: makelist,v 1.29 2016/05/09 21:46:56 christos Exp $
   3 #
   4 # Copyright (c) 1992, 1993
   5 #       The Regents of the University of California.  All rights reserved.
   6 #
   7 # This code is derived from software contributed to Berkeley by
   8 # Christos Zoulas of Cornell University.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. Neither the name of the University nor the names of its contributors
  19 #    may be used to endorse or promote products derived from this software
  20 #    without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32 # SUCH DAMAGE.
  33 #
  34 #       @(#)makelist    5.3 (Berkeley) 6/4/93
  35
  36 # makelist.sh: Automatically generate header files...
  37
  38 AWK=awk
  39 USAGE="Usage: $0 -h|-fc|-fh|-bh <filenames>"
  40
  41 if [ "x$1" = "x" ]
  42 then
  43     echo $USAGE 1>&2
  44     exit 1
  45 fi
  46
  47 FLAG="$1"
  48 shift
  49
  50 FILES="$@"
  51
  52 case $FLAG in
  53
  54 -h)
  55     set - `echo $FILES | sed -e 's/\\./_/g'`
  56     hdr="_h_`basename $1`"
  57     cat $FILES | $AWK '
  58         BEGIN {
  59             printf("/* Automatically generated file, do not edit */\n");
  60             printf("#ifndef %s\n#define %s\n", "'$hdr'", "'$hdr'");
  61         }
  62         /\(\):/ {
  63             pr = substr($2, 1, 2);
  64             if (pr == "vi" || pr == "em" || pr == "ed") {
  65                 name = substr($2, 1, length($2) - 3);
  66 #
  67 # XXX:  need a space between name and prototype so that -fc and -fh
  68 #       parsing is much easier
  69 #
  70                 printf("libedit_private el_action_t\t%s (EditLine *, wint_t);\n",
  71                     name);
  72             }
  73         }
  74         END {
  75             printf("#endif /* %s */\n", "'$hdr'");
  76         }'
  77         ;;
  78
  79 #       generate help.h from various .c files
  80 #
  81 -bh)
  82     cat $FILES | $AWK '
  83         BEGIN {
  84             printf("/* Automatically generated file, do not edit */\n");
  85             printf("static const struct el_bindings_t el_func_help[] = {\n");
  86             low = "abcdefghijklmnopqrstuvwxyz_";
  87             high = "ABCDEFGHIJKLMNOPQRSTUVWXYZ_";
  88             for (i = 1; i <= length(low); i++)
  89                 tr[substr(low, i, 1)] = substr(high, i, 1);
  90         }
  91         /\(\):/ {
  92             pr = substr($2, 1, 2);
  93             if (pr == "vi" || pr == "em" || pr == "ed") {
  94                 name = substr($2, 1, length($2) - 3);
  95                 uname = "";
  96                 fname = "";
  97                 for (i = 1; i <= length(name); i++) {
  98                     s = substr(name, i, 1);
  99                     uname = uname tr[s];
 100                     if (s == "_")
 101                         s = "-";
 102                     fname = fname s;
 103                 }
 104
 105                 printf("    { %-30.30s %-30.30s\n","L\"" fname "\",", uname ",");
 106                 ok = 1;
 107             }
 108         }
 109         /^ \*/ {
 110             if (ok) {
 111                 printf("      L\"");
 112                 for (i = 2; i < NF; i++)
 113                     printf("%s ", $i);
 114                 printf("%s\" },\n", $i);
 115                 ok = 0;
 116             }
 117         }
 118         END {
 119             printf("};\n");
 120         }'
 121         ;;
 122
 123 #       generate fcns.h from various .h files
 124 #
 125 -fh)
 126     cat $FILES | $AWK '/el_action_t/ { print $3 }' | \
 127     sort | tr '[:lower:]' '[:upper:]' | $AWK '
 128         BEGIN {
 129             printf("/* Automatically generated file, do not edit */\n");
 130             count = 0;
 131         }
 132         {
 133             printf("#define\t%-30.30s\t%3d\n", $1, count++);
 134         }
 135         END {
 136             printf("#define\t%-30.30s\t%3d\n", "EL_NUM_FCNS", count);
 137         }'
 138         ;;
 139
 140 #       generate func.h from various .h files
 141 #
 142 -fc)
 143     cat $FILES | $AWK '/el_action_t/ { print $3 }' | sort | $AWK '
 144         BEGIN {
 145             printf("/* Automatically generated file, do not edit */\n");
 146             printf("static const el_func_t el_func[] = {");
 147             maxlen = 80;
 148             needn = 1;
 149             len = 0;
 150         }
 151         {
 152             clen = 25 + 2;
 153             len += clen;
 154             if (len >= maxlen)
 155                 needn = 1;
 156             if (needn) {
 157                 printf("\n    ");
 158                 needn = 0;
 159                 len = 4 + clen;
 160             }
 161             s = $1 ",";
 162             printf("%-26.26s ", s);
 163         }
 164         END {
 165             printf("\n};\n");
 166         }'
 167         ;;
 168
 169 *)
 170     echo $USAGE 1>&2
 171     exit 1
 172     ;;
 173
 174 esac