contrib/llvm/lib/Target/AArch64/AArch64SchedKryo.td

   1 //==- AArch64SchedKryo.td - Qualcomm Kryo Scheduling Defs ---*- tablegen -*-==//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the machine model for Qualcomm Kryo to support
  11 // instruction scheduling and other instruction cost heuristics.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // The issue width is set to five, matching the five issue queues for expanded
  17 // uops. Now, the latency spreadsheet has information based on fragmented uops,
  18 // but these do not actually take up an issue queue.
  19
  20 def KryoModel : SchedMachineModel {
  21   let IssueWidth        =   5; // 5-wide issue for expanded uops
  22   let MicroOpBufferSize = 128; // Out-of-order with temporary unified issue buffer
  23   let LoadLatency       =   4; // Optimistic load latency
  24   let MispredictPenalty =  14; // Fetch + Decode/Rename/Dispatch + Branch
  25
  26   // Enable partial & runtime unrolling. The magic number is chosen based on
  27   // experiments and benchmarking data.
  28   let LoopMicroOpBufferSize = 16;
  29   let CompleteModel = 1;
  30
  31   list<Predicate> UnsupportedFeatures = [HasSVE];
  32 }
  33
  34 //===----------------------------------------------------------------------===//
  35 // Define each kind of processor resource and number available on Kryo.
  36
  37 let SchedModel = KryoModel in {
  38   def KryoUnitXA : ProcResource<1>;                   // Type X(A) micro-ops
  39   def KryoUnitXB : ProcResource<1>;                   // Type X(B) micro-ops
  40   def KryoUnitYA : ProcResource<1>;                   // Type Y(A) micro-ops
  41   def KryoUnitYB : ProcResource<1>;                   // Type Y(B) micro-ops
  42   def KryoUnitX : ProcResGroup<[KryoUnitXA,          // Type X micro-ops
  43                                 KryoUnitXB]>;
  44   def KryoUnitY : ProcResGroup<[KryoUnitYA,          // Type Y micro-ops
  45                                 KryoUnitYB]>;
  46   def KryoUnitXY : ProcResGroup<[KryoUnitXA,         // Type XY micro-ops
  47                                  KryoUnitXB,
  48                                  KryoUnitYA,
  49                                  KryoUnitYB]>;
  50   def KryoUnitLSA : ProcResource<1>;                  // Type LS(A) micro-ops
  51   def KryoUnitLSB : ProcResource<1>;                  // Type LS(B) micro-ops
  52   def KryoUnitLS : ProcResGroup<[KryoUnitLSA,        // Type LS micro-ops
  53                                  KryoUnitLSB]>;
  54 }
  55
  56 let SchedModel = KryoModel in {
  57
  58 //===----------------------------------------------------------------------===//
  59 // Map the target-defined scheduler read/write resources and latency for
  60 // Kryo.
  61
  62 def : WriteRes<WriteImm,   [KryoUnitXY]> { let Latency = 1; }
  63 def : WriteRes<WriteI,     [KryoUnitXY]> { let Latency = 1; }
  64 def : WriteRes<WriteISReg, [KryoUnitXY, KryoUnitXY]>
  65       { let Latency = 2; let NumMicroOps = 2; }
  66 def : WriteRes<WriteIEReg, [KryoUnitXY, KryoUnitXY]>
  67       { let Latency = 2; let NumMicroOps = 2; }
  68 def : WriteRes<WriteExtr,  [KryoUnitXY, KryoUnitX]>
  69       { let Latency = 2; let NumMicroOps = 2; }
  70 def : WriteRes<WriteIS,    [KryoUnitXY]> { let Latency = 2; }
  71 def : WriteRes<WriteID32,  [KryoUnitXA, KryoUnitY]>
  72       { let Latency = 8; let NumMicroOps = 1; } // Fragent -1
  73 def : WriteRes<WriteID64,  [KryoUnitXA, KryoUnitY]>
  74       { let Latency = 8; let NumMicroOps = 1; } // Fragent -1
  75 def : WriteRes<WriteIM32,  [KryoUnitX]> { let Latency = 5; }
  76 def : WriteRes<WriteIM64,  [KryoUnitX]> { let Latency = 5; }
  77 def : WriteRes<WriteBr,    [KryoUnitXY]> { let Latency = 1; }
  78 def : WriteRes<WriteBrReg, [KryoUnitXY]> { let Latency = 1; }
  79 def : WriteRes<WriteLD,    [KryoUnitLS]> { let Latency = 4; }
  80 def : WriteRes<WriteST,    [KryoUnitLS]> { let Latency = 4; }
  81 def : WriteRes<WriteSTP,   [KryoUnitLS]> { let Latency = 4; }
  82 def : WriteRes<WriteAdr,   [KryoUnitXY]> { let Latency = 6; }
  83 def : WriteRes<WriteLDIdx, [KryoUnitLS]> { let Latency = 4; }
  84 def : WriteRes<WriteSTIdx, [KryoUnitLS]> { let Latency = 4; }
  85 def : WriteRes<WriteF,     [KryoUnitXY, KryoUnitXY]>
  86       { let Latency = 3; let NumMicroOps = 2; }
  87 def : WriteRes<WriteFCmp,  [KryoUnitXY]> { let Latency = 2; }
  88 def : WriteRes<WriteFCvt,  [KryoUnitX]> { let Latency = 4; }
  89 def : WriteRes<WriteFCopy, [KryoUnitXY]> { let Latency = 6; }
  90 def : WriteRes<WriteFImm,  [KryoUnitXY]> { let Latency = 6; }
  91 def : WriteRes<WriteFMul,  [KryoUnitX, KryoUnitX]>
  92       { let Latency = 6; let NumMicroOps = 2; }
  93 def : WriteRes<WriteFDiv,  [KryoUnitXA, KryoUnitY]>
  94       { let Latency = 12; let NumMicroOps = 2; } // Fragent -1 / NoRSV +1
  95 def : WriteRes<WriteV,     [KryoUnitXY]> { let Latency = 6; }
  96 def : WriteRes<WriteVLD,   [KryoUnitLS]> { let Latency = 4; }
  97 def : WriteRes<WriteVST,   [KryoUnitLS]> { let Latency = 4; }
  98
  99 def : WriteRes<WriteSys,     []> { let Latency = 1; }
 100 def : WriteRes<WriteBarrier, []> { let Latency = 1; }
 101 def : WriteRes<WriteHint,    []> { let Latency = 1; }
 102
 103 def : WriteRes<WriteLDHi,    []> { let Latency = 4; }
 104
 105 def : WriteRes<WriteAtomic, []> { let Unsupported = 1; }
 106
 107 // No forwarding logic is modelled yet.
 108 def : ReadAdvance<ReadI,       0>;
 109 def : ReadAdvance<ReadISReg,   0>;
 110 def : ReadAdvance<ReadIEReg,   0>;
 111 def : ReadAdvance<ReadIM,      0>;
 112 def : ReadAdvance<ReadIMA,     0>;
 113 def : ReadAdvance<ReadID,      0>;
 114 def : ReadAdvance<ReadExtrHi,  0>;
 115 def : ReadAdvance<ReadAdrBase, 0>;
 116 def : ReadAdvance<ReadVLD,     0>;
 117
 118
 119 //===----------------------------------------------------------------------===//
 120 // Specialize the coarse model by associating instruction groups with the
 121 // subtarget-defined types. As the modeled is refined, this will override most
 122 // of the above SchedWriteRes and SchedAlias mappings.
 123
 124 // Miscellaneous
 125 // -----------------------------------------------------------------------------
 126
 127 def : InstRW<[WriteI], (instrs COPY)>;
 128
 129
 130 // Detailed Refinedments
 131 // -----------------------------------------------------------------------------
 132 include "AArch64SchedKryoDetails.td"
 133
 134
 135 } // SchedModel = KryoModel