contrib/libpcap/configure.in

   1 dnl @(#) $Header: /tcpdump/master/libpcap/configure.in,v 1.87.2.1 2001/01/17 18:21:54 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.87.2.1 $)
  10 AC_INIT(pcap.c)
  11
  12 AC_CANONICAL_SYSTEM
  13
  14 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  15 AC_C_INLINE
  16 AC_C___ATTRIBUTE__
  17
  18 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
  19 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
  20 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
  21
  22 dnl
  23 dnl libpcap doesn't itself use <sys/ioccom.h>; however, the test program
  24 dnl in "AC_LBL_FIXINCLUDES" in "aclocal.m4" uses it, so we have to
  25 dnl test for it and set "HAVE_SYS_IOCCOM_H" if we have it, otherwise
  26 dnl "AC_LBL_FIXINCLUDES" won't work on some platforms such as Solaris.
  27 dnl
  28 AC_CHECK_HEADERS(sys/ioccom.h sys/sockio.h ifaddrs.h netinet/if_ether.h)
  29
  30 AC_LBL_FIXINCLUDES
  31
  32 AC_CHECK_FUNCS(ether_hostton strerror freeifaddrs strlcpy)
  33
  34 dnl to pacify those who hate protochain insn
  35 AC_MSG_CHECKING(if --disable-protochain option is specified)
  36 AC_ARG_ENABLE(protochain, [  --disable-protochain    disable \"protochain\" insn])
  37 case "x$enable_protochain" in
  38 xyes)   enable_protochain=enabled       ;;
  39 xno)    enable_protochain=disabled      ;;
  40 x)      enable_protochain=enabled       ;;
  41 esac
  42
  43 if test "$enable_protochain" = "disabled"; then
  44         AC_DEFINE(NO_PROTOCHAIN,1,[do not use protochain])
  45 fi
  46 AC_MSG_RESULT(${enable_protochain})
  47
  48 dnl
  49 dnl Not all versions of test support -c (character special) but it's a
  50 dnl better way of testing since the device might be protected. So we
  51 dnl check in our normal order using -r and then check the for the /dev
  52 dnl guys again using -c.
  53 dnl
  54 dnl XXX This could be done for cross-compiling, but for now it's not.
  55 dnl
  56 if test -z "$with_pcap" && test "$cross_compiling" = yes; then
  57         AC_MSG_ERROR(pcap type not determined when cross-compiling; use --with-pcap=...)
  58 fi
  59 AC_ARG_WITH(pcap, [  --with-pcap=TYPE        use packet capture TYPE])
  60 AC_MSG_CHECKING(packet capture type)
  61 if test ! -z "$with_pcap" ; then
  62         V_PCAP="$withval"
  63 elif test -r /dev/bpf0 ; then
  64         V_PCAP=bpf
  65 elif test -r /usr/include/net/pfilt.h ; then
  66         V_PCAP=pf
  67 elif test -r /dev/enet ; then
  68         V_PCAP=enet
  69 elif test -r /dev/nit ; then
  70         V_PCAP=snit
  71 elif test -r /usr/include/sys/net/nit.h ; then
  72         V_PCAP=nit
  73 elif test -r /usr/include/net/raw.h ; then
  74         V_PCAP=snoop
  75 elif test -r /usr/include/sys/dlpi.h ; then
  76         V_PCAP=dlpi
  77 elif test -r /usr/include/linux/socket.h ; then
  78         V_PCAP=linux
  79 elif test -c /dev/bpf0 ; then           # check again in case not readable
  80         V_PCAP=bpf
  81 elif test -c /dev/enet ; then           # check again in case not readable
  82         V_PCAP=enet
  83 elif test -c /dev/nit ; then            # check again in case not readable
  84         V_PCAP=snit
  85 else
  86         V_PCAP=null
  87 fi
  88 AC_MSG_RESULT($V_PCAP)
  89
  90 AC_MSG_CHECKING(if --enable-ipv6 option is specified)
  91 AC_ARG_ENABLE(ipv6, [  --enable-ipv6           build IPv6-capable version])
  92 if test "$enable_ipv6" = "yes"; then
  93         AC_DEFINE(INET6,1,[IPv6])
  94 fi
  95 AC_MSG_RESULT(${enable_ipv6-no})
  96
  97 case "$V_PCAP" in
  98
  99 dlpi)
 100         AC_CHECK_HEADERS(sys/bufmod.h sys/dlpi_ext.h)
 101         AC_MSG_CHECKING(for /dev/dlpi device)
 102         if test -c /dev/dlpi ; then
 103                 AC_MSG_RESULT(yes)
 104                 AC_DEFINE(HAVE_DEV_DLPI, 1, [define if you have a /dev/dlpi])
 105         else
 106                 AC_MSG_RESULT(no)
 107                 dir="/dev/dlpi"
 108                 AC_MSG_CHECKING(for $dir directory)
 109                 if test -d $dir ; then
 110                         AC_MSG_RESULT(yes)
 111                         AC_DEFINE_UNQUOTED(PCAP_DEV_PREFIX, "$dir", [/dev/dlpi directory])
 112                 else
 113                         AC_MSG_RESULT(no)
 114                 fi
 115         fi
 116         ;;
 117
 118 linux)
 119         AC_CHECK_HEADERS(netpacket/packet.h)
 120         AC_MSG_CHECKING(Linux kernel version)
 121         if test "$cross_compiling" = yes; then
 122                 AC_CACHE_VAL(ac_cv_linux_vers,
 123                     ac_cv_linux_vers=unknown)
 124         else
 125                 AC_CACHE_VAL(ac_cv_linux_vers,
 126                     ac_cv_linux_vers=`uname -r 2>&1 | \
 127                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
 128         fi
 129         AC_MSG_RESULT($ac_cv_linux_vers)
 130         if test $ac_cv_linux_vers = unknown ; then
 131                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
 132         fi
 133         if test $ac_cv_linux_vers -lt 2 ; then
 134                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
 135         fi
 136         ;;
 137
 138 null)
 139         AC_MSG_WARN(cannot determine packet capture interface)
 140         AC_MSG_WARN((see the INSTALL doc for more info))
 141         ;;
 142
 143 esac
 144
 145 AC_LBL_LEX_AND_YACC(V_LEX, V_YACC, pcap_)
 146 if test "$V_LEX" = lex ; then
 147 # Some versions of lex can't handle the definitions section of scanner.l .
 148 # Try lexing it and complain if it can't deal.
 149         AC_CACHE_CHECK([for capable lex], tcpdump_cv_capable_lex,
 150                 if lex -t scanner.l > /dev/null 2>&1; then
 151                         tcpdump_cv_capable_lex=yes
 152                 else
 153                         tcpdump_cv_capable_lex=insufficient
 154                 fi)
 155         if test $tcpdump_cv_capable_lex = insufficient ; then
 156                 AC_MSG_ERROR([Your operating system's lex is insufficient to compile
 157  libpcap.  flex is a lex replacement that has many advantages, including
 158  being able to compile libpcap.  For more information, see
 159  http://www.gnu.org/software/flex/flex.html .])
 160         fi
 161 fi
 162
 163 case "$target_os" in
 164
 165 aix*)
 166         dnl Workaround to enable certain features
 167         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 168         ;;
 169
 170 hpux9*)
 171         AC_DEFINE(HAVE_HPUX9,1,[on HP-UX 9.x])
 172         ;;
 173
 174 hpux10.0*)
 175         ;;
 176
 177 hpux10.1*)
 178         ;;
 179
 180 hpux*)
 181         dnl HPUX 10.20 and above is similar to HPUX 9...
 182         AC_DEFINE(HAVE_HPUX10_20,1,[on HP-UX 10.20])
 183         ;;
 184
 185 sinix*)
 186         AC_MSG_CHECKING(if SINIX compiler defines sinix)
 187         AC_CACHE_VAL(ac_cv_cc_sinix_defined,
 188                 AC_TRY_COMPILE(
 189                     [],
 190                     [int i = sinix;],
 191                     ac_cv_cc_sinix_defined=yes,
 192                     ac_cv_cc_sinix_defined=no))
 193             AC_MSG_RESULT($ac_cv_cc_sinix_defined)
 194             if test $ac_cv_cc_sinix_defined = no ; then
 195                     AC_DEFINE(sinix,1,[on sinix])
 196             fi
 197         ;;
 198
 199 solaris*)
 200         AC_DEFINE(HAVE_SOLARIS,1,[On solaris])
 201         ;;
 202 esac
 203
 204 AC_PROG_RANLIB
 205
 206 AC_LBL_DEVEL(V_CCOPT)
 207
 208 AC_LBL_SOCKADDR_SA_LEN
 209
 210 AC_LBL_HP_PPA_INFO_T_DL_MODULE_ID_1
 211
 212 AC_LBL_UNALIGNED_ACCESS
 213
 214 rm -f net
 215 ln -s ${srcdir}/bpf/net net
 216
 217 AC_SUBST(V_CCOPT)
 218 AC_SUBST(V_INCLS)
 219 AC_SUBST(V_LEX)
 220 AC_SUBST(V_PCAP)
 221 AC_SUBST(V_RANLIB)
 222 AC_SUBST(V_YACC)
 223
 224 AC_PROG_INSTALL
 225
 226 AC_CONFIG_HEADER(config.h)
 227
 228 AC_OUTPUT(Makefile)
 229
 230 if test -f .devel ; then
 231         make depend
 232 fi
 233 exit 0