contrib/llvm/lib/Target/AArch64/AArch64CallingConvention.td

   1 //=- AArch64CallingConv.td - Calling Conventions for AArch64 -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for AArch64 architecture.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 /// CCIfAlign - Match of the original alignment of the arg
  15 class CCIfAlign<string Align, CCAction A> :
  16   CCIf<!strconcat("ArgFlags.getOrigAlign() == ", Align), A>;
  17 /// CCIfBigEndian - Match only if we're in big endian mode.
  18 class CCIfBigEndian<CCAction A> :
  19   CCIf<"State.getMachineFunction().getDataLayout().isBigEndian()", A>;
  20
  21 //===----------------------------------------------------------------------===//
  22 // ARM AAPCS64 Calling Convention
  23 //===----------------------------------------------------------------------===//
  24
  25 def CC_AArch64_AAPCS : CallingConv<[
  26   CCIfType<[iPTR], CCBitConvertToType<i64>>,
  27   CCIfType<[v2f32], CCBitConvertToType<v2i32>>,
  28   CCIfType<[v2f64, v4f32], CCBitConvertToType<v2i64>>,
  29
  30   // Big endian vectors must be passed as if they were 1-element vectors so that
  31   // their lanes are in a consistent order.
  32   CCIfBigEndian<CCIfType<[v2i32, v2f32, v4i16, v4f16, v8i8],
  33                          CCBitConvertToType<f64>>>,
  34   CCIfBigEndian<CCIfType<[v2i64, v2f64, v4i32, v4f32, v8i16, v8f16, v16i8],
  35                          CCBitConvertToType<f128>>>,
  36
  37   // An SRet is passed in X8, not X0 like a normal pointer parameter.
  38   CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[X8], [W8]>>>,
  39
  40   // Put ByVal arguments directly on the stack. Minimum size and alignment of a
  41   // slot is 64-bit.
  42   CCIfByVal<CCPassByVal<8, 8>>,
  43
  44   // The 'nest' parameter, if any, is passed in X18.
  45   // Darwin uses X18 as the platform register and hence 'nest' isn't currently
  46   // supported there.
  47   CCIfNest<CCAssignToReg<[X18]>>,
  48
  49   // Pass SwiftSelf in a callee saved register.
  50   CCIfSwiftSelf<CCIfType<[i64], CCAssignToRegWithShadow<[X20], [W20]>>>,
  51
  52   CCIfConsecutiveRegs<CCCustom<"CC_AArch64_Custom_Block">>,
  53
  54   // Handle i1, i8, i16, i32, i64, f32, f64 and v2f64 by passing in registers,
  55   // up to eight each of GPR and FPR.
  56   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
  57   CCIfType<[i32], CCAssignToRegWithShadow<[W0, W1, W2, W3, W4, W5, W6, W7],
  58                                           [X0, X1, X2, X3, X4, X5, X6, X7]>>,
  59   // i128 is split to two i64s, we can't fit half to register X7.
  60   CCIfType<[i64], CCIfSplit<CCAssignToRegWithShadow<[X0, X2, X4, X6],
  61                                                     [X0, X1, X3, X5]>>>,
  62
  63   // i128 is split to two i64s, and its stack alignment is 16 bytes.
  64   CCIfType<[i64], CCIfSplit<CCAssignToStackWithShadow<8, 16, [X7]>>>,
  65
  66   CCIfType<[i64], CCAssignToRegWithShadow<[X0, X1, X2, X3, X4, X5, X6, X7],
  67                                           [W0, W1, W2, W3, W4, W5, W6, W7]>>,
  68   CCIfType<[f16], CCAssignToRegWithShadow<[H0, H1, H2, H3, H4, H5, H6, H7],
  69                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
  70   CCIfType<[f32], CCAssignToRegWithShadow<[S0, S1, S2, S3, S4, S5, S6, S7],
  71                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
  72   CCIfType<[f64], CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
  73                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
  74   CCIfType<[v1i64, v2i32, v4i16, v8i8, v1f64, v2f32, v4f16],
  75            CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
  76                                    [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
  77   CCIfType<[f128, v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
  78            CCAssignToReg<[Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
  79
  80   // If more than will fit in registers, pass them on the stack instead.
  81   CCIfType<[i1, i8, i16, f16], CCAssignToStack<8, 8>>,
  82   CCIfType<[i32, f32], CCAssignToStack<8, 8>>,
  83   CCIfType<[i64, f64, v1f64, v2f32, v1i64, v2i32, v4i16, v8i8, v4f16],
  84            CCAssignToStack<8, 8>>,
  85   CCIfType<[f128, v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
  86            CCAssignToStack<16, 16>>
  87 ]>;
  88
  89 def RetCC_AArch64_AAPCS : CallingConv<[
  90   CCIfType<[iPTR], CCBitConvertToType<i64>>,
  91   CCIfType<[v2f32], CCBitConvertToType<v2i32>>,
  92   CCIfType<[v2f64, v4f32], CCBitConvertToType<v2i64>>,
  93
  94   CCIfSwiftError<CCIfType<[i64], CCAssignToRegWithShadow<[X19], [W19]>>>,
  95
  96   // Big endian vectors must be passed as if they were 1-element vectors so that
  97   // their lanes are in a consistent order.
  98   CCIfBigEndian<CCIfType<[v2i32, v2f32, v4i16, v4f16, v8i8],
  99                          CCBitConvertToType<f64>>>,
 100   CCIfBigEndian<CCIfType<[v2i64, v2f64, v4i32, v4f32, v8i16, v8f16, v16i8],
 101                          CCBitConvertToType<f128>>>,
 102
 103   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 104   CCIfType<[i32], CCAssignToRegWithShadow<[W0, W1, W2, W3, W4, W5, W6, W7],
 105                                           [X0, X1, X2, X3, X4, X5, X6, X7]>>,
 106   CCIfType<[i64], CCAssignToRegWithShadow<[X0, X1, X2, X3, X4, X5, X6, X7],
 107                                           [W0, W1, W2, W3, W4, W5, W6, W7]>>,
 108   CCIfType<[f16], CCAssignToRegWithShadow<[H0, H1, H2, H3, H4, H5, H6, H7],
 109                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 110   CCIfType<[f32], CCAssignToRegWithShadow<[S0, S1, S2, S3, S4, S5, S6, S7],
 111                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 112   CCIfType<[f64], CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
 113                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 114   CCIfType<[v1i64, v2i32, v4i16, v8i8, v1f64, v2f32, v4f16],
 115       CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
 116                               [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 117   CCIfType<[f128, v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
 118       CCAssignToReg<[Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>
 119 ]>;
 120
 121
 122 // Darwin uses a calling convention which differs in only two ways
 123 // from the standard one at this level:
 124 //     + i128s (i.e. split i64s) don't need even registers.
 125 //     + Stack slots are sized as needed rather than being at least 64-bit.
 126 def CC_AArch64_DarwinPCS : CallingConv<[
 127   CCIfType<[iPTR], CCBitConvertToType<i64>>,
 128   CCIfType<[v2f32], CCBitConvertToType<v2i32>>,
 129   CCIfType<[v2f64, v4f32, f128], CCBitConvertToType<v2i64>>,
 130
 131   // An SRet is passed in X8, not X0 like a normal pointer parameter.
 132   CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[X8], [W8]>>>,
 133
 134   // Put ByVal arguments directly on the stack. Minimum size and alignment of a
 135   // slot is 64-bit.
 136   CCIfByVal<CCPassByVal<8, 8>>,
 137
 138   // Pass SwiftSelf in a callee saved register.
 139   CCIfSwiftSelf<CCIfType<[i64], CCAssignToRegWithShadow<[X20], [W20]>>>,
 140
 141   // A SwiftError is passed in X19.
 142   CCIfSwiftError<CCIfType<[i64], CCAssignToRegWithShadow<[X19], [W19]>>>,
 143
 144   CCIfConsecutiveRegs<CCCustom<"CC_AArch64_Custom_Block">>,
 145
 146   // Handle i1, i8, i16, i32, i64, f32, f64 and v2f64 by passing in registers,
 147   // up to eight each of GPR and FPR.
 148   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 149   CCIfType<[i32], CCAssignToRegWithShadow<[W0, W1, W2, W3, W4, W5, W6, W7],
 150                                           [X0, X1, X2, X3, X4, X5, X6, X7]>>,
 151   // i128 is split to two i64s, we can't fit half to register X7.
 152   CCIfType<[i64],
 153            CCIfSplit<CCAssignToRegWithShadow<[X0, X1, X2, X3, X4, X5, X6],
 154                                              [W0, W1, W2, W3, W4, W5, W6]>>>,
 155   // i128 is split to two i64s, and its stack alignment is 16 bytes.
 156   CCIfType<[i64], CCIfSplit<CCAssignToStackWithShadow<8, 16, [X7]>>>,
 157
 158   CCIfType<[i64], CCAssignToRegWithShadow<[X0, X1, X2, X3, X4, X5, X6, X7],
 159                                           [W0, W1, W2, W3, W4, W5, W6, W7]>>,
 160   CCIfType<[f16], CCAssignToRegWithShadow<[H0, H1, H2, H3, H4, H5, H6, H7],
 161                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 162   CCIfType<[f32], CCAssignToRegWithShadow<[S0, S1, S2, S3, S4, S5, S6, S7],
 163                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 164   CCIfType<[f64], CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
 165                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 166   CCIfType<[v1i64, v2i32, v4i16, v8i8, v1f64, v2f32, v4f16],
 167            CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
 168                                    [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 169   CCIfType<[v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
 170            CCAssignToReg<[Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 171
 172   // If more than will fit in registers, pass them on the stack instead.
 173   CCIf<"ValVT == MVT::i1 || ValVT == MVT::i8", CCAssignToStack<1, 1>>,
 174   CCIf<"ValVT == MVT::i16 || ValVT == MVT::f16", CCAssignToStack<2, 2>>,
 175   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 176   CCIfType<[i64, f64, v1f64, v2f32, v1i64, v2i32, v4i16, v8i8, v4f16],
 177            CCAssignToStack<8, 8>>,
 178   CCIfType<[v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
 179            CCAssignToStack<16, 16>>
 180 ]>;
 181
 182 def CC_AArch64_DarwinPCS_VarArg : CallingConv<[
 183   CCIfType<[iPTR], CCBitConvertToType<i64>>,
 184   CCIfType<[v2f32], CCBitConvertToType<v2i32>>,
 185   CCIfType<[v2f64, v4f32, f128], CCBitConvertToType<v2i64>>,
 186
 187   CCIfConsecutiveRegs<CCCustom<"CC_AArch64_Custom_Stack_Block">>,
 188
 189   // Handle all scalar types as either i64 or f64.
 190   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 191   CCIfType<[f16, f32],     CCPromoteToType<f64>>,
 192
 193   // Everything is on the stack.
 194   // i128 is split to two i64s, and its stack alignment is 16 bytes.
 195   CCIfType<[i64], CCIfSplit<CCAssignToStack<8, 16>>>,
 196   CCIfType<[i64, f64, v1i64, v2i32, v4i16, v8i8, v1f64, v2f32, v4f16],
 197            CCAssignToStack<8, 8>>,
 198   CCIfType<[v2i64, v4i32, v8i16, v16i8, v4f32, v2f64, v8f16],
 199            CCAssignToStack<16, 16>>
 200 ]>;
 201
 202 // The WebKit_JS calling convention only passes the first argument (the callee)
 203 // in register and the remaining arguments on stack. We allow 32bit stack slots,
 204 // so that WebKit can write partial values in the stack and define the other
 205 // 32bit quantity as undef.
 206 def CC_AArch64_WebKit_JS : CallingConv<[
 207   // Handle i1, i8, i16, i32, and i64 passing in register X0 (W0).
 208   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 209   CCIfType<[i32], CCAssignToRegWithShadow<[W0], [X0]>>,
 210   CCIfType<[i64], CCAssignToRegWithShadow<[X0], [W0]>>,
 211
 212   // Pass the remaining arguments on the stack instead.
 213   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 214   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 215 ]>;
 216
 217 def RetCC_AArch64_WebKit_JS : CallingConv<[
 218   CCIfType<[i32], CCAssignToRegWithShadow<[W0, W1, W2, W3, W4, W5, W6, W7],
 219                                           [X0, X1, X2, X3, X4, X5, X6, X7]>>,
 220   CCIfType<[i64], CCAssignToRegWithShadow<[X0, X1, X2, X3, X4, X5, X6, X7],
 221                                           [W0, W1, W2, W3, W4, W5, W6, W7]>>,
 222   CCIfType<[f32], CCAssignToRegWithShadow<[S0, S1, S2, S3, S4, S5, S6, S7],
 223                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>,
 224   CCIfType<[f64], CCAssignToRegWithShadow<[D0, D1, D2, D3, D4, D5, D6, D7],
 225                                           [Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7]>>
 226 ]>;
 227
 228 //===----------------------------------------------------------------------===//
 229 // ARM64 Calling Convention for GHC
 230 //===----------------------------------------------------------------------===//
 231
 232 // This calling convention is specific to the Glasgow Haskell Compiler.
 233 // The only documentation is the GHC source code, specifically the C header
 234 // file:
 235 //
 236 //     https://github.com/ghc/ghc/blob/master/includes/stg/MachRegs.h
 237 //
 238 // which defines the registers for the Spineless Tagless G-Machine (STG) that
 239 // GHC uses to implement lazy evaluation. The generic STG machine has a set of
 240 // registers which are mapped to appropriate set of architecture specific
 241 // registers for each CPU architecture.
 242 //
 243 // The STG Machine is documented here:
 244 //
 245 //    https://ghc.haskell.org/trac/ghc/wiki/Commentary/Compiler/GeneratedCode
 246 //
 247 // The AArch64 register mapping is under the heading "The ARMv8/AArch64 ABI
 248 // register mapping".
 249
 250 def CC_AArch64_GHC : CallingConv<[
 251   CCIfType<[iPTR], CCBitConvertToType<i64>>,
 252
 253   // Handle all vector types as either f64 or v2f64.
 254   CCIfType<[v1i64, v2i32, v4i16, v8i8, v2f32], CCBitConvertToType<f64>>,
 255   CCIfType<[v2i64, v4i32, v8i16, v16i8, v4f32, f128], CCBitConvertToType<v2f64>>,
 256
 257   CCIfType<[v2f64], CCAssignToReg<[Q4, Q5]>>,
 258   CCIfType<[f32], CCAssignToReg<[S8, S9, S10, S11]>>,
 259   CCIfType<[f64], CCAssignToReg<[D12, D13, D14, D15]>>,
 260
 261   // Promote i8/i16/i32 arguments to i64.
 262   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 263
 264   // Pass in STG registers: Base, Sp, Hp, R1, R2, R3, R4, R5, R6, SpLim
 265   CCIfType<[i64], CCAssignToReg<[X19, X20, X21, X22, X23, X24, X25, X26, X27, X28]>>
 266 ]>;
 267
 268 // FIXME: LR is only callee-saved in the sense that *we* preserve it and are
 269 // presumably a callee to someone. External functions may not do so, but this
 270 // is currently safe since BL has LR as an implicit-def and what happens after a
 271 // tail call doesn't matter.
 272 //
 273 // It would be better to model its preservation semantics properly (create a
 274 // vreg on entry, use it in RET & tail call generation; make that vreg def if we
 275 // end up saving LR as part of a call frame). Watch this space...
 276 def CSR_AArch64_AAPCS : CalleeSavedRegs<(add LR, FP, X19, X20, X21, X22,
 277                                            X23, X24, X25, X26, X27, X28,
 278                                            D8,  D9,  D10, D11,
 279                                            D12, D13, D14, D15)>;
 280
 281 // Constructors and destructors return 'this' in the iOS 64-bit C++ ABI; since
 282 // 'this' and the pointer return value are both passed in X0 in these cases,
 283 // this can be partially modelled by treating X0 as a callee-saved register;
 284 // only the resulting RegMask is used; the SaveList is ignored
 285 //
 286 // (For generic ARM 64-bit ABI code, clang will not generate constructors or
 287 // destructors with 'this' returns, so this RegMask will not be used in that
 288 // case)
 289 def CSR_AArch64_AAPCS_ThisReturn : CalleeSavedRegs<(add CSR_AArch64_AAPCS, X0)>;
 290
 291 def CSR_AArch64_AAPCS_SwiftError
 292     : CalleeSavedRegs<(sub CSR_AArch64_AAPCS, X19)>;
 293
 294 // The function used by Darwin to obtain the address of a thread-local variable
 295 // guarantees more than a normal AAPCS function. x16 and x17 are used on the
 296 // fast path for calculation, but other registers except X0 (argument/return)
 297 // and LR (it is a call, after all) are preserved.
 298 def CSR_AArch64_TLS_Darwin
 299     : CalleeSavedRegs<(add (sub (sequence "X%u", 1, 28), X16, X17),
 300                            FP,
 301                            (sequence "Q%u", 0, 31))>;
 302
 303 // We can only handle a register pair with adjacent registers, the register pair
 304 // should belong to the same class as well. Since the access function on the
 305 // fast path calls a function that follows CSR_AArch64_TLS_Darwin,
 306 // CSR_AArch64_CXX_TLS_Darwin should be a subset of CSR_AArch64_TLS_Darwin.
 307 def CSR_AArch64_CXX_TLS_Darwin
 308     : CalleeSavedRegs<(add CSR_AArch64_AAPCS,
 309                            (sub (sequence "X%u", 1, 28), X15, X16, X17, X18),
 310                            (sequence "D%u", 0, 31))>;
 311
 312 // CSRs that are handled by prologue, epilogue.
 313 def CSR_AArch64_CXX_TLS_Darwin_PE
 314     : CalleeSavedRegs<(add LR, FP)>;
 315
 316 // CSRs that are handled explicitly via copies.
 317 def CSR_AArch64_CXX_TLS_Darwin_ViaCopy
 318     : CalleeSavedRegs<(sub CSR_AArch64_CXX_TLS_Darwin, LR, FP)>;
 319
 320 // The ELF stub used for TLS-descriptor access saves every feasible
 321 // register. Only X0 and LR are clobbered.
 322 def CSR_AArch64_TLS_ELF
 323     : CalleeSavedRegs<(add (sequence "X%u", 1, 28), FP,
 324                            (sequence "Q%u", 0, 31))>;
 325
 326 def CSR_AArch64_AllRegs
 327     : CalleeSavedRegs<(add (sequence "W%u", 0, 30), WSP,
 328                            (sequence "X%u", 0, 28), FP, LR, SP,
 329                            (sequence "B%u", 0, 31), (sequence "H%u", 0, 31),
 330                            (sequence "S%u", 0, 31), (sequence "D%u", 0, 31),
 331                            (sequence "Q%u", 0, 31))>;
 332
 333 def CSR_AArch64_NoRegs : CalleeSavedRegs<(add)>;
 334
 335 def CSR_AArch64_RT_MostRegs :  CalleeSavedRegs<(add CSR_AArch64_AAPCS,
 336                                                 (sequence "X%u", 9, 15))>;
 337