contrib/libf2c/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999, 2002, 2003
   3 #    Free Software Foundation, Inc.
   4 #   Contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GNU Fortran.
   7 #
   8 #GNU Fortran is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GNU Fortran is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU Fortran; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 AC_PREREQ(2.13)
  24 AC_INIT(libF77/Version.c)
  25
  26 # This works around the fact that libtool configuration may change LD
  27 # for this particular configuration, but some shells, instead of
  28 # keeping the changes in LD private, export them just because LD is
  29 # exported.
  30 ORIGINAL_LD_FOR_MULTILIBS=$LD
  31
  32 GLIBCPP_TOPREL_CONFIGURE
  33
  34 AC_CANONICAL_SYSTEM
  35 target_alias=${target_alias-$target}
  36 AC_SUBST(target_alias)
  37
  38 GLIBCPP_CONFIGURE(.)
  39 GLIBCPP_EXPORT_INSTALL_INFO
  40
  41 # If the language specific compiler does not exist, but the "gcc" directory
  42 # does, we do not build anything. Note, $r is set by the top-level Makefile.
  43 # Note that when we look for the compiler, we search both with and without
  44 # extension to handle cross and canadian cross builds.
  45 compiler_name=f771
  46 rm -f skip-this-dir
  47 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  48 AC_CACHE_VAL(g77_cv_compiler_exists,
  49 [g77_cv_compiler_exists=yes
  50 if test -n "$r"; then
  51   if test -d "$r"/gcc; then
  52     if test -f "$r"/gcc/$compiler_name \
  53        || test -f "$r"/gcc/$compiler_name.exe; then
  54       true
  55     else
  56       g77_cv_compiler_exists=no
  57       echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  58     fi
  59   fi
  60 fi
  61 ])
  62 AC_MSG_RESULT($g77_cv_compiler_exists)
  63 if test x$g77_cv_compiler_exists = xno
  64 then
  65   rm -f Makefile conftest* confdefs* core
  66   exit 0
  67 fi
  68
  69 dnl Checks for programs.
  70
  71 AM_PROG_LIBTOOL
  72
  73 dnl These should be inherited in the recursive make, but ensure they are
  74 dnl defined:
  75 test "$AR" || AR=ar
  76 AC_SUBST(AR)
  77 if test "$RANLIB"; then :
  78   AC_SUBST(RANLIB)
  79 else
  80   AC_PROG_RANLIB
  81 fi
  82 AC_PROG_INSTALL
  83 AC_PROG_MAKE_SET
  84
  85 dnl Checks for header files.
  86 # Sanity check for the cross-compilation case:
  87 AC_CHECK_HEADER(stdio.h,:,
  88   [AC_MSG_ERROR([Can't find stdio.h.
  89 You must have a usable C system for the target already installed, at least
  90 including headers and, preferably, the library, before you can configure
  91 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  92 then the target library, then build with \`LANGUAGES=f77'.])])
  93
  94 dnl Checks for g77 integer types built into gcc's C front end.
  95 AC_MSG_CHECKING(for built-in g77 integer types)
  96 AC_CACHE_VAL(libf2c_cv_has_g77_builtin_types,
  97 [AC_TRY_COMPILE(,
  98   [__g77_integer g77i;
  99 __g77_uinteger g77ui;
 100 __g77_longint g77l;
 101 __g77_ulongint g77ul;],
 102   libf2c_cv_has_g77_builtin_types=yes,
 103   libf2c_cv_has_g77_builtin_types=no)])
 104 AC_MSG_RESULT($libf2c_cv_has_g77_builtin_types)
 105 if test $libf2c_cv_has_g77_builtin_types = no; then
 106   AC_MSG_ERROR([gcc doesn't define all of the built in types __g77_integer,
 107 __g77_uinteger, __g77_longint, and __g77_ulongint.  You may not be using
 108 a new enough version of gcc, or your target may not have type sizes which
 109 accommodate those types.])
 110 fi
 111
 112 # avoid confusion in case the `makefile's from the f2c distribution have
 113 # got put here
 114 test -f libF77/makefile && mv libF77/makefile  libF77/makefile.ori
 115 test -f libI77/makefile && mv libI77/makefile  libI77/makefile.ori
 116 test -f libU77/makefile && mv libU77/makefile  libU77/makefile.ori
 117
 118 AC_CONFIG_SUBDIRS(libU77 libI77 libF77)
 119 # Do Makefile first since g2c.h depends on it and shouldn't get an
 120 # earlier timestamp.  Of course, it does when the multilib gunk below
 121 # edits Makefile, sigh; see additional touch below.
 122 AC_OUTPUT(Makefile g2c.h:g2c.hin,
 123  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 124 if test -n "$CONFIG_FILES"; then
 125   LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 126   if test -n "${with_target_subdir}"; then
 127     # FIXME: We shouldn't need to set ac_file
 128     ac_file=Makefile
 129     . ${toplevel_srcdir}/config-ml.in
 130     touch g2c.h   # to keep it more recent than Makefile
 131   fi
 132 fi],
 133 srcdir=${srcdir}
 134 host=${host}
 135 target=${target}
 136 with_target_subdir=${with_target_subdir}
 137 with_multisubdir=${with_multisubdir}
 138 ac_configure_args="--enable-multilib ${ac_configure_args}"
 139 toplevel_srcdir=${toplevel_srcdir}
 140 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 141 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 142 )
 143
 144
 145 dnl Local Variables:
 146 dnl comment-start: "dnl "
 147 dnl comment-end: ""
 148 dnl comment-start-skip: "\\bdnl\\b\\s *"
 149 dnl End: