contrib/libobjc/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999, 2002, 2003
   3 #   Free Software Foundation, Inc.
   4 #   Contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GNU Objective C.
   7 #
   8 #GNU Objective C is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GNU Objective C is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU Objective C; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 AC_PREREQ(2.13)
  24 AC_INIT(objc/objc.h)
  25 AC_CONFIG_HEADER(config.h)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 GLIBCPP_TOPREL_CONFIGURE
  34
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$target}
  37 AC_SUBST(target_alias)
  38
  39 GLIBCPP_CONFIGURE(.)
  40 GLIBCPP_EXPORT_INSTALL_INFO
  41
  42 # If the language specific compiler does not exist, but the "gcc" directory
  43 # does, we do not build anything. Note, $r is set by the top-level Makefile.
  44 # Note that when we look for the compiler, we search both with and without
  45 # extension to handle cross and canadian cross builds.
  46 compiler_name=cc1obj
  47 rm -f skip-this-dir
  48 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  49 AC_CACHE_VAL(objc_cv_compiler_exists,
  50 [objc_cv_compiler_exists=yes
  51 if test -n "$r"; then
  52   if test -d "$r"/gcc; then
  53     if test -f "$r"/gcc/$compiler_name \
  54        || test -f "$r"/gcc/$compiler_name.exe; then
  55       true
  56     else
  57       objc_cv_compiler_exists=no
  58       echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  59     fi
  60   fi
  61 fi
  62 ])
  63 AC_MSG_RESULT($objc_cv_compiler_exists)
  64 if test x$objc_cv_compiler_exists = xno
  65 then
  66   rm -f Makefile conftest* confdefs* core
  67   exit 0
  68 fi
  69
  70 dnl Checks for programs.
  71
  72 # Disable shared libs by default
  73 AC_DISABLE_SHARED
  74 # Enable Win32 DLL on MS Windows - FIXME
  75 AC_LIBTOOL_WIN32_DLL
  76
  77 AC_PROG_LIBTOOL
  78
  79 dnl These should be inherited in the recursive make, but ensure they are
  80 dnl defined:
  81 test "$AR" || AR=ar
  82 AC_SUBST(AR)
  83 if test "$RANLIB"; then :
  84   AC_SUBST(RANLIB)
  85 else
  86   AC_PROG_RANLIB
  87 fi
  88 AC_PROG_INSTALL
  89 AC_PROG_MAKE_SET
  90
  91 dnl Checks for header files.
  92 # Sanity check for the cross-compilation case:
  93 AC_CHECK_HEADER(stdio.h,:,
  94   [AC_MSG_ERROR([Can't find stdio.h.
  95 You must have a usable C system for the target already installed, at least
  96 including headers and, preferably, the library, before you can configure
  97 the Objective C runtime system.  If necessary, install gcc now with
  98 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
  99
 100 AC_HEADER_STDC
 101
 102 AC_CHECK_HEADERS(sched.h)
 103
 104 # Determine CFLAGS for gthread.
 105
 106 AC_CACHE_CHECK([for gthread cflags],objc_cv_gthread_flags,
 107 [if test -f "$r"/gcc/Makefile
 108 then
 109   objc_cv_gthread_flags=`grep \^GTHREAD_FLAGS "$r"/gcc/Makefile | awk -F= '{ print $2 }'`
 110 else
 111   AC_MSG_ERROR([not found])
 112 fi])
 113 GTHREAD_FLAGS=$objc_cv_gthread_flags
 114 AC_SUBST(GTHREAD_FLAGS)
 115
 116 AC_ARG_ENABLE(objc-gc,
 117 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 118                           the GNU Objective-C runtime.],
 119 if [[[ x$enable_objc_gc = xno ]]]; then
 120         OBJC_BOEHM_GC=''
 121 else
 122         OBJC_BOEHM_GC=libobjc_gc.la
 123 fi,
 124 OBJC_BOEHM_GC='')
 125 AC_SUBST(OBJC_BOEHM_GC)
 126
 127
 128 # We need multilib support, but only if configuring for the target.
 129 AC_OUTPUT(Makefile,
 130  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 131 if test -n "$CONFIG_FILES"; then
 132   if test -n "${with_target_subdir}"; then
 133     # FIXME: We shouldn't need to set ac_file
 134     ac_file=Makefile
 135     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 136     . ${toplevel_srcdir}/config-ml.in
 137   fi
 138 fi],
 139 srcdir=${srcdir}
 140 host=${host}
 141 target=${target}
 142 with_target_subdir=${with_target_subdir}
 143 with_multisubdir=${with_multisubdir}
 144 ac_configure_args="--enable-multilib ${ac_configure_args}"
 145 toplevel_srcdir=${toplevel_srcdir}
 146 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 147 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 148 )
 149
 150
 151 dnl Local Variables:
 152 dnl comment-start: "dnl "
 153 dnl comment-end: ""
 154 dnl comment-start-skip: "\\bdnl\\b\\s *"
 155 dnl End: