contrib/libucl/configure.ac

   1 m4_define([maj_ver], [0])
   2 m4_define([med_ver], [8])
   3 m4_define([min_ver], [0])
   4 m4_define([so_version], [6:0:0])
   5 m4_define([ucl_version], [maj_ver.med_ver.min_ver])
   6
   7 AC_INIT([libucl],[ucl_version],[https://github.com/vstakhov/libucl],[libucl])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AM_INIT_AUTOMAKE([1.11 foreign -Wall -Wportability no-dist-gzip dist-xz])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 UCL_VERSION=ucl_version
  13 SO_VERSION=so_version
  14
  15 AC_SUBST(UCL_VERSION)
  16 AC_SUBST(SO_VERSION)
  17
  18 AC_PROG_CC_C99
  19 AM_PROG_CC_C_O
  20 AM_PROG_AR
  21 LT_INIT
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AC_C_CONST
  26 AC_TYPE_SIZE_T
  27
  28 AC_CHECK_HEADERS_ONCE([fcntl.h unistd.h])
  29 AC_TYPE_OFF_T
  30 AC_FUNC_MMAP
  31 AC_CHECK_HEADERS_ONCE([fcntl.h])
  32 AC_CHECK_HEADERS_ONCE([sys/types.h])
  33 AC_CHECK_HEADERS_ONCE([sys/stat.h])
  34 AC_CHECK_HEADERS_ONCE([sys/param.h])
  35 AC_CHECK_HEADERS_ONCE([sys/mman.h])
  36 AC_CHECK_HEADERS_ONCE([stdlib.h])
  37 AC_CHECK_HEADERS_ONCE([stddef.h])
  38 AC_CHECK_HEADERS_ONCE([stdarg.h])
  39 AC_CHECK_HEADERS_ONCE([stdbool.h])
  40 AC_CHECK_HEADERS_ONCE([stdint.h])
  41 AC_CHECK_HEADERS_ONCE([string.h])
  42 AC_CHECK_HEADERS_ONCE([unistd.h])
  43 AC_CHECK_HEADERS_ONCE([ctype.h])
  44 AC_CHECK_HEADERS_ONCE([errno.h])
  45 AC_CHECK_HEADERS_ONCE([limits.h])
  46 AC_CHECK_HEADERS_ONCE([libgen.h])
  47 AC_CHECK_HEADERS_ONCE([stdio.h])
  48 AC_CHECK_HEADERS_ONCE([float.h])
  49 AC_CHECK_HEADERS_ONCE([math.h])
  50 AC_CHECK_HEADERS_ONCE([endian.h sys/endian.h machine/endian.h])
  51
  52 dnl Example of default-disabled feature
  53 AC_ARG_ENABLE([urls], AS_HELP_STRING([--enable-urls],
  54         [Enable URLs fetch (requires libfetch or libcurl) @<:@default=no@:>@]), [],
  55         [enable_urls=no])
  56 AC_ARG_ENABLE([regex], AS_HELP_STRING([--enable-regex],
  57         [Enable regex checking for schema @<:@default=yes@:>@]), [],
  58         [enable_regex=yes])
  59 AC_ARG_ENABLE([signatures], AS_HELP_STRING([--enable-signatures],
  60         [Enable signatures check (requires openssl) @<:@default=no@:>@]), [],
  61         [enable_signatures=no])
  62 AC_ARG_ENABLE([lua], AS_HELP_STRING([--enable-lua],
  63         [Enable lua API build (requires lua libraries and headers) @<:@default=no@:>@]), [],
  64         [enable_lua=no])
  65 AC_ARG_ENABLE([utils],
  66         AS_HELP_STRING([--enable-utils], [Build and install utils @<:@default=no@:>@]),
  67         [case "${enableval}" in
  68                 yes) utils=true ;;
  69                 no)  utils=false ;;
  70                 *) AC_MSG_ERROR([bad value ${enableval} for --enable-utils]) ;;
  71         esac],[utils=false])
  72 AM_CONDITIONAL([UTILS], [test x$utils = xtrue])
  73
  74 AS_IF([test "x$enable_signatures" = "xyes"], [
  75         AC_SEARCH_LIBS([EVP_MD_CTX_create], [crypto], [
  76                 AC_DEFINE(HAVE_OPENSSL, 1, [Define to 1 if you have the 'crypto' library (-lcrypto).])
  77                 LIBCRYPTO_LIB="-lcrypto"
  78                 LIBS_EXTRA="${LIBS_EXTRA} -lcrypto"
  79                 ], [AC_MSG_ERROR([unable to find the EVP_MD_CTX_create() function])])
  80 ])
  81 AC_SUBST(LIBCRYPTO_LIB)
  82 AC_PATH_PROG(PANDOC, pandoc, [/non/existent])
  83
  84 AC_SEARCH_LIBS([clock_gettime], [rt], [], [
  85         AC_CHECK_HEADER([mach/mach_time.h], [
  86                 AC_DEFINE(HAVE_MACH_MACH_TIME_H, 1, [Define to 1 on Darwin])
  87         ], [AC_MSG_ERROR([unable to find clock_gettime or mach_absolute_time])])
  88 ])
  89 AC_SEARCH_LIBS([remainder], [m], [], [AC_MSG_ERROR([unable to find remainder() function])])
  90
  91 AS_IF([test "x$enable_regex" = "xyes"], [
  92         AC_CHECK_HEADER([regex.h], [
  93                 AC_DEFINE(HAVE_REGEX_H, 1, [Define to 1 if you have the <regex.h> header file.])
  94                 AC_SEARCH_LIBS([regexec], [regex], [
  95                         AS_IF([test "x$ac_cv_search_regexec" = "x-lregex"], [
  96                                 LIBREGEX_LIB="-lregex"
  97                                 LIBS_EXTRA="${LIBS_EXTRA} -lregex"
  98                                 ]
  99                         )],
 100                         [AC_MSG_ERROR([unable to find the regexec() function])])],
 101                         [AC_MSG_ERROR([unable to find the regex.h header])
 102                 ],
 103                 [#include <sys/types.h>])
 104 ])
 105 AC_SUBST(LIBREGEX_LIB)
 106
 107 AS_IF([test "x$enable_lua" = "xyes"], [
 108         AX_PROG_LUA([5.1], [], [
 109                 AX_LUA_HEADERS([
 110                         AX_LUA_LIBS([
 111                                 AC_DEFINE(HAVE_LUA, 1, [Define to 1 for lua support.])
 112                                 with_lua="yes"
 113                         ], [AC_MSG_ERROR([unable to find the lua libraries])
 114                         ])
 115                 ], [AC_MSG_ERROR([unable to find the lua header files])
 116                 ])
 117         ], [AC_MSG_ERROR([unable to find the lua interpreter])])
 118 ], [with_lua="no"])
 119
 120 AM_CONDITIONAL([LUA_SUB], [test "$with_lua" = "yes"])
 121
 122 AS_IF([test "x$enable_urls" = "xyes"], [
 123         AC_CHECK_HEADER([fetch.h], [
 124                 AC_DEFINE(HAVE_FETCH_H, 1, [Define to 1 if you have the <fetch.h> header file.])
 125                 AC_CHECK_LIB(fetch, fetchXGet, [
 126                         AC_DEFINE(HAVE_LIBFETCH, 1, [Define to 1 if you have the 'fetch' library (-lfetch).])
 127                         LIBFETCH_LIBS="-lfetch"
 128                         have_libfetch="yes"
 129                         LIBS_EXTRA="${LIBS_EXTRA} -lfetch"
 130                 ])
 131         ], [],[
 132         #include <stdio.h>
 133         #ifdef HAVE_SYS_PARAM_H
 134         #include <sys/param.h>
 135         #endif
 136         ])
 137         AC_SUBST(LIBFETCH_LIBS)
 138
 139         AS_IF([ test "x$have_libfetch" != "xyes"], [
 140                 dnl Fallback to libcurl
 141                 PKG_CHECK_MODULES([CURL], [libcurl], [
 142                         AC_DEFINE(CURL_FOUND, 1, [Use libcurl])
 143                         LIBS_EXTRA="${LIBS_EXTRA} -lcurl"],
 144                 [AC_MSG_ERROR([unable to find neither libfetch nor libcurl])])
 145         ])
 146         AC_SUBST(CURL_FOUND)
 147         AC_SUBST(CURL_LIBS)
 148         AC_SUBST(CURL_CFLAGS)
 149 ])
 150
 151 AC_SUBST(LIBS_EXTRA)
 152
 153 AC_MSG_CHECKING(for GCC atomic builtins)
 154 AC_LINK_IFELSE([
 155         AC_LANG_SOURCE([[
 156                 int main() {
 157                         volatile unsigned long val = 1;
 158                         __sync_synchronize();
 159                         __sync_val_compare_and_swap(&val, 1, 0);
 160                         __sync_add_and_fetch(&val, 1);
 161                         __sync_sub_and_fetch(&val, 1);
 162                         return 0;
 163                 }
 164         ]])
 165 ],
 166 [
 167         AC_MSG_RESULT([yes])
 168         AC_DEFINE([HAVE_ATOMIC_BUILTINS], [1], [Has gcc/MSVC atomic intrinsics])
 169 ],
 170 [
 171         AC_MSG_RESULT([no])
 172         AC_DEFINE([HAVE_ATOMIC_BUILTINS], [0], [Has gcc/MSVC atomic intrinsics])
 173         AC_MSG_WARN([Libucl references could be thread-unsafe because atomic builtins are missing])
 174 ])
 175
 176 AX_CODE_COVERAGE
 177
 178 AC_CONFIG_FILES(Makefile \
 179         src/Makefile \
 180         lua/Makefile
 181         tests/Makefile \
 182         utils/Makefile \
 183         doc/Makefile \
 184         lua/libucl.rockspec \
 185         libucl.pc)
 186 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 187 AC_OUTPUT