contrib/libpcap/grammar.y

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  *
  22  * $FreeBSD$
  23  */
  24 #ifndef lint
  25 static const char rcsid[] =
  26     "@(#) $Header: /tcpdump/master/libpcap/grammar.y,v 1.57 1999/10/19 15:18:30 itojun Exp $ (LBL)";
  27 #endif
  28
  29 #include <sys/types.h>
  30 #include <sys/time.h>
  31 #include <sys/socket.h>
  32
  33 #if __STDC__
  34 struct mbuf;
  35 struct rtentry;
  36 #endif
  37
  38 #include <net/if.h>
  39
  40 #include <netinet/in.h>
  41 #include <net/ethernet.h>
  42
  43 #include <stdio.h>
  44
  45 #include "pcap-int.h"
  46
  47 #include "gencode.h"
  48 #include <pcap-namedb.h>
  49
  50 #include "gnuc.h"
  51 #ifdef HAVE_OS_PROTO_H
  52 #include "os-proto.h"
  53 #endif
  54
  55 #define QSET(q, p, d, a) (q).proto = (p),\
  56                          (q).dir = (d),\
  57                          (q).addr = (a)
  58
  59 int n_errors = 0;
  60
  61 static struct qual qerr = { Q_UNDEF, Q_UNDEF, Q_UNDEF, Q_UNDEF };
  62
  63 static void
  64 yyerror(char *msg)
  65 {
  66         ++n_errors;
  67         bpf_error("%s", msg);
  68         /* NOTREACHED */
  69 }
  70
  71 #ifndef YYBISON
  72 int yyparse(void);
  73
  74 int
  75 pcap_parse()
  76 {
  77         return (yyparse());
  78 }
  79 #endif
  80
  81 %}
  82
  83 %union {
  84         int i;
  85         bpf_u_int32 h;
  86         u_char *e;
  87         char *s;
  88         struct stmt *stmt;
  89         struct arth *a;
  90         struct {
  91                 struct qual q;
  92                 struct block *b;
  93         } blk;
  94         struct block *rblk;
  95 }
  96
  97 %type   <blk>   expr id nid pid term rterm qid
  98 %type   <blk>   head
  99 %type   <i>     pqual dqual aqual ndaqual
 100 %type   <a>     arth narth
 101 %type   <i>     byteop pname pnum relop irelop
 102 %type   <blk>   and or paren not null prog
 103 %type   <rblk>  other
 104
 105 %token  DST SRC HOST GATEWAY
 106 %token  NET MASK PORT LESS GREATER PROTO PROTOCHAIN BYTE
 107 %token  ARP RARP IP TCP UDP ICMP IGMP IGRP PIM
 108 %token  ATALK DECNET LAT SCA MOPRC MOPDL
 109 %token  TK_BROADCAST TK_MULTICAST
 110 %token  NUM INBOUND OUTBOUND
 111 %token  LINK
 112 %token  GEQ LEQ NEQ
 113 %token  ID EID HID HID6
 114 %token  LSH RSH
 115 %token  LEN
 116 %token  ISO ESIS ISIS
 117 %token  IPV6 ICMPV6 AH ESP
 118
 119 %type   <s> ID
 120 %type   <e> EID
 121 %type   <s> HID HID6
 122 %type   <i> NUM
 123
 124 %left OR AND
 125 %nonassoc  '!'
 126 %left '|'
 127 %left '&'
 128 %left LSH RSH
 129 %left '+' '-'
 130 %left '*' '/'
 131 %nonassoc UMINUS
 132 %%
 133 prog:     null expr
 134 {
 135         finish_parse($2.b);
 136 }
 137         | null
 138         ;
 139 null:     /* null */            { $$.q = qerr; }
 140         ;
 141 expr:     term
 142         | expr and term         { gen_and($1.b, $3.b); $$ = $3; }
 143         | expr and id           { gen_and($1.b, $3.b); $$ = $3; }
 144         | expr or term          { gen_or($1.b, $3.b); $$ = $3; }
 145         | expr or id            { gen_or($1.b, $3.b); $$ = $3; }
 146         ;
 147 and:      AND                   { $$ = $<blk>0; }
 148         ;
 149 or:       OR                    { $$ = $<blk>0; }
 150         ;
 151 id:       nid
 152         | pnum                  { $$.b = gen_ncode(NULL, (bpf_u_int32)$1,
 153                                                    $$.q = $<blk>0.q); }
 154         | paren pid ')'         { $$ = $2; }
 155         ;
 156 nid:      ID                    { $$.b = gen_scode($1, $$.q = $<blk>0.q); }
 157         | HID '/' NUM           { $$.b = gen_mcode($1, NULL, $3,
 158                                     $$.q = $<blk>0.q); }
 159         | HID MASK HID          { $$.b = gen_mcode($1, $3, 0,
 160                                     $$.q = $<blk>0.q); }
 161         | HID                   {
 162                                   /* Decide how to parse HID based on proto */
 163                                   $$.q = $<blk>0.q;
 164                                   switch ($$.q.proto) {
 165                                   case Q_DECNET:
 166                                         $$.b = gen_ncode($1, 0, $$.q);
 167                                         break;
 168                                   default:
 169                                         $$.b = gen_ncode($1, 0, $$.q);
 170                                         break;
 171                                   }
 172                                 }
 173         | HID6 '/' NUM          {
 174 #ifdef INET6
 175                                   $$.b = gen_mcode6($1, NULL, $3,
 176                                     $$.q = $<blk>0.q);
 177 #else
 178                                   bpf_error("'ip6addr/prefixlen' not supported "
 179                                         "in this configuration");
 180 #endif /*INET6*/
 181                                 }
 182         | HID6                  {
 183 #ifdef INET6
 184                                   $$.b = gen_mcode6($1, 0, 128,
 185                                     $$.q = $<blk>0.q);
 186 #else
 187                                   bpf_error("'ip6addr' not supported "
 188                                         "in this configuration");
 189 #endif /*INET6*/
 190                                 }
 191         | EID                   { $$.b = gen_ecode($1, $$.q = $<blk>0.q); }
 192         | not id                { gen_not($2.b); $$ = $2; }
 193         ;
 194 not:      '!'                   { $$ = $<blk>0; }
 195         ;
 196 paren:    '('                   { $$ = $<blk>0; }
 197         ;
 198 pid:      nid
 199         | qid and id            { gen_and($1.b, $3.b); $$ = $3; }
 200         | qid or id             { gen_or($1.b, $3.b); $$ = $3; }
 201         ;
 202 qid:      pnum                  { $$.b = gen_ncode(NULL, (bpf_u_int32)$1,
 203                                                    $$.q = $<blk>0.q); }
 204         | pid
 205         ;
 206 term:     rterm
 207         | not term              { gen_not($2.b); $$ = $2; }
 208         ;
 209 head:     pqual dqual aqual     { QSET($$.q, $1, $2, $3); }
 210         | pqual dqual           { QSET($$.q, $1, $2, Q_DEFAULT); }
 211         | pqual aqual           { QSET($$.q, $1, Q_DEFAULT, $2); }
 212         | pqual PROTO           { QSET($$.q, $1, Q_DEFAULT, Q_PROTO); }
 213         | pqual PROTOCHAIN      { QSET($$.q, $1, Q_DEFAULT, Q_PROTOCHAIN); }
 214         | pqual ndaqual         { QSET($$.q, $1, Q_DEFAULT, $2); }
 215         ;
 216 rterm:    head id               { $$ = $2; }
 217         | paren expr ')'        { $$.b = $2.b; $$.q = $1.q; }
 218         | pname                 { $$.b = gen_proto_abbrev($1); $$.q = qerr; }
 219         | arth relop arth       { $$.b = gen_relation($2, $1, $3, 0);
 220                                   $$.q = qerr; }
 221         | arth irelop arth      { $$.b = gen_relation($2, $1, $3, 1);
 222                                   $$.q = qerr; }
 223         | other                 { $$.b = $1; $$.q = qerr; }
 224         ;
 225 /* protocol level qualifiers */
 226 pqual:    pname
 227         |                       { $$ = Q_DEFAULT; }
 228         ;
 229 /* 'direction' qualifiers */
 230 dqual:    SRC                   { $$ = Q_SRC; }
 231         | DST                   { $$ = Q_DST; }
 232         | SRC OR DST            { $$ = Q_OR; }
 233         | DST OR SRC            { $$ = Q_OR; }
 234         | SRC AND DST           { $$ = Q_AND; }
 235         | DST AND SRC           { $$ = Q_AND; }
 236         ;
 237 /* address type qualifiers */
 238 aqual:    HOST                  { $$ = Q_HOST; }
 239         | NET                   { $$ = Q_NET; }
 240         | PORT                  { $$ = Q_PORT; }
 241         ;
 242 /* non-directional address type qualifiers */
 243 ndaqual:  GATEWAY               { $$ = Q_GATEWAY; }
 244         ;
 245 pname:    LINK                  { $$ = Q_LINK; }
 246         | IP                    { $$ = Q_IP; }
 247         | ARP                   { $$ = Q_ARP; }
 248         | RARP                  { $$ = Q_RARP; }
 249         | TCP                   { $$ = Q_TCP; }
 250         | UDP                   { $$ = Q_UDP; }
 251         | ICMP                  { $$ = Q_ICMP; }
 252         | IGMP                  { $$ = Q_IGMP; }
 253         | IGRP                  { $$ = Q_IGRP; }
 254         | PIM                   { $$ = Q_PIM; }
 255         | ATALK                 { $$ = Q_ATALK; }
 256         | DECNET                { $$ = Q_DECNET; }
 257         | LAT                   { $$ = Q_LAT; }
 258         | SCA                   { $$ = Q_SCA; }
 259         | MOPDL                 { $$ = Q_MOPDL; }
 260         | MOPRC                 { $$ = Q_MOPRC; }
 261         | IPV6                  { $$ = Q_IPV6; }
 262         | ICMPV6                { $$ = Q_ICMPV6; }
 263         | AH                    { $$ = Q_AH; }
 264         | ESP                   { $$ = Q_ESP; }
 265         | ISO                   { $$ = Q_ISO; }
 266         | ESIS                  { $$ = Q_ESIS; }
 267         | ISIS                  { $$ = Q_ISIS; }
 268         ;
 269 other:    pqual TK_BROADCAST    { $$ = gen_broadcast($1); }
 270         | pqual TK_MULTICAST    { $$ = gen_multicast($1); }
 271         | LESS NUM              { $$ = gen_less($2); }
 272         | GREATER NUM           { $$ = gen_greater($2); }
 273         | BYTE NUM byteop NUM   { $$ = gen_byteop($3, $2, $4); }
 274         | INBOUND               { $$ = gen_inbound(0); }
 275         | OUTBOUND              { $$ = gen_inbound(1); }
 276         ;
 277 relop:    '>'                   { $$ = BPF_JGT; }
 278         | GEQ                   { $$ = BPF_JGE; }
 279         | '='                   { $$ = BPF_JEQ; }
 280         ;
 281 irelop:   LEQ                   { $$ = BPF_JGT; }
 282         | '<'                   { $$ = BPF_JGE; }
 283         | NEQ                   { $$ = BPF_JEQ; }
 284         ;
 285 arth:     pnum                  { $$ = gen_loadi($1); }
 286         | narth
 287         ;
 288 narth:    pname '[' arth ']'            { $$ = gen_load($1, $3, 1); }
 289         | pname '[' arth ':' NUM ']'    { $$ = gen_load($1, $3, $5); }
 290         | arth '+' arth                 { $$ = gen_arth(BPF_ADD, $1, $3); }
 291         | arth '-' arth                 { $$ = gen_arth(BPF_SUB, $1, $3); }
 292         | arth '*' arth                 { $$ = gen_arth(BPF_MUL, $1, $3); }
 293         | arth '/' arth                 { $$ = gen_arth(BPF_DIV, $1, $3); }
 294         | arth '&' arth                 { $$ = gen_arth(BPF_AND, $1, $3); }
 295         | arth '|' arth                 { $$ = gen_arth(BPF_OR, $1, $3); }
 296         | arth LSH arth                 { $$ = gen_arth(BPF_LSH, $1, $3); }
 297         | arth RSH arth                 { $$ = gen_arth(BPF_RSH, $1, $3); }
 298         | '-' arth %prec UMINUS         { $$ = gen_neg($2); }
 299         | paren narth ')'               { $$ = $2; }
 300         | LEN                           { $$ = gen_loadlen(); }
 301         ;
 302 byteop:   '&'                   { $$ = '&'; }
 303         | '|'                   { $$ = '|'; }
 304         | '<'                   { $$ = '<'; }
 305         | '>'                   { $$ = '>'; }
 306         | '='                   { $$ = '='; }
 307         ;
 308 pnum:     NUM
 309         | paren pnum ')'        { $$ = $2; }
 310         ;
 311 %%