contrib/libpcap/cmake/Modules/FindPacket.cmake

   1 #
   2 # Copyright (C) 2017 Ali Abdulkadir <autostart.ini@gmail.com>.
   3 #
   4 # Permission is hereby granted, free of charge, to any person
   5 # obtaining a copy of this software and associated documentation files
   6 # (the "Software"), to deal in the Software without restriction,
   7 # including without limitation the rights to use, copy, modify, merge,
   8 # publish, distribute, sub-license, and/or sell copies of the Software,
   9 # and to permit persons to whom the Software is furnished to do so,
  10 # subject to the following conditions:
  11 #
  12 # The above copyright notice and this permission notice shall be
  13 # included in all copies or substantial portions of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  16 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  18 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  19 # BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  20 # ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  21 # CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  22 # SOFTWARE.
  23 #
  24 # FindPacket
  25 # ==========
  26 #
  27 # Find the Packet library and include files.
  28 #
  29 # This module defines the following variables:
  30 #
  31 # PACKET_INCLUDE_DIR     - absolute path to the directory containing Packet32.h.
  32 #
  33 # PACKET_LIBRARY         - relative or absolute path to the Packet library to
  34 #                          link with. An absolute path is will be used if the
  35 #                          Packet library is not located in the compiler's
  36 #                          default search path. See e.g. PACKET_DLL_DIR
  37 #                          variable below.
  38
  39 # PACKET_FOUND           - TRUE if the Packet library *and* header are found.
  40 #
  41 # Hints and Backward Compatibility
  42 # ================================
  43 #
  44 # To tell this module where to look, a user may set the environment variable
  45 # PACKET_DLL_DIR to point cmake to the *root* of a directory with include and
  46 # lib subdirectories for packet.dll (e.g WpdPack/npcap-sdk).
  47 # Alternatively, PACKET_DLL_DIR may also be set from cmake command line or GUI
  48 # (e.g cmake -DPACKET_DLL_DIR=/path/to/packet [...])
  49 #
  50
  51 # The 64-bit Packet.lib is located under /x64
  52 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  53   #
  54   # For the WinPcap and Npcap SDKs, the Lib subdirectory of the top-level
  55   # directory contains 32-bit libraries; the 64-bit libraries are in the
  56   # Lib/x64 directory.
  57   #
  58   # The only way to *FORCE* CMake to look in the Lib/x64 directory
  59   # without searching in the Lib directory first appears to be to set
  60   # CMAKE_LIBRARY_ARCHITECTURE to "x64".
  61   #
  62   set(CMAKE_LIBRARY_ARCHITECTURE "x64")
  63 endif()
  64
  65 # Find the header
  66 find_path(PACKET_INCLUDE_DIR Packet32.h
  67   HINTS "${PACKET_DLL_DIR}" ENV PACKET_DLL_DIR
  68   PATH_SUFFIXES include Include
  69 )
  70
  71 # Find the library
  72 find_library(PACKET_LIBRARY
  73   NAMES Packet packet
  74   HINTS "${PACKET_DLL_DIR}" ENV PACKET_DLL_DIR
  75 )
  76
  77 # Set PACKET_FOUND to TRUE if PACKET_INCLUDE_DIR and PACKET_LIBRARY are TRUE.
  78 include(FindPackageHandleStandardArgs)
  79 find_package_handle_standard_args(PACKET
  80   DEFAULT_MSG
  81   PACKET_INCLUDE_DIR
  82   PACKET_LIBRARY
  83 )
  84
  85 mark_as_advanced(PACKET_INCLUDE_DIR PACKET_LIBRARY)
  86
  87 set(PACKET_INCLUDE_DIRS ${PACKET_INCLUDE_DIR})
  88 set(PACKET_LIBRARIES ${PACKET_LIBRARY})