contrib/libreadline/configure.in

   1 dnl
   2 dnl Configure script for readline library
   3 dnl
   4 dnl report bugs to chet@po.cwru.edu
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 AC_REVISION([for Readline 4.2, version 2.26, from autoconf version] AC_ACVERSION)
   8 LIBVERSION=4.2
   9
  10 AC_INIT(readline.h)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 dnl make sure we are using a recent autoconf version
  14 AC_PREREQ(2.10)
  15
  16 AC_CONFIG_AUX_DIR(./support)
  17
  18 AC_CANONICAL_HOST
  19
  20 dnl configure defaults
  21 opt_curses=no
  22 opt_shared=no
  23
  24 dnl arguments to configure
  25 AC_ARG_WITH(curses, --with-curses               use the curses library instead of the termcap library,opt_curses=$withval)
  26
  27 if test "$opt_curses" = "yes"; then
  28         prefer_curses=yes
  29 fi
  30
  31 # We want these before the checks, so the checks can modify their values.
  32 test -z "$CFLAGS" && CFLAGS=-g auto_cflags=1
  33
  34 AC_PROG_MAKE_SET
  35 AC_PROG_CC
  36 dnl AC_AIX
  37 AC_MINIX
  38
  39 # If we're using gcc and the user hasn't specified CFLAGS, add -O to CFLAGS.
  40 test -n "$GCC" && test -n "$auto_cflags" && CFLAGS="$CFLAGS -O"
  41
  42 AC_PROG_GCC_TRADITIONAL
  43 AC_PROG_INSTALL
  44 AC_CHECK_PROG(AR, ar, ar)
  45 dnl Set default for ARFLAGS, since autoconf does not have a macro for it.
  46 dnl This allows people to set it when running configure or make
  47 test -n "$ARFLAGS" || ARFLAGS="cr"
  48 AC_PROG_RANLIB
  49
  50 MAKE_SHELL=/bin/sh
  51 AC_SUBST(MAKE_SHELL)
  52
  53 AC_RETSIGTYPE
  54
  55 AC_HEADER_STAT
  56 AC_HEADER_DIRENT
  57
  58 AC_CHECK_FUNCS(lstat memmove putenv select setenv setlocale \
  59                 strcasecmp tcgetattr)
  60
  61 AC_FUNC_STRCOLL
  62
  63 AC_CHECK_HEADERS(unistd.h stdlib.h varargs.h stdarg.h string.h \
  64                 sys/ptem.h sys/pte.h sys/stream.h sys/select.h \
  65                 termcap.h termios.h termio.h sys/file.h locale.h)
  66
  67 BASH_SIGNAL_CHECK
  68 BASH_REINSTALL_SIGHANDLERS
  69
  70 BASH_FUNC_POSIX_SETJMP
  71 BASH_FUNC_LSTAT
  72 BASH_CHECK_GETPW_FUNCS
  73 BASH_FUNC_STRCOLL
  74
  75 BASH_TYPE_SIGHANDLER
  76 BASH_HAVE_TIOCGWINSZ
  77 BASH_HAVE_TIOCSTAT
  78 BASH_HAVE_FIONREAD
  79 BASH_MISC_SPEED_T
  80 BASH_STRUCT_WINSIZE
  81 BASH_STRUCT_DIRENT_D_INO
  82 BASH_STRUCT_DIRENT_D_FILENO
  83
  84 dnl yuck
  85 case "$host_os" in
  86 aix*)   prefer_curses=yes ;;
  87 esac
  88 BASH_CHECK_LIB_TERMCAP
  89 if test "$TERMCAP_LIB" = "./lib/termcap/libtermcap.a"; then
  90         TERMCAP_LIB=-ltermcap   #default
  91 fi
  92
  93 case "$host_cpu" in
  94 *cray*) LOCAL_CFLAGS=-DCRAY ;;
  95 *s390*) LOCAL_CFLAGS=-fsigned-char ;;
  96 esac
  97
  98 case "$host_os" in
  99 isc*)   LOCAL_CFLAGS=-Disc386 ;;
 100 esac
 101
 102 # shared library configuration section
 103 #
 104 # Shared object configuration section.  These values are generated by
 105 # ${srcdir}/support/shobj-conf
 106 #
 107 if test -f ${srcdir}/support/shobj-conf; then
 108         AC_MSG_CHECKING(configuration for building shared libraries)
 109         eval `${CONFIG_SHELL-/bin/sh} ${srcdir}/support/shobj-conf -C "${CC}" -c ${host_cpu} -o ${host_os} -v ${host_vendor}`
 110         AC_SUBST(SHOBJ_CC)
 111         AC_SUBST(SHOBJ_CFLAGS)
 112         AC_SUBST(SHOBJ_LD)
 113         AC_SUBST(SHOBJ_LDFLAGS)
 114         AC_SUBST(SHOBJ_XLDFLAGS)
 115         AC_SUBST(SHOBJ_LIBS)
 116         AC_SUBST(SHOBJ_STATUS)
 117         AC_SUBST(SHLIB_STATUS)
 118         AC_SUBST(SHLIB_XLDFLAGS)
 119         AC_SUBST(SHLIB_LIBSUFF)
 120         AC_SUBST(SHLIB_LIBVERSION)
 121         AC_SUBST(SHLIB_LIBS)
 122         AC_MSG_RESULT($SHLIB_STATUS)
 123
 124         # shared library versioning
 125         # quoted for m4 so I can use character classes
 126         SHLIB_MAJOR=[`expr "$LIBVERSION" : '\([0-9]\)\..*'`]
 127         SHLIB_MINOR=[`expr "$LIBVERSION" : '[0-9]\.\([0-9]\).*'`]
 128         AC_SUBST(SHLIB_MAJOR)
 129         AC_SUBST(SHLIB_MINOR)
 130 fi
 131
 132 case "$host_os" in
 133 msdosdjgpp*)    BUILD_DIR=`pwd.exe` ;;  # to prevent //d/path/file
 134 *)              BUILD_DIR=`pwd` ;;
 135 esac
 136
 137 AC_SUBST(BUILD_DIR)
 138
 139 AC_SUBST(CFLAGS)
 140 AC_SUBST(LOCAL_CFLAGS)
 141 AC_SUBST(LOCAL_LDFLAGS)
 142 AC_SUBST(LOCAL_DEFS)
 143
 144 AC_SUBST(AR)
 145 AC_SUBST(ARFLAGS)
 146
 147 AC_SUBST(host_cpu)
 148 AC_SUBST(host_os)
 149
 150 AC_SUBST(LIBVERSION)
 151
 152 AC_SUBST(TERMCAP_LIB)
 153
 154 AC_OUTPUT([Makefile doc/Makefile examples/Makefile shlib/Makefile],
 155 [
 156 # Makefile uses this timestamp file to record whether config.h is up to date.
 157 echo > stamp-h
 158 ])